[gn] Support for building libunwind

[phosek]

Summary

This change introduces support for building libuwind. The library
build should be complete, but not all CMake options have been
replicated in GN. We also don't support tests yet.

[thakis]

llvm/utils/gn/secondary/libunwind/src/BUILD.gn

20 ↗

(On Diff #194041)

probably need a comment here to keep the sync script happy?

23 ↗

(On Diff #194041)

Does making this a source_set and having both libs depend on that not work for static_library?

51 ↗

(On Diff #194041)

why do you remove config_nortti and then add -fno-rtti back in here? Can't you just not remove it in the first place?

77 ↗

(On Diff #194041)

It looks for .h files, no matter if in a target or not. Does not adding this to public help the script? That'd surprise me.

[phosek]

llvm/utils/gn/secondary/libunwind/src/BUILD.gn

23 ↗

(On Diff #194041)

I did that originally, but I changed it to build static and shared library separately, which follows the recent change to CMake build which also stopped using object library: https://github.com/llvm/llvm-project/commit/1de15f6f336dba6e26c18c224d1b53ba617f57f0#diff-2467f5cba1ecc34d53f4480cd654aa55 which is itself is a follow up to http://llvm.org/viewvc/llvm-project?view=revision&revision=356150.

The reason why we did that for libunwind, libc++abi and libunwind is because it's sometimes necessary to use different options for the static and shared library, e.g. on some platforms static library would be built without -fPIC but shared would still use it. In case of Fuchsia we also use libunwind_hermetic_static_library option which requires building static library objects with -fvisibility=hidden. This required a lot of complicated logic, not using the source set actually makes it simpler in this case.

51 ↗

(On Diff #194041)

In CMake build, it's possible to re-enable RTTI using the LLVM_ENABLE_RTTI that some users actually use, especially when linking LLVM into other projects. Do we plan on providing the same flag in LLVM build? If yes, that would be an argument for setting -fno-rtti here explicitly because it should be independent of the global LLVM setup.

77 ↗

(On Diff #194041)

I think the problem is that the CMake build uses ${CMAKE_CURRENT_SOURCE_DIR}/../include/libunwind.h while I tried using ../include/libunwind.h, the script doesn't seem to handle variables or ... Any suggestions how to work around it?

[thakis]

llvm/utils/gn/secondary/libunwind/src/BUILD.gn

51 ↗

(On Diff #194041)

Not unless someone needs it. I'd default to not adding things until they're needed.

77 ↗

(On Diff #194041)

Is the ${CMAKE_CURRENT_SOURCE_DIR} needed on the cmake side? Some places don't use it:

$ git grep '\.\..*\.h' 'clang*CMake*'
clang/tools/libclang/CMakeLists.txt: ../../include/clang-c/Index.h

libunwind/trunk/src/CMakeLists.txt

 # Get sources
 
 set(LIBUNWIND_CXX_SOURCES
     libunwind.cpp
     Unwind-EHABI.cpp
-    Unwind-seh.cpp)
+    Unwind-seh.cpp
+    )
 unwind_append_if(LIBUNWIND_CXX_SOURCES APPLE Unwind_AppleExtras.cpp)
 
 set(LIBUNWIND_C_SOURCES
     UnwindLevel1.c
     UnwindLevel1-gcc-ext.c
-    Unwind-sjlj.c)
+    Unwind-sjlj.c
+    )
 set_source_files_properties(${LIBUNWIND_C_SOURCES}
                             PROPERTIES
                               COMPILE_FLAGS "-std=c99")
 
 set(LIBUNWIND_ASM_SOURCES
     UnwindRegistersRestore.S
-    UnwindRegistersSave.S)
+    UnwindRegistersSave.S
+    )
 set_source_files_properties(${LIBUNWIND_ASM_SOURCES}
                             PROPERTIES
                               LANGUAGE C)
 
 set(LIBUNWIND_HEADERS
     AddressSpace.hpp
     assembly.h
     CompactUnwinder.hpp
     config.h
     dwarf2.h
     DwarfInstructions.hpp
     DwarfParser.hpp
     libunwind_ext.h
     Registers.hpp
     RWMutex.hpp
     UnwindCursor.hpp
-    ${CMAKE_CURRENT_SOURCE_DIR}/../include/libunwind.h
-    ${CMAKE_CURRENT_SOURCE_DIR}/../include/unwind.h)
+    ../include/libunwind.h
+    ../include/unwind.h
+    )
 
 unwind_append_if(LIBUNWIND_HEADERS APPLE
-          "${CMAKE_CURRENT_SOURCE_DIR}/../include/mach-o/compact_unwind_encoding.h")
+    ../include/mach-o/compact_unwind_encoding.h
+    )
 
 if (MSVC_IDE)
   # Force them all into the headers dir on MSVC, otherwise they end up at
   # project scope because they don't have extensions.
   source_group("Header Files" FILES ${LIBUNWIND_HEADERS})
 endif()
 
 set(LIBUNWIND_SOURCES

llvm/trunk/utils/gn/secondary/BUILD.gn

 import("//clang/lib/ARCMigrate/enable.gni")
 import("//clang/lib/StaticAnalyzer/Frontend/enable.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 group("default") {
   deps = [
     "//clang-tools-extra/clangd/test",
     "//clang-tools-extra/test",
     "//clang/test",
     "//lld/test",
     "//llvm/test",
   ]
   if (current_os == "linux") {
-    deps += [ "//compiler-rt" ]
+    deps += [
+      "//compiler-rt",
+      "//libunwind",
+    ]
   }
   if (current_os == "linux" || current_os == "android") {
     deps += [ "//compiler-rt/test/hwasan" ]
   }
 
   testonly = true
 }
 

llvm/trunk/utils/gn/secondary/libunwind/BUILD.gn

+group("libunwind") {
+  deps = [
+    "//libunwind/src(//llvm/utils/gn/build/toolchain:stage2_unix)",
+  ]
+}

llvm/trunk/utils/gn/secondary/libunwind/src/BUILD.gn

+import("//clang/runtimes.gni")
+
+declare_args() {
+  # Build libunwind as a shared library.
+  libunwind_enable_shared = true
+
+  # Build libunwind as a static library.
+  libunwind_enable_static = true
+
+  # Do not export any symbols from the static library.
+  libunwind_hermetic_static_library = true
+}
+
+unwind_headers = [
+  "../include/libunwind.h",
+  "../include/unwind.h",
+]
+if (target_os == "mac") {
+  unwind_headers += [
+    # This comment prevents `gn format` from putting the file on the same line
+    # as `sources +=`, for sync_source_lists_from_cmake.py.
+    "../include/mach-o/compact_unwind_encoding.h",
+  ]
+}
+
+unwind_sources = [
+  "libunwind.cpp",
+  "Unwind-EHABI.cpp",
+  "Unwind-seh.cpp",
+  "UnwindLevel1.c",
+  "UnwindLevel1-gcc-ext.c",
+  "Unwind-sjlj.c",
+  "UnwindRegistersRestore.S",
+  "UnwindRegistersSave.S",
+  "AddressSpace.hpp",
+  "assembly.h",
+  "CompactUnwinder.hpp",
+  "config.h",
+  "dwarf2.h",
+  "DwarfInstructions.hpp",
+  "DwarfParser.hpp",
+  "libunwind_ext.h",
+  "Registers.hpp",
+  "RWMutex.hpp",
+  "UnwindCursor.hpp",
+]
+if (target_os == "mac") {
+  unwind_sources += [ "src/Unwind_AppleExtras.cpp" ]
+}
+
+config("unwind_config") {
+  cflags = []
+  cflags_c = [ "-std=c99" ]
+  cflags_cc = [ "-fno-rtti" ]
+  include_dirs = [ "//libunwind/include" ]
+  if (target_os == "mac") {
+    cflags += [ "-U__STRICT_ANSI__" ]
+  }
+}
+
+if (libunwind_enable_shared) {
+  shared_library("unwind_shared") {
+    output_dir = runtimes_dir
+    output_name = "unwind"
+    if (target_os == "linux" || target_os == "mac") {
+      cflags = [ "-fPIC" ]
+      ldflags = [ "-nostdlib++" ]
+      libs = [
+        "dl",
+        "pthread",
+      ]
+    }
+    if (target_os == "mac") {
+      ldflags += [
+        "-compatibility_version 1",
+        "-install_name /usr/lib/libunwind.1.dylib",
+      ]
+    }
+    sources = unwind_sources
+    public = unwind_headers
+    deps = [
+      "//compiler-rt/lib/builtins",
+    ]
+    configs += [ ":unwind_config" ]
+    configs -= [
+      "//llvm/utils/gn/build:no_exceptions",
+      "//llvm/utils/gn/build:no_rtti",
+    ]
+  }
+}
+
+if (libunwind_enable_static) {
+  static_library("unwind_static") {
+    output_dir = runtimes_dir
+    output_name = "unwind"
+    complete_static_lib = true
+    configs -= [ "//llvm/utils/gn/build:thin_archive" ]
+    sources = unwind_sources
+    public = unwind_headers
+    if (libunwind_hermetic_static_library) {
+      cflags = [ "-fvisibility=hidden" ]
+      cflags_cc = [ "-fvisibility-global-new-delete-hidden" ]
+      defines = [ "_LIBUNWIND_DISABLE_VISIBILITY_ANNOTATIONS" ]
+    }
+    deps = [
+      "//compiler-rt/lib/builtins",
+    ]
+    configs += [ ":unwind_config" ]
+    configs -= [
+      "//llvm/utils/gn/build:no_exceptions",
+      "//llvm/utils/gn/build:no_rtti",
+    ]
+  }
+}
+
+group("src") {
+  deps = []
+  if (libunwind_enable_shared) {
+    deps += [ ":unwind_shared" ]
+  }
+  if (libunwind_enable_static) {
+    deps += [ ":unwind_static" ]
+  }
+}