[libc][bazel] Add tests to the bazel build

[gchatelet]

Summary

This patch adds bazel tests for llvm-libc.

Some math tests rely on the mpfr library. This is controlled via the --@llvm-project//libc:libc_math_mpfr flag. It can take three values:

• external (default) will build mpfr and gmp from source.
• system will use the system installed mpfr library.
• disable will skip tests relying on mpfr.

[gchatelet]

gmp and mpfr are built from source. Right now this is quite slow as Bazel does not parallelize the job yet (https://github.com/bazelbuild/rules_foreign_cc/issues/329).
Once the build is cached this is fast though.

[gchatelet]

We'd need to have autotools installed on the CI machine though.

[gchatelet]

• Add documentation on why -Wno-error is needed to compile gmp and mpfr.

[GMNGeoffrey]

I think we should provide at least the option for users to use these from their system, as we do with zlib

utils/bazel/WORKSPACE

79

Maybe switch to git_repository

[GMNGeoffrey]

@chandlerc any opinions on having multiple methods for depending on external libraries? Version 0.7 doesn't inspire confidence

[gchatelet]

@GMNGeoffrey I'm having an issue that you may know how to solve.
.bazelrc automatically appends -Wall -Werror to everything that is built.

• Math tests depend on mpfr,
• mpfr (and gmp) are built from source using rules_foreign_cc,
• For hermeticity rules_foreign_cc compiles make

I could tweak the ./configure options for mpfr and gmp and explicitly disable -Werror (see file "mpfr.BUILD" and "gmp.BUILD") but I cannot tweak the compile options for when rules_foreign_cc compiles make.
I could work around this by preventing rules_foreign_cc to compiles make in the first place, but then the build is not hermetic anymore...

register_built_tools = False,
register_default_tools = False,

What do you think? Is .bazelrc too strict? Is there a clean way to work around this without lowering the error level?

[gchatelet]

Another hack is to modify the .bazelrc file to pass -Wall -Werror only to cxxopt, instead of copt. Since make, gmp and mpfr are C and not C++ it works. But yeah, quite a hacky solution as well,

[GMNGeoffrey]

In D119547#3369973, @gchatelet wrote:

@GMNGeoffrey I'm having an issue that you may know how to solve.
.bazelrc automatically appends -Wall -Werror to everything that is built.

• Math tests depend on mpfr,
• mpfr (and gmp) are built from source using rules_foreign_cc,
• For hermeticity rules_foreign_cc compiles make

I could tweak the ./configure options for mpfr and gmp and explicitly disable -Werror (see file "mpfr.BUILD" and "gmp.BUILD") but I cannot tweak the compile options for when rules_foreign_cc compiles make.
I could work around this by preventing rules_foreign_cc to compiles make in the first place, but then the build is not hermetic anymore...

register_built_tools = False,
register_default_tools = False,

What do you think? Is .bazelrc too strict? Is there a clean way to work around this without lowering the error level?

You can use per_file_copt to limit where copts get applied, and for clang specifically the system_header_prefix copt. I think using the make on a user's machine instead of compiling it from source is entirely reasonable though. Only at Google would that be considered a good idea

[gchatelet]

• Use git_repository with tags, re-enable tool registration to check if CI works (m4 is missing), apply .bazelrc flags more specifically

[gchatelet]

• rebase and test CI now that https://github.com/google/llvm-premerge-checks/commit/86e2347137812b329d0ed603140737ceebaa1e9f is submitted.

[gchatelet]

• rebase

[gchatelet]

• Fix bazel files after cpp_standalone splitting

[gchatelet]

• Update bazel files to get closer to internal files

[gchatelet]

• Try to use prebuilt tools

[gchatelet]

• rebase

[gchatelet]

• rebase and update

[gchatelet]

• remove project prefix

[gchatelet]

• Update file structure

[sivachandra]

Is this ready for review?

[gchatelet]

In D119547#3907302, @sivachandra wrote:

Is this ready for review?

Almost, I'm still facing internal import issues that also need to be resolved upstream. I'll ping here when it's ready.

[gchatelet]

• update visibility

[gchatelet]

As-is this patch requires to have autotools installed (make, m4 and maybe other tools)
@GMNGeoffrey @sivachandra can we update the bazel builder?

[gchatelet]

Let rules_foreign_cc_dependencies build make - this should fixe premerge bot.

[gchatelet]

In D119547#3908018, @gchatelet wrote:

As-is this patch requires to have autotools installed (make, m4 and maybe other tools)
@GMNGeoffrey @sivachandra can we update the bazel builder?

I just updated the patch so it builds make hermetically but I had to disable copt_host -Werror
See diff https://reviews.llvm.org/D119547?vs=473188&id=473229#toc

Let me know which one of the two solutions you prefer.

edit Even if Bazel is able to build make, m4 is required to build gmp. It's actually a known issue : https://github.com/bazelbuild/rules_foreign_cc/issues/755
So for now we need at least m4, autoconf and automake to be installed on the machine anyways. So let's assume that make is available as well.

[GMNGeoffrey]

In D119547#3908195, @gchatelet wrote:

edit Even if Bazel is able to build make, m4 is required to build gmp. It's actually a known issue : https://github.com/bazelbuild/rules_foreign_cc/issues/755
So for now we need at least m4, autoconf and automake to be installed on the machine anyways. So let's assume that make is available as well.

@aeubanks can we see about installing these dependencies on the builders?

[GMNGeoffrey]

utils/bazel/.bazelrc

51 ↗

(On Diff #473229)

Based on your other comment, I think this could be removed now? But also there's https://reviews.llvm.org/D123481 to remove -Werror from the default config. Note, though, that the CI still builds with -Werror

utils/bazel/llvm-project-overlay/libc/test/libc_test_rules.bzl

2

Please add a license header and further explanation of why tests are constructed this way.

14

Can you use **kwargs for consistency with the rest of the starlark macros?

17

It seems like calling the "additional_deps" argument "deps" would also be fine? Generally it's preferred to use standard names (https://bazel.build/rules/bzl-style). I do see the argument for different naming, thouhg. Your call

utils/bazel/llvm-project-overlay/libc/test/src/math/BUILD.bazel

218

Couldn't we just tag it to be excluded from Aarch64 tests?

utils/bazel/llvm-project-overlay/libc/test/src/math/libc_math_test_rules.bzl

37

Oh no 😨 How much does this extend CI runtime? Also, how many tests are like this? Instead of hardcoding "enormous" for every test, could you just pass that argument for the few that are in fact enormous? Separately, I think it is a better fit to use the timeout argument here timeout = "eternal". Test size is ill-defined, but I think by any reasonable definition this test isn't an enormous one. Those usually involve spinning up whole servers and such. I think it's a small test that just happens to take a very long time.

utils/bazel/third_party_build/mpfr.BUILD

12

Probably want to turn off all warnings entirely. Getting warnings from this is not going to be useful for anyone. I think -w is the flag for both clang and gcc.

[gchatelet]

• Let rules_foreign_cc_dependencies build make
• Revert "Let rules_foreign_cc_dependencies build make"

[gchatelet]

• rebase to integrate https://reviews.llvm.org/D123481

[gchatelet]

• Add licence to libc_test_rules.bzl
• Rename kw into kwargs
• Disable math:sqrtl_test on aarch64
• Suppress warnings for mpfr build

[gchatelet]

utils/bazel/llvm-project-overlay/libc/test/libc_test_rules.bzl

17

@sivachandra WDYT?

utils/bazel/llvm-project-overlay/libc/test/src/math/libc_math_test_rules.bzl

37

It is not that bad. Here are the top tests sorted by runtime:

@llvm-project//libc/test/src/math:hypot_test                             PASSED in 44.1s
@llvm-project//libc/test/src/math:hypotf_test                            PASSED in 31.4s
@llvm-project//libc/test/src/math:remquol_test                           PASSED in 19.7s
@llvm-project//libc/test/src/math:sincosf_test                           PASSED in 12.8s
@llvm-project//libc/test/src/math:sqrtf_test                             PASSED in 6.3s
@llvm-project//libc/test/src/math:sqrt_test                              PASSED in 6.0s
@llvm-project//libc/test/src/math:sqrtl_test                             PASSED in 4.8s
@llvm-project//libc/test/src/math:sinf_test                              PASSED in 3.8s
...

@lntue can we add the size tag only on the few bad ones?

[gchatelet]

• Use selects.with_or as platform can be a list.

[gchatelet]

• Add licence to libc_test_rules.bzl
• Rename kw into kwargs
• Disable math:sqrtl_test on aarch64
• Suppress warnings for mpfr build
• Use selects.with_or as platform can be a list.
• Also add -w to gmp
• Remove unneeded visibility
• rebase

[GMNGeoffrey]

utils/bazel/llvm-project-overlay/libc/test/src/math/libc_math_test_rules.bzl

37

Thos are all within the timeouts for "short", which is implied by "small". It doesn't seem like any of these should be tagged "enormous"

[gchatelet]

utils/bazel/llvm-project-overlay/libc/test/src/math/libc_math_test_rules.bzl

37

So I've run more tests on different archs and build modes.

• for local machine x86_64 test time is < 45s in opt and < 80s in fastbuild.
• for local machine aarch64 test time is < 45s in optand < 87s in fastbuild.
• for Google aarch64 test time is < 100s in opt and < 160s in fastbuild.
• for Google qemued aarch64 test time is < 30m in opt and timing out after 1h in fastbuild.

So indeed these are enormous but only when run through an emulator. Let's mark the bigger tests wit the correct size and handle the timeouts internally.

[gchatelet]

• Add missing library for sqrtl
• Remove size from math_test
• add --with-pic configure option to gmp and mpfr (necessary for aarch64)

[gchatelet]

utils/bazel/llvm-project-overlay/libc/test/src/math/libc_math_test_rules.bzl

37

Actually I'm just removing the size attribute as the default is fine for all tests here.

[aeubanks]

In D119547#3915920, @GMNGeoffrey wrote:

In D119547#3908195, @gchatelet wrote:

edit Even if Bazel is able to build make, m4 is required to build gmp. It's actually a known issue : https://github.com/bazelbuild/rules_foreign_cc/issues/755
So for now we need at least m4, autoconf and automake to be installed on the machine anyways. So let's assume that make is available as well.

@aeubanks can we see about installing these dependencies on the builders?

was at the llvm dev meeting, I'll try to find time to look into this

[sivachandra]

In D119547#3908018, @gchatelet wrote:

@GMNGeoffrey @sivachandra can we update the bazel builder?

Sorry, I missed this - I do not maintain the bazel builder so this question should probably be answered by someone who maintains it.

utils/bazel/llvm-project-overlay/libc/test/libc_test_rules.bzl

17

Fine with calling it deps. IIRC, I named it additional_deps and not deps so that we do not mistakenly end up putting libc_function_deps in deps.

[aeubanks]

it took ~90 seconds to build libgmp and then ~60 seconds to build libmpfr on the bots, then ~40 for the longest test, that's not a great build experience even if it'll be cached most times

but anyway, make and m4 are now installed on the pre and post submit bazel bots

[aeubanks]

is there an issue with using a preinstalled version of mpfr/gmp on the bots?

[gchatelet]

• Use 'deps' instead of 'additional_deps'

[gchatelet]

In D119547#3922498, @aeubanks wrote:

is there an issue with using a preinstalled version of mpfr/gmp on the bots?

I don't think there are any issues, I think we can do the same as for zlib and terminfo.
Let me tinker with it a bit.

[gchatelet]

• libc math mpfr=(disable|system|eternal)

[gchatelet]

@aeubanks I've added a way to use the system's mpfr.
We need to add --@llvm-project//libc:libc_math_mpfr=system on the build bot command line. Do you know where to change this?
Also could you add libmpfr-dev to the build bot? (libgmp-dev will automatically come as a dependency)

[aeubanks]

In D119547#3927699, @gchatelet wrote:

@aeubanks I've added a way to use the system's mpfr.
We need to add --@llvm-project//libc:libc_math_mpfr=system on the build bot command line. Do you know where to change this?
Also could you add libmpfr-dev to the build bot? (libgmp-dev will automatically come as a dependency)

see --config=ci at the bottom of utils/bazel/.bazelrc

[aeubanks]

and added libmpfr-dev to the bots

[gchatelet]

• Use system's mpfr for CI
• Make mpfr dependency explicit

[gchatelet]

In D119547#3927932, @aeubanks wrote:

In D119547#3927699, @gchatelet wrote:

@aeubanks I've added a way to use the system's mpfr.
We need to add --@llvm-project//libc:libc_math_mpfr=system on the build bot command line. Do you know where to change this?
Also could you add libmpfr-dev to the build bot? (libgmp-dev will automatically come as a dependency)

see --config=ci at the bottom of utils/bazel/.bazelrc

Thx!

[gchatelet]

• Fix documentation

[gchatelet]

• Add licence to libc_test_rules.bzl
• Rename kw into kwargs
• Disable math:sqrtl_test on aarch64
• Suppress warnings for mpfr build
• Use selects.with_or as platform can be a list.
• Also add -w to gmp
• Remove unneeded visibility
• Add missing library for sqrtl
• Remove size from math_test
• add --with-pic configure option to gmp and mpfr (necessary for aarch64)
• Use 'deps' instead of 'additional_deps'
• libc math mpfr=(disable|system|eternal)
• Use system's mpfr for CI
• Make mpfr dependency explicit
• Fix documentation
• Add missing dependencies
• Use canonical version of mpfr_impl
• Rebase

[gchatelet]

• Add licence to libc_test_rules.bzl
• Rename kw into kwargs
• Disable math:sqrtl_test on aarch64
• Suppress warnings for mpfr build
• Use selects.with_or as platform can be a list.
• Also add -w to gmp
• Remove unneeded visibility
• Add missing library for sqrtl
• Remove size from math_test
• add --with-pic configure option to gmp and mpfr (necessary for aarch64)
• Use 'deps' instead of 'additional_deps'
• libc math mpfr=(disable|system|eternal)
• Use system's mpfr for CI
• Make mpfr dependency explicit
• Fix documentation
• Add missing dependencies
• Use canonical version of mpfr_impl
• Fix __support_unit deps after rebase
• Fix wrong target
• Rebase

[gchatelet]

• Fix typo
• Fix comment

[gchatelet]

I think it's good to go. @sivachandra @GMNGeoffrey looks good to you?

[lntue]

utils/bazel/llvm-project-overlay/libc/test/src/math/BUILD.bazel

263–264

I think this comment does not apply anymore. Can you add a TODO for me to double check this on an aarch64 machine and re-enable the test? Thanks,

[gchatelet]

• Add licence to libc_test_rules.bzl
• Rename kw into kwargs
• Disable math:sqrtl_test on aarch64
• Suppress warnings for mpfr build
• Use selects.with_or as platform can be a list.
• Also add -w to gmp
• Remove unneeded visibility
• Add missing library for sqrtl
• Remove size from math_test
• add --with-pic configure option to gmp and mpfr (necessary for aarch64)
• Use 'deps' instead of 'additional_deps'
• libc math mpfr=(disable|system|eternal)
• Use system's mpfr for CI
• Make mpfr dependency explicit
• Fix documentation
• Add missing dependencies
• Use canonical version of mpfr_impl
• Fix __support_unit deps after rebase
• Fix wrong target
• Fix typo
• Fix comment
• Remove unneeded dependencies and aarch64 test restriction

utils/bazel/llvm-project-overlay/libc/test/src/math/BUILD.bazel

263–264

Just tested on an aarch64 machine with the following dependencies and it passes.
Get:1 http://deb.debian.org/debian bullseye/main arm64 libgmpxx4ldbl arm64 2:6.2.1+dfsg-1+deb11u1 [337 kB]
Get:2 http://deb.debian.org/debian bullseye/main arm64 libgmp-dev arm64 2:6.2.1+dfsg-1+deb11u1 [625 kB]
Get:3 http://deb.debian.org/debian bullseye/main arm64 libmpfr-dev arm64 4.1.0-3 [236 kB]

I'll simplify the target then.

[sivachandra]

LGTM but please wait for @GMNGeoffrey . As a follow up, can you please add a doc for building and testing with Bazel similar to https://libc.llvm.org/build_and_test.html?

[GMNGeoffrey]

LGTM with some nits

utils/bazel/WORKSPACE

76

It seems like we don't actually use this anywhere?

90

bazelrc. Note that this is no longer set in the bazelr by default, but it is set in the CI

utils/bazel/llvm-project-overlay/libc/BUILD.bazel

28 ↗

(On Diff #475904)

I think it would be good to throw a usage example in here and a link to the docs. This Bazel flag stuff is pretty new and I think not widely used. IIUC this would be passed like bazel build @llvm-project//libc:libc_math_mpfr=disable .... Having written it out, I think you should drop the "libc" from the flag name: it already has to be referenced with a qualified name. Is "math" important? Maybe just bazel build @llvm-project//libc:mpfr=disable .... That looks quite a bit cleaner

utils/bazel/llvm-project-overlay/libc/test/libc_test_rules.bzl

2

Would still like to see an explanation of why these tests are constructed this way. The docstrings kind of look like just rearranging the words in the file/function name

10–26

It's a bit weird to introspect kwargs this way IMO. You can instead add deps as an explicit kwarg with a default

utils/bazel/llvm-project-overlay/libc/test/src/math/libc_math_test_rules.bzl

5

Again, more explanation of what's going on here and why would be helpful

14

Same comment about just making deps explicit

utils/bazel/llvm-project-overlay/libc/test/src/stdlib/BUILD.bazel

2

Please add license headers to all the files, as we have in the other Bazel files

utils/bazel/llvm-project-overlay/libc/utils/MPFRWrapper/BUILD.bazel

10–13

It is wild to me that this is how you disable something in Bazel...

utils/bazel/third_party_build/mpfr.BUILD

12

I think that with this you don't need to also turn off -Werror. -w -> no warnings so it doesn't matter that all warnings are errors :-)

[gchatelet]

utils/bazel/WORKSPACE

90

This is no more relevant, thx for the heads up.
I've added some documentation as well.

utils/bazel/llvm-project-overlay/libc/utils/MPFRWrapper/BUILD.bazel

10–13

This is the recommended way as far as I understand
https://youtu.be/01BHJT7GL9o

Please correct me if I'm wrong!

utils/bazel/third_party_build/mpfr.BUILD

12

Fair enough 🙂

[gchatelet]

• Remove unused bazel_toolchain
• Update documentation in WORKSPACE
• Rename mpfr flag and improve documentation
• Use deps in rules arguments
• Added documentation to custom rules
• Add license headers
• Remove unneeded -Wno-error

[gchatelet]

Thx @GMNGeoffrey for the valuable comments. I'll submit as is. Let me know if you have any other modifications and I'll deal with them in subsequent patches.

[gchatelet]

Reopening to use bazel_platforms incompatible_setting instead of creating my own.

[gchatelet]

• Removed custom constrain_setttings and rely on @platform//:incompatible
• Format build files

[gchatelet]

• Remove unused load directives
• Fix dosctring in libc_math_test_rules.bzl

utils/bazel/WORKSPACE

 # This file is licensed under the Apache License v2.0 with LLVM Exceptions.
 # See https://llvm.org/LICENSE.txt for license information.
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
 load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
 load("@bazel_tools//tools/build_defs/repo:utils.bzl", "maybe")
+load("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository")
 
 SKYLIB_VERSION = "1.3.0"
 
 http_archive(
     name = "bazel_skylib",
     sha256 = "74d544d96f4a5bb630d465ca8bbcfe231e3594e5aae57e1edbf17a6eb3ca2506",
     urls = [
         "https://mirror.bazel.build/github.com/bazelbuild/bazel-skylib/releases/download/{version}/bazel-skylib-{version}.tar.gz".format(version=SKYLIB_VERSION),

 
 load("@llvm-raw//utils/bazel:vulkan_sdk.bzl", "vulkan_sdk_setup")
 
 maybe(
     vulkan_sdk_setup,
     name = "vulkan_sdk",
 )
 
+git_repository(
+    name = "bazel_toolchains",
+    tag = "5.1.2",
+    remote = "https://github.com/bazelbuild/bazel-toolchains.git"
+)
+
+git_repository(
+    name = "rules_foreign_cc",
+    tag = "0.9.0",
+    remote = "https://github.com/bazelbuild/rules_foreign_cc.git"
+)
+
+load("@rules_foreign_cc//foreign_cc:repositories.bzl", "rules_foreign_cc_dependencies")
+
+# We set register_built_tools to False to prevent building make from source.
+# Building make from source fails because of "-Wall -Werror" (.blazerc).
+rules_foreign_cc_dependencies(register_built_tools = False)
+
+maybe(
+    http_archive,
+    name = "gmp",
+    build_file = "@llvm-raw//utils/bazel/third_party_build:gmp.BUILD",
+    sha256 = "fd4829912cddd12f84181c3451cc752be224643e87fac497b69edddadc49b4f2",
+    strip_prefix = "gmp-6.2.1",
+    urls = [
+        "https://gmplib.org/download/gmp/gmp-6.2.1.tar.xz",
+        "https://ftp.gnu.org/gnu/gmp/gmp-6.2.1.tar.xz",
+    ],
+)
+
+maybe(
+    http_archive,
+    name = "mpfr",
+    build_file = "@llvm-raw//utils/bazel/third_party_build:mpfr.BUILD",
+    sha256 = "3127fe813218f3a1f0adf4e8899de23df33b4cf4b4b3831a5314f78e65ffa2d6",
+    strip_prefix = "mpfr-4.1.0",
+    urls = ["https://www.mpfr.org/mpfr-current/mpfr-4.1.0.tar.gz"],
+)
+

utils/bazel/llvm-project-overlay/libc/test/libc_test_rules.bzl

+"""LLVM libc starlark rules for tests."""
+
+load("@llvm-project//libc:libc_build_rules.bzl", "INTERNAL_SUFFIX")
+
+def libc_test(name, srcs, libc_function_deps, additional_deps = None, **kw):
+    """Add target for a libc test.
+
+    Args:
+      name: Test target name
+      srcs: List of sources for the test.
+      libc_function_deps: List of libc_function targets used by this test.
+      additional_deps: List of additional targets used by this test.
+      **kw: Attributes relevant for a cc_test. For example, name, srcs, deps.
+    """
+    if "deps" in kw:
+        fail("A libc_test target should list 'libc_function_deps' and " +
+             "'additional_deps' instead of 'deps'.")
+    deps = [
+        "@llvm-project//libc:libc_root",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+    ]
+    for d in libc_function_deps:
+        deps.append(d + INTERNAL_SUFFIX)
+    if additional_deps:
+        deps.extend(additional_deps)
+    native.cc_test(
+        name = name,
+        srcs = srcs,
+        deps = deps,
+        features = ["-link_llvmlibc"],  # Do not link libllvmlibc.a
+        **kw
+    )

utils/bazel/llvm-project-overlay/libc/test/src/fenv/BUILD.bazel

+# Tests for LLVM libc math.h functions.
+
+load("@llvm-project//libc:test/libc_test_rules.bzl", "libc_test")
+
+licenses(["notice"])
+
+libc_test(
+    name = "exception_status_test",
+    srcs = ["exception_status_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc:__support_fputil_fenv_impl"
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:feclearexcept",
+        "@llvm-project//libc:feraiseexcept",
+        "@llvm-project//libc:fetestexcept",
+    ],
+)
+
+libc_test(
+    name = "rounding_mode_test",
+    srcs = ["rounding_mode_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:fegetround",
+        "@llvm-project//libc:fesetround",
+    ],
+)
+
+libc_test(
+    name = "enabled_exceptions_test",
+    srcs = ["enabled_exceptions_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+        "@llvm-project//libc:__support_common",
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:feclearexcept",
+        "@llvm-project//libc:feraiseexcept",
+        "@llvm-project//libc:fetestexcept",
+    ],
+    tags = ["nosan"],
+)
+
+libc_test(
+    name = "feholdexcept_test",
+    srcs = ["feholdexcept_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+        "@llvm-project//libc:__support_common",
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:feholdexcept",
+    ],
+    tags = ["nosan"],
+)
+
+libc_test(
+    name = "exception_flags_test",
+    srcs = ["exception_flags_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:fegetexceptflag",
+        "@llvm-project//libc:fesetexceptflag",
+    ],
+)
+
+libc_test(
+    name = "feclearexcept_test",
+    srcs = ["feclearexcept_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:feclearexcept",
+    ],
+)
+
+libc_test(
+    name = "feenableexcept_test",
+    srcs = ["feenableexcept_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc:__support_common",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:fedisableexcept",
+        "@llvm-project//libc:feenableexcept",
+        "@llvm-project//libc:fegetexcept",
+    ],
+)
+
+libc_test(
+    name = "feupdateenv_test",
+    srcs = ["feupdateenv_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:feupdateenv",
+    ],
+)
+
+libc_test(
+    name = "getenv_and_setenv_test",
+    srcs = ["getenv_and_setenv_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:fegetenv",
+        "@llvm-project//libc:fegetround",
+        "@llvm-project//libc:fesetenv",
+        "@llvm-project//libc:fesetround",
+    ],
+)

utils/bazel/llvm-project-overlay/libc/test/src/math/BUILD.bazel

+# Tests for LLVM libc math.h functions.
+
+load("@llvm-project//libc/test/src/math:libc_math_test_rules.bzl", "math_test")
+
+licenses(["notice"])
+
+math_test(
+    name = "fabs",
+    hdrs = ["FAbsTest.h"],
+)
+
+math_test(
+    name = "fabsf",
+    hdrs = ["FAbsTest.h"],
+)
+
+math_test(
+    name = "fabsl",
+    hdrs = ["FAbsTest.h"],
+)
+
+math_test(
+    name = "ceil",
+    hdrs = ["CeilTest.h"],
+)
+
+math_test(
+    name = "ceilf",
+    hdrs = ["CeilTest.h"],
+)
+
+math_test(
+    name = "ceill",
+    hdrs = ["CeilTest.h"],
+)
+
+math_test(
+    name = "floor",
+    hdrs = ["FloorTest.h"],
+)
+
+math_test(
+    name = "floorf",
+    hdrs = ["FloorTest.h"],
+)
+
+math_test(
+    name = "floorl",
+    hdrs = ["FloorTest.h"],
+)
+
+math_test(
+    name = "trunc",
+    hdrs = ["TruncTest.h"],
+)
+
+math_test(
+    name = "truncf",
+    hdrs = ["TruncTest.h"],
+)
+
+math_test(
+    name = "truncl",
+    hdrs = ["TruncTest.h"],
+)
+
+math_test(
+    name = "round",
+    hdrs = ["RoundTest.h"],
+)
+
+math_test(
+    name = "roundf",
+    hdrs = ["RoundTest.h"],
+)
+
+math_test(
+    name = "roundl",
+    hdrs = ["RoundTest.h"],
+)
+
+math_test(
+    name = "frexp",
+    hdrs = ["FrexpTest.h"],
+)
+
+math_test(
+    name = "frexpf",
+    hdrs = ["FrexpTest.h"],
+)
+
+math_test(
+    name = "frexpl",
+    hdrs = ["FrexpTest.h"],
+)
+
+math_test(
+    name = "hypot",
+    hdrs = ["HypotTest.h"],
+)
+
+math_test(
+    name = "hypotf",
+    hdrs = [
+        "HypotTest.h",
+        "hypotf_hard_to_round.h",
+    ],
+)
+
+math_test(
+    name = "logb",
+    hdrs = ["LogbTest.h"],
+)
+
+math_test(
+    name = "logbf",
+    hdrs = ["LogbTest.h"],
+)
+
+math_test(
+    name = "logbl",
+    hdrs = ["LogbTest.h"],
+)
+
+math_test(
+    name = "modf",
+    hdrs = ["ModfTest.h"],
+)
+
+math_test(
+    name = "modff",
+    hdrs = ["ModfTest.h"],
+)
+
+math_test(
+    name = "modfl",
+    hdrs = ["ModfTest.h"],
+)
+
+cc_library(
+    name = "remquo_test_template",
+    hdrs = ["RemQuoTest.h"],
+    deps = [
+        "@llvm-project//libc:__support_fputil_basic_operations",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc/utils/MPFRWrapper:mpfr_wrapper",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+    ],
+)
+
+math_test(
+    name = "remquo",
+    additional_deps = [":remquo_test_template"],
+)
+
+math_test(
+    name = "remquof",
+    additional_deps = [":remquo_test_template"],
+)
+
+math_test(
+    name = "remquol",
+    additional_deps = [":remquo_test_template"],
+)
+
+math_test(
+    name = "fmin",
+    hdrs = ["FMinTest.h"],
+)
+
+math_test(
+    name = "fminf",
+    hdrs = ["FMinTest.h"],
+)
+
+math_test(
+    name = "fminl",
+    hdrs = ["FMinTest.h"],
+)
+
+math_test(
+    name = "fmax",
+    hdrs = ["FMaxTest.h"],
+)
+
+math_test(
+    name = "fmaxf",
+    hdrs = ["FMaxTest.h"],
+)
+
+math_test(
+    name = "fmaxl",
+    hdrs = ["FMaxTest.h"],
+)
+
+math_test(
+    name = "sqrt",
+    hdrs = ["SqrtTest.h"],
+    additional_deps = [
+        "@llvm-project//libc:__support_cpp_array",
+        "@llvm-project//libc:__support_cpp_bit",
+    ],
+)
+
+math_test(
+    name = "sqrtf",
+    hdrs = ["SqrtTest.h"],
+    additional_deps = [
+        "@llvm-project//libc:__support_cpp_array",
+        "@llvm-project//libc:__support_cpp_bit",
+    ],
+)
+
+# TODO(sivachandra): sqrtl test currently fails on Aarch64 because of
+# insufficient precision in MPFR leading to https://hal.archives-ouvertes.fr/hal-01091186/document
+# We will comment it out for now and wait for it to get fixed upstream.
+# math_test(name = "sqrtl")
+
+math_test(
+    name = "copysign",
+    hdrs = ["CopySignTest.h"],
+)
+
+math_test(
+    name = "copysignf",
+    hdrs = ["CopySignTest.h"],
+)
+
+math_test(
+    name = "copysignl",
+    hdrs = ["CopySignTest.h"],
+)
+
+cc_library(
+    name = "ilogb_test_template",
+    hdrs = ["ILogbTest.h"],
+    deps = [
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc:__support_fputil_manipulation_functions",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+    ],
+)
+
+math_test(
+    name = "ilogb",
+    additional_deps = [":ilogb_test_template"],
+)
+
+math_test(
+    name = "ilogbf",
+    additional_deps = [":ilogb_test_template"],
+)
+
+math_test(
+    name = "ilogbl",
+    additional_deps = [":ilogb_test_template"],
+)
+
+cc_library(
+    name = "fdim_test_template",
+    hdrs = ["FDimTest.h"],
+    deps = [
+        "@llvm-project//libc:__support_fputil_basic_operations",
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+    ],
+)
+
+math_test(
+    name = "fdim",
+    additional_deps = [":fdim_test_template"],
+)
+
+math_test(
+    name = "fdimf",
+    additional_deps = [":fdim_test_template"],
+)
+
+math_test(
+    name = "fdiml",
+    additional_deps = [":fdim_test_template"],
+)
+
+cc_library(
+    name = "ldexp_test_template",
+    hdrs = ["LdExpTest.h"],
+    deps = [
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc:__support_fputil_normal_float",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+    ],
+)
+
+math_test(
+    name = "ldexp",
+    additional_deps = [":ldexp_test_template"],
+)
+
+math_test(
+    name = "ldexpf",
+    additional_deps = [":ldexp_test_template"],
+)
+
+math_test(
+    name = "ldexpl",
+    additional_deps = [":ldexp_test_template"],
+)
+
+cc_library(
+    name = "rint_test_template",
+    hdrs = ["RIntTest.h"],
+    deps = [
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc/utils/MPFRWrapper:mpfr_wrapper",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+    ],
+)
+
+math_test(
+    name = "rint",
+    additional_deps = [":rint_test_template"],
+)
+
+math_test(
+    name = "rintf",
+    additional_deps = [":rint_test_template"],
+)
+
+math_test(
+    name = "rintl",
+    additional_deps = [":rint_test_template"],
+)
+
+cc_library(
+    name = "round_to_integer_test_template",
+    hdrs = ["RoundToIntegerTest.h"],
+    deps = [
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc/utils/MPFRWrapper:mpfr_wrapper",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+    ],
+)
+
+math_test(
+    name = "lrint",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "lrintf",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "lrintl",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "llrint",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "llrintf",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "llrintl",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "lround",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "lroundf",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "lroundl",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "llround",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "llroundf",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+math_test(
+    name = "llroundl",
+    additional_deps = [":round_to_integer_test_template"],
+)
+
+cc_library(
+    name = "nextafter_test_template",
+    hdrs = ["NextAfterTest.h"],
+    deps = [
+        "@llvm-project//libc:__support_cpp_array",
+        "@llvm-project//libc:__support_cpp_bit",
+        "@llvm-project//libc:__support_cpp_type_traits",
+        "@llvm-project//libc:__support_fputil_basic_operations",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+    ],
+)
+
+math_test(
+    name = "nextafter",
+    additional_deps = [":nextafter_test_template"],
+)
+
+math_test(
+    name = "nextafterf",
+    additional_deps = [":nextafter_test_template"],
+)
+
+math_test(
+    name = "nextafterl",
+    additional_deps = [":nextafter_test_template"],
+)
+
+cc_library(
+    name = "sdcomp26094",
+    hdrs = ["sdcomp26094.h"],
+    deps = [
+        "@llvm-project//libc:__support_cpp_array",
+        "@llvm-project//libc:libc_root",
+    ],
+)
+
+math_test(
+    name = "cosf",
+    additional_deps = [
+        ":sdcomp26094",
+        "@llvm-project//libc:__support_cpp_array",
+    ],
+)
+
+math_test(
+    name = "sincosf",
+    additional_deps = [
+        ":sdcomp26094",
+        "@llvm-project//libc:__support_cpp_array",
+    ],
+)
+
+math_test(
+    name = "sinf",
+    additional_deps = [
+        ":sdcomp26094",
+        "@llvm-project//libc:__support_cpp_array",
+    ],
+)

utils/bazel/llvm-project-overlay/libc/test/src/math/libc_math_test_rules.bzl

+load("@llvm-project//libc:test/libc_test_rules.bzl", "libc_test")
+
+def math_test(name, additional_deps = None, need_mpfr = True, hdrs = None):
+    """Add a target for the unittest of a math function.
+
+    Args:
+      name: The name of the function being tested.
+      additional_deps: List of additional depenencies required by the test.
+      need_mpfr: True if the test uses mpfr_wrappper, False otherwise.
+      hdrs: List of headers to add.
+    """
+    test_name = name + "_test"
+    srcs = [test_name + ".cpp"] + (hdrs or [])
+    additional_deps = additional_deps or []
+    libc_function_deps = ["@llvm-project//libc:" + name]
+    additional_deps += [
+        "@llvm-project//libc:__support_fputil_basic_operations",
+        "@llvm-project//libc:__support_builtin_wrappers",
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+        "@llvm-project//libc:__support_fputil_float_properties",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc:__support_uint128",
+        "@llvm-project//libc:__support_fputil_manipulation_functions",
+        "@llvm-project//libc:__support_fputil_nearest_integer_operations",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+    ]
+    if need_mpfr:
+        additional_deps.append(
+            "@llvm-project//libc/utils/MPFRWrapper:mpfr_wrapper",
+        )
+    libc_test(
+        name = test_name,
+        srcs = srcs,
+        libc_function_deps = libc_function_deps,
+        additional_deps = additional_deps,
+        size = "enormous",  # Some tests are emulated and take very long.
+    )

utils/bazel/llvm-project-overlay/libc/test/src/stdlib/BUILD.bazel

+# Tests for LLVM libc stdlib.h functions.
+
+load("@llvm-project//libc:test/libc_test_rules.bzl", "libc_test")
+
+licenses(["notice"])
+
+libc_test(
+    name = "atoi_test",
+    srcs = ["atoi_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:atoi"
+    ],
+)
+
+libc_test(
+    name = "atol_test",
+    srcs = ["atol_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:atol"
+    ],
+)
+
+libc_test(
+    name = "atoll_test",
+    srcs = ["atoll_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:atoll"
+    ],
+)
+
+libc_test(
+    name = "bsearch_test",
+    srcs = ["bsearch_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:bsearch"
+    ],
+)
+
+libc_test(
+    name = "qsort_test",
+    srcs = ["qsort_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:qsort"
+    ],
+)
+
+libc_test(
+    name = "strtol_test",
+    srcs = ["strtol_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strtol"
+    ],
+)
+
+libc_test(
+    name = "strtoll_test",
+    srcs = ["strtoll_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strtoll"
+    ],
+)
+
+libc_test(
+    name = "strtoul_test",
+    srcs = ["strtoul_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strtoul"
+    ],
+)
+
+libc_test(
+    name = "strtoull_test",
+    srcs = ["strtoull_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strtoull"
+    ],
+)

utils/bazel/llvm-project-overlay/libc/test/src/string/BUILD.bazel

+# Tests for LLVM libc string.h functions.
+
+load("@llvm-project//libc:test/libc_test_rules.bzl", "libc_test")
+
+licenses(["notice"])
+
+libc_test(
+    name = "strlen_test",
+    srcs = ["strlen_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strlen"
+    ],
+)
+
+libc_test(
+    name = "strcpy_test",
+    srcs = ["strcpy_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strcpy_sanitized",
+    ],
+)
+
+libc_test(
+    name = "strcmp_test",
+    srcs = ["strcmp_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strcmp",
+    ],
+)
+
+libc_test(
+    name = "memchr_test",
+    srcs = ["memchr_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:memchr",
+    ],
+)
+
+libc_test(
+    name = "strchr_test",
+    srcs = ["strchr_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strchr",
+    ],
+)
+
+libc_test(
+    name = "strstr_test",
+    srcs = ["strstr_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strstr",
+    ],
+)
+
+libc_test(
+    name = "strnlen_test",
+    srcs = ["strnlen_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strnlen",
+    ],
+)
+
+libc_test(
+    name = "memrchr_test",
+    srcs = ["memrchr_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:memrchr",
+    ],
+)
+
+libc_test(
+    name = "strrchr_test",
+    srcs = ["strrchr_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strrchr",
+    ],
+)
+
+libc_test(
+    name = "strcspn_test",
+    srcs = ["strcspn_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strcspn",
+    ],
+)
+
+libc_test(
+    name = "strspn_test",
+    srcs = ["strspn_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strspn",
+    ],
+)
+
+libc_test(
+    name = "strtok_test",
+    srcs = ["strtok_test.cpp"],
+    libc_function_deps = [
+        "@llvm-project//libc:strtok",
+    ],
+)
+
+cc_library(
+    name = "memory_check_utils",
+    hdrs = ["memory_utils/memory_check_utils.h"],
+    deps = [
+        "@llvm-project//libc:__support_cpp_span",
+        "@llvm-project//libc:string_memory_utils",
+    ],
+)
+
+libc_test(
+    name = "memcpy_test",
+    srcs = ["memcpy_test.cpp"],
+    additional_deps = [":memory_check_utils"],
+    libc_function_deps = [
+        "@llvm-project//libc:memcpy",
+    ],
+)
+
+libc_test(
+    name = "memset_test",
+    srcs = ["memset_test.cpp"],
+    additional_deps = [":memory_check_utils"],
+    libc_function_deps = [
+        "@llvm-project//libc:memset",
+    ],
+)
+
+libc_test(
+    name = "memmove_test",
+    srcs = ["memmove_test.cpp"],
+    additional_deps = [
+        "@llvm-project//libc:__support_cpp_span",
+        "@llvm-project//libc/utils/UnitTest:memory_matcher",
+    ],
+    libc_function_deps = [
+        "@llvm-project//libc:memcmp",
+        "@llvm-project//libc:memmove",
+    ],
+)
+
+libc_test(
+    name = "memcmp_test",
+    srcs = ["memcmp_test.cpp"],
+    additional_deps = [":memory_check_utils"],
+    libc_function_deps = [
+        "@llvm-project//libc:memcmp",
+    ],
+)
+
+libc_test(
+    name = "bcmp_test",
+    srcs = ["bcmp_test.cpp"],
+    additional_deps = [":memory_check_utils"],
+    libc_function_deps = [
+        "@llvm-project//libc:bcmp",
+    ],
+)
+
+libc_test(
+    name = "bzero_test",
+    srcs = ["bzero_test.cpp"],
+    additional_deps = [":memory_check_utils"],
+    libc_function_deps = [
+        "@llvm-project//libc:bzero",
+    ],
+)

utils/bazel/llvm-project-overlay/libc/utils/MPFRWrapper/BUILD.bazel

+# A wrapper library over MPFR for use with LLVM libc math unittests.
+
+package(default_visibility = ["//visibility:public"])
+
+licenses(["notice"])
+
+cc_library(
+    name = "mpfr_wrapper",
+    srcs = ["MPFRUtils.cpp"],
+    hdrs = ["MPFRUtils.h"],
+    deps = [
+        "@llvm-project//libc:__support_common",
+        "@llvm-project//libc:__support_cpp_bit",
+        "@llvm-project//libc:__support_cpp_bitset",
+        "@llvm-project//libc:__support_cpp_string_view",
+        "@llvm-project//libc:__support_cpp_type_traits",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc:__support_fputil_platform_defs",
+        "@llvm-project//libc:libc_root",
+        "@llvm-project//libc/utils/UnitTest:LibcUnitTest",
+        "@llvm-project//libc/utils/UnitTest:fp_test_helpers",
+        "@llvm-project//libc/utils/testutils:libc_test_utils",
+        "@mpfr//:mpfr_",
+    ],
+)

utils/bazel/llvm-project-overlay/libc/utils/UnitTest/BUILD.bazel

+# LLVM libc unittest library.
+
+package(default_visibility = ["//visibility:public"])
+
+licenses(["notice"])
+
+cc_library(
+    name = "LibcUnitTest",
+    srcs = [
+        "LibcTest.cpp",
+        "LibcTestMain.cpp",
+    ],
+    hdrs = [
+        "LibcTest.h",
+        "PlatformDefs.h",
+        "Test.h",
+    ],
+    deps = [
+        "@llvm-project//libc:__support_cpp_bit",
+        "@llvm-project//libc:__support_cpp_bitset",
+        "@llvm-project//libc:__support_cpp_span",
+        "@llvm-project//libc:__support_cpp_string_view",
+        "@llvm-project//libc:__support_cpp_type_traits",
+        "@llvm-project//libc:__support_uint128",
+        "@llvm-project//libc:libc_root",
+        "@llvm-project//libc/utils/testutils:libc_test_utils",
+        "//llvm:Support",
+    ],
+)
+
+cc_library(
+    name = "fp_test_helpers",
+    srcs = [
+        "FPExceptMatcher.cpp",
+        "FPMatcher.cpp",
+    ],
+    hdrs = [
+        "FPExceptMatcher.h",
+        "FPMatcher.h",
+    ],
+    deps = [
+        ":LibcUnitTest",
+        ":string_utils",
+        "@llvm-project//libc:__support_cpp_bit",
+        "@llvm-project//libc:__support_cpp_bitset",
+        "@llvm-project//libc:__support_cpp_span",
+        "@llvm-project//libc:__support_cpp_type_traits",
+        "@llvm-project//libc:__support_fputil_fenv_impl",
+        "@llvm-project//libc:__support_fputil_fp_bits",
+        "@llvm-project//libc:libc_root",
+    ],
+)
+
+cc_library(
+    name = "memory_matcher",
+    srcs = [
+        "MemoryMatcher.cpp",
+    ],
+    hdrs = [
+        "MemoryMatcher.h",
+    ],
+    deps = [
+        ":LibcUnitTest",
+        "@llvm-project//libc:__support_cpp_bit",
+        "@llvm-project//libc:__support_cpp_bitset",
+        "@llvm-project//libc:__support_cpp_span",
+        "@llvm-project//libc:__support_cpp_type_traits",
+    ],
+)
+
+cc_library(
+    name = "string_utils",
+    hdrs = [
+        "StringUtils.h",
+    ],
+    deps = [
+        "@llvm-project//libc:__support_cpp_type_traits",
+    ],
+)

utils/bazel/llvm-project-overlay/libc/utils/testutils/BUILD.bazel

+package(default_visibility = ["//visibility:public"])
+
+licenses(["notice"])
+
+cc_library(
+    name = "libc_test_utils",
+    srcs = [
+        "ExecuteFunctionUnix.cpp",
+        "FDReaderUnix.cpp",
+        "RoundingModeUtils.cpp",
+        "StreamWrapper.cpp",
+    ],
+    hdrs = [
+        "ExecuteFunction.h",
+        "FDReader.h",
+        "RoundingModeUtils.h",
+        "StreamWrapper.h",
+    ],
+    deps = [
+        "//llvm:Support",
+        "@llvm-project//libc:libc_root",
+    ],
+)

utils/bazel/third_party_build/gmp.BUILD

+load("@rules_foreign_cc//foreign_cc:defs.bzl", "configure_make_variant")
+
+filegroup(
+    name = "sources",
+    srcs = glob(["**"]),
+)
+
+configure_make_variant(
+    name = "gmp",
+    toolchain = "@rules_foreign_cc//toolchains:preinstalled_autoconf_toolchain",
+    copts = ["-Wno-error"],  # ./configure crashes with `-Werror`
+    lib_name = "libgmp",
+    lib_source = ":sources",
+    visibility = ["//visibility:public"],
+)

utils/bazel/third_party_build/mpfr.BUILD

+load("@rules_foreign_cc//foreign_cc:defs.bzl", "configure_make_variant")
+
+filegroup(
+    name = "sources",
+    srcs = glob(["**"]),
+)
+
+configure_make_variant(
+    name = "mpfr",
+    toolchain = "@rules_foreign_cc//toolchains:preinstalled_autoconf_toolchain",
+    copts = ["-Wno-error"],  # ./configure crashes with `-Werror`
+    lib_name = "libmpfr",
+    lib_source = ":sources",
+    visibility = ["//visibility:public"],
+    deps = ["@gmp//:gmp_"],
+)