[mlir] Add AnyAttrOf tablegen attribute constraint

[math-fehr]

Summary

AnyAttrOf, similar to AnyTypeOf, expects the attribute to be one of the
given attributes.
For instance, AnyAttrOf<[I32Attr, StrAttr]> expects either a I32Attr,
or a StrAttr.

[math-fehr]

Thanks, would it be possible to land it for me?

mlir/include/mlir/IR/OpBase.td

 // Any attribute.
 def AnyAttr : Attr<CPred<"true">, "any attribute"> {
   let storageType = "::mlir::Attribute";
   let returnType = "::mlir::Attribute";
   let convertFromStorage = "$_self";
   let constBuilderCall = "$0";
 }
 
+// Any attribute from the given list
+class AnyAttrOf<list<Attr> allowedAttrs, string summary = "",
+                string cppClassName = "::mlir::Attribute",
+                string fromStorage = "$_self"> : Attr<
+    // Satisfy any of the allowed attribute's condition
+    Or<!foreach(allowedattr, allowedAttrs, allowedattr.predicate)>,
+    !if(!eq(summary, ""),
+        !interleave(!foreach(t, allowedAttrs, t.summary), " or "),
+        summary)> {
+    let returnType = cppClassName;
+    let convertFromStorage = fromStorage;
+}
+
 def BoolAttr : Attr<CPred<"$_self.isa<::mlir::BoolAttr>()">, "bool attribute"> {
   let storageType = [{ ::mlir::BoolAttr }];
   let returnType = [{ bool }];
   let valueType = I1;
   let constBuilderCall = "$_builder.getBoolAttr($0)";
 }
 
 // Index attribute.

mlir/test/IR/attribute.mlir

 // RUN: mlir-opt %s -split-input-file -allow-unregistered-dialect -verify-diagnostics | FileCheck %s
 
 //===----------------------------------------------------------------------===//
+// Test AnyAttrOf attributes
+//===----------------------------------------------------------------------===//
+
+func @any_attr_of_pass() {
+  "test.any_attr_of_i32_str"() {
+    // CHECK: attr = 3 : i32
+    attr = 3 : i32
+  } : () -> ()
+
+  "test.any_attr_of_i32_str"() {
+    // CHECK: attr = "string_data"
+    attr = "string_data"
+  } : () -> ()
+
+  return
+}
+
+// -----
+
+func @any_attr_of_fail() {
+  // expected-error @+1 {{'test.any_attr_of_i32_str' op attribute 'attr' failed to satisfy constraint: 32-bit signless integer attribute or string attribute}}
+  "test.any_attr_of_i32_str"() {
+    attr = 3 : i64
+  } : () -> ()
+
+  return
+}
+
+// -----
+
+//===----------------------------------------------------------------------===//
 // Test integer attributes
 //===----------------------------------------------------------------------===//
 
 func @int_attrs_pass() {
   "test.int_attrs"() {
     // CHECK: any_i32_attr = 5 : ui32
     any_i32_attr = 5 : ui32,
     // CHECK-SAME: index_attr = 8 : index

mlir/test/lib/Dialect/Test/TestOps.td

let results = (outs
     Variadic<AnyTensor>:$output3
   );
 }
 
 //===----------------------------------------------------------------------===//
 // Test Attributes
 //===----------------------------------------------------------------------===//
 
+def AnyAttrOfOp : TEST_Op<"any_attr_of_i32_str"> {
+  let arguments = (ins AnyAttrOf<[I32Attr, StrAttr]>:$attr);
+}
+
 def NonNegIntAttrOp : TEST_Op<"non_negative_int_attr"> {
   let arguments = (ins
       Confined<I32Attr, [IntNonNegative]>:$i32attr,
       Confined<I64Attr, [IntNonNegative]>:$i64attr
   );
 }
 
 def PositiveIntAttrOp : TEST_Op<"positive_int_attr"> {