Wrong debug info generated at -O2 (-O0 is correct)

[kamleshbhalui]

Summary

Instcombiner pass was erasing trivially dead instruction without updating dependent llvm.dbg.value.
which was not showing programmer current state of variables while debugging.
As a part of this fix I did following,
Iterate throught all the users (llvm.dbg) of a instruction which is trivially dead and set each if them undef, Before deleting the instruction.
Now user will see optimized out, when try to print those variables.
This fixes
https://bugs.llvm.org/show_bug.cgi?id=43893

This is my first fix to llvm.

[lebedev.ri]

llvm/lib/Transforms/InstCombine/InstructionCombining.cpp

3217

What about other users of eraseInstFromFunction()?
Should this go into that function?

[davide]

llvm/lib/Transforms/InstCombine/InstructionCombining.cpp

3215–3223

I think there should be an utility to do this. Did you check what other callers of isInstructionTriviallyDead do? e.g. EarlyCSE ?

[kamleshbhalui]

Used the existing utility, which can be seen in other places too.

[kamleshbhalui]

Formatted the diff.

[davide]

LGTM. @aprantl / @vsk ? Do you need somebody to commit this for you?

[davide]

I'll commit this for you later tonight.

[davide]

uh, how can this possibly work?

[1/47] Building CXX object lib/Transforms/InstCombine/CMakeFiles/LLVMInstCombine.dir/InstructionCombining.cpp.o
/Users/dcci/work/llvm-mono/llvm-project/llvm/lib/Transforms/InstCombine/InstructionCombining.cpp:3237:33: warning: if statement has empty body [-Wempty-body]
      if (!salvageDebugInfo(*I));
                                ^
/Users/dcci/work/llvm-mono/llvm-project/llvm/lib/Transforms/InstCombine/InstructionCombining.cpp:3237:33: note: put the semicolon on a separate line to silence this warning
1 warning generated.

[davide]

If I fix your patch by removing the semicolon, I see three tests failing.

Testing Time: 412.65s
********************
Failing Tests (3):
    LLVM :: Transforms/InstCombine/cast-mul-select.ll
    LLVM :: Transforms/InstCombine/debuginfo-dce.ll
    LLVM :: Transforms/InstCombine/stacksave-debuginfo.ll

  Expected Passes    : 32961
  Expected Failures  : 151
  Unsupported Tests  : 1107
  Unexpected Failures: 3

Can you please look at these [and make sure you rerun ninja check-llvm if you modify the patch?]. Thanks.

[kamleshbhalui]

Oops, semicolon due to screwed-up formatting.

Removed the semicolon and updated other failing test cases.

[davide]

llvm/test/Transforms/InstCombine/debuginfo-dce.ll

36–37

Do you know why this changed?

[kamleshbhalui]

llvm/test/Transforms/InstCombine/debuginfo-dce.ll

36–37

Before the fix instcombiner was deleting all the users (even dbg.value ) of a trivially dead instruction.
But now we mark dbg.value as undef instead of deleting it .
and that's why modified the check like this.

[lebedev.ri]

llvm/lib/Transforms/InstCombine/InstructionCombining.cpp

3217

My comment wasn't addressed.

[djtodoro]

llvm/test/Transforms/InstCombine/pr43893.ll

26

This is unused. We can delete this from the test.

[kamleshbhalui]

llvm/lib/Transforms/InstCombine/InstructionCombining.cpp

3217

I have seen this is in EarlyCSE.
And yes, It should go into several other places too, But need to come up with testcases.

[kamleshbhalui]

removed unused declaration from testcase(pr43893.ll)

[kamleshbhalui]

llvm/test/Transforms/InstCombine/pr43893.ll

26

Yes deleted that.

[jmorse]

A few nits inline, otherwise great!

llvm/lib/Transforms/InstCombine/InstructionCombining.cpp

3217

replaceDbgUsesWithUndef should quite possibly go into the intstruction-deleting methods, D69787 even puts salvageDebugInfo in those methods too. It's not clear to me why this hasn't always been the case (performance)? IMO, that would be another patch though.

llvm/test/Transforms/InstCombine/debuginfo-dce.ll

36–37

Best to give the checked-for dbg.value an operand, so "dbg.value(metadata %struct.entry *undef" or similar. Otherwise this isn't fully checking for the correct behaviour here.

llvm/test/Transforms/InstCombine/pr43893.ll

1

It'd be nice to have a summary comment at the top of the test, explaining what it's testing for.

32

We usually delete all attributes from tests, as they're an un-necessary maintenance burden.

[kamleshbhalui]

Cleaned up and added comments in testcase.

[jmorse]

LGTM, although it's worth leaving this 24h in case other reviewers have an opinion.

[vsk]

@kamleshbhalui thanks for working on this, and welcome to llvm :)

eraseInstFromFunction already calls salvageDebufInfo: why not have it call replaceDbgUsesWithUndef as well, or better, define a salvageDebufInfoOrMarkUndef helper? I'd expect that to be reasonable to tackle in this patch.

llvm/test/Transforms/InstCombine/stacksave-debuginfo.ll

11–15

Please do not hardcode metadata numbers in check lines. If the variable referenced by a metadata node is obvious from context, it's better not to match the number at all.

[kamleshbhalui]

Incorporated @vsk comments.

[vsk]

Looks great, thanks. @lebedev.ri, @davide -- it looks like your comments are addressed. All tests pass locally for me. I'll wait a day to be safe, then land this on kamlesh's behalf if no one beats me to it.

[davide]

Go for it.

llvm/lib/Transforms/InstCombine/InstructionCombining.cpp

 bool InstCombiner::run() {
   while (!Worklist.isEmpty()) {
     Instruction *I = Worklist.RemoveOne();
     if (I == nullptr) continue;  // skip null values.
 
     // Check to see if we can DCE the instruction.
     if (isInstructionTriviallyDead(I, &TLI)) {
       LLVM_DEBUG(dbgs() << "IC: DCE: " << *I << '\n');
+
+      if (!salvageDebugInfo(*I))
+        replaceDbgUsesWithUndef(I);
       eraseInstFromFunction(*I);
       ++NumDeadInst;
       MadeIRChange = true;
       continue;
     }
 
     if (!DebugCounter::shouldExecute(VisitCounter))
       continue;
 
     // Instruction isn't dead, see if we can constant propagate it.
     if (!I->use_empty() &&
         (I->getNumOperands() == 0 || isa<Constant>(I->getOperand(0)))) {
       if (Constant *C = ConstantFoldInstruction(I, DL, &TLI)) {
         LLVM_DEBUG(dbgs() << "IC: ConstFold to: " << *C << " from: " << *I
                           << '\n');

llvm/test/Transforms/InstCombine/cast-mul-select.ll

 ; RUN: opt < %s -instcombine -S | FileCheck %s
 ; RUN: opt -debugify -instcombine -S < %s | FileCheck %s -check-prefix DBGINFO
 
 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32"
 
 define i32 @mul(i32 %x, i32 %y) {
 ; CHECK-LABEL: @mul(
 ; CHECK-NEXT:    [[C:%.*]] = mul i32 [[X:%.*]], [[Y:%.*]]
 ; CHECK-NEXT:    [[D:%.*]] = and i32 [[C]], 255
 ; CHECK-NEXT:    ret i32 [[D]]
 
 ; Test that when zext is evaluated in different type
 ; we preserve the debug information in the resulting
 ; instruction.
 ; DBGINFO-LABEL: @mul(
+; DBGINFO-NEXT:    call void @llvm.dbg.value(metadata i8 undef
+; DBGINFO-NEXT:    call void @llvm.dbg.value(metadata i8 undef
 ; DBGINFO-NEXT:    [[C:%.*]] = mul i32 {{.*}}
 ; DBGINFO-NEXT:    [[D:%.*]] = and i32 {{.*}}
 ; DBGINFO-NEXT:    call void @llvm.dbg.value(metadata i32 [[C]]
 ; DBGINFO-NEXT:    call void @llvm.dbg.value(metadata i32 [[D]]
 
   %A = trunc i32 %x to i8
   %B = trunc i32 %y to i8
   %C = mul i8 %A, %B

llvm/test/Transforms/InstCombine/debuginfo-dce.ll

 ; be maintained.
 define void @salvage_load(%struct.entry** %queue) local_unnamed_addr #0 !dbg !14 {
 entry:
   %im_not_dead = alloca %struct.entry*
   %0 = load %struct.entry*, %struct.entry** %queue, align 8, !dbg !19
   %1 = load %struct.entry*, %struct.entry** %queue, align 8, !dbg !19
   call void @llvm.dbg.value(metadata %struct.entry* %1, metadata !18, metadata !20), !dbg !19
 ; CHECK: define void @salvage_load
 ; CHECK-NEXT: entry:
-; CHECK-NOT: dbg.value
+; CHECK-NEXT: dbg.value
   store %struct.entry* %1, %struct.entry** %im_not_dead, align 8
   ret void, !dbg !21
 }
 
 define void @salvage_bitcast(%struct.entry* %queue) local_unnamed_addr #0 !dbg !22 {
 entry:
   %im_not_dead = alloca i8*
   %0 = bitcast %struct.entry* %queue to i8*, !dbg !23

llvm/test/Transforms/InstCombine/pr43893.ll

+; RUN: opt -instcombine -S -o - %s | FileCheck %s
+
+@a = common dso_local global i8 0, align 1, !dbg !0
+@b = common dso_local global i8 0, align 1, !dbg !6
+
+; Function Attrs: noinline nounwind uwtable
+define dso_local i32 @main() #0 !dbg !13 {
+entry:
+  %0 = load i8, i8* @a, align 1, !dbg !17
+  %dec = add i8 %0, -1, !dbg !17
+  store i8 %dec, i8* @a, align 1, !dbg !17
+;CHECK: call void @llvm.dbg.value(metadata i32 undef
+;CHECK: call void @llvm.dbg.value(metadata i32 -8
+;CHECK call void @llvm.dbg.value(metadata i32 undef
+  %conv = sext i8 %dec to i32, !dbg !17
+  call void @llvm.dbg.value(metadata i32 %conv, metadata !18, metadata !DIExpression()), !dbg !19
+  call void @llvm.dbg.value(metadata i32 -8, metadata !20, metadata !DIExpression()), !dbg !19
+  call void @llvm.dbg.value(metadata i32 %conv, metadata !20, metadata !DIExpression()), !dbg !19
+  store i8 0, i8* @b, align 1, !dbg !21
+  %cmp = icmp sgt i32 %conv, 0, !dbg !22
+  %conv1 = zext i1 %cmp to i32, !dbg !22
+  ret i32 0, !dbg !23
+}
+
+; Function Attrs: nounwind readnone speculatable willreturn
+declare void @llvm.dbg.declare(metadata, metadata, metadata) #1
+
+; Function Attrs: nounwind readnone speculatable willreturn
+declare void @llvm.dbg.value(metadata, metadata, metadata) #1
+
+attributes #0 = { noinline nounwind uwtable }
+attributes #1 = { nounwind readnone speculatable willreturn }
+
+!llvm.dbg.cu = !{!2}
+!llvm.module.flags = !{!9, !10, !11}
+!llvm.ident = !{!12}
+
+!0 = !DIGlobalVariableExpression(var: !1, expr: !DIExpression())
+!1 = distinct !DIGlobalVariable(name: "a", scope: !2, file: !3, line: 1, type: !8, isLocal: false, isDefinition: true)
+!2 = distinct !DICompileUnit(language: DW_LANG_C99, file: !3, producer: "clang version 10.0.0", isOptimized: false, runtimeVersion: 0, emissionKind: FullDebug, enums: !4, globals: !5, nameTableKind: None)
+!3 = !DIFile(filename: "test", directory: "n")
+!4 = !{}
+!5 = !{!0, !6}
+!6 = !DIGlobalVariableExpression(var: !7, expr: !DIExpression())
+!7 = distinct !DIGlobalVariable(name: "b", scope: !2, file: !3, line: 1, type: !8, isLocal: false, isDefinition: true)
+!8 = !DIBasicType(name: "char", size: 8, encoding: DW_ATE_signed_char)
+!9 = !{i32 2, !"Dwarf Version", i32 4}
+!10 = !{i32 2, !"Debug Info Version", i32 3}
+!11 = !{i32 1, !"wchar_size", i32 4}
+!12 = !{!"clang version 10.0.0"}
+!13 = distinct !DISubprogram(name: "main", scope: !3, file: !3, line: 2, type: !14, scopeLine: 2, spFlags: DISPFlagDefinition, unit: !2, retainedNodes: !4)
+!14 = !DISubroutineType(types: !15)
+!15 = !{!16}
+!16 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
+!17 = !DILocation(line: 4, column: 11, scope: !13)
+!18 = !DILocalVariable(name: "c", scope: !13, file: !3, line: 4, type: !16)
+!19 = !DILocation(line: 0, scope: !13)
+!20 = !DILocalVariable(name: "l_1240", scope: !13, file: !3, line: 6, type: !16)
+!21 = !DILocation(line: 10, column: 10, scope: !13)
+!22 = !DILocation(line: 10, column: 5, scope: !13)
+!23 = !DILocation(line: 12, column: 1, scope: !13)

llvm/test/Transforms/InstCombine/stacksave-debuginfo.ll

 ; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
 ; dbg.value instrinsics should not affect peephole combining of stacksave/stackrestore.
 ; PR37713
 ; RUN: opt -instcombine %s -S | FileCheck %s
 
 declare i8* @llvm.stacksave() #0
 declare void @llvm.stackrestore(i8*) #0
 
 define i32* @test1(i32 %P) !dbg !6 {
 ; CHECK-LABEL: @test1(
-; CHECK-NEXT:    [[TMP1:%.*]] = zext i32 [[P:%.*]] to i64, !dbg !12
-; CHECK-NEXT:    [[A:%.*]] = alloca i32, i64 [[TMP1]], align 4, !dbg !12
-; CHECK-NEXT:    call void @llvm.dbg.value(metadata i32* [[A]], metadata !11, metadata !DIExpression()), !dbg !12
-; CHECK-NEXT:    ret i32* [[A]], !dbg !13
+; CHECK-NEXT:    call void @llvm.dbg.value(metadata i8* undef, metadata !9, metadata !DIExpression()), !dbg !12
+; CHECK-NEXT:    [[TMP1:%.*]] = zext i32 [[P:%.*]] to i64, !dbg !13
+; CHECK-NEXT:    [[A:%.*]] = alloca i32, i64 [[TMP1]], align 4, !dbg !13
+; CHECK-NEXT:    call void @llvm.dbg.value(metadata i32* [[A]], metadata !11, metadata !DIExpression()), !dbg !13
+; CHECK-NEXT:    ret i32* [[A]], !dbg !14
 ;
   %tmp = call i8* @llvm.stacksave(), !dbg !12
   call void @llvm.dbg.value(metadata i8* %tmp, metadata !9, metadata !DIExpression()), !dbg !12
   call void @llvm.stackrestore(i8* %tmp), !dbg !13
   %A = alloca i32, i32 %P, !dbg !14
   call void @llvm.dbg.value(metadata i32* %A, metadata !11, metadata !DIExpression()), !dbg !14
   ret i32* %A, !dbg !15
 }