[IPSCCP] Don't require noundef for !range annotation

[nikic]

Summary

Since https://reviews.llvm.org/D141386 !range violations return poison instead of causing immediate undefined behavior. As such, it is fine for IPSCCP to infer !range even if the value might be poison. (The value cannot be undef as this would promote undef to poison, but this is already checked separately.)

This basically undoes the late change done to D83952, restoring it to its original version (which is now valid).

[nikic]

ping

[fhahn]

LGTM, thanks! The range is guaranteed to not include undef as per an earlier check.

[tingwang]

I saw following case failed due to this commit with IPSCCPPass opt -passes="ipsccp"

; ModuleID = 'ld-temp.o'
source_filename = "ld-temp.o"
target datalayout = "e-m:e-i64:64-n32:64-S128-v256:256:256-v512:512:512"
target triple = "powerpc64le-unknown-linux-gnu"

; Function Attrs: noinline nounwind optnone uwtable
define internal <2 x i64> @cntlzVector(<2 x i64> noundef %0) #0 {
  %2 = alloca <2 x i64>, align 16
  %3 = alloca <2 x i64>, align 16
  store <2 x i64> %0, ptr %3, align 16
  %4 = load <2 x i64>, ptr %3, align 16
  store <2 x i64> %4, ptr %2, align 16
  %5 = load <2 x i64>, ptr %2, align 16
  %6 = call <2 x i64> @llvm.ctlz.v2i64(<2 x i64> %5, i1 false)
  ret <2 x i64> %6
}

; Function Attrs: mustprogress nocallback nofree nosync nounwind speculatable willreturn memory(none)
declare <2 x i64> @llvm.ctlz.v2i64(<2 x i64>, i1 immarg) #1

; Function Attrs: noinline nounwind optnone uwtable
define dso_local signext i32 @main() #0 {
  %1 = alloca i32, align 4
  %2 = alloca <2 x i64>, align 16
  store i32 0, ptr %1, align 4
  %3 = load <2 x i64>, ptr %2, align 16
  %4 = call <2 x i64> @cntlzVector(<2 x i64> noundef %3)
  store <2 x i64> %4, ptr %2, align 16
  ret i32 0
}

attributes #0 = { noinline nounwind optnone uwtable "frame-pointer"="all" "no-trapping-math"="true" "stack-protector-buffer-size"="8" "target-cpu"="ppc64le" "target-features"="+altivec,+bpermd,+crbits,+crypto,+direct-move,+extdiv,+htm,+isa-v206-instructions,+isa-v207-instructions,+power8-vector,+vsx,-isa-v30-instructions,-power9-vector,-privileged,-quadword-atomics,-rop-protect,-spe" }
attributes #1 = { mustprogress nocallback nofree nosync nounwind speculatable willreturn }

!llvm.ident = !{!0}
!llvm.module.flags = !{!1, !2, !3, !4, !5, !6, !7, !8}

!0 = !{!""}
!1 = !{i32 1, !"wchar_size", i32 4}
!2 = !{i32 8, !"PIC Level", i32 2}
!3 = !{i32 7, !"PIE Level", i32 2}
!4 = !{i32 7, !"uwtable", i32 2}
!5 = !{i32 7, !"frame-pointer", i32 2}
!6 = !{i32 1, !"ThinLTO", i32 0}
!7 = !{i32 1, !"EnableSplitLTOUnit", i32 1}
!8 = !{i32 1, !"LTOPostLink", i32 1}

[nikic]

@tingwang Thanks for the report. Here's a reduced test case:

define internal <2 x i64> @ctlz(<2 x i64> %arg) {
  %res = call <2 x i64> @llvm.ctlz.v2i64(<2 x i64> %arg, i1 false)
  ret <2 x i64> %res
}

define <2 x i64> @caller(<2 x i64> %arg) {
  %res = call <2 x i64> @ctlz(<2 x i64> %arg)
  ret <2 x i64> %res
}

declare <2 x i64> @llvm.ctlz.v2i64(<2 x i64>, i1)

The problem is that !range is currently not supported for vector types.

[nikic]

Fixed by https://github.com/llvm/llvm-project/commit/e0282cb4da9402de5712ac7855af6c71a03d0c19.

[DavidSpickett]

After this change one of our bots started failing a gcc test suite test on our SVE bot. However on closer inspection, it was that clang is now able to tail call some things it previously couldn't. Which is actually a good thing!

I've posted a fix for the test file https://reviews.llvm.org/D146143.

llvm/lib/Transforms/IPO/SCCP.cpp

if (ReturnValue.isConstantRange() &&
         continue;
 
       auto &CR = ReturnValue.getConstantRange();
       for (User *User : F->users()) {
         auto *CB = dyn_cast<CallBase>(User);
         if (!CB || CB->getCalledFunction() != F)
           continue;
 
-        // Limit to cases where the return value is guaranteed to be neither
-        // poison nor undef. Poison will be outside any range and currently
-        // values outside of the specified range cause immediate undefined
-        // behavior.
-        if (!isGuaranteedNotToBeUndefOrPoison(CB, nullptr, CB))
-          continue;
-
         // Do not touch existing metadata for now.
         // TODO: We should be able to take the intersection of the existing
         // metadata and the inferred range.
         if (CB->getMetadata(LLVMContext::MD_range))
           continue;
 
         LLVMContext &Context = CB->getParent()->getContext();
         Metadata *RangeMD[] = {

llvm/test/Transforms/SCCP/ip-add-range-to-call.ll

 ; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
 ; RUN: opt -passes=ipsccp -S %s | FileCheck %s
 
 ; Test 1.
 ; Both arguments and return value of @callee can be tracked. The inferred range
 ; can be added to call sites.
-define internal noundef i32 @callee(i32 %x) {
+define internal i32 @callee(i32 %x) {
 ; CHECK-LABEL: @callee(
 ; CHECK-NEXT:    ret i32 [[X:%.*]]
 ;
   ret i32 %x
 }
 
 define i32 @caller1() {
 ; CHECK-LABEL: @caller1(

 
 ; Test 2.
 ; The return value of @callee2 can be tracked, but arguments cannot, because
 ; it is passed to @use_cb1. We cannot infer a range for the return value, no
 ; metadata should be added.
 
 declare void @use_cb1(ptr)
 
-define internal noundef i32 @callee2(i32 %x) {
+define internal i32 @callee2(i32 %x) {
 ; CHECK-LABEL: @callee2(
 ; CHECK-NEXT:    ret i32 [[X:%.*]]
 ;
   ret i32 %x
 }
 
 define void @caller_cb1() {
 ; CHECK-LABEL: @caller_cb1(

 
 ; Test 3.
 ; The return value can be tracked and it the result range ([500, 601) does not
 ; depend on the arguments, which cannot be tracked because @callee3 is passed
 ; to @use_cb2. The result range can be added to the call sites of @callee.
 
 declare void @use_cb2(ptr)
 
-define internal noundef i32 @callee3(i32 %x) {
+define internal i32 @callee3(i32 %x) {
 ; CHECK-LABEL: @callee3(
 ; CHECK-NEXT:    [[C:%.*]] = icmp eq i32 [[X:%.*]], 10
 ; CHECK-NEXT:    [[S:%.*]] = select i1 [[C]], i32 500, i32 600
 ; CHECK-NEXT:    ret i32 [[S]]
 ;
   %c = icmp eq i32 %x, 10
   %s = select i1 %c, i32 500, i32 600
   ret i32 %s

 }
 
 ; Test 4.
 ; The return value of @callee4 can be tracked, but depends on an argument which
 ; cannot be tracked. No result range can be inferred.
 
 declare void @use_cb3(ptr)
 
-define internal noundef i32 @callee4(i32 %x, i32 %y) {
+define internal i32 @callee4(i32 %x, i32 %y) {
 ; CHECK-LABEL: @callee4(
 ; CHECK-NEXT:    [[C:%.*]] = icmp eq i32 [[X:%.*]], 10
 ; CHECK-NEXT:    [[S:%.*]] = select i1 [[C]], i32 500, i32 [[Y:%.*]]
 ; CHECK-NEXT:    ret i32 [[S]]
 ;
   %c = icmp eq i32 %x, 10
   %s = select i1 %c, i32 500, i32 %y
   ret i32 %s
;
   %c2 = call i32 @callee4(i32 12, i32 40)
   call void @use_cb3(ptr @callee4)
   ret void
 }
 
 ; Test 5.
 ; Range for the return value of callee5 includes undef. No range metadata
 ; should be added at call sites.
-define internal noundef i32 @callee5(i32 %x, i32 %y) {
+define internal i32 @callee5(i32 %x, i32 %y) {
 ; CHECK-LABEL: @callee5(
 ; CHECK-NEXT:    [[C:%.*]] = icmp slt i32 [[X:%.*]], 15
 ; CHECK-NEXT:    br i1 [[C]], label [[BB1:%.*]], label [[BB2:%.*]]
 ; CHECK:       bb1:
 ; CHECK-NEXT:    br label [[EXIT:%.*]]
 ; CHECK:       bb2:
 ; CHECK-NEXT:    br label [[EXIT]]
 ; CHECK:       exit: