This is an archive of the discontinued LLVM Phabricator instance.

Differential D109185

[gn build] Add build files for LLDB
ClosedPublic

Authored by thakis on Sep 2 2021, 12:47 PM.

Details

Reviewers
pcc
alexander-shaposhnikov
Commits
rGcfe02847496b: [gn build] Add build files for LLDB
Summary

This is enough to get the lit-based tests to pass on macOS.

Doesn't yet add build targets for:

  • Any LLDB unit tests
  • swig bindings
  • various targets not needed by lit tests

LLDB has many dependency cycles, something GN doesn't allow. For
that reason, I've omitted some dependency edges. Hopefully we can
clean up the cycles one day.

LLDB has a public/private header distinction, but mostly ignores it.
Many libraries include private headers from other modules.

Since LLDB is the first target the LLVM/GN build that uses Objective-C++
code, add some machinery to the toolchain file to handle that.

Diff Detail

Event Timeline

thakis created this revision.Sep 2 2021, 12:47 PM
Herald added a reviewer: alexander-shaposhnikov. · View Herald TranscriptSep 2 2021, 12:47 PM
Herald added subscribers: delcypher, sbc100, mgorny, emaste. · View Herald Transcript
thakis requested review of this revision.Sep 2 2021, 12:47 PM
Herald added a project: Restricted Project. · View Herald TranscriptSep 2 2021, 12:47 PM
Herald added subscribers: MaskRay, aheejin. · View Herald Transcript
thakis edited the summary of this revision. (Show Details)Sep 2 2021, 12:49 PM
thakis updated this revision to Diff 370376.Sep 2 2021, 12:57 PM

minor tweaks

llvm/utils/gn/secondary/lldb/tools/lldb-test/BUILD.gn
27

This is probably something I should figure out before landing this.

Harbormaster completed remote builds in B122376: Diff 370376.Sep 2 2021, 1:46 PM
pcc added a comment.Sep 2 2021, 3:12 PM

Thanks for working on this!

I developed a Linux port as a patch on top of yours:

0001-linux.patch12 KBDownload

Feel free to fold it in.

With that lldb seems to work and check-lldb looks like this for me on Linux:

Failed Tests (1):
  lldb-shell :: Breakpoint/ppc64-localentry.test


Testing Time: 12.20s
  Unsupported      : 1046
  Passed           :  334
  Expectedly Failed:    5
  Failed           :    1

I'm not sure what's going on with that test. I tried including the PowerPC ABI plugin, but that didn't help.

thakis added a comment.Sep 2 2021, 6:01 PM

I developed a Linux port as a patch on top of yours:

Very cool! That was admittedly more involved than I had naively assumed :)

I'm not sure what's going on with that test. I tried including the PowerPC ABI plugin, but that didn't help.

Hey that test fails over here too (on macOS, that is – but also on my Linux box with your patch), I just never noticed since I never build with the PPC target enabled :) I'll see if I can debug it a bit when I have some time.

thakis added a comment.Sep 2 2021, 6:27 PM

This fixes that one PPC64 test. I guess the other plugins in Architecture/ aren't covered by shell tests...

$ git diff HEAD
diff --git a/llvm/utils/gn/secondary/lldb/source/Plugins/Architecture/PPC64/BUILD.gn b/llvm/utils/gn/secondary/lldb/source/Plugins/Architecture/PPC64/BUILD.gn
new file mode 100644
index 000000000000..177620783e8d
--- /dev/null
+++ b/llvm/utils/gn/secondary/lldb/source/Plugins/Architecture/PPC64/BUILD.gn
@@ -0,0 +1,14 @@
+static_library("PPC64") {
+  output_name = "lldbPluginArchitecturePPC64"
+  configs += [ "//llvm/utils/gn/build:lldb_code" ]
+  deps = [
+    "//lldb/source/Core",
+    "//lldb/source/Target",
+    "//lldb/source/Utility",
+    "//lldb/source/Plugins/Process/Utility",
+    "//llvm/lib/Support",
+  ]
+  # Uses source-relative paths for own includes.
+  include_dirs = [ "//lldb/source" ]
+  sources = [ "ArchitecturePPC64.cpp" ]
+}
diff --git a/llvm/utils/gn/secondary/lldb/source/Plugins/BUILD.gn b/llvm/utils/gn/secondary/lldb/source/Plugins/BUILD.gn
index 35149476aff6..219b0732bc25 100644
--- a/llvm/utils/gn/secondary/lldb/source/Plugins/BUILD.gn
+++ b/llvm/utils/gn/secondary/lldb/source/Plugins/BUILD.gn
@@ -5,6 +5,7 @@ import("//llvm/utils/gn/build/write_cmake_config.gni")
 plugins = [
   "ABIPowerPC",
   "ABIX86",
+  "ArchitecturePPC64",
   "DisassemblerLLVMC",
   "DynamicLoaderDarwinKernel",
   "DynamicLoaderMacOSXDYLD",
diff --git a/llvm/utils/gn/secondary/lldb/tools/driver/BUILD.gn b/llvm/utils/gn/secondary/lldb/tools/driver/BUILD.gn
index 22dc74e0b98b..8455ba4751c9 100644
--- a/llvm/utils/gn/secondary/lldb/tools/driver/BUILD.gn
+++ b/llvm/utils/gn/secondary/lldb/tools/driver/BUILD.gn
@@ -20,6 +20,7 @@ executable("lldb") {
     # FIXME: in the cmake build these come in from elsewhere
     "//lldb/source/Plugins/ABI/PowerPC",
     "//lldb/source/Plugins/ABI/X86",
+    "//lldb/source/Plugins/Architecture/PPC64",
     "//lldb/source/Plugins/Disassembler/LLVMC",
     "//lldb/source/Plugins/DynamicLoader/MacOSX-DYLD",
     "//lldb/source/Plugins/DynamicLoader/POSIX-DYLD",
diff --git a/llvm/utils/gn/secondary/lldb/tools/lldb-test/BUILD.gn b/llvm/utils/gn/secondary/lldb/tools/lldb-test/BUILD.gn
index 7f67be94ad1c..1e2a7f67bb79 100644
--- a/llvm/utils/gn/secondary/lldb/tools/lldb-test/BUILD.gn
+++ b/llvm/utils/gn/secondary/lldb/tools/lldb-test/BUILD.gn
@@ -24,6 +24,7 @@ executable("lldb-test") {
 
     # FIXME: in the cmake build these come in from elsewhere
     # FIXME: also, don't duplicate this in driver and lldb-test
+    "//lldb/source/Plugins/Architecture/PPC64",
     "//lldb/source/Plugins/ABI/PowerPC",
     "//lldb/source/Plugins/ABI/X86",
     "//lldb/source/Plugins/Disassembler/LLVMC",
diff --git a/llvm/utils/gn/secondary/lldb/tools/lldb-vscode/BUILD.gn b/llvm/utils/gn/secondary/lldb/tools/lldb-vscode/BUILD.gn
index 1ba744912d4e..deebb31fbaf5 100644
--- a/llvm/utils/gn/secondary/lldb/tools/lldb-vscode/BUILD.gn
+++ b/llvm/utils/gn/secondary/lldb/tools/lldb-vscode/BUILD.gn
@@ -15,6 +15,7 @@ executable("lldb-vscode") {
 
     # FIXME: in the cmake build these come in from elsewhere
     # FIXME: also, don't duplicate this in driver and lldb-test and lldb-vscode
+    "//lldb/source/Plugins/Architecture/PPC64",
     "//lldb/source/Plugins/ABI/PowerPC",
     "//lldb/source/Plugins/ABI/X86",
     "//lldb/source/Plugins/Disassembler/LLVMC",
• hafixo added a commit: rCRT373035: hwasan: Compatibility fixes for short granules..Sep 6 2021, 12:44 AM
• hafixo added a commit: rGc336557f0238: hwasan: Compatibility fixes for short granules..Sep 6 2021, 12:47 AM
thopre removed a commit: rGc336557f0238: hwasan: Compatibility fixes for short granules..Sep 7 2021, 2:47 AM
thopre removed a commit: rCRT373035: hwasan: Compatibility fixes for short granules..Sep 7 2021, 2:51 AM
thakis updated this revision to Diff 371081.Sep 7 2021, 8:12 AM
  • don't repeat plugin list in 4 places
  • run gn format on all new files
Herald added subscribers: kbarton, nemanjai. · View Herald TranscriptSep 7 2021, 8:12 AM
thakis added inline comments.Sep 7 2021, 8:13 AM
lldb/source/Plugins/ObjectFile/CMakeLists.txt
3 ↗(On Diff #371081)

Oh sorry, these weren't meant for this patch, I'll send them out separately. (They aren't needed for anything, just seems nice to keep them alphabetized -- and it makes it a bit easier to manually compare Plugins.def between the two builds.)

Harbormaster completed remote builds in B122874: Diff 371081.Sep 7 2021, 8:45 AM
thakis updated this revision to Diff 371128.Sep 7 2021, 10:59 AM
  • rebase
  • add -sectcreate flags for embedding Info.plist files into lldb and lldb-vscode

This is probably in shape enough to iterate in in-tree. I didn't squash in your linux change; let's land that separately :)

thakis updated this revision to Diff 371131.Sep 7 2021, 11:21 AM

minor tweaks

pcc accepted this revision.Sep 7 2021, 11:59 AM

LGTM

In D109185#2987403, @thakis wrote:
  • rebase
  • add -sectcreate flags for embedding Info.plist files into lldb and lldb-vscode

This is probably in shape enough to iterate in in-tree. I didn't squash in your linux change; let's land that separately :)

Okay, sounds good.

llvm/utils/gn/secondary/lldb/source/Host/BUILD.gn
12

Maybe add the missing dependency on //lldb/include/lldb/Host:Config from my patch here? That seems more like a generic dependency problem than something Linux-specific.

This revision is now accepted and ready to land.Sep 7 2021, 11:59 AM
Harbormaster completed remote builds in B122907: Diff 371131.Sep 7 2021, 12:07 PM
thakis marked an inline comment as done.Sep 7 2021, 12:25 PM

Thanks!

This revision was landed with ongoing or failed builds.Sep 7 2021, 12:25 PM
Closed by commit rGcfe02847496b: [gn build] Add build files for LLDB (authored by thakis). · Explain Why
This revision was automatically updated to reflect the committed changes.
thakis added a commit: rGcfe02847496b: [gn build] Add build files for LLDB.
Herald added a project: Restricted Project. · View Herald TranscriptSep 7 2021, 12:25 PM
Herald added a subscriber: lldb-commits. · View Herald Transcript
teemperor added a subscriber: teemperor.Sep 8 2021, 1:06 AM
Herald added a subscriber: JDevlieghere. · View Herald TranscriptSep 8 2021, 1:06 AM
teemperor added a comment.EditedSep 8 2021, 1:30 AM

Thanks! Out of curiosity, is there a public GN bot that is testing this?

LLDB has many dependency cycles, something GN doesn't allow. For that reason, I've omitted some dependency edges. Hopefully we can clean up the cycles one day.

No idea about GN, but I would assume this would break the build in some form? Or does this just mean ninja doesn't know the dependencies and the build process has a race condition?

LLDB has a public/private header distinction, but mostly ignores it.
Many libraries include private headers from other modules.

Is this referring to some private-*.h public-*.h files or what are those public/private headers that are incorrectly included?

thakis added a comment.Sep 8 2021, 1:29 PM
In D109185#2988837, @teemperor wrote:

Thanks! Out of curiosity, is there a public GN bot that is testing this?

The GN bots at http://45.33.8.238/ do the compile step. They don't yet run lldb tests. Maybe I'll add that, but maybe I'll wait until more of the test suite is brought up.

LLDB has many dependency cycles, something GN doesn't allow. For that reason, I've omitted some dependency edges. Hopefully we can clean up the cycles one day.

No idea about GN, but I would assume this would break the build in some form? Or does this just mean ninja doesn't know the dependencies and the build process has a race condition?

The CMake build works around this with the set_target_properties(lldbCore PROPERTIES LINK_INTERFACE_MULTIPLICITY 5) hack in lldb/source/Core/CMakeLists.txt.

In the GN build, it means you can't really build the libraries independently. But the binaries build fine (…at least with lld and ld64. It's possible BFD ld needs a --start-group / --end-group around libraries? Haven't tried that yet.)

LLDB has a public/private header distinction, but mostly ignores it.
Many libraries include private headers from other modules.

Is this referring to some private-*.h public-*.h files or what are those public/private headers that are incorrectly included?

LLDB has lldb/include/lldb/Foo which (like in the other LLVM projects) are supposed to define a module's public interface from what I understand, while headers in lldb/source/Foo are Foo's internal headers. At least that's how it works in clang and llvm. In lldb, many modules include another module's private headers (in that sense that they're in lldb/source/Foo instead of in lldb/include/lldb/Foo), while that's much less common in llvm and clang.

Revision Contents

PathSize
lldb/
source/
Symbol/
4 lines
llvm/
utils/
gn/
build/
14 lines
toolchain/
8 lines
secondary/
3 lines
lldb/
include/
lldb/
Host/
58 lines
9 lines
source/
API/
113 lines
29 lines
Breakpoint/
40 lines
Commands/
66 lines
Core/
90 lines
DataFormatters/
31 lines
Expression/
38 lines
Host/
154 lines
macosx/
objcxx/
20 lines
Initialization/
20 lines
Interpreter/
74 lines
Plugins/
ABI/
X86/
19 lines
75 lines
Disassembler/
LLVMC/
15 lines
DynamicLoader/
Darwin-Kernel/
32 lines
MacOSX-DYLD/
26 lines
POSIX-DYLD/
24 lines
Static/
13 lines
ExpressionParser/
Clang/
65 lines
Instruction/
ARM/
19 lines
JITLoader/
GDB/
31 lines
Language/
CPlusPlus/
43 lines
ClangCommon/
13 lines
ObjC/
37 lines
ObjCPlusPlus/
15 lines
LanguageRuntime/
CPlusPlus/
10 lines
ItaniumABI/
19 lines
ObjC/
AppleObjCRuntime/
34 lines
16 lines
RenderScript/
RenderScriptRuntime/
30 lines
ObjectContainer/
BSD-Archive/
11 lines
Universal-Mach-O/
12 lines
ObjectFile/
Breakpad/
17 lines
ELF/
17 lines
JIT/
12 lines
Mach-O/
16 lines
PDB/
11 lines
PECOFF/
24 lines
wasm/
14 lines
Platform/
MacOSX/
49 lines
objcxx/
14 lines
POSIX/
18 lines
Windows/
13 lines
Process/
Utility/
72 lines
elf-core/
27 lines
gdb-remote/
49 lines
mach-core/
22 lines
minidump/
26 lines
ScriptInterpreter/
None/
9 lines
SymbolFile/
Breakpad/
16 lines
DWARF/
75 lines
NativePDB/
34 lines
PDB/
25 lines
Symtab/
10 lines
SymbolVendor/
ELF/
14 lines
MacOSX/
14 lines
wasm/
14 lines
TypeSystem/
Clang/
27 lines
UnwindAssembly/
InstEmulation/
10 lines
x86/
17 lines
Symbol/
48 lines
Target/
102 lines
Utility/
84 lines
test/
191 lines
4 lines
tools/
argdumper/
6 lines
driver/
56 lines
lldb-server/
58 lines
lldb-test/
71 lines
lldb-vscode/
68 lines
utils/
TableGen/
12 lines
43 lines
lit-cpuid/
4 lines
llvm/
utils/
llvm-lit/
21 lines

Diff 370376

lldb/source/Symbol/CMakeLists.txt

set(LLVM_OPTIONAL_SOURCES LocateSymbolFileMacOSX.cpp) set(LLVM_OPTIONAL_SOURCES LocateSymbolFileMacOSX.cpp)
if (CMAKE_SYSTEM_NAME MATCHES "Darwin") if (CMAKE_SYSTEM_NAME MATCHES "Darwin")
set(PLATFORM_SOURCES LocateSymbolFileMacOSX.cpp) set(PLATFORM_SOURCES
LocateSymbolFileMacOSX.cpp
)
endif() endif()
add_lldb_library(lldbSymbol add_lldb_library(lldbSymbol
ArmUnwindInfo.cpp ArmUnwindInfo.cpp
Block.cpp Block.cpp
CompactUnwindInfo.cpp CompactUnwindInfo.cpp
CompileUnit.cpp CompileUnit.cpp
CompilerDecl.cpp CompilerDecl.cpp
Show All 38 Lines

llvm/utils/gn/build/BUILD.gn

Show First 20 Lines • Show All 342 Lines • ▼ Show 20 Lines if (use_thinlto) {
} else { } else {
ldflags += [ ldflags += [
"-flto=thin", "-flto=thin",
"-Wl,--thinlto-jobs=" + max_jobs_per_lto_link, "-Wl,--thinlto-jobs=" + max_jobs_per_lto_link,
"-Wl,--lto-O" + lto_opt_level, "-Wl,--lto-O" + lto_opt_level,
] ]
} }
} }
cflags_objcc = cflags_cc
} }
config("no_exceptions") { config("no_exceptions") {
if (host_os != "win") { if (host_os != "win") {
cflags_cc = [ "-fno-exceptions" ] cflags_cc = [ "-fno-exceptions" ]
} }
cflags_objcc = cflags_cc
} }
config("no_rtti") { config("no_rtti") {
if (current_os == "win") { if (current_os == "win") {
cflags_cc = [ "/GR-" ] cflags_cc = [ "/GR-" ]
} else { } else {
cflags_cc = [ "-fno-rtti" ] cflags_cc = [ "-fno-rtti" ]
} }
cflags_objcc = cflags_cc
} }
# To make an archive that can be distributed, you need to remove this config and # To make an archive that can be distributed, you need to remove this config and
# set complete_static_lib. # set complete_static_lib.
config("thin_archive") { config("thin_archive") {
if (current_os != "ios" && current_os != "mac" && current_os != "win") { if (current_os != "ios" && current_os != "mac" && current_os != "win") {
arflags = [ "-T" ] arflags = [ "-T" ]
} }
Show All 38 Lines if (is_clang) {
cflags += [ cflags += [
"-Werror=thread-safety", "-Werror=thread-safety",
"-Werror=thread-safety-reference", "-Werror=thread-safety-reference",
"-Werror=thread-safety-beta", "-Werror=thread-safety-beta",
] ]
} }
} }
config("lldb_code") {
if (host_os != "win") {
cflags = [ "-fno-strict-aliasing" ]
}
include_dirs = [
"//lldb/include",
"$root_gen_dir/lldb/include",
]
}
config("warn_covered_switch_default") { config("warn_covered_switch_default") {
if (is_clang) { if (is_clang) {
cflags = [ "-Wcovered-switch-default" ] cflags = [ "-Wcovered-switch-default" ]
} }
} }

llvm/utils/gn/build/toolchain/BUILD.gn

Show First 20 Lines • Show All 45 Lines • ▼ Show 20 Lines toolchain(target_name) {
tool("cxx") { tool("cxx") {
depfile = "{{output}}.d" depfile = "{{output}}.d"
command = "$cxx -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}}" command = "$cxx -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}}"
depsformat = "gcc" depsformat = "gcc"
description = "CXX {{output}}" description = "CXX {{output}}"
outputs = [ "{{source_out_dir}}/{{label_name}}.{{source_name_part}}.o" ] outputs = [ "{{source_out_dir}}/{{label_name}}.{{source_name_part}}.o" ]
} }
tool("objcxx") {
depfile = "{{output}}.d"
command = "$cxx -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_objcc}}"
depsformat = "gcc"
description = "OBJCXX {{output}}"
outputs = [ "{{source_out_dir}}/{{label_name}}.{{source_name_part}}.o" ]
}
tool("asm") { tool("asm") {
depfile = "{{output}}.d" depfile = "{{output}}.d"
command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{asmflags}}" command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{asmflags}}"
depsformat = "gcc" depsformat = "gcc"
description = "ASM {{output}}" description = "ASM {{output}}"
outputs = [ "{{source_out_dir}}/{{label_name}}.{{source_name_part}}.o" ] outputs = [ "{{source_out_dir}}/{{label_name}}.{{source_name_part}}.o" ]
} }
▲ Show 20 Lines • Show All 328 Lines • Show Last 20 Lines

llvm/utils/gn/secondary/BUILD.gn

Show All 14 Lines deps = [
"//llvm/test", "//llvm/test",
] ]
if (current_os == "linux") { if (current_os == "linux") {
deps += [ deps += [
"//libcxx", "//libcxx",
"//libcxxabi", "//libcxxabi",
] ]
} }
if (current_os == "mac") {
deps += [ "//lldb/test" ]
}
if (current_os == "linux" || current_os == "android") { if (current_os == "linux" || current_os == "android") {
deps += [ "//compiler-rt/test/hwasan" ] deps += [ "//compiler-rt/test/hwasan" ]
} }
if (current_os == "linux" || current_os == "mac") { if (current_os == "linux" || current_os == "mac") {
deps += [ "//libunwind" ] deps += [ "//libunwind" ]
} }
testonly = true testonly = true
▲ Show 20 Lines • Show All 69 Lines • Show Last 20 Lines

llvm/utils/gn/secondary/lldb/include/lldb/Host/BUILD.gn

  • This file was added.
import("libedit.gni")
import("//llvm/utils/gn/build/libs/xml/enable.gni")
import("//llvm/utils/gn/build/write_cmake_config.gni")
# In lldb/cmake/modules/LLDBGenerateConfig.cmake,
# brought in by lldb/cmake/modules/LLDBConfig.cmake,
# brought in by lldb/CMakeLists.txt in the CMake build.
write_cmake_config("Config") {
input = "Config.h.cmake"
output = "$target_gen_dir/Config.h"
values = [
# FIXME: Actual values for everything.
"LLDB_EDITLINE_USE_WCHAR=",
"LLDB_HAVE_EL_RFUNC_T=",
"HAVE_PPOLL=",
"HAVE_PTSNAME_R=",
"HAVE_PROCESS_VM_READV=",
"HAVE_NR_PROCESS_VM_READV=",
"LLDB_ENABLE_LZMA=",
"LLDB_ENABLE_CURSES=",
"CURSES_HAVE_NCURSES_CURSES_H=",
"LLDB_ENABLE_LUA=",
"LLDB_ENABLE_PYTHON=",
"LLDB_EMBED_PYTHON_HOME=",
"LLDB_PYTHON_HOME=",
"LLVM_LIBDIR_SUFFIX=",
"HAVE_LIBCOMPRESSION=",
]
if (lldb_enable_libedit) {
values += [ "LLDB_ENABLE_LIBEDIT=1" ]
} else {
values += [ "LLDB_ENABLE_LIBEDIT=" ]
}
if (llvm_enable_libxml2) {
values += [ "LLDB_ENABLE_LIBXML2=1" ]
} else {
values += [ "LLDB_ENABLE_LIBXML2=" ]
}
if (current_os == "win") {
values += [
"HAVE_SYS_EVENT_H=",
"LLDB_ENABLE_POSIX=",
"LLDB_ENABLE_TERMIOS=",
]
} else {
values += [
"HAVE_SYS_EVENT_H=1",
"LLDB_ENABLE_POSIX=1",
"LLDB_ENABLE_TERMIOS=1",
]
}
}

llvm/utils/gn/secondary/lldb/include/lldb/Host/libedit.gni

  • This file was added.
declare_args() {
# Whether lldb links against libedit. Set to `true` or `false`, or to
# `"default"` to get the platform default.
lldb_enable_libedit = "default"
}
if (lldb_enable_libedit == "default") {
lldb_enable_libedit = current_os == "mac"
}

llvm/utils/gn/secondary/lldb/source/API/BUILD.gn

  • This file was added.
static_library("liblldb") {
# XXX if win -DEXPORT_LIBLLDB
# XXX LLDB_BUILD_FRAMEWORK
# XXX LLDB_ENABLE_PYTHON
# XXX LLDB_ENABLE_LUA
output_name = "liblldb" # XXX lib prefix?
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
#"//lldb/include/lldb/Host:Config",
"//lldb/source:lldbBase",
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Initialization",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/tools/argdumper:lldb-argdumper",
"//llvm/lib/Support",
# XXX LLDB_ALL_PLUGINS
"//lldb/source/Plugins:Plugins.def",
"//lldb/source/Plugins/Language/CPlusPlus",
]
include_dirs = [
# SBTarget.cpp includes Commands-internal header Commands/CommandObjectBreakpoint.h
"..",
# SystemInitializerFull.cpp includes "Plugins/Plugins.def"
# (XXX push via config on dep?)
"$root_gen_dir/lldb/source",
]
sources = [
"SBAddress.cpp",
"SBAttachInfo.cpp",
"SBBlock.cpp",
"SBBreakpoint.cpp",
"SBBreakpointLocation.cpp",
"SBBreakpointName.cpp",
"SBBreakpointOptionCommon.cpp",
"SBBroadcaster.cpp",
"SBCommandInterpreter.cpp",
"SBCommandInterpreterRunOptions.cpp",
"SBCommandReturnObject.cpp",
"SBCommunication.cpp",
"SBCompileUnit.cpp",
"SBData.cpp",
"SBDebugger.cpp",
"SBDeclaration.cpp",
"SBEnvironment.cpp",
"SBError.cpp",
"SBEvent.cpp",
"SBExecutionContext.cpp",
"SBExpressionOptions.cpp",
"SBFileSpec.cpp",
"SBFile.cpp",
"SBFileSpecList.cpp",
"SBFrame.cpp",
"SBFunction.cpp",
"SBHostOS.cpp",
"SBInstruction.cpp",
"SBInstructionList.cpp",
"SBLanguageRuntime.cpp",
"SBLaunchInfo.cpp",
"SBLineEntry.cpp",
"SBListener.cpp",
"SBMemoryRegionInfo.cpp",
"SBMemoryRegionInfoList.cpp",
"SBModule.cpp",
"SBModuleSpec.cpp",
"SBPlatform.cpp",
"SBProcess.cpp",
"SBProcessInfo.cpp",
"SBQueue.cpp",
"SBQueueItem.cpp",
"SBReproducer.cpp",
"SBSection.cpp",
"SBSourceManager.cpp",
"SBStream.cpp",
"SBStringList.cpp",
"SBStructuredData.cpp",
"SBSymbol.cpp",
"SBSymbolContext.cpp",
"SBSymbolContextList.cpp",
"SBTarget.cpp",
"SBThread.cpp",
"SBThreadCollection.cpp",
"SBThreadPlan.cpp",
"SBTrace.cpp",
"SBType.cpp",
"SBTypeCategory.cpp",
"SBTypeEnumMember.cpp",
"SBTypeFilter.cpp",
"SBTypeFormat.cpp",
"SBTypeNameSpecifier.cpp",
"SBTypeSummary.cpp",
"SBTypeSynthetic.cpp",
"SBValue.cpp",
"SBValueList.cpp",
"SBVariablesOptions.cpp",
"SBWatchpoint.cpp",
"SBUnixSignals.cpp",
"SystemInitializerFull.cpp",
]
# XXX liblldb.exports or liblldb-private.expoorts
# XXX dep on clang resource directory
}

llvm/utils/gn/secondary/lldb/source/BUILD.gn

  • This file was added.
import("//llvm/utils/gn/build/write_vcsrevision.gni")
config("write_vcsrevision_config") {
# To pick up the generated inc file.
include_dirs = [ target_gen_dir ]
visibility = [ ":write_vcsrevision" ]
}
write_vcsrevision("write_vcsversion") {
visibility = [ ":lldbBase" ]
header = "$target_gen_dir/VCSVersion.inc"
names = [ "LLDB" ]
public_configs = [ ":write_vcsrevision_config" ]
}
static_library("lldbBase") {
configs += [
"//llvm/utils/gn/build:lldb_code",
# To pick up clang/Basic/Version.h.
"//llvm/utils/gn/build:clang_code",
]
sources = [ "lldb.cpp" ]
deps = [
":write_vcsversion",
"//clang/lib/Basic",
]
# XXX define LLDB_VERSION_STRING
}

llvm/utils/gn/secondary/lldb/source/Breakpoint/BUILD.gn

  • This file was added.
static_library("Breakpoint") {
output_name = "lldbBreakpoint"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/include/lldb/Host:Config",
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//llvm/lib/Support",
]
sources = [
"Breakpoint.cpp",
"BreakpointID.cpp",
"BreakpointIDList.cpp",
"BreakpointList.cpp",
"BreakpointLocation.cpp",
"BreakpointLocationCollection.cpp",
"BreakpointLocationList.cpp",
"BreakpointName.cpp",
"BreakpointOptions.cpp",
"BreakpointPrecondition.cpp",
"BreakpointResolver.cpp",
"BreakpointResolverAddress.cpp",
"BreakpointResolverFileLine.cpp",
"BreakpointResolverFileRegex.cpp",
"BreakpointResolverName.cpp",
"BreakpointResolverScripted.cpp",
"BreakpointSite.cpp",
"BreakpointSiteList.cpp",
"Stoppoint.cpp",
"StoppointCallbackContext.cpp",
"StoppointSite.cpp",
"Watchpoint.cpp",
"WatchpointList.cpp",
"WatchpointOptions.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Commands/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("CommandOptions") {
args = [ "-gen-lldb-option-defs" ]
td_file = "Options.td" # FIXME: rename?
}
static_library("Commands") {
output_name = "lldbCommands"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":CommandOptions",
"//llvm/lib/Support",
# FIXME:
#"//lldb/source", # This is lldbBase. Why is this not a real lib?
#"//lldb/source/Breakpoint", # FIXME: many-hop dependency cycle.
"//lldb/source/Core",
"//lldb/source/DataFormatters",
#"//lldb/source/Expression", # FIXME: 2-hop dependency cycle.
"//lldb/source/Host",
#"//lldb/source/Interpreter", # FIXME: Dependency cycle.
#"//lldb/source/Symbol", # FIXME: many-hop dependency cycle.
#"//lldb/source/Target", # FIXME: 2-hop dependency cycle.
"//lldb/source/Utility",
]
sources = [
"CommandCompletions.cpp",
"CommandObjectApropos.cpp",
"CommandObjectBreakpoint.cpp",
"CommandObjectBreakpointCommand.cpp",
"CommandObjectCommands.cpp",
"CommandObjectDisassemble.cpp",
"CommandObjectExpression.cpp",
"CommandObjectFrame.cpp",
"CommandObjectGUI.cpp",
"CommandObjectHelp.cpp",
"CommandObjectLanguage.cpp",
"CommandObjectLog.cpp",
"CommandObjectMemory.cpp",
"CommandObjectMemoryTag.cpp",
"CommandObjectMultiword.cpp",
"CommandObjectPlatform.cpp",
"CommandObjectPlugin.cpp",
"CommandObjectProcess.cpp",
"CommandObjectQuit.cpp",
"CommandObjectRegexCommand.cpp",
"CommandObjectRegister.cpp",
"CommandObjectReproducer.cpp",
"CommandObjectScript.cpp",
"CommandObjectSession.cpp",
"CommandObjectSettings.cpp",
"CommandObjectSource.cpp",
"CommandObjectStats.cpp",
"CommandObjectTarget.cpp",
"CommandObjectThread.cpp",
"CommandObjectThreadUtil.cpp",
"CommandObjectTrace.cpp",
"CommandObjectType.cpp",
"CommandObjectVersion.cpp",
"CommandObjectWatchpoint.cpp",
"CommandObjectWatchpointCommand.cpp",
"CommandOptionsProcessLaunch.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Core/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("CoreProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("CorePropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "CoreProperties.td"
}
static_library("Core") {
output_name = "lldbCore"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
":CoreProperties",
":CorePropertiesEnum",
"//clang/lib/Driver",
"//llvm/lib/Demangle",
"//llvm/lib/Support",
#"//lldb/source/Breakpoint", # Dependency cycle.
#"//lldb/source/DataFormatters", # Dependency cycle.
#"//lldb/source/Expression", # Dependency cycle.
"//lldb/source/Host",
#"//lldb/source/Interpreter", # Dependency cycle.
#"//lldb/source/Symbol", # Dependency cycle.
#"//lldb/source/Target", # Dependency cycle.
"//lldb/source/Utility",
#"//lldb/source/Plugins/Language/CPlusPlus", # 3-hop dependency cycle.
#"//lldb/source/Plugins/Language/ObjC", # Many-hop dependency cycle.
# FIXME:
# ${LLDB_CURSES_LIBS}
]
# FIXME: Link curses, libedit if neededdit if needed.
include_dirs = [ ".." ]
sources = [
"Address.cpp",
"AddressRange.cpp",
"AddressResolver.cpp",
"AddressResolverFileLine.cpp",
"Communication.cpp",
"Debugger.cpp",
"Declaration.cpp",
"Disassembler.cpp",
"DumpDataExtractor.cpp",
"DumpRegisterValue.cpp",
"DynamicLoader.cpp",
"EmulateInstruction.cpp",
"FileLineResolver.cpp",
"FileSpecList.cpp",
"FormatEntity.cpp",
"Highlighter.cpp",
"IOHandler.cpp",
"IOHandlerCursesGUI.cpp",
"Mangled.cpp",
"Module.cpp",
"ModuleChild.cpp",
"ModuleList.cpp",
"Opcode.cpp",
"PluginManager.cpp",
"Progress.cpp",
"RichManglingContext.cpp",
"SearchFilter.cpp",
"Section.cpp",
"SourceLocationSpec.cpp",
"SourceManager.cpp",
"StreamAsynchronousIO.cpp",
"StreamFile.cpp",
"UserSettingsController.cpp",
"Value.cpp",
"ValueObject.cpp",
"ValueObjectCast.cpp",
"ValueObjectChild.cpp",
"ValueObjectConstResult.cpp",
"ValueObjectConstResultCast.cpp",
"ValueObjectConstResultChild.cpp",
"ValueObjectConstResultImpl.cpp",
"ValueObjectDynamicValue.cpp",
"ValueObjectList.cpp",
"ValueObjectMemory.cpp",
"ValueObjectRegister.cpp",
"ValueObjectSyntheticFilter.cpp",
"ValueObjectUpdater.cpp",
"ValueObjectVariable.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/DataFormatters/BUILD.gn

  • This file was added.
static_library("DataFormatters") {
output_name = "lldbDataFormatters"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//llvm/lib/Support",
"//lldb/source/Core",
#"//lldb/source/Interpreter", # FIXME: Dependency cycle.
#"//lldb/source/Symbol", # FIXME: 3-hop Dependency cycle (DataFormatters->Symbol->Expression->Interpreter->DataFormatters)
#"//lldb/source/Target", # FIXME: 3-hop Dependency cycle (DataFormatters->Target->Expression->Interpreter->DataFormatters)
"//lldb/source/Utility",
]
sources = [
"CXXFunctionPointer.cpp",
"DataVisualization.cpp",
"DumpValueObjectOptions.cpp",
"FormatCache.cpp",
"FormatClasses.cpp",
"FormatManager.cpp",
"FormattersHelpers.cpp",
"LanguageCategory.cpp",
"StringPrinter.cpp",
"TypeCategory.cpp",
"TypeCategoryMap.cpp",
"TypeFormat.cpp",
"TypeSummary.cpp",
"TypeSynthetic.cpp",
"ValueObjectPrinter.cpp",
"VectorType.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Expression/BUILD.gn

  • This file was added.
static_library("Expression") {
output_name = "lldbExpression"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//llvm/lib/IR",
"//llvm/lib/ExecutionEngine",
"//llvm/lib/Support",
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Interpreter",
#"//lldb/source/Symbol", # FIXME: Dependency cycle.
#"//lldb/source/Target", # FIXME: Dependency cycle.
"//lldb/source/Utility",
"//lldb/source/Plugins/ObjectFile/JIT",
#"//lldb/source/Plugins/Language/CPlusPlus", # 4-hop dependency cycle.
# FIXME:
# DEPENDS
# intrinsics_gen
]
include_dirs = [ ".." ]
sources = [
"DiagnosticManager.cpp",
"DWARFExpression.cpp",
"Expression.cpp",
"ExpressionVariable.cpp",
"FunctionCaller.cpp",
"IRExecutionUnit.cpp",
"IRInterpreter.cpp",
"IRMemoryMap.cpp",
"LLVMUserExpression.cpp",
"Materializer.cpp",
"REPL.cpp",
"UserExpression.cpp",
"UtilityFunction.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Host/BUILD.gn

  • This file was added.
import("//lldb/include/lldb/Host/libedit.gni")
static_library("Host") {
output_name = "lldbHost"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//llvm/lib/Object",
"//llvm/lib/Support",
"//llvm/utils/gn/build/libs/xml",
"//lldb/source/Utility",
pccUnsubmitted
Done
ReplyInline Actions

Maybe add the missing dependency on //lldb/include/lldb/Host:Config from my patch here? That seems more like a generic dependency problem than something Linux-specific.

pcc: Maybe add the missing dependency on //lldb/include/lldb/Host:Config from my patch here? That…
# FIXME:
# LINK_LIBS
# ${EXTRA_LIBS}
# ${LLDBObjCLibs}
]
sources = [
"common/FileAction.cpp",
"common/FileCache.cpp",
"common/File.cpp",
"common/FileSystem.cpp",
"common/GetOptInc.cpp",
"common/Host.cpp",
"common/HostInfoBase.cpp",
"common/HostNativeThreadBase.cpp",
"common/HostProcess.cpp",
"common/HostThread.cpp",
"common/LockFileBase.cpp",
"common/LZMA.cpp",
"common/MainLoop.cpp",
"common/MonitoringProcessLauncher.cpp",
"common/NativeProcessProtocol.cpp",
"common/NativeRegisterContext.cpp",
"common/NativeThreadProtocol.cpp",
"common/NativeWatchpointList.cpp",
"common/OptionParser.cpp",
"common/PipeBase.cpp",
"common/ProcessLaunchInfo.cpp",
"common/ProcessRunLock.cpp",
"common/PseudoTerminal.cpp",
"common/SocketAddress.cpp",
"common/Socket.cpp",
"common/StringConvert.cpp",
"common/TCPSocket.cpp",
"common/Terminal.cpp",
"common/ThreadLauncher.cpp",
"common/UDPSocket.cpp",
"common/XML.cpp",
]
if (lldb_enable_libedit) {
libs = [ "edit" ]
sources += [ "common/Editline.cpp" ]
if (host_os == "mac") {
libs += [ "curses" ] # For USE_SETUPTERM_WORKAROUND :/
}
}
# XXX why is this separate
sources += [ "posix/ConnectionFileDescriptorPosix.cpp" ]
if (current_os == "win") {
sources += [
"windows/ConnectionGenericFileWindows.cpp",
"windows/FileSystem.cpp",
"windows/Host.cpp",
"windows/HostInfoWindows.cpp",
"windows/HostProcessWindows.cpp",
"windows/HostThreadWindows.cpp",
"windows/LockFileWindows.cpp",
"windows/PipeWindows.cpp",
"windows/ProcessLauncherWindows.cpp",
"windows/ProcessRunLock.cpp",
"windows/Windows.cpp",
]
} else {
sources += [
"posix/DomainSocket.cpp",
"posix/FileSystemPosix.cpp",
"posix/HostInfoPosix.cpp",
"posix/HostProcessPosix.cpp",
"posix/HostThreadPosix.cpp",
"posix/LockFilePosix.cpp",
"posix/PipePosix.cpp",
"posix/ProcessLauncherPosixFork.cpp",
]
}
if (current_os == "mac") {
sources += [
"macosx/cfcpp/CFCBundle.cpp",
"macosx/cfcpp/CFCData.cpp",
"macosx/cfcpp/CFCMutableArray.cpp",
"macosx/cfcpp/CFCMutableDictionary.cpp",
"macosx/cfcpp/CFCMutableSet.cpp",
"macosx/cfcpp/CFCString.cpp",
]
deps += [ "macosx/objcxx" ]
# FIXME: Maybe define NO_XPC_SERVICES
}
if (current_os == "linux" || current_os == "android") {
sources += [
"linux/AbstractSocket.cpp",
"linux/Host.cpp",
"linux/HostInfoLinux.cpp",
"linux/LibcGlue.cpp",
"linux/Support.cpp",
]
}
if (current_os == "android") {
sources += [
"android/HostInfoAndroid.cpp",
"android/LibcGlue.cpp",
]
}
if (current_os == "freebsd") {
sources += [
"freebsd/Host.cpp",
"freebsd/HostInfoFreeBSD.cpp",
]
}
if (current_os == "netbsd") {
sources += [
"netbsd/HostNetBSD.cpp",
"netbsd/HostInfoNetBSD.cpp",
]
}
if (current_os == "openbsd") {
sources += [
"openbsd/Host.cpp",
"openbsd/HostInfoOpenBSD.cpp",
]
}
# FIXME:
# set(EXTRA_LIBS)
# if (CMAKE_SYSTEM_NAME MATCHES "NetBSD")
# list(APPEND EXTRA_LIBS kvm)
# endif()
# if (HAVE_LIBDL)
# list(APPEND EXTRA_LIBS ${CMAKE_DL_LIBS})
# endif()
# if (LLDB_ENABLE_LIBEDIT)
# list(APPEND EXTRA_LIBS ${LibEdit_LIBRARIES})
# endif()
# if (LLDB_ENABLE_LZMA)
# list(APPEND EXTRA_LIBS ${LIBLZMA_LIBRARIES})
# endif()
# if (WIN32)
# list(APPEND LLDB_SYSTEM_LIBS psapi)
# endif()
}

llvm/utils/gn/secondary/lldb/source/Host/macosx/objcxx/BUILD.gn

  • This file was added.
static_library("objcxx") {
output_name = "lldbHostMacOSXObjCXX"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//llvm/lib/Support",
"//lldb/source/Utility",
]
include_dirs = [ "//lldb/source" ] # Includes internal headers from Utility.
cflags_objcc = [ "-fno-objc-exceptions" ]
sources = [
"Host.mm",
"HostInfoMacOSX.mm",
"HostThreadMacOSX.mm",
]
frameworks = [
"Foundation.framework",
"CoreServices.framework",
"Security.framework",
]
}

llvm/utils/gn/secondary/lldb/source/Initialization/BUILD.gn

  • This file was added.
static_library("Initialization") {
output_name = "lldbInitialization"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Plugins/Process/gdb-remote",
# XXX:
# lldbPluginProcessPOSIX on linux/android
# lldbPluginProcessWindowsCommon on win
"//llvm/lib/Support",
]
# SystemInitializerCommon.cpp includes headers from Plugins/Process/....
include_dirs = [ ".." ]
sources = [
"SystemInitializerCommon.cpp",
"SystemInitializer.cpp",
"SystemLifetimeManager.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Interpreter/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("InterpreterProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("InterpreterPropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "InterpreterProperties.td"
}
static_library("Interpreter") {
output_name = "lldbInterpreter"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":InterpreterProperties",
":InterpreterPropertiesEnum",
"//llvm/lib/Support",
"//lldb/source/Commands",
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Host",
#"//lldb/source/Target", # FIXME: 2-hop dependency cyle (Interpreter->Target->Expression->Interpreter)
"//lldb/source/Utility",
]
include_dirs = [ ".." ] # Yuck, reaches into source/Commands implementation details
sources = [
"CommandAlias.cpp",
"CommandHistory.cpp",
"CommandInterpreter.cpp",
"CommandObject.cpp",
"CommandOptionValidators.cpp",
"CommandReturnObject.cpp",
"OptionArgParser.cpp",
"OptionGroupArchitecture.cpp",
"OptionGroupBoolean.cpp",
"OptionGroupFile.cpp",
"OptionGroupFormat.cpp",
"OptionGroupPythonClassWithDict.cpp",
"OptionGroupOutputFile.cpp",
"OptionGroupPlatform.cpp",
"OptionGroupString.cpp",
"OptionGroupUInt64.cpp",
"OptionGroupUUID.cpp",
"OptionGroupValueObjectDisplay.cpp",
"OptionValue.cpp",
"OptionValueArch.cpp",
"OptionValueArgs.cpp",
"OptionValueArray.cpp",
"OptionValueBoolean.cpp",
"OptionValueChar.cpp",
"OptionValueDictionary.cpp",
"OptionValueEnumeration.cpp",
"OptionValueFileColonLine.cpp",
"OptionValueFileSpec.cpp",
"OptionValueFileSpecList.cpp",
"OptionValueFormat.cpp",
"OptionValueFormatEntity.cpp",
"OptionValueLanguage.cpp",
"OptionValuePathMappings.cpp",
"OptionValueProperties.cpp",
"OptionValueRegex.cpp",
"OptionValueSInt64.cpp",
"OptionValueString.cpp",
"OptionValueUInt64.cpp",
"OptionValueUUID.cpp",
"OptionGroupVariable.cpp",
"OptionGroupWatchpoint.cpp",
"Options.cpp",
"Property.cpp",
"ScriptInterpreter.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ABI/X86/BUILD.gn

  • This file was added.
static_library("X86") {
output_name = "lldbPluginABIX86"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//llvm/lib/Support",
]
# Uses source-relative paths for own includes.
include_dirs = [ "//lldb/source" ]
sources = [
"ABIX86.cpp",
"ABIMacOSX_i386.cpp",
"ABISysV_i386.cpp",
"ABISysV_x86_64.cpp",
"ABIWindows_x86_64.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/BUILD.gn

  • This file was added.
import("//llvm/utils/gn/build/write_cmake_config.gni")
# XXX comment on how cmake does this dynamically and we use a static list
# XXX maybe have buildtarget / name pairs and also add deps
plugins = [
"ABIX86",
"DisassemblerLLVMC",
"DynamicLoaderDarwinKernel",
"DynamicLoaderMacOSXDYLD",
"DynamicLoaderPosixDYLD",
"DynamicLoaderStatic",
"InstructionARM",
"JITLoaderGDB",
"CPlusPlusLanguage",
"ObjCLanguage",
"ObjCPlusPlusLanguage",
"CXXItaniumABI",
"AppleObjCRuntime",
"RenderScriptRuntime",
"ObjectContainerBSDArchive",
"ObjectContainerMachOArchive",
"ObjectFileBreakpad",
"ObjectFileELF",
"ObjectFileJIT",
"ObjectFileMachO",
"ObjectFilePDB",
"ObjectFilePECOFF",
"ObjectFileWasm",
"PlatformMacOSX",
#"PlatformPOSIX", # Not in cmake
"PlatformWindows",
"ProcessElfCore",
#"ProcessGDBRemote", # Not in cmake
"ProcessMachCore",
"ProcessMinidump",
#"ProcessUtility", # Not in cmake
"SymbolFileBreakpad",
"SymbolFileDWARF",
"SymbolFilePDB", # XXX why not also SymbolFileNativePDB?
"SymbolFileSymtab",
"SymbolVendorELF",
"SymbolVendorMacOSX",
"SymbolVendorWasm",
"TypeSystemClang",
"UnwindAssemblyInstEmulation",
"UnwindAssemblyX86",
]
write_cmake_config("Plugins.def") {
input = "Plugins.def.in"
output = "$target_gen_dir/Plugins.def"
enum_plugins = ""
foreach(plugin, plugins) {
# \n is a literal '\' followed by a literal 'n', not a newline character.
# write_cmake_config.py replaces it with a real newline.
enum_plugins += "LLDB_PLUGIN(" + plugin + ")\n"
}
deps = [ "//lldb/source/Plugins/ScriptInterpreter/None" ]
enum_plugins += "LLDB_SCRIPT_PLUGIN(ScriptInterpreterNone)"
values = [ "LLDB_ENUM_PLUGINS=" + enum_plugins ]
if (current_os == "win") {
values += [
"LLDB_PROCESS_GDB_PLUGIN=",
"LLDB_PROCESS_WINDOWS_PLUGIN=LLDB_PLUGIN(XXX)",
]
} else {
values += [
"LLDB_PROCESS_GDB_PLUGIN=LLDB_PLUGIN(ProcessGDBRemote)",
"LLDB_PROCESS_WINDOWS_PLUGIN=",
]
}
}

llvm/utils/gn/secondary/lldb/source/Plugins/Disassembler/LLVMC/BUILD.gn

  • This file was added.
static_library("LLVMC") {
output_name = "lldbPluginDisassemblerLLVMC"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//llvm/lib/ExecutionEngine/RuntimeDyld",
"//llvm/lib/MC",
"//llvm/lib/MC/MCDisassembler",
"//llvm/lib/Target:TargetsToBuild",
"//llvm/lib/Support",
]
sources = [ "DisassemblerLLVMC.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/DynamicLoader/Darwin-Kernel/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("DynamicLoaderDarwinKernelProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("DynamicLoaderDarwinKernelPropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "DynamicLoaderDarwinKernelProperties.td"
}
static_library("Darwin-Kernel") {
output_name = "lldbPluginDynamicLoaderDarwinKernel"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":DynamicLoaderDarwinKernelProperties",
":DynamicLoaderDarwinKernelPropertiesEnum",
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/Platform/MacOSX",
"//llvm/lib/Support",
]
# Reaches into Plugins/Platform/MacOSX.
include_dirs = [ "//lldb/source" ]
sources = [ "DynamicLoaderDarwinKernel.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/DynamicLoader/MacOSX-DYLD/BUILD.gn

  • This file was added.
static_library("MacOSX-DYLD") {
output_name = "lldbPluginDynamicLoaderMacOSXDYLD"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/TypeSystem/Clang",
"//llvm/lib/Support",
]
# Reaches into Plugins/LanguageRuntime/ObjC.
include_dirs = [ "//lldb/source" ]
sources = [
"DynamicLoaderMacOSXDYLD.cpp",
"DynamicLoaderMacOS.cpp",
"DynamicLoaderDarwin.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/DynamicLoader/POSIX-DYLD/BUILD.gn

  • This file was added.
static_library("POSIX-DYLD") {
output_name = "lldbPluginDynamicLoaderPosixDYLD"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
#"//lldb/source/Plugins/Process/elf-core", # Dependency cycle.
"//lldb/source/Plugins/Process/Utility",
"//llvm/lib/Support",
]
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [
"DYLDRendezvous.cpp",
"DynamicLoaderPOSIXDYLD.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/DynamicLoader/Static/BUILD.gn

  • This file was added.
static_library("Static") {
output_name = "lldbPluginDynamicLoaderStatic"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
]
sources = [ "DynamicLoaderStatic.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ExpressionParser/Clang/BUILD.gn

  • This file was added.
static_library("Clang") {
output_name = "lldbPluginExpressionParserClang"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//clang/lib/AST",
"//clang/lib/CodeGen",
"//clang/lib/Driver",
"//clang/lib/Edit",
"//clang/lib/Frontend",
"//clang/lib/Frontend/Rewrite",
"//clang/lib/Lex",
"//clang/lib/Parse",
"//clang/lib/Rewrite",
"//clang/lib/Sema",
"//clang/lib/Serialization",
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
#"//lldb/source/Plugins/Language/CPlusPlus", # 3-hop dependency cycle
"//lldb/source/Plugins/LanguageRuntime/CPlusPlus",
"//lldb/source/Plugins/LanguageRuntime/ObjC",
"//lldb/source/Plugins/LanguageRuntime/RenderScript/RenderScriptRuntime",
#"//lldb/source/Plugins/TypeSystem/Clang", # Dependency cycle
"//llvm/lib/IR",
"//llvm/lib/ExecutionEngine",
"//llvm/lib/ExecutionEngine/MCJIT",
"//llvm/lib/Transforms/IPO",
"//llvm/lib/Support",
]
# Uses source-relative paths for own includes (!)
include_dirs = [ "//lldb/source" ]
sources = [
"ASTResultSynthesizer.cpp",
"ASTStructExtractor.cpp",
"ASTUtils.cpp",
"ClangASTImporter.cpp",
"ClangASTMetadata.cpp",
"ClangASTSource.cpp",
"ClangDeclVendor.cpp",
"ClangExpressionDeclMap.cpp",
"ClangExpressionParser.cpp",
"ClangExpressionSourceCode.cpp",
"ClangExpressionVariable.cpp",
"ClangExternalASTSourceCallbacks.cpp",
"ClangFunctionCaller.cpp",
"ClangHost.cpp",
"ClangModulesDeclVendor.cpp",
"ClangPersistentVariables.cpp",
"ClangUserExpression.cpp",
"ClangUtil.cpp",
"ClangUtilityFunction.cpp",
"CppModuleConfiguration.cpp",
"CxxModuleHandler.cpp",
"IRForTarget.cpp",
"IRDynamicChecks.cpp",
"NameSearchContext.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Instruction/ARM/BUILD.gn

  • This file was added.
static_library("ARM") {
output_name = "lldbPluginInstructionARM"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Plugins/Process/Utility",
"//llvm/lib/Support",
]
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [
"EmulateInstructionARM.cpp",
"EmulationStateARM.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/JITLoader/GDB/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("JITLoaderGDBProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("JITLoaderGDBPropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "JITLoaderGDBProperties.td"
}
static_library("GDB") {
output_name = "lldbPluginJITLoaderGDB"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":JITLoaderGDBProperties",
":JITLoaderGDBPropertiesEnum",
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/ObjectFile/Mach-O",
"//llvm/lib/Support",
]
# Reaches into Plugins/ObjectFile/Mach-O.
include_dirs = [ "//lldb/source" ]
sources = [ "JITLoaderGDB.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Language/CPlusPlus/BUILD.gn

  • This file was added.
static_library("CPlusPlus") {
output_name = "lldbPluginCPlusPlusLanguage"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/Language/ClangCommon",
"//lldb/source/Plugins/LanguageRuntime/CPlusPlus",
"//lldb/source/Plugins/TypeSystem/Clang",
"//llvm/lib/Support",
]
# Reaches into Plugins/Language/ClangCommon.
include_dirs = [ "//lldb/source" ]
sources = [
"BlockPointer.cpp",
"CPlusPlusLanguage.cpp",
"CPlusPlusNameParser.cpp",
"CxxStringTypes.cpp",
"LibCxx.cpp",
"LibCxxAtomic.cpp",
"LibCxxBitset.cpp",
"LibCxxInitializerList.cpp",
"LibCxxList.cpp",
"LibCxxMap.cpp",
"LibCxxOptional.cpp",
"LibCxxQueue.cpp",
"LibCxxTuple.cpp",
"LibCxxUnorderedMap.cpp",
"LibCxxVariant.cpp",
"LibCxxVector.cpp",
"LibStdcpp.cpp",
"LibStdcppTuple.cpp",
"LibStdcppUniquePointer.cpp",
"MSVCUndecoratedNameParser.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Language/ClangCommon/BUILD.gn

  • This file was added.
static_library("ClangCommon") {
output_name = "lldbPluginClangCommon"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Core",
"//lldb/source/Utility",
"//llvm/lib/Support",
]
sources = [ "ClangHighlighter.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Language/ObjC/BUILD.gn

  • This file was added.
static_library("ObjC") {
output_name = "lldbPluginObjCLanguage"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//clang/lib/AST",
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/Language/ClangCommon",
"//lldb/source/Plugins/LanguageRuntime/ObjC/AppleObjCRuntime",
#"//lldb/source/Plugins/TypeSystem/Clang", # 3-hop dependency cycle.
"//llvm/lib/Support",
]
# Uses source-relative includes for own headers.
include_dirs = [ "//lldb/source" ]
sources = [
"ObjCLanguage.cpp",
"CF.cpp",
"CFBasicHash.cpp",
"Cocoa.cpp",
"CoreMedia.cpp",
"NSArray.cpp",
"NSDictionary.cpp",
"NSError.cpp",
"NSException.cpp",
"NSIndexPath.cpp",
"NSSet.cpp",
"NSString.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Language/ObjCPlusPlus/BUILD.gn

  • This file was added.
static_library("ObjCPlusPlus") {
output_name = "lldbPluginObjCPlusPlusLanguage"
configs += [
#"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Core",
"//lldb/source/Target",
"//lldb/source/Plugins/Language/ClangCommon",
]
# Reaches into Plugins/Language/ClangCommon.
include_dirs = [ "//lldb/source" ]
sources = [ "ObjCPlusPlusLanguage.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/LanguageRuntime/CPlusPlus/BUILD.gn

  • This file was added.
static_library("CPlusPlus") {
output_name = "lldbPluginCPPRuntime"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
]
sources = [ "CPPLanguageRuntime.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/LanguageRuntime/CPlusPlus/ItaniumABI/BUILD.gn

  • This file was added.
static_library("ItaniumABI") {
output_name = "lldbPluginCXXItaniumABI"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Plugins/LanguageRuntime/CPlusPlus",
"//lldb/source/Plugins/TypeSystem/Clang",
]
# Reaches into Plugins/LanguageRuntime/CPlusPlus.
include_dirs = [ "//lldb/source" ]
sources = [ "ItaniumABILanguageRuntime.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/LanguageRuntime/ObjC/AppleObjCRuntime/BUILD.gn

  • This file was added.
static_library("AppleObjCRuntime") {
output_name = "lldbPluginAppleObjCRuntime"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//clang/lib/AST",
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/ExpressionParser/Clang",
"//lldb/source/Plugins/LanguageRuntime/CPlusPlus",
#"//lldb/source/Plugins/TypeSystem/Clang", # 4-hop dependency cycle.
"//llvm/lib/Support",
]
# Reaches into Plugins/ExpressionParser/Clang.
include_dirs = [ "//lldb/source" ]
sources = [
"AppleObjCRuntime.cpp",
"AppleObjCRuntimeV1.cpp",
"AppleObjCRuntimeV2.cpp",
"AppleObjCTrampolineHandler.cpp",
"AppleObjCDeclVendor.cpp",
"AppleThreadPlanStepThroughObjCTrampoline.cpp",
"AppleObjCClassDescriptorV2.cpp",
"AppleObjCTypeEncodingParser.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/LanguageRuntime/ObjC/BUILD.gn

  • This file was added.
static_library("ObjC") {
output_name = "lldbPluginObjCRuntime"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
]
# Reaches into Plugins/TypeSystem/Clang.
include_dirs = [ "//lldb/source" ]
sources = [ "ObjCLanguageRuntime.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/LanguageRuntime/RenderScript/RenderScriptRuntime/BUILD.gn

  • This file was added.
static_library("RenderScriptRuntime") {
output_name = "lldbPluginRenderScriptRuntime"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
#"//clang/lib/Basic", # XXX needed in cmake?
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//llvm/lib/IR",
"//llvm/lib/IRReader",
"//llvm/lib/Support",
"//llvm/lib/Target",
]
# Reaches into Plugins/LanguageRuntime/CPlusPlus.
include_dirs = [ "//lldb/source" ]
sources = [
"RenderScriptRuntime.cpp",
"RenderScriptExpressionOpts.cpp",
"RenderScriptx86ABIFixups.cpp",
"RenderScriptScriptGroup.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectContainer/BSD-Archive/BUILD.gn

  • This file was added.
static_library("BSD-Archive") {
output_name = "lldbPluginObjectContainerBSDArchive"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//llvm/lib/Support",
]
sources = [ "ObjectContainerBSDArchive.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectContainer/Universal-Mach-O/BUILD.gn

  • This file was added.
static_library("Universal-Mach-O") {
output_name = "lldbPluginObjectContainerMachOArchive"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
]
sources = [ "ObjectContainerUniversalMachO.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/Breakpad/BUILD.gn

  • This file was added.
static_library("Breakpad") {
output_name = "lldbPluginObjectFileBreakpad"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Utility",
"//llvm/lib/Support",
]
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [
"BreakpadRecords.cpp",
"ObjectFileBreakpad.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/ELF/BUILD.gn

  • This file was added.
static_library("ELF") {
output_name = "lldbPluginObjectFileELF"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//llvm/lib/BinaryFormat",
"//llvm/lib/Object",
"//llvm/lib/Support",
]
sources = [
"ELFHeader.cpp",
"ObjectFileELF.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/JIT/BUILD.gn

  • This file was added.
static_library("JIT") {
output_name = "lldbPluginObjectFileJIT"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
#"//lldb/source/Symbol", # 2-hop dependency cycle.
#"//lldb/source/Target", # 2-hop dependency cycle.
"//llvm/lib/Support",
]
sources = [ "ObjectFileJIT.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/Mach-O/BUILD.gn

  • This file was added.
static_library("Mach-O") {
output_name = "lldbPluginObjectFileMachO"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/Process/Utility",
"//llvm/lib/Support",
]
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [ "ObjectFileMachO.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/PDB/BUILD.gn

  • This file was added.
static_library("PDB") {
output_name = "lldbPluginObjectFilePDB"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Utility",
"//llvm/lib/Support",
]
sources = [ "ObjectFilePDB.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/PECOFF/BUILD.gn

  • This file was added.
static_library("PECOFF") {
output_name = "lldbPluginObjectFilePECOFF"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//llvm/lib/BinaryFormat",
"//llvm/lib/Support",
]
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [
"ObjectFilePECOFF.cpp",
"PECallFrameInfo.cpp",
"WindowsMiniDump.cpp",
]
if (current_os == "win") {
# Dbghelp is used on windows for writing minidump files.
libs = [ "dbghelp" ]
}
}

llvm/utils/gn/secondary/lldb/source/Plugins/ObjectFile/wasm/BUILD.gn

  • This file was added.
static_library("wasm") {
output_name = "lldbPluginObjectFileWasm"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Utility",
"//llvm/lib/Support",
]
sources = [
"ObjectFileWasm.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Platform/MacOSX/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("PlatformMacOSXProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("PlatformMacOSXPropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "PlatformMacOSXProperties.td"
}
static_library("MacOSX") {
output_name = "lldbPluginPlatformMacOSX"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
":PlatformMacOSXProperties",
":PlatformMacOSXPropertiesEnum",
"//clang/lib/Basic",
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/Platform/POSIX",
"//llvm/lib/Support",
]
# Reaches into Plugins/Platform/POSIX.
include_dirs = [ "//lldb/source" ]
sources = [
"PlatformDarwin.cpp",
"PlatformDarwinKernel.cpp",
"PlatformMacOSX.cpp",
"PlatformRemoteAppleBridge.cpp",
"PlatformRemoteAppleTV.cpp",
"PlatformRemoteAppleWatch.cpp",
"PlatformRemoteDarwinDevice.cpp",
"PlatformRemoteMacOSX.cpp",
"PlatformRemoteiOS.cpp",
]
if (host_os == "mac") {
deps += [ "objcxx" ]
sources += [ "PlatformAppleSimulator.cpp" ]
}
}

llvm/utils/gn/secondary/lldb/source/Plugins/Platform/MacOSX/objcxx/BUILD.gn

  • This file was added.
static_library("objcxx") {
output_name = "lldbPluginPlatformMacOSXObjCXX"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//llvm/lib/Object",
"//llvm/lib/Support",
]
cflags_objcc = [ "-fno-objc-exceptions" ]
sources = [ "PlatformiOSSimulatorCoreSimulatorSupport.mm" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Platform/POSIX/BUILD.gn

  • This file was added.
static_library("POSIX") {
output_name = "lldbPluginPlatformPOSIX"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Target",
"//lldb/source/Plugins/TypeSystem/Clang",
]
# Reaches into Plugins/TypeSystem/Clang.
include_dirs = [ "//lldb/source" ]
sources = [ "PlatformPOSIX.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Platform/Windows/BUILD.gn

  • This file was added.
static_library("Windows") {
output_name = "lldbPluginPlatformWindows"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Target",
]
# Reaches into Plugins/TypeSystem/Clang.
#include_dirs = [ "//lldb/source" ]
sources = [ "PlatformWindows.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Process/Utility/BUILD.gn

  • This file was added.
static_library("Utility") {
output_name = "lldbPluginProcessUtility"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
#"//lldb/source/Breakpoint", # 3-hop dependency cycle.
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Symbol",
#"//lldb/source/Target", # Dependency cycle.
"//lldb/source/Utility",
"//llvm/lib/Support",
]
# Uses source-relative includes for own headers.
include_dirs = [ "//lldb/source" ]
sources = [
"AuxVector.cpp",
"DynamicRegisterInfo.cpp",
"FreeBSDSignals.cpp",
"GDBRemoteSignals.cpp",
"HistoryThread.cpp",
"HistoryUnwind.cpp",
"InferiorCallPOSIX.cpp",
"LinuxProcMaps.cpp",
"LinuxSignals.cpp",
"MemoryTagManagerAArch64MTE.cpp",
"MipsLinuxSignals.cpp",
"NativeProcessSoftwareSingleStep.cpp",
"NativeRegisterContextDBReg_arm64.cpp",
"NativeRegisterContextDBReg_x86.cpp",
"NativeRegisterContextRegisterInfo.cpp",
"NetBSDSignals.cpp",
"RegisterContext_x86.cpp",
"RegisterContextDarwin_arm.cpp",
"RegisterContextDarwin_arm64.cpp",
"RegisterContextDarwin_i386.cpp",
"RegisterContextDarwin_x86_64.cpp",
"RegisterContextDummy.cpp",
"RegisterContextFreeBSD_i386.cpp",
"RegisterContextFreeBSD_mips64.cpp",
"RegisterContextFreeBSD_powerpc.cpp",
"RegisterContextFreeBSD_x86_64.cpp",
"RegisterContextHistory.cpp",
"RegisterContextLinux_i386.cpp",
"RegisterContextLinux_x86_64.cpp",
"RegisterContextLinux_s390x.cpp",
"RegisterContextMach_arm.cpp",
"RegisterContextMach_i386.cpp",
"RegisterContextMach_x86_64.cpp",
"RegisterContextMemory.cpp",
"RegisterContextNetBSD_i386.cpp",
"RegisterContextNetBSD_x86_64.cpp",
"RegisterContextOpenBSD_i386.cpp",
"RegisterContextOpenBSD_x86_64.cpp",
"RegisterContextPOSIX_arm.cpp",
"RegisterContextPOSIX_arm64.cpp",
"RegisterContextPOSIX_mips64.cpp",
"RegisterContextPOSIX_powerpc.cpp",
"RegisterContextPOSIX_ppc64le.cpp",
"RegisterContextPOSIX_s390x.cpp",
"RegisterContextPOSIX_x86.cpp",
"RegisterContextThreadMemory.cpp",
"RegisterContextWindows_i386.cpp",
"RegisterContextWindows_x86_64.cpp",
"RegisterInfoPOSIX_arm.cpp",
"RegisterInfoPOSIX_arm64.cpp",
"RegisterInfoPOSIX_ppc64le.cpp",
"StopInfoMachException.cpp",
"ThreadMemory.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Process/elf-core/BUILD.gn

  • This file was added.
static_library("elf-core") {
output_name = "lldbPluginProcessElfCore"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Target",
"//lldb/source/Plugins/DynamicLoader/POSIX-DYLD",
"//lldb/source/Plugins/ObjectFile/ELF",
"//lldb/source/Plugins/Process/Utility",
"//llvm/lib/BinaryFormat",
"//llvm/lib/Support",
]
# Reaches into Plugins/DynamicLoader/POSIX-DYLD.
include_dirs = [ "//lldb/source" ]
sources = [
"ProcessElfCore.cpp",
"ThreadElfCore.cpp",
"RegisterContextPOSIXCore_arm.cpp",
"RegisterContextPOSIXCore_arm64.cpp",
"RegisterContextPOSIXCore_mips64.cpp",
"RegisterContextPOSIXCore_powerpc.cpp",
"RegisterContextPOSIXCore_ppc64le.cpp",
"RegisterContextPOSIXCore_s390x.cpp",
"RegisterContextPOSIXCore_x86_64.cpp",
"RegisterUtilities.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Process/gdb-remote/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("ProcessGDBRemoteProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("ProcessGDBRemotePropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "ProcessGDBRemoteProperties.td"
}
static_library("gdb-remote") {
output_name = "lldbPluginProcessGDBRemote"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":ProcessGDBRemoteProperties",
":ProcessGDBRemotePropertiesEnum",
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/Process/Utility",
"//lldb/source/Plugins/Platform/MacOSX",
"//llvm/lib/Support",
]
# XXX if (have_libcompression) { deps += [ compression } }
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [
"GDBRemoteClientBase.cpp",
"GDBRemoteCommunication.cpp",
"GDBRemoteCommunicationClient.cpp",
"GDBRemoteCommunicationHistory.cpp",
"GDBRemoteCommunicationReplayServer.cpp",
"GDBRemoteCommunicationServer.cpp",
"GDBRemoteCommunicationServerCommon.cpp",
"GDBRemoteCommunicationServerLLGS.cpp",
"GDBRemoteCommunicationServerPlatform.cpp",
"GDBRemoteRegisterContext.cpp",
"ProcessGDBRemote.cpp",
"ProcessGDBRemoteLog.cpp",
"ThreadGDBRemote.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Process/mach-core/BUILD.gn

  • This file was added.
static_library("mach-core") {
output_name = "lldbPluginProcessMachCore"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/DynamicLoader/Darwin-Kernel",
"//lldb/source/Plugins/DynamicLoader/MacOSX-DYLD",
"//lldb/source/Plugins/ObjectFile/Mach-O",
"//llvm/lib/Support",
]
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [
"ProcessMachCore.cpp",
"ThreadMachCore.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/Process/minidump/BUILD.gn

  • This file was added.
static_library("minidump") {
output_name = "lldbPluginProcessMinidump"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/Process/elf-core",
"//lldb/source/Plugins/Process/Utility",
"//llvm/lib/BinaryFormat",
"//llvm/lib/Object",
"//llvm/lib/Support",
]
# Reaches into Plugins/Process/Utility.
include_dirs = [ "//lldb/source" ]
sources = [
"MinidumpTypes.cpp",
"MinidumpParser.cpp",
"RegisterContextMinidump_ARM.cpp",
"RegisterContextMinidump_ARM64.cpp",
"RegisterContextMinidump_x86_32.cpp",
"RegisterContextMinidump_x86_64.cpp",
"ProcessMinidump.cpp",
"ThreadMinidump.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/ScriptInterpreter/None/BUILD.gn

  • This file was added.
static_library("None") {
output_name = "lldbPluginScriptInterpreterNone"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Interpreter",
]
sources = [ "ScriptInterpreterNone.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolFile/Breakpad/BUILD.gn

  • This file was added.
static_library("Breakpad") {
output_name = "lldbPluginSymbolFileBreakpad"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Utility",
"//lldb/source/Plugins/ObjectFile/Breakpad",
"//llvm/lib/Support",
]
# Reaches into Plugins/SymbolFile/Breakpad.
include_dirs = [ "//lldb/source" ]
sources = [ "SymbolFileBreakpad.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolFile/DWARF/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("SymbolFileDWARFProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("SymbolFileDWARFPropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "SymbolFileDWARFProperties.td"
}
static_library("DWARF") {
output_name = "lldbPluginSymbolFileDWARF"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
":SymbolFileDWARFProperties",
":SymbolFileDWARFPropertiesEnum",
"//clang/lib/AST",
"//clang/lib/Basic",
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
#"//lldb/source/Plugins/Language/CPlusPlus", # 3-hop dependency cycle.
"//lldb/source/Plugins/Language/ObjC",
"//lldb/source/Plugins/ExpressionParser/Clang",
#"//lldb/source/Plugins/TypeSystem/Clang", # Dependency cycle.
"//llvm/lib/DebugInfo/DWARF",
"//llvm/lib/Support",
]
# Uses source-relative includes for own headers.
include_dirs = [ "//lldb/source" ]
sources = [
"AppleDWARFIndex.cpp",
"DebugNamesDWARFIndex.cpp",
"DIERef.cpp",
"DWARFAbbreviationDeclaration.cpp",
"DWARFASTParserClang.cpp",
"DWARFAttribute.cpp",
"DWARFBaseDIE.cpp",
"DWARFCompileUnit.cpp",
"DWARFContext.cpp",
"DWARFDataExtractor.cpp",
"DWARFDebugAbbrev.cpp",
"DWARFDebugAranges.cpp",
"DWARFDebugArangeSet.cpp",
"DWARFDebugInfo.cpp",
"DWARFDebugInfoEntry.cpp",
"DWARFDebugMacro.cpp",
"DWARFDebugRanges.cpp",
"DWARFDeclContext.cpp",
"DWARFDefines.cpp",
"DWARFDIE.cpp",
"DWARFFormValue.cpp",
"DWARFIndex.cpp",
"DWARFTypeUnit.cpp",
"DWARFUnit.cpp",
"HashedNameToDIE.cpp",
"LogChannelDWARF.cpp",
"ManualDWARFIndex.cpp",
"NameToDIE.cpp",
"SymbolFileDWARF.cpp",
"SymbolFileDWARFDwo.cpp",
"SymbolFileDWARFDebugMap.cpp",
"UniqueDWARFASTType.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolFile/NativePDB/BUILD.gn

  • This file was added.
static_library("NativePDB") {
output_name = "lldbPluginSymbolFileNativePDB"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//clang/lib/AST",
"//clang/lib/Lex",
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Utility",
"//lldb/source/Plugins/ObjectFile/PDB",
#"//lldb/source/Plugins/TypeSystem/Clang", # 3-hop dependency cycle.
"//llvm/lib/DebugInfo/CodeView",
"//llvm/lib/DebugInfo/PDB",
"//llvm/lib/Support",
]
# Reaches into Plugins/ExpressionParser.
include_dirs = [ "//lldb/source" ]
sources = [
"CodeViewRegisterMapping.cpp",
"CompileUnitIndex.cpp",
"DWARFLocationExpression.cpp",
"PdbAstBuilder.cpp",
"PdbFPOProgramToDWARFExpression.cpp",
"PdbIndex.cpp",
"PdbSymUid.cpp",
"PdbUtil.cpp",
"SymbolFileNativePDB.cpp",
"UdtRecordCompleter.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolFile/PDB/BUILD.gn

  • This file was added.
static_library("PDB") {
output_name = "lldbPluginSymbolFilePDB"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//clang/lib/AST",
"//clang/lib/Lex",
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Utility",
"//lldb/source/Plugins/SymbolFile/NativePDB",
#"//lldb/source/Plugins/TypeSystem/Clang", # Dependency cycle.
"//llvm/lib/DebugInfo/PDB",
"//llvm/lib/Support",
]
# Reaches into Plugins/ExpressionParser/Clang.
include_dirs = [ "//lldb/source" ]
sources = [
"PDBASTParser.cpp",
"PDBLocationToDWARFExpression.cpp",
"SymbolFilePDB.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolFile/Symtab/BUILD.gn

  • This file was added.
static_library("Symtab") {
output_name = "lldbPluginSymbolFileSymtab"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
]
sources = [ "SymbolFileSymtab.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolVendor/ELF/BUILD.gn

  • This file was added.
static_library("ELF") {
output_name = "lldbPluginSymbolVendorELF"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Plugins/ObjectFile/ELF",
]
# Reaches into Plugins/ObjectFile/ELF.
include_dirs = [ "//lldb/source" ]
sources = [ "SymbolVendorELF.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolVendor/MacOSX/BUILD.gn

  • This file was added.
static_library("MacOSX") {
output_name = "lldbPluginSymbolVendorMacOSX"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Plugins/ObjectFile/Mach-O",
]
# Reaches into Plugins/ObjectFile/Mach-O.
include_dirs = [ "//lldb/source" ]
sources = [ "SymbolVendorMacOSX.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/SymbolVendor/wasm/BUILD.gn

  • This file was added.
static_library("wasm") {
output_name = "lldbPluginSymbolVendorWasm"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Host",
"//lldb/source/Symbol",
"//lldb/source/Plugins/ObjectFile/wasm",
]
# Reaches into Plugins/ObjectFile/wasm.
include_dirs = [ "//lldb/source" ]
sources = [ "SymbolVendorWasm.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/TypeSystem/Clang/BUILD.gn

  • This file was added.
static_library("Clang") {
output_name = "lldbPluginTypeSystemClang"
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
"//clang/lib/AST",
"//clang/lib/Basic",
"//clang/lib/Frontend",
"//clang/lib/Sema",
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//lldb/source/Plugins/ExpressionParser/Clang",
"//lldb/source/Plugins/LanguageRuntime/ObjC",
"//lldb/source/Plugins/SymbolFile/DWARF",
"//lldb/source/Plugins/SymbolFile/PDB",
"//llvm/lib/Support",
]
# Reaches into Plugins/ExpressionParser/Clang.
include_dirs = [ "//lldb/source" ]
sources = [ "TypeSystemClang.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/UnwindAssembly/InstEmulation/BUILD.gn

  • This file was added.
static_library("InstEmulation") {
output_name = "lldbPluginUnwindAssemblyInstEmulation"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
]
sources = [ "UnwindAssemblyInstEmulation.cpp" ]
}

llvm/utils/gn/secondary/lldb/source/Plugins/UnwindAssembly/x86/BUILD.gn

  • This file was added.
static_library("x86") {
output_name = "lldbPluginUnwindAssemblyX86"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//lldb/source/Core",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
"//llvm/lib/MC",
"//llvm/lib/MC/MCDisassembler",
"//llvm/lib/Support",
]
sources = [
"UnwindAssembly-x86.cpp",
"x86AssemblyInspectionEngine.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Symbol/BUILD.gn

  • This file was added.
static_library("Symbol") {
output_name = "lldbSymbol"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//llvm/lib/Support",
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Host",
#"//lldb/source/Target", # FIXME: Dependency cycle.
"//lldb/source/Utility",
]
include_dirs = [ ".." ] # FIXME: Reaches into Utility and Host internals.
sources = [
"ArmUnwindInfo.cpp",
"Block.cpp",
"CompactUnwindInfo.cpp",
"CompileUnit.cpp",
"CompilerDecl.cpp",
"CompilerDeclContext.cpp",
"CompilerType.cpp",
"DWARFCallFrameInfo.cpp",
"DebugMacros.cpp",
"DeclVendor.cpp",
"FuncUnwinders.cpp",
"Function.cpp",
"LineEntry.cpp",
"LineTable.cpp",
"LocateSymbolFile.cpp",
"ObjectFile.cpp",
"PostfixExpression.cpp",
"Symbol.cpp",
"SymbolContext.cpp",
"SymbolFile.cpp",
"SymbolVendor.cpp",
"Symtab.cpp",
"Type.cpp",
"TypeList.cpp",
"TypeMap.cpp",
"TypeSystem.cpp",
"UnwindPlan.cpp",
"UnwindTable.cpp",
"Variable.cpp",
"VariableList.cpp",
]
if (current_os == "mac") {
sources += [ "LocateSymbolFileMacOSX.cpp" ]
}
}

llvm/utils/gn/secondary/lldb/source/Target/BUILD.gn

  • This file was added.
import("//lldb/utils/TableGen/lldb_tablegen.gni")
lldb_tablegen("TargetProperties") {
args = [ "-gen-lldb-property-defs" ]
}
lldb_tablegen("TargetPropertiesEnum") {
args = [ "-gen-lldb-property-enum-defs" ]
td_file = "TargetProperties.td"
}
static_library("Target") {
output_name = "lldbTarget"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":TargetProperties",
":TargetPropertiesEnum",
"//llvm/lib/MC",
"//llvm/lib/Support",
"//lldb/source/Core",
#"//lldb/source/Breakpoint", # FIXME: Dependency cycle
"//lldb/source/Core",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Utility",
"//lldb/source/Plugins/Process/Utility",
]
include_dirs = [ ".." ] # FIXME: Reaches into Plugins internals.
sources = [
"ABI.cpp",
"AssertFrameRecognizer.cpp",
"ExecutionContext.cpp",
"InstrumentationRuntime.cpp",
"InstrumentationRuntimeStopInfo.cpp",
"JITLoader.cpp",
"JITLoaderList.cpp",
"Language.cpp",
"LanguageRuntime.cpp",
"Memory.cpp",
"MemoryHistory.cpp",
"MemoryRegionInfo.cpp",
"ModuleCache.cpp",
"OperatingSystem.cpp",
"PathMappingList.cpp",
"Platform.cpp",
"Process.cpp",
"ProcessTrace.cpp",
"Queue.cpp",
"QueueItem.cpp",
"QueueList.cpp",
"RegisterContext.cpp",
"RegisterContextUnwind.cpp",
"RegisterNumber.cpp",
"RemoteAwarePlatform.cpp",
"SectionLoadHistory.cpp",
"SectionLoadList.cpp",
"StackFrame.cpp",
"StackFrameList.cpp",
"StackFrameRecognizer.cpp",
"StackID.cpp",
"StopInfo.cpp",
"StructuredDataPlugin.cpp",
"SystemRuntime.cpp",
"Target.cpp",
"TargetList.cpp",
"Thread.cpp",
"ThreadCollection.cpp",
"ThreadList.cpp",
"ThreadPlan.cpp",
"ThreadPlanBase.cpp",
"ThreadPlanCallFunction.cpp",
"ThreadPlanCallFunctionUsingABI.cpp",
"ThreadPlanCallOnFunctionExit.cpp",
"ThreadPlanCallUserExpression.cpp",
"ThreadPlanPython.cpp",
"ThreadPlanRunToAddress.cpp",
"ThreadPlanShouldStopHere.cpp",
"ThreadPlanStepInRange.cpp",
"ThreadPlanStepInstruction.cpp",
"ThreadPlanStepOut.cpp",
"ThreadPlanStepOverBreakpoint.cpp",
"ThreadPlanStepOverRange.cpp",
"ThreadPlanStepRange.cpp",
"ThreadPlanStepThrough.cpp",
"ThreadPlanStepUntil.cpp",
"ThreadPlanTracer.cpp",
"ThreadPlanStack.cpp",
"ThreadSpec.cpp",
"Trace.cpp",
"TraceCursor.cpp",
"TraceExporter.cpp",
"TraceInstructionDumper.cpp",
"UnixSignals.cpp",
"UnwindAssembly.cpp",
"UnwindLLDB.cpp",
]
}

llvm/utils/gn/secondary/lldb/source/Utility/BUILD.gn

  • This file was added.
static_library("Utility") {
output_name = "lldbUtility"
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
"//llvm/lib/BinaryFormat",
"//llvm/lib/Support",
]
sources = [
"ArchSpec.cpp",
"Args.cpp",
"Baton.cpp",
"Broadcaster.cpp",
"CompletionRequest.cpp",
"Connection.cpp",
"ConstString.cpp",
"DataBufferHeap.cpp",
"DataBufferLLVM.cpp",
"DataEncoder.cpp",
"DataExtractor.cpp",
"Environment.cpp",
"Event.cpp",
"FileSpec.cpp",
"GDBRemote.cpp",
"IOObject.cpp",
"LLDBAssert.cpp",
"Listener.cpp",
"Log.cpp",
"Logging.cpp",
"NameMatches.cpp",
"ProcessInfo.cpp",
"RegisterValue.cpp",
"RegularExpression.cpp",
"Reproducer.cpp",
"ReproducerInstrumentation.cpp",
"ReproducerProvider.cpp",
"Scalar.cpp",
"SelectHelper.cpp",
"State.cpp",
"Status.cpp",
"Stream.cpp",
"StreamCallback.cpp",
"StreamString.cpp",
"StringExtractor.cpp",
"StringExtractorGDBRemote.cpp",
"StringLexer.cpp",
"StringList.cpp",
"StructuredData.cpp",
"TildeExpressionResolver.cpp",
"Timer.cpp",
"TraceGDBRemotePackets.cpp",
"TraceIntelPTGDBRemotePackets.cpp",
"UnimplementedError.cpp",
"UUID.cpp",
"UriParser.cpp",
"UserID.cpp",
"UserIDResolver.cpp",
"VASprintf.cpp",
"VMRange.cpp",
"XcodeSDK.cpp",
]
# FIXME:
# if (APPLE)
# list(APPEND LLDB_SYSTEM_LIBS
# ${FOUNDATION_LIBRARY}
# ${CORE_FOUNDATION_LIBRARY}
# ${CORE_SERVICES_LIBRARY}
# ${SECURITY_LIBRARY}
# ${DEBUG_SYMBOLS_LIBRARY})
# endif()
#
# if(NOT PURE_WINDOWS)
# list(APPEND LLDB_SYSTEM_LIBS ${CMAKE_THREAD_LIBS_INIT})
# endif()
#
# list(APPEND LLDB_SYSTEM_LIBS ${CMAKE_DL_LIBS})
#
# if (CMAKE_SYSTEM_NAME MATCHES "Windows")
# list(APPEND LLDB_SYSTEM_LIBS ws2_32 rpcrt4)
# endif ()
#
# if (NOT HAVE_CXX_ATOMICS64_WITHOUT_LIB )
# list(APPEND LLDB_SYSTEM_LIBS atomic)
# endif()
}

llvm/utils/gn/secondary/lldb/test/BUILD.gn

  • This file was added.
import("//llvm/triples.gni")
#import("//llvm/utils/gn/build/libs/xar/enable.gni")
import("//llvm/utils/gn/build/libs/xml/enable.gni")
import("//llvm/utils/gn/build/libs/zlib/enable.gni")
import("//llvm/utils/gn/build/write_cmake_config.gni")
import("lldb_lit_site_cfg_files.gni")
# The bits common to writing lit.site.cfg.py.in, API/lit.site.cfg.py,
# Shell/lit.site.cfg.py, and Unit/lit.site.cfg.py.in.
template("write_lit_cfg") {
write_cmake_config(target_name) {
input = invoker.input
output = invoker.output
values = [
"LIT_SITE_CFG_IN_HEADER=## Autogenerated from $input, do not edit",
"LLDB_BINARY_DIR=" +
rebase_path(get_label_info("//lldb", "target_out_dir")),
"LLDB_SOURCE_DIR=" + rebase_path("//lldb"),
"LLVM_BINARY_DIR=" +
rebase_path(get_label_info("//llvm", "target_out_dir")),
"LLVM_LIBS_DIR=", # needed only for shared builds
"LLVM_LIT_TOOLS_DIR=", # Intentionally empty, matches cmake build.
"LLVM_SOURCE_DIR=" + rebase_path("//llvm"),
"LLVM_TOOLS_DIR=" + rebase_path("$root_out_dir/bin"),
"Python3_EXECUTABLE=$python_path",
"TARGET_TRIPLE=$llvm_target_triple",
]
values += invoker.extra_values
}
}
write_cmake_config("lit-lldb-init") {
input = "//lldb/test/Shell/lit-lldb-init.in"
# XXX nicer way to get this path
output = "$root_out_dir/obj/lldb/test/Shell/lit-lldb-init"
values = [
"LLDB_TEST_MODULE_CACHE_LLDB=" +
rebase_path("$target_gen_dir/lldb-test-build.noindex/module-cache-lldb"),
]
}
write_lit_cfg("lit_site_cfg") {
# Fully-qualified instead of relative for LIT_SITE_CFG_IN_HEADER.
input = "//lldb/test/lit.site.cfg.py.in"
output = lldb_lit_site_cfg_file
extra_values = [ "LLVM_BUILD_MODE=." ]
}
write_lit_cfg("lit_api_site_cfg") {
# Fully-qualified instead of relative for LIT_SITE_CFG_IN_HEADER.
input = "//lldb/test/API/lit.site.cfg.py.in"
output = lldb_lit_api_site_cfg_file
extra_values = [
"LLDB_BUILD_INTEL_PT=0",
"LLDB_DOTEST_ARGS=",
"LLDB_ENABLE_PYTHON=0",
"LLDB_LIBS_DIR=", # FIXME: for shared builds only (?)
"LLDB_TEST_ARCH=$current_cpu",
"LLDB_TEST_COMPILER=" + rebase_path("$root_build_dir/bin/clang"),
"LLDB_TEST_BUILD_DIRECTORY=" + rebase_path("$target_gen_dir/test_build"),
"LLDB_TEST_DSYMUTIL=" + rebase_path("$root_build_dir/bin/dsymutil"),
"LLDB_TEST_EXECUTABLE=" + rebase_path("$root_build_dir/bin/lldb"),
"LLDB_TEST_MODULE_CACHE_CLANG=" +
rebase_path("$target_gen_dir/lldb-test-build.noindex/module-cache-clang"),
"LLDB_TEST_MODULE_CACHE_LLDB=" +
rebase_path("$target_gen_dir/lldb-test-build.noindex/module-cache-lldb"),
"LLVM_BUILD_MODE=.",
"LLVM_ENABLE_SHARED_LIBS=0",
"LLVM_HOST_TRIPLE=$llvm_current_triple",
"LLVM_USE_SANITIZER=",
"LLDB_FRAMEWORK_DIR=XXX_framework_dir",
"CMAKE_CXX_COMPILER=c++", # XXX use bin/clang++ instead?
"HOST_OS=$host_os", # XXX
]
dir = get_path_info(output, "dir")
if (host_os == "win") {
# See comment for Windows solink in llvm/utils/gn/build/toolchain/BUILD.gn
extra_values += [ "SHLIBDIR=" + rebase_path("$root_out_dir/bin", dir) ]
} else {
extra_values += [ "SHLIBDIR=" + rebase_path("$root_out_dir/lib", dir) ]
}
}
write_lit_cfg("lit_shell_site_cfg") {
# Fully-qualified instead of relative for LIT_SITE_CFG_IN_HEADER.
input = "//lldb/test/Shell/lit.site.cfg.py.in"
output = lldb_lit_shell_site_cfg_file
extra_values = [
"LLDB_ENABLE_LUA=0", # FIXME: gn arg, use in Config.h
"LLDB_ENABLE_LZMA=0", # FIXME: gn arg, use in Config.h
"LLDB_ENABLE_PYTHON=0", # FIXME: gn arg, use in Config.h
"LLDB_IS_64_BITS=1",
"LLDB_LIBS_DIR=", # FIXME: for shared builds only (?)
"LLDB_LIT_TOOLS_DIR=", # Intentionally empty, matches cmake build.
"LLDB_TEST_BUILD_DIRECTORY=" + rebase_path("$target_gen_dir/test_build"),
"LLDB_TEST_MODULE_CACHE_CLANG=" +
rebase_path("$target_gen_dir/lldb-test-build.noindex/module-cache-clang"),
"LLDB_TEST_MODULE_CACHE_LLDB=" +
rebase_path("$target_gen_dir/lldb-test-build.noindex/module-cache-lldb"),
"LLDB_TOOLS_DIR=" + rebase_path("$root_out_dir/bin"),
"LLDB_USE_SYSTEM_DEBUGSERVER=1", # XXX port //lldb/tools/debugserver (?)
"LLVM_HOST_TRIPLE=$llvm_current_triple",
]
if (llvm_enable_zlib) {
extra_values += [ "LLVM_ENABLE_ZLIB=1" ]
} else {
extra_values += [ "LLVM_ENABLE_ZLIB=0" ] # Must be 0.
}
dir = get_path_info(output, "dir")
if (host_os == "win") {
# See comment for Windows solink in llvm/utils/gn/build/toolchain/BUILD.gn
extra_values += [ "SHLIBDIR=" + rebase_path("$root_out_dir/bin", dir) ]
} else {
extra_values += [ "SHLIBDIR=" + rebase_path("$root_out_dir/lib", dir) ]
}
}
write_lit_cfg("lit_unit_site_cfg") {
# Fully-qualified instead of relative for LIT_SITE_CFG_IN_HEADER.
input = "//lldb/test/Unit/lit.site.cfg.py.in"
output = lldb_lit_unit_site_cfg_file
extra_values = [ "LLVM_BUILD_MODE=." ]
}
# This target should contain all dependencies of check-lldb.
# //:default depends on it, so that ninja's default target builds all
# prerequisites for check-lldb but doesn't run check-lldb itself.
group("test") {
deps = [
":lit_site_cfg",
":lit_api_site_cfg",
":lit-lldb-init",
":lit_shell_site_cfg",
":lit_unit_site_cfg",
"//clang/tools/driver:clang",
"//lld/tools/lld:symlinks",
"//lldb/tools/driver:lldb",
# XXX lldb-instr, darwin-debug, etc
"//lldb/tools/lldb-server",
"//lldb/tools/lldb-test",
"//lldb/tools/lldb-vscode",
"//lldb/utils/lit-cpuid",
#"//lldb/unittests",
"//llvm/tools/dsymutil",
"//llvm/tools/llc",
"//llvm/tools/lli",
"//llvm/tools/llvm-config",
"//llvm/tools/llvm-dwarfdump",
"//llvm/tools/llvm-dwp",
"//llvm/tools/llvm-nm:symlinks",
"//llvm/tools/llvm-mc",
"//llvm/tools/llvm-objcopy:symlinks",
"//llvm/tools/llvm-pdbutil",
"//llvm/tools/llvm-readobj:symlinks",
"//llvm/tools/split-file",
"//llvm/tools/yaml2obj",
"//llvm/utils/FileCheck",
"//llvm/utils/count",
"//llvm/utils/llvm-lit",
"//llvm/utils/not",
]
testonly = true
}
# This is the action that runs all of lldb's tests, check-lldb.
action("check-lldb") {
script = "$root_out_dir/bin/llvm-lit"
if (host_os == "win") {
script += ".py"
}
args = [
"-sv",
rebase_path(".", root_out_dir),
]
outputs = [ "$target_gen_dir/run-lit" ] # Non-existing, so that ninja runs it
# each time.
# Since check-lldb is always dirty, //:default doesn't depend on it so that
# it's not part of the default ninja target. Hence, check-lld shouldn't
# have any deps except :test, so that the default target is sure to build
# all the deps.
deps = [ ":test" ]
testonly = true
pool = "//:console"
}

llvm/utils/gn/secondary/lldb/test/lldb_lit_site_cfg_files.gni

  • This file was added.
lldb_lit_site_cfg_file = "$root_gen_dir/lldb/test/lit.site.cfg.py"
lldb_lit_api_site_cfg_file = "$root_gen_dir/lldb/test/API/lit.site.cfg.py"
lldb_lit_shell_site_cfg_file = "$root_gen_dir/lldb/test/Shell/lit.site.cfg.py"
lldb_lit_unit_site_cfg_file = "$root_gen_dir/lldb/test/Unit/lit.site.cfg.py"

llvm/utils/gn/secondary/lldb/tools/argdumper/BUILD.gn

  • This file was added.
executable("lldb-argdumper") {
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [ "//llvm/lib/Support" ]
sources = [ "argdumper.cpp" ]
# XXX ADD_TO_FRAMEWORK
}

llvm/utils/gn/secondary/lldb/tools/driver/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("Options") {
visibility = [ ":lldb" ]
args = [ "-gen-opt-parser-defs" ]
}
# XXX configure lldb-Info.plist.in, pass as sectcreate on maOS
executable("lldb") {
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":Options",
"//lldb/include/lldb/Host:Config",
"//lldb/source/API:liblldb",
"//llvm/lib/Option",
"//llvm/lib/Support",
"//llvm/utils/gn/build/libs/xar",
# FIXME: in the cmake build these come in from elsewhere
"//lldb/source/Plugins/ABI/X86",
"//lldb/source/Plugins/Disassembler/LLVMC",
"//lldb/source/Plugins/DynamicLoader/MacOSX-DYLD",
"//lldb/source/Plugins/DynamicLoader/POSIX-DYLD",
"//lldb/source/Plugins/DynamicLoader/Static",
"//lldb/source/Plugins/Instruction/ARM",
"//lldb/source/Plugins/JITLoader/GDB",
"//lldb/source/Plugins/Language/ObjCPlusPlus",
"//lldb/source/Plugins/LanguageRuntime/CPlusPlus/ItaniumABI",
"//lldb/source/Plugins/ObjectContainer/BSD-Archive",
"//lldb/source/Plugins/ObjectContainer/Universal-Mach-O",
"//lldb/source/Plugins/ObjectFile/Breakpad",
"//lldb/source/Plugins/ObjectFile/ELF",
"//lldb/source/Plugins/ObjectFile/Mach-O",
"//lldb/source/Plugins/ObjectFile/PECOFF",
"//lldb/source/Plugins/ObjectFile/wasm",
"//lldb/source/Plugins/Platform/Windows",
"//lldb/source/Plugins/Process/elf-core",
"//lldb/source/Plugins/Process/mach-core",
"//lldb/source/Plugins/Process/minidump",
"//lldb/source/Plugins/ScriptInterpreter/None",
"//lldb/source/Plugins/SymbolFile/Breakpad",
"//lldb/source/Plugins/SymbolFile/Symtab",
"//lldb/source/Plugins/SymbolVendor/ELF",
"//lldb/source/Plugins/SymbolVendor/MacOSX",
"//lldb/source/Plugins/SymbolVendor/wasm",
"//lldb/source/Plugins/UnwindAssembly/InstEmulation",
"//lldb/source/Plugins/UnwindAssembly/x86",
]
sources = [
"Driver.cpp",
"Platform.cpp",
]
# XXX if win -DIMPORT_LIBLLDB
# XXX LLDB_BUILD_FRAMEWORK rpath stuff
}

llvm/utils/gn/secondary/lldb/tools/lldb-server/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("LLGSOptions") {
visibility = [ ":lldb-server" ]
args = [ "-gen-opt-parser-defs" ]
}
executable("lldb-server") {
configs += [
#"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
":LLGSOptions",
#"//lldb/include/lldb/Host:Config",
"//lldb/source:lldbBase",
"//lldb/source/Host",
"//lldb/source/Initialization",
#"//lldb/source/Plugins/Instruction/ARM", # XXX
#"//lldb/source/Plugins/Instruction/MIPS", # XXX
#"//lldb/source/Plugins/Instruction/MIPS64", # XXX
"//llvm/lib/Option",
"//llvm/lib/Support",
# Dep of //lldb/source/Core, but omitted there due to a
# dependency cyle. Need to add dep here.
"//lldb/source/Plugins/Language/CPlusPlus",
]
if (current_os == "android" || current_os == "linux") {
deps += [ "//lldb/source/Plugins/Process/Linux" ]
#} else if (current_os == "freebsd") {
#deps += [ "//lldb/source/Plugins/Process/FreeBSD" ]
#} else if (current_os == "netbsd") {
#deps += [ "//lldb/source/Plugins/Process/NetBSD" ]
}
if (current_os == "mac") {
deps += [ "//lldb/source/Plugins/ObjectFile/Mach-O" ]
} else if (current_os == "win") {
deps += [ "//lldb/source/Plugins/ObjectFile/PECOFF" ]
} else {
deps += [ "//lldb/source/Plugins/ObjectFile/ELF" ]
}
# FIXME: codesign stuff on macos; default to "lldb_codesign"
# Reaches into Plugins/ObjectFile/Mach-O.
include_dirs = [ "//lldb/source" ]
sources = [
"Acceptor.cpp",
"lldb-gdbserver.cpp",
"lldb-platform.cpp",
"lldb-server.cpp",
"LLDBServerUtilities.cpp",
"SystemInitializerLLGS.cpp",
]
}

llvm/utils/gn/secondary/lldb/tools/lldb-test/BUILD.gn

  • This file was added.
executable("lldb-test") {
configs += [
"//llvm/utils/gn/build:clang_code",
"//llvm/utils/gn/build:lldb_code",
]
deps = [
#"//lldb/include/lldb/Host:Config",
"//lldb/source:lldbBase",
"//lldb/source/Breakpoint",
"//lldb/source/Core",
"//lldb/source/DataFormatters",
"//lldb/source/Expression",
"//lldb/source/Host",
"//lldb/source/Initialization",
"//lldb/source/Interpreter",
"//lldb/source/Symbol",
"//lldb/source/Target",
"//lldb/source/Utility",
#"//lldb/source/API:liblldb",
"//llvm/lib/Support",
# XXX ${host_lib} (?)
# XXX LLDB_ALL_PLUGINS
"//lldb/source/Plugins:Plugins.def",
# FIXME: in the cmake build these come in from elsewhere
# FIXME: also, don't duplicate this in driver and lldb-test
"//lldb/source/Plugins/ABI/X86",
thakisAuthorUnsubmitted
Done
ReplyInline Actions

This is probably something I should figure out before landing this.

thakis: This is probably something I should figure out before landing this.
"//lldb/source/Plugins/Disassembler/LLVMC",
"//lldb/source/Plugins/DynamicLoader/MacOSX-DYLD",
"//lldb/source/Plugins/DynamicLoader/POSIX-DYLD",
"//lldb/source/Plugins/DynamicLoader/Static",
"//lldb/source/Plugins/Instruction/ARM",
"//lldb/source/Plugins/JITLoader/GDB",
"//lldb/source/Plugins/Language/ObjCPlusPlus",
"//lldb/source/Plugins/LanguageRuntime/CPlusPlus/ItaniumABI",
"//lldb/source/Plugins/ObjectContainer/BSD-Archive",
"//lldb/source/Plugins/ObjectContainer/Universal-Mach-O",
"//lldb/source/Plugins/ObjectFile/Breakpad",
"//lldb/source/Plugins/ObjectFile/ELF",
"//lldb/source/Plugins/ObjectFile/Mach-O",
"//lldb/source/Plugins/ObjectFile/PECOFF",
"//lldb/source/Plugins/ObjectFile/wasm",
"//lldb/source/Plugins/Platform/Windows",
"//lldb/source/Plugins/Process/elf-core",
"//lldb/source/Plugins/Process/mach-core",
"//lldb/source/Plugins/Process/minidump",
"//lldb/source/Plugins/ScriptInterpreter/None",
"//lldb/source/Plugins/SymbolFile/Breakpad",
"//lldb/source/Plugins/SymbolFile/Symtab",
"//lldb/source/Plugins/SymbolVendor/ELF",
"//lldb/source/Plugins/SymbolVendor/MacOSX",
"//lldb/source/Plugins/SymbolVendor/wasm",
"//lldb/source/Plugins/UnwindAssembly/InstEmulation",
"//lldb/source/Plugins/UnwindAssembly/x86",
"//lldb/source/Plugins/Language/CPlusPlus",
]
include_dirs = [
# XXX commment
"//lldb/source",
# SystemInitializerFull.cpp includes "Plugins/Plugins.def"
# (XXX push via config on dep?)
"$root_gen_dir/lldb/source",
]
sources = [
"FormatUtil.cpp",
"lldb-test.cpp",
"SystemInitializerTest.cpp",
]
}

llvm/utils/gn/secondary/lldb/tools/lldb-vscode/BUILD.gn

  • This file was added.
import("//llvm/utils/TableGen/tablegen.gni")
tablegen("Options") {
visibility = [ ":lldb-vscode" ]
args = [ "-gen-opt-parser-defs" ]
}
executable("lldb-vscode") {
configs += [ "//llvm/utils/gn/build:lldb_code" ]
deps = [
":Options",
"//lldb/source/API:liblldb",
"//llvm/lib/Option",
"//llvm/lib/Support",
# FIXME: in the cmake build these come in from elsewhere
# FIXME: also, don't duplicate this in driver and lldb-test and lldb-vscode
"//lldb/source/Plugins/ABI/X86",
"//lldb/source/Plugins/Disassembler/LLVMC",
"//lldb/source/Plugins/DynamicLoader/MacOSX-DYLD",
"//lldb/source/Plugins/DynamicLoader/POSIX-DYLD",
"//lldb/source/Plugins/DynamicLoader/Static",
"//lldb/source/Plugins/Instruction/ARM",
"//lldb/source/Plugins/JITLoader/GDB",
"//lldb/source/Plugins/Language/ObjCPlusPlus",
"//lldb/source/Plugins/LanguageRuntime/CPlusPlus/ItaniumABI",
"//lldb/source/Plugins/ObjectContainer/BSD-Archive",
"//lldb/source/Plugins/ObjectContainer/Universal-Mach-O",
"//lldb/source/Plugins/ObjectFile/Breakpad",
"//lldb/source/Plugins/ObjectFile/ELF",
"//lldb/source/Plugins/ObjectFile/Mach-O",
"//lldb/source/Plugins/ObjectFile/PECOFF",
"//lldb/source/Plugins/ObjectFile/wasm",
"//lldb/source/Plugins/Platform/Windows",
"//lldb/source/Plugins/Process/elf-core",
"//lldb/source/Plugins/Process/mach-core",
"//lldb/source/Plugins/Process/minidump",
"//lldb/source/Plugins/ScriptInterpreter/None",
"//lldb/source/Plugins/SymbolFile/Breakpad",
"//lldb/source/Plugins/SymbolFile/Symtab",
"//lldb/source/Plugins/SymbolVendor/ELF",
"//lldb/source/Plugins/SymbolVendor/MacOSX",
"//lldb/source/Plugins/SymbolVendor/wasm",
"//lldb/source/Plugins/UnwindAssembly/InstEmulation",
"//lldb/source/Plugins/UnwindAssembly/x86",
]
# FIXME: link in //lldb/source/Host on Win (and netbsd)
# FIXME: link in pthread
# FIXME: process lldb-vscode-Info.plist.in and embed output via -sectcreate
# on macOS
# FIXME: rpath/install_name stuff on macOS for framework on macOS
sources = [
"lldb-vscode.cpp",
"BreakpointBase.cpp",
"ExceptionBreakpoint.cpp",
"FifoFiles.cpp",
"FunctionBreakpoint.cpp",
"IOStream.cpp",
"JSONUtils.cpp",
"LLDBUtils.cpp",
"OutputRedirector.cpp",
"ProgressEvent.cpp",
"RunInTerminal.cpp",
"SourceBreakpoint.cpp",
"VSCode.cpp",
]
}

llvm/utils/gn/secondary/lldb/utils/TableGen/BUILD.gn

  • This file was added.
executable("lldb-tblgen") {
deps = [
"//llvm/lib/Support",
"//llvm/lib/TableGen",
]
sources = [
"LLDBOptionDefEmitter.cpp",
"LLDBPropertyDefEmitter.cpp",
"LLDBTableGen.cpp",
"LLDBTableGenUtils.cpp",
]
}

llvm/utils/gn/secondary/lldb/utils/TableGen/lldb_tablegen.gni

  • This file was added.
# This file introduces a template for running lldb-tblgen.
#
# Parameters:
#
# args (required)
# [list of strings] Flags to pass to lldb-tblgen.
#
# output_name (optional)
# Basename of the generated output file.
# Defaults to target name with ".inc" appended.
#
# td_file (optional)
# The .td file to pass to llvm-tblgen.
# Defaults to target name with ".td" appended.
#
# visibility (optional)
# GN's regular visibility attribute, see `gn help visibility`.
#
# Example of usage:
#
# lldb_tablegen("CorePropertiesEnum") {
# args = [ "-gen-lldb-property-enum-defs" ]
# td_file = "CoreProperties.td"
# }
import("//llvm/utils/TableGen/tablegen.gni")
template("lldb_tablegen") {
tablegen(target_name) {
forward_variables_from(invoker,
[
"output_name",
"td_file",
"visibility",
])
args = [
#"-I",
#rebase_path("//lldb/include", root_build_dir),
] + invoker.args
tblgen_target = "//lldb/utils/TableGen:lldb-tblgen"
}
}

llvm/utils/gn/secondary/lldb/utils/lit-cpuid/BUILD.gn

  • This file was added.
executable("lit-cpuid") {
deps = [ "//llvm/lib/Support" ]
sources = [ "lit-cpuid.cpp" ]
}

llvm/utils/gn/secondary/llvm/utils/llvm-lit/BUILD.gn

import("//clang-tools-extra/clangd/test/clangd_lit_site_cfg_files.gni") import("//clang-tools-extra/clangd/test/clangd_lit_site_cfg_files.gni")
import("//clang-tools-extra/test/clang_tools_extra_lit_site_cfg_files.gni") import("//clang-tools-extra/test/clang_tools_extra_lit_site_cfg_files.gni")
import("//clang/test/clang_lit_site_cfg_files.gni") import("//clang/test/clang_lit_site_cfg_files.gni")
import("//lld/test/lld_lit_site_cfg_files.gni") import("//lld/test/lld_lit_site_cfg_files.gni")
import("//lldb/test/lldb_lit_site_cfg_files.gni")
import("//llvm/test/llvm_lit_site_cfg_files.gni") import("//llvm/test/llvm_lit_site_cfg_files.gni")
import("//llvm/utils/gn/build/write_cmake_config.gni") import("//llvm/utils/gn/build/write_cmake_config.gni")
import("//llvm/utils/llvm-lit/lit_path_function.gni") import("//llvm/utils/llvm-lit/lit_path_function.gni")
write_cmake_config("llvm-lit") { write_cmake_config("llvm-lit") {
input = "llvm-lit.in" input = "llvm-lit.in"
output = "$root_out_dir/bin/llvm-lit" output = "$root_out_dir/bin/llvm-lit"
if (host_os == "win") { if (host_os == "win") {
# llvm-lit needs suffix.py for multiprocess to find a main module. # llvm-lit needs suffix.py for multiprocess to find a main module.
output = "${output}.py" output = "${output}.py"
} }
# lit's lit/llvm/config.py shells out to llvm-config. # lit's lit/llvm/config.py shells out to llvm-config.
deps = [ "//llvm/tools/llvm-config" ] deps = [ "//llvm/tools/llvm-config" ]
deps += [ deps += [
"//clang-tools-extra/test:lit_site_cfg", "//clang-tools-extra/test:lit_site_cfg",
"//clang-tools-extra/test:lit_unit_site_cfg", "//clang-tools-extra/test:lit_unit_site_cfg",
"//clang/test:lit_site_cfg", "//clang/test:lit_site_cfg",
"//clang/test:lit_unit_site_cfg", "//clang/test:lit_unit_site_cfg",
"//lld/test:lit_site_cfg", "//lld/test:lit_site_cfg",
"//lld/test:lit_unit_site_cfg", "//lld/test:lit_unit_site_cfg",
"//lldb/test:lit_site_cfg",
"//lldb/test:lit_api_site_cfg",
"//lldb/test:lit_shell_site_cfg",
"//lldb/test:lit_unit_site_cfg",
"//llvm/test:lit_site_cfg", "//llvm/test:lit_site_cfg",
"//llvm/test:lit_unit_site_cfg", "//llvm/test:lit_unit_site_cfg",
] ]
entries = [ entries = [
[ [
"//clang-tools-extra/test/lit.cfg.py", "//clang-tools-extra/test/lit.cfg.py",
clang_tools_extra_lit_site_cfg_file, clang_tools_extra_lit_site_cfg_file,
Show All 22 Lines [
"//lld/test/lit.cfg.py", "//lld/test/lit.cfg.py",
lld_lit_site_cfg_file, lld_lit_site_cfg_file,
], ],
[ [
"//lld/test/Unit/lit.cfg.py", "//lld/test/Unit/lit.cfg.py",
lld_lit_unit_site_cfg_file, lld_lit_unit_site_cfg_file,
], ],
[ [
"//lldb/test/lit.cfg.py",
lldb_lit_site_cfg_file,
],
[
"//lldb/test/API/lit.cfg.py",
lldb_lit_api_site_cfg_file,
],
[
"//lldb/test/Shell/lit.cfg.py",
lldb_lit_shell_site_cfg_file,
],
[
"//lldb/test/Unit/lit.cfg.py",
lldb_lit_unit_site_cfg_file,
],
[
"//llvm/test/lit.cfg.py", "//llvm/test/lit.cfg.py",
llvm_lit_site_cfg_file, llvm_lit_site_cfg_file,
], ],
[ [
"//llvm/test/Unit/lit.cfg.py", "//llvm/test/Unit/lit.cfg.py",
llvm_lit_unit_site_cfg_file, llvm_lit_unit_site_cfg_file,
], ],
] ]
Show All 20 Lines