[compiler-rt][XRay] Stash xmm registers in the trampolines

[dberris]

Summary

We now stash and restore the xmm registers in the trampolines so that
log handlers don't need to worry about clobbering these registers.

In response to comments in D21612.

[dberris]

• Fixed the wrong math on stack adjustment

[rSerge]

lib/xray/xray_trampoline_x86.S

92–97

Wouldn't it suffice to save only xmm0 and xmm1 here? As I understood, no calling convention uses registers beyond xmm1 for return values: http://www.agner.org/optimize/calling_conventions.pdf

[dberris]

Only save xmm0 and xmm1 on the exit trampoline

lib/xray/xray_trampoline_x86.S

92–97

It should be -- thanks for the link!

[rnk]

lgtm

lib/xray/xray_trampoline_x86.S

//===----------------------------------------------------------------------===//
   .align 16, 0x90
   .type __xray_FunctionEntry,@function
 
 __xray_FunctionEntry:
   .cfi_startproc
   // Save caller provided registers before doing any actual work.
   pushq %rbp
   .cfi_def_cfa_offset 16
-  subq $72, %rsp
+  subq $200, %rsp
+  movupd  %xmm0, 184(%rsp)
+  movupd  %xmm1, 168(%rsp)
+  movupd  %xmm2, 152(%rsp)
+  movupd  %xmm3, 136(%rsp)
+  movupd  %xmm4, 120(%rsp)
+  movupd  %xmm5, 104(%rsp)
+  movupd  %xmm6, 88(%rsp)
+  movupd  %xmm7, 72(%rsp)
   movq  %rdi, 64(%rsp)
   movq  %rax, 56(%rsp)
   movq  %rdx, 48(%rsp)
   movq  %rsi, 40(%rsp)
   movq  %rcx, 32(%rsp)
   movq  %r8, 24(%rsp)
   movq  %r9, 16(%rsp)
 
   // de-mangled, that's __xray::XRayPatchedFunction, and we're doing an acquire
   // load (on x86 is a normal mov instruction).
   movq  _ZN6__xray19XRayPatchedFunctionE(%rip), %rax
   testq %rax, %rax
   je  .Ltmp0
 
   // assume that %r10d has the function id.
   movl  %r10d, %edi
   xor %esi,%esi
   callq *%rax
 .Ltmp0:
   // restore the registers
+  movupd  184(%rsp), %xmm0
+  movupd  168(%rsp), %xmm1
+  movupd  152(%rsp), %xmm2
+  movupd  136(%rsp), %xmm3
+  movupd  120(%rsp), %xmm4
+  movupd  104(%rsp), %xmm5
+  movupd  88(%rsp) , %xmm6
+  movupd  72(%rsp) , %xmm7
   movq  64(%rsp), %rdi
   movq  56(%rsp), %rax
   movq  48(%rsp), %rdx
   movq  40(%rsp), %rsi
   movq  32(%rsp), %rcx
   movq  24(%rsp), %r8
   movq  16(%rsp), %r9
-  addq  $72, %rsp
+  addq  $200, %rsp
   popq  %rbp
   retq
 .Ltmp1:
   .size __xray_FunctionEntry, .Ltmp1-__xray_FunctionEntry
   .cfi_endproc
 
   .globl __xray_FunctionExit
   .align 16, 0x90
   .type __xray_FunctionExit,@function
 __xray_FunctionExit:
   .cfi_startproc
   // Save the important registers first. Since we're assuming that this
   // function is only jumped into, we only preserve the registers for
   // returning.
-  // FIXME: Figure out whether this is sufficient.
   pushq %rbp
   .cfi_def_cfa_offset 16
-  subq  $24, %rsp
+  subq  $152, %rsp
   .cfi_def_cfa_offset 32
+  movupd  %xmm0, 136(%rsp)
+  movupd  %xmm1, 120(%rsp)
+  movupd  %xmm2, 104(%rsp)
+  movupd  %xmm3, 88(%rsp)
+  movupd  %xmm4, 72(%rsp)
+  movupd  %xmm5, 56(%rsp)
+  movupd  %xmm6, 40(%rsp)
+  movupd  %xmm7, 24(%rsp)
   movq  %rax, 16(%rsp)
   movq  %rdx, 8(%rsp)
   movq  _ZN6__xray19XRayPatchedFunctionE(%rip), %rax
   testq %rax,%rax
   je  .Ltmp2
 
   movl  %r10d, %edi
   movl  $1, %esi
   callq *%rax
 .Ltmp2:
   // Restore the important registers.
+  movupd  136(%rsp), %xmm0
+  movupd  120(%rsp), %xmm1
+  movupd  104(%rsp), %xmm2
+  movupd  88(%rsp), %xmm3
+  movupd  72(%rsp), %xmm4
+  movupd  56(%rsp), %xmm5
+  movupd  40(%rsp), %xmm6
+  movupd  24(%rsp), %xmm7
   movq  16(%rsp), %rax
   movq  8(%rsp), %rdx
-  addq  $24, %rsp
+  addq  $152, %rsp
   popq  %rbp
   retq
 .Ltmp3:
   .size __xray_FunctionExit, .Ltmp3-__xray_FunctionExit
   .cfi_endproc