[gn] Support for building libc++abi

[phosek]

Summary

This change introduces support for building libc++abi. The library
build should be complete, but not all CMake options have been
replicated in GN. We also don't support tests yet.

[thakis]

Basically lgtm, some questions about the declare_args (mirroring https://reviews.llvm.org/D60253#1456632 a bit)

llvm/utils/gn/secondary/libcxxabi/src/BUILD.gn

5 ↗

(On Diff #194050)

Does this one have to be settable? That seems like an implementation detail from a distance.

17 ↗

(On Diff #194050)

Wouldn't you always want this? What's an example where one would want to statically link c++abi but export its symbols? They only thing I can think of is when linking it into libc++.dylib, which which case we probably want a toggle for that instead?

Why is the default false? Why is this settable?

38 ↗

(On Diff #194050)

no trailing "

[ldionne]

LLVM uses CMake as a build system, and we should not start checking-in support for other build systems. This sort of thing is what's fine to keep downstream only, otherwise there's an implication that upstream should somehow support that build system, which isn't the case. For example, when we make a change to CMake, we don't want to have to update the gn-based build system.

Similarly, we use a Xcode project to build libc++/libc++abi/libunwind, but we don't check those in upstream (and I've been working hard to switch us over to the CMake build, actually).

[ldionne]

Hmm, sorry, I missed the fact that there was already this support for other components. Well, as long as there's no assumption that we'll maintain this in any way, I'm not concerned with this.

[jfb]

For those without context, it would be really helpful if every GN commit had a link to documentation about what GN is, and how LLVM supports it. The initial commit had a note, maybe the LLVM docs should have this?

[thakis]

In D60372#1458540, @jfb wrote:

For those without context, it would be really helpful if every GN commit had a link to documentation about what GN is, and how LLVM supports it. The initial commit had a note, maybe the LLVM docs should have this?

llvm/utils/gn/README.rst has a readme with links etc. It explicitly mentions that this build config is unsupported and that there's no expectation to keep that build up to date, as requested by ldionne.

[ldionne]

In D60372#1458553, @thakis wrote:

In D60372#1458540, @jfb wrote:

For those without context, it would be really helpful if every GN commit had a link to documentation about what GN is, and how LLVM supports it. The initial commit had a note, maybe the LLVM docs should have this?

llvm/utils/gn/README.rst has a readme with links etc. It explicitly mentions that this build config is unsupported and that there's no expectation to keep that build up to date, as requested by ldionne.

Yup, my bad, I just spoke a little too fast.

[thakis]

In D60372#1458557, @ldionne wrote:

In D60372#1458553, @thakis wrote:

In D60372#1458540, @jfb wrote:

For those without context, it would be really helpful if every GN commit had a link to documentation about what GN is, and how LLVM supports it. The initial commit had a note, maybe the LLVM docs should have this?

llvm/utils/gn/README.rst has a readme with links etc. It explicitly mentions that this build config is unsupported and that there's no expectation to keep that build up to date, as requested by ldionne.

Yup, my bad, I just spoke a little too fast.

Can you clean the "Needs Revision" please? :)

[ldionne]

In D60372#1458652, @thakis wrote:

In D60372#1458557, @ldionne wrote:

In D60372#1458553, @thakis wrote:

In D60372#1458540, @jfb wrote:

For those without context, it would be really helpful if every GN commit had a link to documentation about what GN is, and how LLVM supports it. The initial commit had a note, maybe the LLVM docs should have this?

llvm/utils/gn/README.rst has a readme with links etc. It explicitly mentions that this build config is unsupported and that there's no expectation to keep that build up to date, as requested by ldionne.

Yup, my bad, I just spoke a little too fast.

Can you clean the "Needs Revision" please? :)

I thought it would remove it upon resigning from the revision. I accepted the revision since there didn't seem to be a way of just removing my "request for changes". Please ignore my approval, too.

[phosek]

llvm/utils/gn/secondary/libcxxabi/src/BUILD.gn

5 ↗

(On Diff #194050)

We have a concrete use case for this in Fuchsia where we build multiple different variants of libc++ using the multilib layout, including one without exceptions support, see D60926.

17 ↗

(On Diff #194050)

I've tried to match the CMake build where this is disabled by default. I agree with your reasoning but I'm not sure whether we want to deviate from the CMake build?

[thakis]

llvm/utils/gn/secondary/libcxxabi/src/BUILD.gn

17 ↗

(On Diff #194050)

I think it's fine to deviate from CMake where it makes sense.

• there are many examples of things that are options in cmake but not in gn (usually, because noone needed the option in GN yet, but not always)

• there are a few examples where variable defaults are different because cmake's defaults are arguably not optimal for the average case (examples: gn gives you release+asserts by default while cmake gives you debug by default, gn only builds host target by default while cmake builds all of them by default, ...)

So if that's the only reason this is the way it is, I think it's fine to change it if you agree that that makes sense.

[phosek]

llvm/utils/gn/secondary/libcxxabi/src/BUILD.gn

17 ↗

(On Diff #194050)

It depends on the expected use case. If you want to build static libc++abi so you can link it into the shared libc++, then you want this option to be disabled. If you want to build static libc++abi so you can distribute it as an archive, you probably want it enabled. It seems like CMake build is optimized for the former, but in practice I'd argue that the latter is more common so I'm fine making that the default.

[thakis]

Sorry, didn't realize I hadn't accepted this yet. lgtm with the change you had suggested below.

llvm/utils/gn/secondary/libcxxabi/src/BUILD.gn

17 ↗

(On Diff #194050)

Sounds good.

libcxxabi/trunk/CMakeLists.txt

 
 set(LIBCXXABI_LIBUNWIND_INCLUDES "${LIBCXXABI_LIBUNWIND_INCLUDES}" CACHE PATH
     "Specify path to libunwind includes." FORCE)
 set(LIBCXXABI_LIBUNWIND_PATH "${LIBCXXABI_LIBUNWIND_PATH}" CACHE PATH
     "Specify path to libunwind source." FORCE)
 
 include_directories(include)
 if (LIBCXXABI_USE_LLVM_UNWINDER OR LLVM_NATIVE_ARCH MATCHES ARM)
-  find_path(
-    LIBCXXABI_LIBUNWIND_INCLUDES_INTERNAL
-    libunwind.h
+  find_path(LIBCXXABI_LIBUNWIND_INCLUDES_INTERNAL libunwind.h
     PATHS ${LIBCXXABI_LIBUNWIND_INCLUDES}
           ${LIBCXXABI_LIBUNWIND_PATH}/include
           ${CMAKE_BINARY_DIR}/${LIBCXXABI_LIBUNWIND_INCLUDES}
           ${LLVM_MAIN_SRC_DIR}/projects/libunwind/include
           ${LLVM_MAIN_SRC_DIR}/runtimes/libunwind/include
           ${LLVM_MAIN_SRC_DIR}/../libunwind/include
     NO_DEFAULT_PATH
     NO_CMAKE_FIND_ROOT_PATH

libcxxabi/trunk/src/CMakeLists.txt

set(LIBCXXABI_SOURCES
   private_typeinfo.cpp
 )
 
 if (LIBCXXABI_ENABLE_NEW_DELETE_DEFINITIONS)
   list(APPEND LIBCXXABI_SOURCES stdlib_new_delete.cpp)
 endif()
 
 if (LIBCXXABI_ENABLE_EXCEPTIONS)
-  list(APPEND LIBCXXABI_SOURCES cxa_exception.cpp)
-  list(APPEND LIBCXXABI_SOURCES cxa_personality.cpp)
+  list(APPEND LIBCXXABI_SOURCES
+    cxa_exception.cpp
+    cxa_personality.cpp
+  )
 else()
-  list(APPEND LIBCXXABI_SOURCES cxa_noexception.cpp)
+  list(APPEND LIBCXXABI_SOURCES
+    cxa_noexception.cpp
+  )
 endif()
 
 if (LIBCXXABI_ENABLE_THREADS AND (UNIX OR FUCHSIA) AND NOT (APPLE OR CYGWIN))
   list(APPEND LIBCXXABI_SOURCES cxa_thread_atexit.cpp)
 endif()
 
-set(LIBCXXABI_HEADERS ../include/cxxabi.h)
+set(LIBCXXABI_HEADERS
+  ../include/cxxabi.h
+)
 
 # Add all the headers to the project for IDEs.
 if (MSVC_IDE OR XCODE)
   # Force them all into the headers dir on MSVC, otherwise they end up at
   # project scope because they don't have extensions.
   if (MSVC_IDE)
     source_group("Header Files" FILES ${LIBCXXABI_HEADERS})
   endif()

llvm/trunk/utils/gn/secondary/BUILD.gn

 import("//clang/lib/ARCMigrate/enable.gni")
 import("//clang/lib/StaticAnalyzer/Frontend/enable.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 group("default") {
   deps = [
     "//clang-tools-extra/clangd/test",
     "//clang-tools-extra/test",
     "//clang/test",
     "//lld/test",
     "//llvm/test",
   ]
   if (current_os == "linux") {
     deps += [
       "//compiler-rt",
+      "//libcxxabi",
       "//libunwind",
     ]
   }
   if (current_os == "linux" || current_os == "android") {
     deps += [ "//compiler-rt/test/hwasan" ]
   }
 
   testonly = true

llvm/trunk/utils/gn/secondary/libcxxabi/BUILD.gn

+group("libcxxabi") {
+  deps = [
+    "//libcxxabi/src(//llvm/utils/gn/build/toolchain:stage2_unix)",
+  ]
+}

llvm/trunk/utils/gn/secondary/libcxxabi/src/BUILD.gn

+import("//clang/runtimes.gni")
+
+declare_args() {
+  # Use exceptions.
+  libcxxabi_enable_exceptions = true
+
+  # Build libc++abi with definitions for operator new/delete.
+  libcxxabi_enable_new_delete_definitions = true
+
+  # Build libcxxabi as a shared library.
+  libcxxabi_enable_shared = true
+
+  # Build libcxxabi as a static library.
+  libcxxabi_enable_static = true
+
+  # Do not export any symbols from the static library.
+  libcxxabi_hermetic_static_library = true
+}
+
+cxxabi_headers = [
+  # This comment prevents `gn format` from putting the file on the same line
+  # as `sources +=`, for sync_source_lists_from_cmake.py.
+  "../include/cxxabi.h",
+]
+
+cxxabi_sources = [
+  # C++ABI files
+  "cxa_aux_runtime.cpp",
+  "cxa_default_handlers.cpp",
+  "cxa_demangle.cpp",
+  "cxa_exception_storage.cpp",
+  "cxa_guard.cpp",
+  "cxa_handlers.cpp",
+  "cxa_unexpected.cpp",
+  "cxa_vector.cpp",
+  "cxa_virtual.cpp",
+
+  # C++ STL files
+  "stdlib_exception.cpp",
+  "stdlib_stdexcept.cpp",
+  "stdlib_typeinfo.cpp",
+
+  # Internal files
+  "abort_message.cpp",
+  "fallback_malloc.cpp",
+  "private_typeinfo.cpp",
+]
+if (libcxxabi_enable_new_delete_definitions) {
+  cxxabi_sources += [ "stdlib_new_delete.cpp" ]
+}
+if (libcxxabi_enable_exceptions) {
+  cxxabi_sources += [
+    "cxa_exception.cpp",
+    "cxa_personality.cpp",
+  ]
+} else {
+  cxxabi_sources += [
+    # This comment prevents `gn format` from putting the file on the same line
+    # as `sources +=`, for sync_source_lists_from_cmake.py.
+    "cxa_noexception.cpp",
+  ]
+}
+if (target_os == "linux" || target_os == "fuchsia") {
+  cxxabi_sources += [
+    # This comment prevents `gn format` from putting the file on the same line
+    # as `sources +=`, for sync_source_lists_from_cmake.py.
+    "cxa_thread_atexit.cpp"
+  ]
+}
+
+config("cxxabi_config") {
+  include_dirs = [
+    "//libcxxabi/include",
+    "//libcxx/include",
+  ]
+  cflags_cc = [ "-nostdinc++" ]
+  defines = [ "_LIBCXXABI_BUILDING_LIBRARY" ]
+  if (target_os == "win") {
+    defines += [ "_LIBCXXABI_DISABLE_VISIBILITY_ANNOTATIONS" ]
+  }
+}
+
+if (libcxxabi_enable_shared) {
+  shared_library("cxxabi_shared") {
+    output_dir = runtimes_dir
+    output_name = "c++abi"
+    if (target_os == "linux" || target_os == "mac") {
+      cflags = [ "-fPIC" ]
+      ldflags = [ "-nostdlib++" ]
+      libs = [
+        "dl",
+        "pthread",
+      ]
+    }
+    sources = cxxabi_sources
+    public = cxxabi_headers
+    deps = [
+      "//compiler-rt/lib/builtins",
+      "//libunwind/src:unwind_shared",
+    ]
+    configs += [ ":cxxabi_config" ]
+    configs -= [
+      "//llvm/utils/gn/build:no_exceptions",
+      "//llvm/utils/gn/build:no_rtti",
+    ]
+  }
+}
+
+if (libcxxabi_enable_static) {
+  static_library("cxxabi_static") {
+    output_dir = runtimes_dir
+    output_name = "c++abi"
+    complete_static_lib = true
+    configs -= [ "//llvm/utils/gn/build:thin_archive" ]
+    sources = cxxabi_sources
+    public = cxxabi_headers
+    if (libcxxabi_hermetic_static_library) {
+      cflags = [ "-fvisibility=hidden" ]
+      cflags_cc = [ "-fvisibility-global-new-delete-hidden" ]
+      defines = [
+        "_LIBCXXABI_DISABLE_VISIBILITY_ANNOTATIONS",
+        "_LIBCPP_DISABLE_VISIBILITY_ANNOTATIONS",
+      ]
+    }
+    deps = [
+      "//compiler-rt/lib/builtins",
+      "//libunwind/src:unwind_static",
+    ]
+    configs += [ ":cxxabi_config" ]
+    configs -= [
+      "//llvm/utils/gn/build:no_exceptions",
+      "//llvm/utils/gn/build:no_rtti",
+    ]
+  }
+}
+
+group("src") {
+  deps = []
+  if (libcxxabi_enable_shared) {
+    deps += [ ":cxxabi_shared" ]
+  }
+  if (libcxxabi_enable_static) {
+    deps += [ ":cxxabi_static" ]
+  }
+}