[DWARF] Inlined variables with no location should not have a DW_TAG_variable

[jmorse]

Summary

Discussed in this thread:

https://lists.llvm.org/pipermail/llvm-dev/2021-January/148139.html

DwarfDebug::collectEntityInfo accidentally distinguishes between variable locations that never have a location specified, and variable locations that have an empty location specified. The latter leads to the creation of an empty variable referring to the abstract origin:

DW_TAG_formal_parameter
    DW_AT_abstract_origin       (0x0000005a "bar")

Which is needless and potentially misleading. This patch makes collectEntityInfo behave the same way for both ways an empty variable can be represented, by only emitting a concrete variable if it actually has a location. The added test exercises this, and checks variables are created for "normal" functions too.

The NVPTX tests fail with this; this is because they were compiled to LLVM-IR before retainedNodes was correctly tracked, apparently. I've made the following changes to reflect changes in output:

• debug-addr-class.ll: Added the list of retained nodes to the input. This causes two types to shift position in the output for reasons I don't understand.
• debug-info.ll: The size of the unit changes because we cease emitting two parameters with abstract-origins as a result of this patch
• debug-loc-offset.ll: adding retainedNodes to this makes the abbrev numbering change, and one new variable to be emitted.

[djtodoro]

llvm/lib/CodeGen/AsmPrinter/DwarfDebug.cpp

1789–1800

Can we refactor this into a predicate function (according to the CodingStandards)?

1803

Are we covering inlined variables only with this?

[jmorse]

Shift "does this list have a location?" predicate into a function

[jmorse]

llvm/lib/CodeGen/AsmPrinter/DwarfDebug.cpp

1803

This filter covers everything -- otherwise we risk having some other distinction between inlined and non-inlined variables with no location IMO.

There's a loop at the bottom of this function to create concrete entities for non-inlined variables that weren't given a location, and back in endFunctionImpl there's a loop over all abstract scopes to ensure they get abstract entities created.

[djtodoro]

lgtm, thanks!

NOTE: I will try to address this in llvm-dwarfdump --stats/locstats as well (asap).

[jmorse]

I reverted this as a builtbot objected:

http://lab.llvm.org:8011/#builders/105/builds/5486

The failing test, missing-abstract-variable.ll, is a known bad behaver on certain platforms. In the past it's been XFailed on those platforms because certain inlined parameters get optimised out. That xfail was deleted after these two commits:

https://reviews.llvm.org/rGff2073a51fe283bde05f48c300e3a9ee807b1b6d
https://reviews.llvm.org/rG93faeecd8fa1fc148f2ee0d0cb64f11c3d41ce49

I believe the latter was allowing more DBG_VALUEs to pass through isel, which are then optimised out in this test. The behaviour that lets this test pass on (mips, powerpc64, s390x, sparc) is thus exactly the behaviour this patch is trying to disable, and it's fine to re-apply the XFail.

I'll leave this as re-opened but accepted for a ~day, I'm confident about the fix but wanted somewhere to write the explanation, plus leave a little time in case there's a wider view.

[dblaikie]

In D95617#2541646, @jmorse wrote:

I reverted this as a builtbot objected:

http://lab.llvm.org:8011/#builders/105/builds/5486

The failing test, missing-abstract-variable.ll, is a known bad behaver on certain platforms. In the past it's been XFailed on those platforms because certain inlined parameters get optimised out. That xfail was deleted after these two commits:

https://reviews.llvm.org/rGff2073a51fe283bde05f48c300e3a9ee807b1b6d
https://reviews.llvm.org/rG93faeecd8fa1fc148f2ee0d0cb64f11c3d41ce49

I believe the latter was allowing more DBG_VALUEs to pass through isel, which are then optimised out in this test. The behaviour that lets this test pass on (mips, powerpc64, s390x, sparc) is thus exactly the behaviour this patch is trying to disable, and it's fine to re-apply the XFail.

I'll leave this as re-opened but accepted for a ~day, I'm confident about the fix but wanted somewhere to write the explanation, plus leave a little time in case there's a wider view.

In a separate/preparatory commit, perhaps you could add checks that these inlined formal parameters have DW_AT_location. (& adding the xfail for the architectures that don't have locations on these variables/parameters)

& then this change won't have to touch that test, I think.

[MaskRay]

Reproduce: https://gist.github.com/MaskRay/4c67b29bb038d5a016260437c9e25a7a

# git revert -n 56fa34ae3570a34fd0f4c2cf1bfaf095da01a959 # revert the workaround
% cat run.sh 
#!/bin/sh -e
llc -split-dwarf-file x.dwo -filetype=obj $1 -o x.o
if llvm-dwarfdump -debug-gnu-pubnames x.o 2> log; then
  exit 1
fi
grep 'name lookup table at' log
% ./run.sh a.ll
error: name lookup table at offset 0x12cc has a terminator at offset 0x12da before the expected end at 0x12fd

[jmorse]

In D95617#2547069, @dblaikie wrote:

In a separate/preparatory commit, perhaps you could add checks that these inlined formal parameters have DW_AT_location. (& adding the xfail for the architectures that don't have locations on these variables/parameters)

& then this change won't have to touch that test, I think.

Added in e05c10380ce7, I'll leave it to soak for a bit, then put this patch back in.

In D95617#2547111, @MaskRay wrote:

Reproduce: https://gist.github.com/MaskRay/4c67b29bb038d5a016260437c9e25a7a

[...]

error: name lookup table at offset 0x12cc has a terminator at offset 0x12da before the expected end at 0x12fd

I think this was destined for D94976 (the _other_ dwarf patch of mine that's going in and out), I'll copy it there and start investigating, thanks for the reproducer.

[thakis]

Added in e05c10380ce7, I'll leave it to soak for a bit, then put this patch back in.

That change makes the test fail on arm (or at least on mac/arm): http://45.33.8.238/macm1/3175/step_10.txt Please take a look.

[jmorse]

Hi Nico,

In D95617#2550054, @thakis wrote:

That change makes the test fail on arm (or at least on mac/arm): http://45.33.8.238/macm1/3175/step_10.txt Please take a look.

I've rolled back the change; this is curious though, because it was passing on a 32-bit arm bot [0], and I added aarch64 to the list of XFails so would imagine that arm-macs would be caught by that. What triple does that bot target?

[0] http://lab.llvm.org:8011/#/builders/111/builds/1545 <--- note this has unrelated test failures

[thakis]

In D95617#2550717, @jmorse wrote:

Hi Nico,

In D95617#2550054, @thakis wrote:

That change makes the test fail on arm (or at least on mac/arm): http://45.33.8.238/macm1/3175/step_10.txt Please take a look.

I've rolled back the change; this is curious though, because it was passing on a 32-bit arm bot [0], and I added aarch64 to the list of XFails so would imagine that arm-macs would be caught by that. What triple does that bot target?

[0] http://lab.llvm.org:8011/#/builders/111/builds/1545 <--- note this has unrelated test failures

I won't be near my arm mac for a few more hours, but de1bca4b36deb2a405bed85f7a7c71c09ab3c586 suggests that the triple is arm64-apple.

[thakis]

I won't be near my arm mac for a few more hours, but de1bca4b36deb2a405bed85f7a7c71c09ab3c586 suggests that the triple is arm64-apple.

Here's what cmake prints when running it on an m1 mbp:

-- LLVM host triple: arm64-apple-darwin20.2.0
-- LLVM default target triple: arm64-apple-darwin20.2.0

[jmorse]

In D95617#2552257, @thakis wrote:

• LLVM host triple: arm64-apple-darwin20.2.0
• LLVM default target triple: arm64-apple-darwin20.2.0

Hmmmmm. I'll stick "arm64" into the XFail list when re-applying that patch, there's very little chance of the term "arm64" ever referring to another architecture. To state the obvious, it's not ideal that there are two names for the same architecture, but I'll move that discussion to the mailing list rather than code review.

[dblaikie]

Oh, interesting note I just realized in some other code I was investigating (for https://bugs.llvm.org/show_bug.cgi?id=49769 ) - this sort of change should be made for non-inline functions too. WEll, specifically non-inline functions that have an abstract origin.

eg:

void do_stuff();
__attribute__((always_inline)) void f1() {
  int i;
  do_stuff();
}
void f2() { f1(); }

$ clang++-tot -O1 test.cpp -g -c && llvm-dwarfdump-tot test.o
...
0x0000002a:   DW_TAG_subprogram
                DW_AT_low_pc    (0x0000000000000000)
                DW_AT_high_pc   (0x0000000000000008)
                DW_AT_frame_base        (DW_OP_reg7 RSP)
                DW_AT_GNU_all_call_sites        (true)
                DW_AT_abstract_origin   (0x0000005b "_Z2f1v")

0x0000003d:     DW_TAG_variable
                  DW_AT_abstract_origin (0x00000067 "i")

0x00000042:     DW_TAG_GNU_call_site
                  DW_AT_abstract_origin (0x00000050 "_Z8do_stuffv")
                  DW_AT_low_pc  (0x0000000000000006)

0x0000004f:     NULL

[ro]

no-empty-child-vars.ll FAILs on SPARC: the first

; CHECK:     DW_TAG_subprogram
; CHECK:       DW_AT_abstract_origin (0x{{[0-9a-f]*}} "foo")

is missing completely and both qux and croix lack DW_TAG_inlined_subroutine.

Any suggestion what to do about this?

Thanks.

[jmorse]

In D95617#3300552, @ro wrote:

no-empty-child-vars.ll FAILs on SPARC: the first

; CHECK:     DW_TAG_subprogram
; CHECK:       DW_AT_abstract_origin (0x{{[0-9a-f]*}} "foo")

is missing completely and both qux and croix lack DW_TAG_inlined_subroutine.

Any suggestion what to do about this?

Hi @ro,

I took a look at the DWARF produced when passing "-mtriple sparc--", to llc, which I've assumed is a good enough triple as it's replicated what you're describing. In the test, there's a single instruction with several inlining scopes:

%add.i = add nsw i32 %quux, 12, !dbg !33

The debug-info describes it as being from the "foo" function, inlined into croix, and that's what the test expects to be in the DWARF. However, sparc applies some optimisations to the add instruction which makes it disappear from the line tables, which stops the inlining information from appearing in the DWARF, hence the test failure.

The simplest and most straightforwards fix is to change the "!dbg !34" attachment on the IR "ret" instruction in croix to "!dbg !33", and repeat for the other two functions (!16 -> !15 in foo, !25 -> !24 in qux). That makes the test pass for me locally, and matches the intention of the check, which is to look at the DWARF that's emitted. The changes avoids relying on the add instruction appearing in the output, which sparc seems to optimise away.

Before taking that path though, could I ask whether the sparc line table is correct: I've no good understanding of what's going on on sparc (there are instruction bundles, I think?). At the end of compilation, the MIR looks like this:

RETL 8, implicit $o0, debug-location !29; test.c:2:16 @[ test.c:12:15 ] {
  $o0 = nsw ADDri killed $o0, 12, debug-location !29; test.c:2:16 @[ test.c:12:15 ]
}

Where the ADDri instruction has the correct location + inlining information attached to it. Looking at the line table produced, the ADDri instruction has it's location dropped, and it gets the line number from the RETL instruction. If that's expected and the correct behaviour for sparc, then we should alter the test, however if that ADDri is supposed to get the inlined line number then there's a bug somewhere else.

[dblaikie]

In D95617#3300552, @ro wrote:

no-empty-child-vars.ll FAILs on SPARC: the first

; CHECK:     DW_TAG_subprogram
; CHECK:       DW_AT_abstract_origin (0x{{[0-9a-f]*}} "foo")

is missing completely and both qux and croix lack DW_TAG_inlined_subroutine.

Any suggestion what to do about this?

Thanks.

Did the add instructions get somehow lost in Sparc? (like they got merged into the ret instruction somehow, or something in the Sparc backend transformed the add instructions and lost the debug locations along the way? Perhaps that could/should be fixed - but also, I think using call instructions rather than add instructions is more robust for this sort of testing (call to an opaque/declared-but-not-defined function is unlikely to get transformed in interesting ways or lose its debug location), so the test case could be changed to do that)

[ro]

In D95617#3305333, @dblaikie wrote:

Did the add instructions get somehow lost in Sparc? (like they got merged into the ret instruction somehow, or something in the Sparc backend transformed the add instructions and lost the debug locations along the way? Perhaps that could/should be fixed - but also, I think using call instructions rather than add instructions is more robust for this sort of testing (call to an opaque/declared-but-not-defined function is unlikely to get transformed in interesting ways or lose its debug location), so the test case could be changed to do that)

The add insns didn't get lost at all, but were placed in the delay slots of retl. Which reminded me: this seems to be yet another instance of Issue #46473.

[ro]

I just found the -disable-sparc-delay-filler option in llvm/lib/Target/Sparc/DelaySlotFiller.cpp. As expected, with it added to the llc invocation the unmodified test PASSes.

I wonder what the best way forward is: just XFAIL the test on SPARC as was done for other instances of Issue #46473, add that option as a workaround (it's silently ignored on non-SPARC targets), or go for the solution/workaround @jmorse suggested?

[ro]

I've now updated Issue #46473 for this failure and posted D120238 to XFAIL the test. I think that's the best solution for now and in line with what was done for the other affected testcases. This way, when/if the bug gets fixed, all affected tests start to XPASS and can be adjusted.

llvm/include/llvm/CodeGen/DbgEntityHistoryCalculator.h

bool startDbgValue(InlinedEntity Var, const MachineInstr &MI,
                      EntryIndex &NewIndex);
   EntryIndex startClobber(InlinedEntity Var, const MachineInstr &MI);
 
   Entry &getEntry(InlinedEntity Var, EntryIndex Index) {
     auto &Entries = VarEntries[Var];
     return Entries[Index];
   }
 
+  /// Test whether a vector of entries features any non-empty locations. It
+  /// could have no entries, or only DBG_VALUE $noreg entries.
+  bool hasNonEmptyLocation(const Entries &Entries) const;
+
   /// Drop location ranges which exist entirely outside each variable's scope.
   void trimLocationRanges(const MachineFunction &MF, LexicalScopes &LScopes,
                           const InstructionOrdering &Ordering);
   bool empty() const { return VarEntries.empty(); }
   void clear() { VarEntries.clear(); }
   EntriesMap::const_iterator begin() const { return VarEntries.begin(); }
   EntriesMap::const_iterator end() const { return VarEntries.end(); }
 

llvm/lib/CodeGen/AsmPrinter/DbgEntityHistoryCalculator.cpp

for (auto &Record : VarEntries) {
 
     // Now actually remove the entries. Iterate backwards so that our remaining
     // ToRemove indices are valid after each erase.
     for (auto Itr = ToRemove.rbegin(), End = ToRemove.rend(); Itr != End; ++Itr)
       HistoryMapEntries.erase(HistoryMapEntries.begin() + *Itr);
   }
 }
 
+bool DbgValueHistoryMap::hasNonEmptyLocation(const Entries &Entries) const {
+  for (const auto &Entry : Entries) {
+    if (!Entry.isDbgValue())
+      continue;
+
+    const MachineInstr *MI = Entry.getInstr();
+    assert(MI->isDebugValue());
+    // A DBG_VALUE $noreg is an empty variable location
+    if (MI->getOperand(0).isReg() && MI->getOperand(0).getReg() == 0)
+      continue;
+
+    return true;
+  }
+
+  return false;
+}
+
 void DbgLabelInstrMap::addInstr(InlinedEntity Label, const MachineInstr &MI) {
   assert(MI.isDebugLabel() && "not a DBG_LABEL");
   LabelInstr[Label] = &MI;
 }
 
 namespace {
 
 // Maps physreg numbers to the variables they describe.

llvm/lib/CodeGen/AsmPrinter/DwarfDebug.cpp

void DwarfDebug::collectEntityInfo(DwarfCompileUnit &TheCU,
 
   for (const auto &I : DbgValues) {
     InlinedEntity IV = I.first;
     if (Processed.count(IV))
       continue;
 
     // Instruction ranges, specifying where IV is accessible.
     const auto &HistoryMapEntries = I.second;
-    if (HistoryMapEntries.empty())
+
+    // Try to find any non-empty variable location. Do not create a concrete
+    // entity if there are no locations.
+    if (!DbgValues.hasNonEmptyLocation(HistoryMapEntries))
       continue;
 
     LexicalScope *Scope = nullptr;
     const DILocalVariable *LocalVar = cast<DILocalVariable>(IV.first);
     if (const DILocation *IA = IV.second)
       Scope = LScopes.findInlinedScope(LocalVar->getScope(), IA);
     else
       Scope = LScopes.findLexicalScope(LocalVar->getScope());
     // If variable scope is not found then skip this variable.
     if (!Scope)
       continue;
 
     Processed.insert(IV);
     DbgVariable *RegVar = cast<DbgVariable>(createConcreteEntity(TheCU,
                                             *Scope, LocalVar, IV.second));
 
     const MachineInstr *MInsn = HistoryMapEntries.front().getInstr();
     assert(MInsn->isDebugValue() && "History must begin with debug value");
 
     // Check if there is a single DBG_VALUE, valid throughout the var's scope.
     // If the history map contains a single debug value, there may be an
     // additional entry which clobbers the debug value.

llvm/test/DebugInfo/Generic/no-empty-child-vars.ll

+; RUN: %llc_dwarf %s -o - -filetype=obj | llvm-dwarfdump - | FileCheck %s -implicit-check-not=DW_TAG
+;
+; This tests that we do not create concrete variable DIEs for variables that
+; have no location -- for both ways that LLVM-IR can express a variable with
+; no location. It's possible to:
+;   1) Omit all dbg.values and place the variable in the subprograms retained
+;      nodes list,
+;   2) Have a dbg.value with an undef operand, and none with "real" operands.
+; Both of these should produce the same DWARF. In the two functions below
+; (qux and croix) I've modified the IR to represent both scenarios.
+;
+; Original C, LLVM-IR modified afterwards:
+;
+; int foo(int bar) {
+;   int baz = 12 + bar;
+;   return baz;
+; }
+;
+; int qux(int quux) {
+;   int xyzzy = foo(quux);
+;   return xyzzy;
+; }
+;
+; int croix(int quux) {
+;   int xyzzy = foo(quux);
+;   return xyzzy;
+; }
+;
+;; Note the implicit DW_TAG check-not in the FileCheck command line.
+; CHECK: DW_TAG_compile_unit
+;;
+;; First subprogram is attached to the plain "foo" function in the output
+;; object. It should have locations for the two variables in the function,
+;; let's be non-specific as to how.
+; CHECK:     DW_TAG_subprogram
+; CHECK:       DW_AT_abstract_origin (0x{{[0-9a-f]*}} "foo")
+; CHECK:       DW_TAG_formal_parameter
+; CHECK:         DW_AT_location
+; CHECK:       DW_TAG_variable
+; CHECK:         DW_AT_location
+;
+;; Abstract subprogram; should have plain variable declarations
+; CHECK:     DW_TAG_subprogram
+; CHECK:       DW_AT_name ("foo")
+; CHECK:       DW_TAG_formal_parameter
+; CHECK:         DW_AT_name ("bar")
+; CHECK:       DW_TAG_variable
+; CHECK:         DW_AT_name ("baz")
+;
+; CHECK:     DW_TAG_base_type
+;
+;; The copy of "foo" inlined into "qux" should have no children.
+; CHECK:     DW_TAG_subprogram
+; CHECK:       DW_AT_name ("qux")
+; CHECK:       DW_TAG_formal_parameter
+; CHECK:       DW_TAG_variable
+; CHECK:       DW_TAG_inlined_subroutine
+; CHECK:     NULL
+;
+;; Same for the copy of foo inlined into "croix"
+; CHECK:     DW_TAG_subprogram
+; CHECK:       DW_AT_name ("croix")
+; CHECK:       DW_TAG_formal_parameter
+; CHECK:       DW_TAG_variable
+; CHECK:       DW_TAG_inlined_subroutine
+; CHECK:     NULL
+
+; Function Attrs: norecurse nounwind readnone uwtable willreturn
+define dso_local i32 @foo(i32 %bar) local_unnamed_addr !dbg !7 {
+entry:
+  call void @llvm.dbg.value(metadata i32 %bar, metadata !12, metadata !DIExpression()), !dbg !14
+  %add = add nsw i32 %bar, 12, !dbg !15
+  call void @llvm.dbg.value(metadata i32 %add, metadata !13, metadata !DIExpression()), !dbg !14
+  ret i32 %add, !dbg !16
+}
+
+; Function Attrs: norecurse nounwind readnone uwtable willreturn
+define dso_local i32 @qux(i32 %quux) local_unnamed_addr !dbg !17 {
+entry:
+  %add.i = add nsw i32 %quux, 12, !dbg !24
+  ret i32 %add.i, !dbg !25
+}
+
+; Function Attrs: norecurse nounwind readnone uwtable willreturn
+define dso_local i32 @croix(i32 %quux) local_unnamed_addr !dbg !26 {
+entry:
+  call void @llvm.dbg.value(metadata i32 undef, metadata !28, metadata !DIExpression()), !dbg !30
+  call void @llvm.dbg.value(metadata i32 undef, metadata !12, metadata !DIExpression()), !dbg !31
+  %add.i = add nsw i32 %quux, 12, !dbg !33
+  call void @llvm.dbg.value(metadata i32 undef, metadata !13, metadata !DIExpression()), !dbg !31
+  call void @llvm.dbg.value(metadata i32 undef, metadata !29, metadata !DIExpression()), !dbg !30
+  ret i32 %add.i, !dbg !34
+}
+
+; Function Attrs: nofree nosync nounwind readnone speculatable willreturn
+declare void @llvm.dbg.value(metadata, metadata, metadata)
+
+!llvm.dbg.cu = !{!0}
+!llvm.module.flags = !{!3, !4, !5}
+!llvm.ident = !{!6}
+
+!0 = distinct !DICompileUnit(language: DW_LANG_C99, file: !1, producer: "clang", isOptimized: true, runtimeVersion: 0, emissionKind: FullDebug, enums: !2, splitDebugInlining: false, nameTableKind: None)
+!1 = !DIFile(filename: "test.c", directory: ".")
+!2 = !{}
+!3 = !{i32 7, !"Dwarf Version", i32 4}
+!4 = !{i32 2, !"Debug Info Version", i32 3}
+!5 = !{i32 1, !"wchar_size", i32 4}
+!6 = !{!"clang"}
+!7 = distinct !DISubprogram(name: "foo", scope: !1, file: !1, line: 1, type: !8, scopeLine: 1, flags: DIFlagPrototyped | DIFlagAllCallsDescribed, spFlags: DISPFlagDefinition | DISPFlagOptimized, unit: !0, retainedNodes: !11)
+!8 = !DISubroutineType(types: !9)
+!9 = !{!10, !10}
+!10 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
+!11 = !{!12, !13}
+!12 = !DILocalVariable(name: "bar", arg: 1, scope: !7, file: !1, line: 1, type: !10)
+!13 = !DILocalVariable(name: "baz", scope: !7, file: !1, line: 2, type: !10)
+!14 = !DILocation(line: 0, scope: !7)
+!15 = !DILocation(line: 2, column: 16, scope: !7)
+!16 = !DILocation(line: 3, column: 3, scope: !7)
+!17 = distinct !DISubprogram(name: "qux", scope: !1, file: !1, line: 6, type: !8, scopeLine: 6, flags: DIFlagPrototyped | DIFlagAllCallsDescribed, spFlags: DISPFlagDefinition | DISPFlagOptimized, unit: !0, retainedNodes: !18)
+!18 = !{!19, !20}
+!19 = !DILocalVariable(name: "quux", arg: 1, scope: !17, file: !1, line: 6, type: !10)
+!20 = !DILocalVariable(name: "xyzzy", scope: !17, file: !1, line: 7, type: !10)
+!21 = !DILocation(line: 0, scope: !17)
+!22 = !DILocation(line: 0, scope: !7, inlinedAt: !23)
+!23 = distinct !DILocation(line: 7, column: 15, scope: !17)
+!24 = !DILocation(line: 2, column: 16, scope: !7, inlinedAt: !23)
+!25 = !DILocation(line: 8, column: 3, scope: !17)
+!26 = distinct !DISubprogram(name: "croix", scope: !1, file: !1, line: 11, type: !8, scopeLine: 11, flags: DIFlagPrototyped | DIFlagAllCallsDescribed, spFlags: DISPFlagDefinition | DISPFlagOptimized, unit: !0, retainedNodes: !27)
+!27 = !{!28, !29}
+!28 = !DILocalVariable(name: "quux", arg: 1, scope: !26, file: !1, line: 11, type: !10)
+!29 = !DILocalVariable(name: "xyzzy", scope: !26, file: !1, line: 12, type: !10)
+!30 = !DILocation(line: 0, scope: !26)
+!31 = !DILocation(line: 0, scope: !7, inlinedAt: !32)
+!32 = distinct !DILocation(line: 12, column: 15, scope: !26)
+!33 = !DILocation(line: 2, column: 16, scope: !7, inlinedAt: !32)
+!34 = !DILocation(line: 13, column: 3, scope: !26)

llvm/test/DebugInfo/NVPTX/debug-addr-class.ll

 !9 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
 !10 = !{void (float, float*, float*, i32)* @test, !"kernel", i32 1}
 !11 = !{i32 2, !"Dwarf Version", i32 2}
 !12 = !{i32 2, !"Debug Info Version", i32 3}
 !13 = !{i32 1, !"wchar_size", i32 4}
 !14 = !{i32 4, !"nvvm-reflect-ftz", i32 0}
 !15 = !{i32 7, !"PIC Level", i32 2}
 !16 = !{!"clang version 9.0.0 (trunk 351969) (llvm/trunk 351973)"}
-!17 = distinct !DISubprogram(name: "test", linkageName: "test", scope: !8, file: !8, line: 6, type: !18, scopeLine: 6, flags: DIFlagPrototyped, spFlags: DISPFlagDefinition, unit: !2, retainedNodes: !4)
+!17 = distinct !DISubprogram(name: "test", linkageName: "test", scope: !8, file: !8, line: 6, type: !18, scopeLine: 6, flags: DIFlagPrototyped, spFlags: DISPFlagDefinition, unit: !2, retainedNodes: !40)
 !18 = !DISubroutineType(types: !19)
 !19 = !{null, !20, !21, !21, !9}
 !20 = !DIBasicType(name: "float", size: 32, encoding: DW_ATE_float)
 !21 = !DIDerivedType(tag: DW_TAG_pointer_type, baseType: !20, size: 64)
 !22 = !DILocalVariable(name: "a", arg: 1, scope: !17, file: !8, line: 6, type: !20)
 !23 = !DILocation(line: 6, column: 41, scope: !17)
 !24 = !DILocalVariable(name: "x", arg: 2, scope: !17, file: !8, line: 6, type: !21)
 !25 = !DILocation(line: 6, column: 51, scope: !17)
 !26 = !DILocalVariable(name: "y", arg: 3, scope: !17, file: !8, line: 6, type: !21)
 !27 = !DILocation(line: 6, column: 61, scope: !17)
 !28 = !DILocalVariable(name: "i", arg: 4, scope: !17, file: !8, line: 6, type: !9)
 !29 = !DILocation(line: 6, column: 68, scope: !17)
 !30 = !DILocation(line: 7, column: 10, scope: !17)
 !31 = !DILocation(line: 7, column: 14, scope: !17)
 !32 = !DILocation(line: 7, column: 16, scope: !17)
 !33 = !DILocation(line: 7, column: 12, scope: !17)
 !34 = !DILocation(line: 7, column: 3, scope: !17)
 !35 = !DILocation(line: 7, column: 5, scope: !17)
 !36 = !DILocation(line: 7, column: 8, scope: !17)
 !37 = !DILocation(line: 8, column: 10, scope: !17)
 !38 = !DILocation(line: 9, column: 10, scope: !17)
 !39 = !DILocation(line: 10, column: 1, scope: !17)
+!40 = !{!22, !24, !26, !28}
 
 ; CHECK:        .section        .debug_abbrev
 ; CHECK-NEXT:        {
 ; CHECK-NEXT:.b8 1                                   // Abbreviation Code
 ; CHECK-NEXT:.b8 17                                  // DW_TAG_compile_unit
 ; CHECK-NEXT:.b8 1                                   // DW_CHILDREN_yes
 ; CHECK-NEXT:.b8 37                                  // DW_AT_producer
 ; CHECK-NEXT:.b8 8                                   // DW_FORM_string

 ; CHECK-NEXT:.b8 1                                   // DW_AT_decl_file
 ; CHECK-NEXT:.b8 6                                   // DW_AT_decl_line
 ; CHECK-NEXT:.b8 1                                   // DW_AT_external
 ; CHECK-NEXT:.b8 5                                   // Abbrev [5] 0xc0:0x9 DW_TAG_formal_parameter
 ; CHECK-NEXT:.b8 97                                  // DW_AT_name
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b8 1                                   // DW_AT_decl_file
 ; CHECK-NEXT:.b8 6                                   // DW_AT_decl_line
-; CHECK-NEXT:.b32 234                                // DW_AT_type
+; CHECK-NEXT:.b32 229                                // DW_AT_type
 ; CHECK-NEXT:.b8 5                                   // Abbrev [5] 0xc9:0x9 DW_TAG_formal_parameter
 ; CHECK-NEXT:.b8 120                                 // DW_AT_name
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b8 1                                   // DW_AT_decl_file
 ; CHECK-NEXT:.b8 6                                   // DW_AT_decl_line
-; CHECK-NEXT:.b32 229                                // DW_AT_type
+; CHECK-NEXT:.b32 238                                // DW_AT_type
 ; CHECK-NEXT:.b8 5                                   // Abbrev [5] 0xd2:0x9 DW_TAG_formal_parameter
 ; CHECK-NEXT:.b8 121                                 // DW_AT_name
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b8 1                                   // DW_AT_decl_file
 ; CHECK-NEXT:.b8 6                                   // DW_AT_decl_line
-; CHECK-NEXT:.b32 229                                // DW_AT_type
+; CHECK-NEXT:.b32 238                                // DW_AT_type
 ; CHECK-NEXT:.b8 5                                   // Abbrev [5] 0xdb:0x9 DW_TAG_formal_parameter
 ; CHECK-NEXT:.b8 105                                 // DW_AT_name
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b8 1                                   // DW_AT_decl_file
 ; CHECK-NEXT:.b8 6                                   // DW_AT_decl_line
 ; CHECK-NEXT:.b32 127                                // DW_AT_type
 ; CHECK-NEXT:.b8 0                                   // End Of Children Mark
-; CHECK-NEXT:.b8 6                                   // Abbrev [6] 0xe5:0x5 DW_TAG_pointer_type
-; CHECK-NEXT:.b32 234                                // DW_AT_type
-; CHECK-NEXT:.b8 3                                   // Abbrev [3] 0xea:0x9 DW_TAG_base_type
+; CHECK-NEXT:.b8 3                                   // Abbrev [3] 0xe5:0x9 DW_TAG_base_type
 ; CHECK-NEXT:.b8 102                                 // DW_AT_name
 ; CHECK-NEXT:.b8 108
 ; CHECK-NEXT:.b8 111
 ; CHECK-NEXT:.b8 97
 ; CHECK-NEXT:.b8 116
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b8 4                                   // DW_AT_encoding
 ; CHECK-NEXT:.b8 4                                   // DW_AT_byte_size
+; CHECK-NEXT:.b8 6                                   // Abbrev [6] 0xee:0x5 DW_TAG_pointer_type
+; CHECK-NEXT:.b32 229                                // DW_AT_type
 ; CHECK-NEXT:.b8 0                                   // End Of Children Mark
 ; CHECK-NEXT:        }
 ; CHECK-NEXT:         .section        .debug_loc      {       }
 ; CHECK-NOT: debug_

llvm/test/DebugInfo/NVPTX/debug-info.ll

 ; CHECK-NEXT:.b8 49                                  // DW_AT_abstract_origin
 ; CHECK-NEXT:.b8 19                                  // DW_FORM_ref4
 ; CHECK-NEXT:.b8 0                                   // EOM(1)
 ; CHECK-NEXT:.b8 0                                   // EOM(2)
 ; CHECK-NEXT:.b8 0                                   // EOM(3)
 ; CHECK-NEXT: }
 ; CHECK-NEXT: .section  .debug_info
 ; CHECK-NEXT: {
-; CHECK-NEXT:.b32 10039                              // Length of Unit
+; CHECK-NEXT:.b32 10029                              // Length of Unit
 ; CHECK-NEXT:.b8 2                                   // DWARF version number
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b32 .debug_abbrev                      // Offset Into Abbrev. Section
 ; CHECK-NEXT:.b8 8                                   // Address Size (in bytes)
-; CHECK-NEXT:.b8 1                                   // Abbrev [1] 0xb:0x2730 DW_TAG_compile_unit
+; CHECK-NEXT:.b8 1                                   // Abbrev [1] 0xb:0x2726 DW_TAG_compile_unit
 ; CHECK-NEXT:.b8 0                                   // DW_AT_producer
 ; CHECK-NEXT:.b8 4                                   // DW_AT_language
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b8 100                                 // DW_AT_name
 ; CHECK-NEXT:.b8 101
 ; CHECK-NEXT:.b8 98
 ; CHECK-NEXT:.b8 117
 ; CHECK-NEXT:.b8 103

 ; CHECK-NEXT:.b8 114                                 // DW_AT_name
 ; CHECK-NEXT:.b8 101
 ; CHECK-NEXT:.b8 115
 ; CHECK-NEXT:.b8 0
 ; CHECK-NEXT:.b8 12                                  // DW_AT_decl_file
 ; CHECK-NEXT:.b8 3                                   // DW_AT_decl_line
 ; CHECK-NEXT:.b32 3345                               // DW_AT_type
 ; CHECK-NEXT:.b8 0                                   // End Of Children Mark
-; CHECK-NEXT:.b8 40                                  // Abbrev [40] 0x2671:0xc9 DW_TAG_subprogram
+; CHECK-NEXT:.b8 40                                  // Abbrev [40] 0x2671:0xbf DW_TAG_subprogram
 ; CHECK-NEXT:.b64 Lfunc_begin0                       // DW_AT_low_pc
 ; CHECK-NEXT:.b64 Lfunc_end0                         // DW_AT_high_pc
 ; CHECK-NEXT:.b8 1                                   // DW_AT_frame_base
 ; CHECK-NEXT:.b8 156
 ; CHECK-NEXT:.b8 95                                  // DW_AT_MIPS_linkage_name
 ; CHECK-NEXT:.b8 90
 ; CHECK-NEXT:.b8 53
 ; CHECK-NEXT:.b8 115

 ; CHECK-NEXT:.b8 24                                  // DW_AT_call_column
 ; CHECK-NEXT:.b8 42                                  // Abbrev [42] 0x26f9:0x18 DW_TAG_inlined_subroutine
 ; CHECK-NEXT:.b32 9785                               // DW_AT_abstract_origin
 ; CHECK-NEXT:.b64 Ltmp2                              // DW_AT_low_pc
 ; CHECK-NEXT:.b64 Ltmp3                              // DW_AT_high_pc
 ; CHECK-NEXT:.b8 12                                  // DW_AT_call_file
 ; CHECK-NEXT:.b8 6                                   // DW_AT_call_line
 ; CHECK-NEXT:.b8 37                                  // DW_AT_call_column
-; CHECK-NEXT:.b8 43                                  // Abbrev [43] 0x2711:0x28 DW_TAG_inlined_subroutine
+; CHECK-NEXT:.b8 43                                  // Abbrev [43] 0x2711:0x1e DW_TAG_inlined_subroutine
 ; CHECK-NEXT:.b32 9791                               // DW_AT_abstract_origin
 ; CHECK-NEXT:.b64 Ltmp9                              // DW_AT_low_pc
 ; CHECK-NEXT:.b64 Ltmp10                             // DW_AT_high_pc
 ; CHECK-NEXT:.b8 12                                  // DW_AT_call_file
 ; CHECK-NEXT:.b8 8                                   // DW_AT_call_line
 ; CHECK-NEXT:.b8 5                                   // DW_AT_call_column
 ; CHECK-NEXT:.b8 44                                  // Abbrev [44] 0x2729:0x5 DW_TAG_formal_parameter
-; CHECK-NEXT:.b32 9811                               // DW_AT_abstract_origin
-; CHECK-NEXT:.b8 44                                  // Abbrev [44] 0x272e:0x5 DW_TAG_formal_parameter
 ; CHECK-NEXT:.b32 9820                               // DW_AT_abstract_origin
-; CHECK-NEXT:.b8 44                                  // Abbrev [44] 0x2733:0x5 DW_TAG_formal_parameter
-; CHECK-NEXT:.b32 9829                               // DW_AT_abstract_origin
 ; CHECK-NEXT:.b8 0                                   // End Of Children Mark
 ; CHECK-NEXT:.b8 0                                   // End Of Children Mark
 ; CHECK-NEXT:.b8 0                                   // End Of Children Mark
 ; CHECK-NEXT: }
 ; CHECK-NEXT: .section  .debug_loc  { }
 ; CHECK-NOT: debug_
 
 ; Function Attrs: nounwind readnone

llvm/test/DebugInfo/NVPTX/debug-loc-offset.ll

 
 !llvm.dbg.cu = !{!0, !9}
 !llvm.module.flags = !{!18, !19}
 !llvm.ident = !{!20, !20}
 
 !0 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus, producer: "clang version 3.5.0 (210479)", isOptimized: false, emissionKind: FullDebug, file: !1, enums: !2, retainedTypes: !2, globals: !2, imports: !2, nameTableKind: None)
 !1 = !DIFile(filename: "debug-loc-offset1.cc", directory: "/llvm_cmake_gcc")
 !2 = !{}
-!4 = distinct !DISubprogram(name: "bar", linkageName: "_Z3bari", line: 1, isLocal: false, isDefinition: true, virtualIndex: 6, flags: DIFlagPrototyped, isOptimized: false, unit: !0, scopeLine: 1, file: !1, scope: !5, type: !6, retainedNodes: !2)
+!4 = distinct !DISubprogram(name: "bar", linkageName: "_Z3bari", line: 1, isLocal: false, isDefinition: true, virtualIndex: 6, flags: DIFlagPrototyped, isOptimized: false, unit: !0, scopeLine: 1, file: !1, scope: !5, type: !6, retainedNodes: !35)
 !5 = !DIFile(filename: "debug-loc-offset1.cc", directory: "/llvm_cmake_gcc")
 !6 = !DISubroutineType(types: !7)
 !7 = !{!8, !8}
 !8 = !DIBasicType(tag: DW_TAG_base_type, name: "int", size: 32, align: 32, encoding: DW_ATE_signed)
 !9 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus, producer: "clang version 3.5.0 (210479)", isOptimized: false, emissionKind: FullDebug, file: !10, enums: !2, retainedTypes: !11, globals: !2, imports: !2, nameTableKind: None)
 !10 = !DIFile(filename: "debug-loc-offset2.cc", directory: "/llvm_cmake_gcc")
 !11 = !{!12}
 !12 = !DICompositeType(tag: DW_TAG_structure_type, name: "A", line: 1, flags: DIFlagFwdDecl, file: !10, identifier: "_ZTS1A")
-!14 = distinct !DISubprogram(name: "baz", linkageName: "_Z3baz1A", line: 6, isLocal: false, isDefinition: true, virtualIndex: 6, flags: DIFlagPrototyped, isOptimized: false, unit: !9, scopeLine: 6, file: !10, scope: !15, type: !16, retainedNodes: !2)
+!14 = distinct !DISubprogram(name: "baz", linkageName: "_Z3baz1A", line: 6, isLocal: false, isDefinition: true, virtualIndex: 6, flags: DIFlagPrototyped, isOptimized: false, unit: !9, scopeLine: 6, file: !10, scope: !15, type: !16, retainedNodes: !36)
 !15 = !DIFile(filename: "debug-loc-offset2.cc", directory: "/llvm_cmake_gcc")
 !16 = !DISubroutineType(types: !17)
 !17 = !{null, !12}
 !18 = !{i32 2, !"Dwarf Version", i32 4}
 !19 = !{i32 2, !"Debug Info Version", i32 3}
 !20 = !{!"clang version 3.5.0 (210479)"}
 !21 = !DILocalVariable(name: "b", line: 1, arg: 1, scope: !4, file: !5, type: !8)
 !22 = !DILocation(line: 1, scope: !4)
 !23 = !DILocation(line: 2, scope: !4)
 !24 = !DILocalVariable(name: "a", line: 6, arg: 1, scope: !14, file: !15, type: !12)
 !25 = !DILocation(line: 6, scope: !14)
 !26 = !DILocalVariable(name: "z", line: 7, scope: !14, file: !15, type: !8)
 !27 = !DILocation(line: 7, scope: !14)
 !28 = !DILocation(line: 8, scope: !29)
 !29 = distinct !DILexicalBlock(line: 8, column: 0, file: !10, scope: !14)
 !30 = !DILocation(line: 9, scope: !29)
 !31 = !DILocation(line: 10, scope: !32)
 !32 = distinct !DILexicalBlock(line: 10, column: 0, file: !10, scope: !14)
 !33 = !DILocation(line: 11, scope: !32)
 !34 = !DILocation(line: 12, scope: !14)
+!35 = !{!21}
+!36 = !{!24, !26}
 
 ; CHECK: .section .debug_abbrev
 ; CHECK-NEXT: {
 ; CHECK-NEXT: .b8 1                                // Abbreviation Code
 ; CHECK-NEXT: .b8 17                               // DW_TAG_compile_unit
 ; CHECK-NEXT: .b8 1                                // DW_CHILDREN_yes
 ; CHECK-NEXT: .b8 37                               // DW_AT_producer
 ; CHECK-NEXT: .b8 8                                // DW_FORM_string

 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 59                               // DW_AT_decl_line
 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 63                               // DW_AT_external
 ; CHECK-NEXT: .b8 12                               // DW_FORM_flag
 ; CHECK-NEXT: .b8 0                                // EOM(1)
 ; CHECK-NEXT: .b8 0                                // EOM(2)
 ; CHECK-NEXT: .b8 4                                // Abbreviation Code
+; CHECK-NEXT: .b8 5                                // DW_TAG_formal_parameter
+; CHECK-NEXT: .b8 0                                // DW_CHILDREN_no
+; CHECK-NEXT: .b8 3                                // DW_AT_name
+; CHECK-NEXT: .b8 8                                // DW_FORM_string
+; CHECK-NEXT: .b8 58                               // DW_AT_decl_file
+; CHECK-NEXT: .b8 11                               // DW_FORM_data1
+; CHECK-NEXT: .b8 59                               // DW_AT_decl_line
+; CHECK-NEXT: .b8 11                               // DW_FORM_data1
+; CHECK-NEXT: .b8 73                               // DW_AT_type
+; CHECK-NEXT: .b8 19                               // DW_FORM_ref4
+; CHECK-NEXT: .b8 0                                // EOM(1)
+; CHECK-NEXT: .b8 0                                // EOM(2)
+; CHECK-NEXT: .b8 5                                // Abbreviation Code
 ; CHECK-NEXT: .b8 52                               // DW_TAG_variable
 ; CHECK-NEXT: .b8 0                                // DW_CHILDREN_no
 ; CHECK-NEXT: .b8 3                                // DW_AT_name
 ; CHECK-NEXT: .b8 8                                // DW_FORM_string
 ; CHECK-NEXT: .b8 58                               // DW_AT_decl_file
 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 59                               // DW_AT_decl_line
 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 73                               // DW_AT_type
 ; CHECK-NEXT: .b8 16                               // DW_FORM_ref_addr
 ; CHECK-NEXT: .b8 0                                // EOM(1)
 ; CHECK-NEXT: .b8 0                                // EOM(2)
-; CHECK-NEXT: .b8 5                                // Abbreviation Code
+; CHECK-NEXT: .b8 6                                // Abbreviation Code
 ; CHECK-NEXT: .b8 46                               // DW_TAG_subprogram
 ; CHECK-NEXT: .b8 1                                // DW_CHILDREN_yes
 ; CHECK-NEXT: .b8 17                               // DW_AT_low_pc
 ; CHECK-NEXT: .b8 1                                // DW_FORM_addr
 ; CHECK-NEXT: .b8 18                               // DW_AT_high_pc
 ; CHECK-NEXT: .b8 1                                // DW_FORM_addr
 ; CHECK-NEXT: .b8 64                               // DW_AT_frame_base
 ; CHECK-NEXT: .b8 10                               // DW_FORM_block1
 ; CHECK-NEXT: .b8 135                              // DW_AT_MIPS_linkage_name
 ; CHECK-NEXT: .b8 64
 ; CHECK-NEXT: .b8 8                                // DW_FORM_string
 ; CHECK-NEXT: .b8 3                                // DW_AT_name
 ; CHECK-NEXT: .b8 8                                // DW_FORM_string
 ; CHECK-NEXT: .b8 58                               // DW_AT_decl_file
 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 59                               // DW_AT_decl_line
 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 73                               // DW_AT_type
 ; CHECK-NEXT: .b8 19                               // DW_FORM_ref4
 ; CHECK-NEXT: .b8 63                               // DW_AT_external
 ; CHECK-NEXT: .b8 12                               // DW_FORM_flag
 ; CHECK-NEXT: .b8 0                                // EOM(1)
 ; CHECK-NEXT: .b8 0                                // EOM(2)
-; CHECK-NEXT: .b8 6                                // Abbreviation Code
-; CHECK-NEXT: .b8 5                                // DW_TAG_formal_parameter
-; CHECK-NEXT: .b8 0                                // DW_CHILDREN_no
-; CHECK-NEXT: .b8 3                                // DW_AT_name
-; CHECK-NEXT: .b8 8                                // DW_FORM_string
-; CHECK-NEXT: .b8 58                               // DW_AT_decl_file
-; CHECK-NEXT: .b8 11                               // DW_FORM_data1
-; CHECK-NEXT: .b8 59                               // DW_AT_decl_line
-; CHECK-NEXT: .b8 11                               // DW_FORM_data1
-; CHECK-NEXT: .b8 73                               // DW_AT_type
-; CHECK-NEXT: .b8 19                               // DW_FORM_ref4
-; CHECK-NEXT: .b8 0                                // EOM(1)
-; CHECK-NEXT: .b8 0                                // EOM(2)
 ; CHECK-NEXT: .b8 7                                // Abbreviation Code
 ; CHECK-NEXT: .b8 36                               // DW_TAG_base_type
 ; CHECK-NEXT: .b8 0                                // DW_CHILDREN_no
 ; CHECK-NEXT: .b8 3                                // DW_AT_name
 ; CHECK-NEXT: .b8 8                                // DW_FORM_string
 ; CHECK-NEXT: .b8 62                               // DW_AT_encoding
 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 11                               // DW_AT_byte_size
 ; CHECK-NEXT: .b8 11                               // DW_FORM_data1
 ; CHECK-NEXT: .b8 0                                // EOM(1)
 ; CHECK-NEXT: .b8 0                                // EOM(2)
 ; CHECK-NEXT: .b8 0                                // EOM(3)
 ; CHECK-NEXT: }
 ; CHECK-NEXT: .section .debug_info
 ; CHECK-NEXT: {
-; CHECK-NEXT: .b32 150                             // Length of Unit
+; CHECK-NEXT: .b32 159                             // Length of Unit
 ; CHECK-NEXT: .b8 2                                // DWARF version number
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b32 .debug_abbrev                   // Offset Into Abbrev. Section
 ; CHECK-NEXT: .b8 8                                // Address Size (in bytes)
-; CHECK-NEXT: .b8 1                                // Abbrev [1] 0xb:0x8f DW_TAG_compile_unit
+; CHECK-NEXT: .b8 1                                // Abbrev [1] 0xb:0x98 DW_TAG_compile_unit
 ; CHECK-NEXT: .b8 99                               // DW_AT_producer
 ; CHECK-NEXT: .b8 108
 ; CHECK-NEXT: .b8 97
 ; CHECK-NEXT: .b8 110
 ; CHECK-NEXT: .b8 103
 ; CHECK-NEXT: .b8 32
 ; CHECK-NEXT: .b8 118
 ; CHECK-NEXT: .b8 101

 ; CHECK-NEXT: .b8 99
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b64 Lfunc_begin1                    // DW_AT_low_pc
 ; CHECK-NEXT: .b64 Lfunc_end1                      // DW_AT_high_pc
 ; CHECK-NEXT: .b8 2                                // Abbrev [2] 0x64:0x4 DW_TAG_structure_type
 ; CHECK-NEXT: .b8 65                               // DW_AT_name
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b8 1                                // DW_AT_declaration
-; CHECK-NEXT: .b8 3                                // Abbrev [3] 0x68:0x31 DW_TAG_subprogram
+; CHECK-NEXT: .b8 3                                // Abbrev [3] 0x68:0x3a DW_TAG_subprogram
 ; CHECK-NEXT: .b64 Lfunc_begin1                    // DW_AT_low_pc
 ; CHECK-NEXT: .b64 Lfunc_end1                      // DW_AT_high_pc
 ; CHECK-NEXT: .b8 1                                // DW_AT_frame_base
 ; CHECK-NEXT: .b8 156
 ; CHECK-NEXT: .b8 95                               // DW_AT_MIPS_linkage_name
 ; CHECK-NEXT: .b8 90
 ; CHECK-NEXT: .b8 51
 ; CHECK-NEXT: .b8 98
 ; CHECK-NEXT: .b8 97
 ; CHECK-NEXT: .b8 122
 ; CHECK-NEXT: .b8 49
 ; CHECK-NEXT: .b8 65
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b8 98                               // DW_AT_name
 ; CHECK-NEXT: .b8 97
 ; CHECK-NEXT: .b8 122
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b8 2                                // DW_AT_decl_file
 ; CHECK-NEXT: .b8 6                                // DW_AT_decl_line
 ; CHECK-NEXT: .b8 1                                // DW_AT_external
-; CHECK-NEXT: .b8 4                                // Abbrev [4] 0x8b:0xd DW_TAG_variable
+; CHECK-NEXT: .b8 4                                // Abbrev [4] 0x8b:0x9 DW_TAG_formal_parameter
+; CHECK-NEXT: .b8 97                               // DW_AT_name
+; CHECK-NEXT: .b8 0
+; CHECK-NEXT: .b8 2                                // DW_AT_decl_file
+; CHECK-NEXT: .b8 6                                // DW_AT_decl_line
+; CHECK-NEXT: .b32 100                             // DW_AT_type
+; CHECK-NEXT: .b8 5                                // Abbrev [5] 0x94:0xd DW_TAG_variable
 ; CHECK-NEXT: .b8 122                              // DW_AT_name
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b8 2                                // DW_AT_decl_file
 ; CHECK-NEXT: .b8 7                                // DW_AT_decl_line
-; CHECK-NEXT: .b64 .debug_info+302                 // DW_AT_type
+; CHECK-NEXT: .b64 .debug_info+311                 // DW_AT_type
 ; CHECK-NEXT: .b8 0                                // End Of Children Mark
 ; CHECK-NEXT: .b8 0                                // End Of Children Mark
 ; CHECK-NEXT: .b32 152                             // Length of Unit
 ; CHECK-NEXT: .b8 2                                // DWARF version number
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b32 .debug_abbrev                   // Offset Into Abbrev. Section
 ; CHECK-NEXT: .b8 8                                // Address Size (in bytes)
 ; CHECK-NEXT: .b8 1                                // Abbrev [1] 0xb:0x91 DW_TAG_compile_unit

 ; CHECK-NEXT: .b8 101
 ; CHECK-NEXT: .b8 95
 ; CHECK-NEXT: .b8 103
 ; CHECK-NEXT: .b8 99
 ; CHECK-NEXT: .b8 99
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b64 Lfunc_begin0                    // DW_AT_low_pc
 ; CHECK-NEXT: .b64 Lfunc_end0                      // DW_AT_high_pc
-; CHECK-NEXT: .b8 5                                // Abbrev [5] 0x64:0x30 DW_TAG_subprogram
+; CHECK-NEXT: .b8 6                                // Abbrev [6] 0x64:0x30 DW_TAG_subprogram
 ; CHECK-NEXT: .b64 Lfunc_begin0                    // DW_AT_low_pc
 ; CHECK-NEXT: .b64 Lfunc_end0                      // DW_AT_high_pc
 ; CHECK-NEXT: .b8 1                                // DW_AT_frame_base
 ; CHECK-NEXT: .b8 156
 ; CHECK-NEXT: .b8 95                               // DW_AT_MIPS_linkage_name
 ; CHECK-NEXT: .b8 90
 ; CHECK-NEXT: .b8 51
 ; CHECK-NEXT: .b8 98
 ; CHECK-NEXT: .b8 97
 ; CHECK-NEXT: .b8 114
 ; CHECK-NEXT: .b8 105
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b8 98                               // DW_AT_name
 ; CHECK-NEXT: .b8 97
 ; CHECK-NEXT: .b8 114
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b8 1                                // DW_AT_decl_file
 ; CHECK-NEXT: .b8 1                                // DW_AT_decl_line
 ; CHECK-NEXT: .b32 148                             // DW_AT_type
 ; CHECK-NEXT: .b8 1                                // DW_AT_external
-; CHECK-NEXT: .b8 6                                // Abbrev [6] 0x8a:0x9 DW_TAG_formal_parameter
+; CHECK-NEXT: .b8 4                                // Abbrev [4] 0x8a:0x9 DW_TAG_formal_parameter
 ; CHECK-NEXT: .b8 98                               // DW_AT_name
 ; CHECK-NEXT: .b8 0
 ; CHECK-NEXT: .b8 1                                // DW_AT_decl_file
 ; CHECK-NEXT: .b8 1                                // DW_AT_decl_line
 ; CHECK-NEXT: .b32 148                             // DW_AT_type
 ; CHECK-NEXT: .b8 0                                // End Of Children Mark
 ; CHECK-NEXT: .b8 7                                // Abbrev [7] 0x94:0x7 DW_TAG_base_type
 ; CHECK-NEXT: .b8 105                              // DW_AT_name