[mlir][openacc] Add shutdown operation

[clementval]

Summary

This patch introduces the acc.shutdown operation that represents an OpenACC shutdown directive.
Clauses are derived from the spec 2.14.2

[rriddle]

mlir/lib/Dialect/OpenACC/IR/OpenACC.cpp

814

You can return the error directly. Also, you can use emitOpError to prefix the message with the op name.

[clementval]

Address review comments

[kiranchandramohan]

mlir/lib/Dialect/OpenACC/IR/OpenACC.cpp

813

Would it be good to add an isComputeOperation function?

mlir/test/Dialect/OpenACC/invalid.mlir

71

Can you add a test where the check has to skip at least on level of parentOp before finding a compute operation?

[clementval]

Address review comment

[clementval]

mlir/lib/Dialect/OpenACC/IR/OpenACC.cpp

813

I added one since it will be shared with at least acc.init

[ftynse]

mlir/test/Dialect/OpenACC/invalid.mlir

1

Why do you need to allow unregistered dialects?

90

I'd rather use a dummy op with a generic syntax to avoid spurious test breakages if scf.if decides to change somehow.

[clementval]

Address review comments , rebase

[clementval]

mlir/test/Dialect/OpenACC/invalid.mlir

1

I was plaining on using a dummy op and I now switched the scf.if with a dummy so now it is needed.

[mehdi_amini]

mlir/test/Dialect/OpenACC/invalid.mlir

1

Can we use a test op and avoid unregistered-dialect?
This makes the verifier a bit lose, which is undesirable for test I believe.

[clementval]

mlir/test/Dialect/OpenACC/invalid.mlir

1

Sure. Are there test op that we can use directly?

[mehdi_amini]

mlir/test/Dialect/OpenACC/invalid.mlir

1

You can looking the op definitions for the test dialect, but it also accept any unregistered op directly.
Using an op name after the test is likely "safe" (no one will register it in the test dialect later):

"test.openacc_dummy_op"() : () -> ()

[clementval]

mlir/test/Dialect/OpenACC/invalid.mlir

1

Ok, I'll send a patch today which will also remove the -allow-unregistered-dialect in the mlir/test/Dialect/OpenACC/ops.mlir tests.

1

@mehdi_amini Done in D88587

mlir/include/mlir/Dialect/OpenACC/OpenACCOps.td

OpBuilder<"OpBuilder &builder, OperationState &result",
               [{ /* nothing to do */ }]>
   ];
 
   let verifier = ?;
 
   let assemblyFormat = "attr-dict ($operands^ `:` type($operands))?";
 }
 
+//===----------------------------------------------------------------------===//
+// 2.14.2. Shutdown
+//===----------------------------------------------------------------------===//
+
+def OpenACC_ShutdownOp : OpenACC_Op<"shutdown", [AttrSizedOperandSegments]> {
+  let summary = "shutdown operation";
+
+  let description = [{
+    The "acc.shutdown" operation represents the OpenACC shutdown executable
+    directive.
+
+    Example:
+
+    ```mlir
+    acc.shutdown
+    acc.shutdown device_num(%dev1 : i32)
+    ```
+  }];
+
+  let arguments = (ins Variadic<AnyInteger>:$deviceTypeOperands,
+                       Optional<IntOrIndex>:$deviceNumOperand,
+                       Optional<I1>:$ifCond);
+
+  let assemblyFormat = [{
+    ( `device_type` `(` $deviceTypeOperands^ `:` type($deviceTypeOperands) `)` )?
+    ( `device_num` `(` $deviceNumOperand^ `:` type($deviceNumOperand) `)` )?
+    ( `if` `(` $ifCond^ `)` )? attr-dict-with-keyword
+  }];
+}
+
 #endif // OPENACC_OPS

mlir/lib/Dialect/OpenACC/IR/OpenACC.cpp

static LogicalResult verifyLoopOp(acc::LoopOp loopOp) {
   if (loopOp.region().empty()) {
     loopOp.emitError("expected non-empty body.");
     return failure();
   }
 
   return success();
 }
 
+//===----------------------------------------------------------------------===//
+// ShutdownOp
+//===----------------------------------------------------------------------===//
+
+static LogicalResult verify(acc::ShutdownOp op) {
+  Operation *currOp = op;
+  while ((currOp = currOp->getParentOp())) {
+    if (isa<acc::ParallelOp>(currOp) || isa<acc::LoopOp>(currOp))
+      return op.emitOpError("cannot be nested in a compute operation");
+  }
+  return success();
+}
+
 #define GET_OP_CLASSES
 #include "mlir/Dialect/OpenACC/OpenACCOps.cpp.inc"

mlir/test/Dialect/OpenACC/invalid.mlir

 // RUN: mlir-opt -split-input-file -verify-diagnostics %s
 
 // expected-error@+1 {{gang, worker or vector cannot appear with the seq attr}}
 acc.loop gang {
   "some.op"() : () -> ()
   acc.yield
 } attributes {seq}
 
 // -----

 // -----
 
 // expected-error@+1 {{only one of auto, independent, seq can be present at the same time}}
 acc.loop {
   acc.yield
 } attributes {auto_, seq}
 
 // -----
+
+acc.parallel {
+// expected-error@+1 {{'acc.shutdown' op cannot be nested in a compute operation}}
+  acc.shutdown
+  acc.yield
+}
+
+// -----
+
+acc.loop {
+// expected-error@+1 {{'acc.shutdown' op cannot be nested in a compute operation}}
+  acc.shutdown
+  acc.yield
+}

mlir/test/Dialect/OpenACC/ops.mlir

 // CHECK:      acc.data delete([[ARGA]]: memref<10xf32>, [[ARGB]]: memref<10xf32>, [[ARGC]]: memref<10x10xf32>) {
 // CHECK-NEXT: }
 // CHECK:      acc.data attach([[ARGA]]: memref<10xf32>, [[ARGB]]: memref<10xf32>, [[ARGC]]: memref<10x10xf32>) {
 // CHECK-NEXT: }
 // CHECK:      acc.data detach([[ARGA]]: memref<10xf32>, [[ARGB]]: memref<10xf32>, [[ARGC]]: memref<10x10xf32>) {
 // CHECK-NEXT: }
 // CHECK:      acc.data present([[ARGA]]: memref<10xf32>) copyin([[ARGB]]: memref<10xf32>) copyout([[ARGC]]: memref<10x10xf32>) {
 // CHECK-NEXT: }
+
+// -----
+
+%i64Value = constant 1 : i64
+%i32Value = constant 1 : i32
+%i32Value2 = constant 2 : i32
+%idxValue = constant 1 : index
+%ifCond = constant true
+acc.shutdown
+acc.shutdown device_type(%i32Value : i32)
+acc.shutdown device_type(%i32Value, %i32Value2 : i32, i32)
+acc.shutdown device_num(%i64Value : i64)
+acc.shutdown device_num(%i32Value : i32)
+acc.shutdown device_num(%idxValue : index)
+acc.shutdown if(%ifCond)
+
+// CHECK: [[I64VALUE:%.*]] = constant 1 : i64
+// CHECK: [[I32VALUE:%.*]] = constant 1 : i32
+// CHECK: [[I32VALUE2:%.*]] = constant 2 : i32
+// CHECK: [[IDXVALUE:%.*]] = constant 1 : index
+// CHECK: [[IFCOND:%.*]] = constant true
+// CHECK: acc.shutdown
+// CHECK: acc.shutdown device_type([[I32VALUE]] : i32)
+// CHECK: acc.shutdown device_type([[I32VALUE]], [[I32VALUE2]] : i32, i32)
+// CHECK: acc.shutdown device_num([[I64VALUE]] : i64)
+// CHECK: acc.shutdown device_num([[I32VALUE]] : i32)
+// CHECK: acc.shutdown device_num([[IDXVALUE]] : index)
+// CHECK: acc.shutdown if([[IFCOND]])