[mlir][Math] Add constant folder for CosOp.

[jacquesguan]

Summary

This patch adds constant folder for CosOp which only supports single and double precision floating-point.

[ftynse]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

360–376

I don't think this test should be affected

[Mogball]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

360–376

+1 can you please look into this? Is it an issue with the C++ cos function?

[jacquesguan]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

360–376

Yes, I think so. I tried cosf(acosf(-1.0f/2)), the result is not zero too. I think the way cosf and cos caculates might cause some difference.

[jacquesguan]

I look the constant folder in llvm, it also use cos in libmath to fold llvm.cos. C cos function would cause some inaccuracy than the approximation we had. Any advice for this?

[mehdi_amini]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

358–359

Can you extra the constant in a function and call it so that folder does not kick in here?

[jacquesguan]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

358–359

It maybe a little odd to have a floating point constant here. In this situation, we need to extra all constant that is integral multiple of PI/2, and we need a new float epsilon to compare our constant input and target number.

[Mogball]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

358–359

That's been a feature request for FileCheck for a long time

360–376

I think this test needs to be changed so that the ops don't fold away. If they're just folding away, they're not testing the polynomial approximations.

[jacquesguan]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

360–376

Good idea. I do not know well about mlir's command line, how to disable
canonicalize for this test case?

[Mogball]

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

360–376

Unfortunately, since these are folders, you'll have to "hide" the constants from the op by passing them as function arguments.

[jacquesguan]

Address comment.

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

360–376

Thanks, I changed to this form, will this be OK?

[Mogball]

LGTM, but all the other test cases in this file will need to be changed. Since you added folders, they're folding instead of testing the pass. Can you do that in a follow-up?

[jacquesguan]

In D131233#3772229, @Mogball wrote:

LGTM, but all the other test cases in this file will need to be changed. Since you added folders, they're folding instead of testing the pass. Can you do that in a follow-up?

OK.

[Mogball]

I've filed https://github.com/llvm/llvm-project/issues/57613. PTAL when you have time

[jpienaar]

mlir/test/Dialect/Math/canonicalize.mlir

362

Note: on Mac I'm getting

%cst = arith.constant 0.540302336 : f32

here.

mlir/include/mlir/Dialect/Math/IR/MathOps.td

let description = [{
 
     Example:
 
     ```mlir
     // Scalar cosine value.
     %a = math.cos %b : f64
     ```
   }];
+  let hasFolder = 1;
 }
 
 //===----------------------------------------------------------------------===//
 // SinOp
 //===----------------------------------------------------------------------===//
 
 def Math_SinOp : Math_FloatUnaryOp<"sin"> {
   let summary = "sine of the specified value";

mlir/lib/Dialect/Math/IR/MathOps.cpp

return constFoldBinaryOp<FloatAttr>(operands,
                                       [](const APFloat &a, const APFloat &b) {
                                         APFloat result(a);
                                         result.copySign(b);
                                         return result;
                                       });
 }
 
 //===----------------------------------------------------------------------===//
+// CosOp folder
+//===----------------------------------------------------------------------===//
+
+OpFoldResult math::CosOp::fold(ArrayRef<Attribute> operands) {
+  return constFoldUnaryOpConditional<FloatAttr>(
+      operands, [](const APFloat &a) -> Optional<APFloat> {
+        switch (a.getSizeInBits(a.getSemantics())) {
+        case 64:
+          return APFloat(cos(a.convertToDouble()));
+        case 32:
+          return APFloat(cosf(a.convertToFloat()));
+        default:
+          return {};
+        }
+      });
+}
+
+//===----------------------------------------------------------------------===//
 // CountLeadingZerosOp folder
 //===----------------------------------------------------------------------===//
 
 OpFoldResult math::CountLeadingZerosOp::fold(ArrayRef<Attribute> operands) {
   return constFoldUnaryOp<IntegerAttr>(operands, [](const APInt &a) {
     return APInt(a.getBitWidth(), a.countLeadingZeros());
   });
 }

mlir/test/Dialect/Math/canonicalize.mlir

 // CHECK-NEXT:   return %[[cst]]
 func.func @atan2_fold_vec() -> (vector<4xf32>) {
   %v1 = arith.constant dense<[0.0, 0.0, 1.0, 1.0]> : vector<4xf32>
   %v2 = arith.constant dense<[1.0, 1.0, 2.0, 2.0]> : vector<4xf32>
   %0 = math.atan2 %v1, %v2 : vector<4xf32>
   return %0 : vector<4xf32>
 }
 
+// CHECK-LABEL: @cos_fold
+// CHECK-NEXT: %[[cst:.+]] = arith.constant 0.540302277 : f32
+// CHECK-NEXT:   return %[[cst]]
+func.func @cos_fold() -> f32 {
+  %c = arith.constant 1.0 : f32
+  %r = math.cos %c : f32
+  return %r : f32
+}
+
+// CHECK-LABEL: @cos_fold_vec
+// CHECK-NEXT: %[[cst:.+]] = arith.constant dense<[1.000000e+00, 0.540302277, 1.000000e+00, 0.540302277]> : vector<4xf32>
+// CHECK-NEXT:   return %[[cst]]
+func.func @cos_fold_vec() -> (vector<4xf32>) {
+  %v1 = arith.constant dense<[0.0, 1.0, 0.0, 1.0]> : vector<4xf32>
+  %0 = math.cos %v1 : vector<4xf32>
+  return %0 : vector<4xf32>
+}

mlir/test/mlir-cpu-runner/math-polynomial-approx.mlir

func.func @sin() {
 
   return
 }
 
 // -------------------------------------------------------------------------- //
 // cos.
 // -------------------------------------------------------------------------- //
 
-func.func @cos() {
+func.func @cos(%zero : f32, %pi_over_4 : f32, %pi_over_2 : f32, %pi : f32, %pi_3_over_2 : f32, %vec_cos : vector<3xf32>) {
   // CHECK: 1
-  %0 = arith.constant 0.0 : f32
-  %cos_0 = math.cos %0 : f32
+  %cos_0 = math.cos %zero : f32
   vector.print %cos_0 : f32
 
   // CHECK: 0.707107
-  %pi_over_4 = arith.constant 0.78539816339 : f32
   %cos_pi_over_4 = math.cos %pi_over_4 : f32
   vector.print %cos_pi_over_4 : f32
 
   //// CHECK: 0
-  %pi_over_2 = arith.constant 1.57079632679 : f32
   %cos_pi_over_2 = math.cos %pi_over_2 : f32
   vector.print %cos_pi_over_2 : f32
 
   /// CHECK: -1
-  %pi = arith.constant 3.14159265359 : f32
   %cos_pi = math.cos %pi : f32
   vector.print %cos_pi : f32
 
   // CHECK: 0
-  %pi_3_over_2 = arith.constant 4.71238898038 : f32
   %cos_pi_3_over_2 = math.cos %pi_3_over_2 : f32
   vector.print %cos_pi_3_over_2 : f32
 
   // CHECK: -1, -0.5, 0
-  %vec_x = arith.constant dense<[9.42477796077, 2.09439510239, -1.57079632679]> : vector<3xf32>
-  %cos_vec_x = math.cos %vec_x : vector<3xf32>
+  %cos_vec_x = math.cos %vec_cos : vector<3xf32>
   vector.print %cos_vec_x : vector<3xf32>
 
-
   return
 }
 
 // -------------------------------------------------------------------------- //
 // Atan.
 // -------------------------------------------------------------------------- //
 
 func.func @atan() {
func.func @main() {
   call @tanh(): () -> ()
   call @log(): () -> ()
   call @log2(): () -> ()
   call @log1p(): () -> ()
   call @erf(): () -> ()
   call @exp(): () -> ()
   call @expm1(): () -> ()
   call @sin(): () -> ()
-  call @cos(): () -> ()
+  %zero = arith.constant 0.0 : f32
+  %pi_over_4 = arith.constant 0.78539816339 : f32
+  %pi_over_2 = arith.constant 1.57079632679 : f32
+  %pi = arith.constant 3.14159265359 : f32
+  %pi_3_over_2 = arith.constant 4.71238898038 : f32
+  %vec_cos = arith.constant dense<[9.42477796077, 2.09439510239, -1.57079632679]> : vector<3xf32>
+  call @cos(%zero, %pi_over_4, %pi_over_2, %pi, %pi_3_over_2, %vec_cos): (f32, f32, f32, f32, f32, vector<3xf32>) -> ()
   call @atan() : () -> ()
   call @atan2() : () -> ()
   return
 }