[mlir] Allow negative strides and offset in StridedLayoutAttr

[Hardcode84]

Summary

Negative strides are useful for creating reverse-view of array. We don't have specific example for negative offset yet but will add it for consistency.

[Hardcode84]

Discussion https://discourse.llvm.org/t/status-of-negative-strides-support-in-memref-subview/65346

[ezhulenev]

mlir/lib/IR/BuiltinAttributes.cpp

273

If negative strides supported to represent reversed arrays, maybe zero strides should be also supported to represent broadcasted arrays?

[bondhugula]

mlir/lib/IR/BuiltinAttributes.cpp

273

There is a fundamental difference between the two and they shouldn't be equated. Negative strides still imply a one-to-one function. However, zero strides make the mapping many-to-one.

[nicolasvasilache]

Thanks Ivan!

mlir/lib/IR/BuiltinAttributes.cpp

273

+1 to @bondhugula's comment, the indexing scheme is still expected to not have internal aliasing.

[Hardcode84]

use consumeIf, basic llvm lowering test

mlir/lib/AsmParser/AttributeParser.cpp

Attribute Parser::parseStridedLayoutAttr() {
   // and returns None if the current token is neither. The integer token must
   // fit into int64_t limits.
   auto parseStrideOrOffset = [&]() -> Optional<int64_t> {
     if (consumeIf(Token::question))
       return ShapedType::kDynamicStrideOrOffset;
 
     SMLoc loc = getToken().getLoc();
     auto emitWrongTokenError = [&] {
-      emitError(loc, "expected a non-negative 64-bit signed integer or '?'");
+      emitError(loc, "expected a 64-bit signed integer or '?'");
       return llvm::None;
     };
 
+    bool negative = false;
+    if (getToken().is(Token::minus)) {
+      negative = true;
+      consumeToken(Token::minus);
+    }
+
     if (getToken().is(Token::integer)) {
       Optional<uint64_t> value = getToken().getUInt64IntegerValue();
       if (!value ||
           *value > static_cast<uint64_t>(std::numeric_limits<int64_t>::max()))
         return emitWrongTokenError();
       consumeToken();
-      return static_cast<int64_t>(*value);
+      auto result = static_cast<int64_t>(*value);
+      if (negative)
+        result = -result;
+
+      return result;
     }
 
     return emitWrongTokenError();
   };
 
   // Parse strides.
   SmallVector<int64_t> strides;
   if (!getToken().is(Token::r_square)) {

mlir/lib/IR/BuiltinAttributes.cpp

 AffineMap StridedLayoutAttr::getAffineMap() const {
   return makeStridedLinearLayoutMap(getStrides(), getOffset(), getContext());
 }
 
 /// Checks that the type-agnostic strided layout invariants are satisfied.
 LogicalResult
 StridedLayoutAttr::verify(function_ref<InFlightDiagnostic()> emitError,
                           int64_t offset, ArrayRef<int64_t> strides) {
-  if (offset < 0 && offset != ShapedType::kDynamicStrideOrOffset)
-    return emitError() << "offset must be non-negative or dynamic";
-
-  if (llvm::any_of(strides, [&](int64_t stride) {
-        return stride <= 0 && stride != ShapedType::kDynamicStrideOrOffset;
-      })) {
-    return emitError() << "strides must be positive or dynamic";
+  if (llvm::any_of(strides, [&](int64_t stride) { return stride == 0; })) {
+    return emitError() << "strides must not be zero";
   }
   return success();
 }
 
 /// Checks that the type-specific strided layout invariants are satisfied.
 LogicalResult StridedLayoutAttr::verifyLayout(
     ArrayRef<int64_t> shape,
     function_ref<InFlightDiagnostic()> emitError) const {

mlir/test/Dialect/Builtin/types.mlir

 // CHECK: memref<?x?xf32, strided<[42, 1]>>
 func.func private @f5() -> memref<?x?xf32, strided<[42, 1]>>
 // CHECK: memref<?x?xf32, strided<[42, 1]>>
 func.func private @f6() -> memref<?x?xf32, strided<[42, 1], offset: 0>>
 // CHECK: memref<f32, strided<[]>>
 func.func private @f7() -> memref<f32, strided<[]>>
 // CHECK: memref<f32, strided<[], offset: ?>>
 func.func private @f8() -> memref<f32, strided<[], offset: ?>>
+// CHECK: memref<?xf32, strided<[-1], offset: ?>>
+func.func private @f9() -> memref<?xf32, strided<[-1], offset: ?>>
+// CHECK: memref<f32, strided<[], offset: -1>>
+func.func private @f10() -> memref<f32, strided<[], offset: -1>>

mlir/test/Dialect/MemRef/canonicalize.mlir

func.func @multiple_reducing_dims_all_dynamic(%arg0 : memref<?x?x?xf32, strided<[?, ?, ?], offset: ?>>,
   return %1 : memref<?xf32, strided<[?], offset: ?>>
 }
 //       CHECK: func @multiple_reducing_dims_all_dynamic
 //       CHECK:   %[[REDUCED1:.+]] = memref.subview %{{.+}}[0, %{{.+}}, %{{.+}}] [1, 1, %{{.+}}] [1, 1, 1]
 //  CHECK-SAME:       : memref<?x?x?xf32, strided<[?, ?, ?], offset: ?>> to memref<1x?xf32, strided<[?, ?], offset: ?>>
 //       CHECK:   %[[REDUCED2:.+]] = memref.subview %[[REDUCED1]][0, 0] [1, %{{.+}}] [1, 1]
 //  CHECK-SAME:       : memref<1x?xf32, strided<[?, ?], offset: ?>> to memref<?xf32, strided<[?], offset: ?>>
 
+// -----
+
+func.func @subview_negative_stride1(%arg0 : memref<?xf32>) -> memref<?xf32, strided<[?], offset: ?>>
+{
+  %c0 = arith.constant 0 : index
+  %c1 = arith.constant -1 : index
+  %1 = memref.dim %arg0, %c0 : memref<?xf32>
+  %2 = arith.addi %1, %c1 : index
+  %3 = memref.subview %arg0[%2] [%1] [%c1] : memref<?xf32> to memref<?xf32, strided<[?], offset: ?>>
+  return %3 : memref<?xf32, strided<[?], offset: ?>>
+}
+//       CHECK: func @subview_negative_stride1
+//  CHECK-SAME:   (%[[ARG0:.*]]: memref<?xf32>)
+//       CHECK:   %[[C1:.*]] = arith.constant 0
+//       CHECK:   %[[C2:.*]] = arith.constant -1
+//       CHECK:   %[[DIM1:.*]] = memref.dim %[[ARG0]], %[[C1]] : memref<?xf32>
+//       CHECK:   %[[DIM2:.*]] = arith.addi %[[DIM1]], %[[C2]] : index
+//       CHECK:   %[[RES1:.*]] = memref.subview %[[ARG0]][%[[DIM2]]] [%[[DIM1]]] [-1] : memref<?xf32> to memref<?xf32, strided<[-1], offset: ?>>
+//       CHECK:   %[[RES2:.*]] = memref.cast %[[RES1]] : memref<?xf32, strided<[-1], offset: ?>> to memref<?xf32, strided<[?], offset: ?>>
+//       CHECK:   return %[[RES2]] : memref<?xf32, strided<[?], offset: ?>>
+
+// -----
+
+func.func @subview_negative_stride2(%arg0 : memref<7xf32>) -> memref<?xf32, strided<[?], offset: ?>>
+{
+  %c0 = arith.constant 0 : index
+  %c1 = arith.constant -1 : index
+  %1 = memref.dim %arg0, %c0 : memref<7xf32>
+  %2 = arith.addi %1, %c1 : index
+  %3 = memref.subview %arg0[%2] [%1] [%c1] : memref<7xf32> to memref<?xf32, strided<[?], offset: ?>>
+  return %3 : memref<?xf32, strided<[?], offset: ?>>
+}
+//       CHECK: func @subview_negative_stride2
+//  CHECK-SAME:   (%[[ARG0:.*]]: memref<7xf32>)
+//       CHECK:   %[[RES1:.*]] = memref.subview %[[ARG0]][6] [7] [-1] : memref<7xf32> to memref<7xf32, strided<[-1], offset: 6>>
+//       CHECK:   %[[RES2:.*]] = memref.cast %[[RES1]] : memref<7xf32, strided<[-1], offset: 6>> to memref<?xf32, strided<[?], offset: ?>>
+//       CHECK:   return %[[RES2]] : memref<?xf32, strided<[?], offset: ?>>
 
 // -----
 
 // CHECK-LABEL: func @dim_of_sized_view
 //  CHECK-SAME:   %{{[a-z0-9A-Z_]+}}: memref<?xi8>
 //  CHECK-SAME:   %[[SIZE:.[a-z0-9A-Z_]+]]: index
 //       CHECK:   return %[[SIZE]] : index
 func.func @dim_of_sized_view(%arg : memref<?xi8>, %size: index) -> index {

mlir/test/IR/invalid-builtin-types.mlir

 
 // -----
 
 // expected-error @below {{expected '['}}
 func.func private @memref_unfinished_strided() -> memref<?x?xf32, strided<>>
 
 // -----
 
-// expected-error @below {{expected a non-negative 64-bit signed integer or '?'}}
+// expected-error @below {{expected a 64-bit signed integer or '?'}}
 func.func private @memref_unfinished_stride_list() -> memref<?x?xf32, strided<[>>
 
 // -----
 
 // expected-error @below {{expected 'offset' after comma}}
 func.func private @memref_missing_offset() -> memref<?x?xf32, strided<[], >>
 
 // -----
 
 // expected-error @below {{expected ':' after 'offset'}}
 func.func private @memref_missing_offset_colon() -> memref<?x?xf32, strided<[], offset>>
 
 // -----
 
-// expected-error @below {{expected a non-negative 64-bit signed integer or '?'}}
+// expected-error @below {{expected a 64-bit signed integer or '?'}}
 func.func private @memref_missing_offset_value() -> memref<?x?xf32, strided<[], offset: >>
 
 // -----
 
 // expected-error @below {{expected '>'}}
 func.func private @memref_incorrect_strided_ending() -> memref<?x?xf32, strided<[], offset: 32)>
 
 // -----
 
-// expected-error @below {{strides must be positive or dynamic}}
+// expected-error @below {{strides must not be zero}}
 func.func private @memref_zero_stride() -> memref<?x?xf32, strided<[0, 0]>>
 
 // -----
 
-// expected-error @below {{expected a non-negative 64-bit signed integer or '?'}}
-func.func private @memref_negative_stride() -> memref<?x?xf32, strided<[-2, -2]>>
-
-// -----
-
-// expected-error @below {{expected a non-negative 64-bit signed integer or '?'}}
-func.func private @memref_negative_offset() -> memref<?x?xf32, strided<[2, 1], offset: -2>>
-
-// -----
-
 // expected-error @below {{expected the number of strides to match the rank}}
 func.func private @memref_strided_rank_mismatch() -> memref<?x?xf32, strided<[1]>>
 
 // -----
 
 func.func @tensor_encoding_mismatch(%arg0: tensor<8xi32, "enc">) -> (tensor<8xi32>) { // expected-note {{prior use here}}
   return %arg0: tensor<8xi32> // expected-error {{use of value '%arg0' expects different type than prior uses: 'tensor<8xi32>' vs 'tensor<8xi32, "enc">'}}
 }