[ThinLTO][test] Add visibility related tests

[MaskRay]

Improve tests

[MaskRay]

Add a Mach-O test

[MaskRay]

Check %tb.bc as well

[MaskRay]

Is this good?

[tejohnson]

Couple minor suggestions copied from review for D92900. Also, I think the macho test will fail right now since it references some symbols that don't exist there?

llvm/test/ThinLTO/X86/visibility-elf.ll

36 ↗

(On Diff #310705)

Suggest making this comment a bit more explicit, e.g.:

;; Currently the visibility is not propagated onto an unimported function, because we don't have summaries for declarations.

40 ↗

(On Diff #310705)

Suggest making this comment something like:

;; This can be hidden, but we cannot communicate the declaration's visibility to other modules because
;; declarations don't have summaries, and the IRLinker overrides it when importing the protected def.

llvm/test/ThinLTO/X86/visibility-macho.ll

36 ↗

(On Diff #310705)

The protected_* symbols are not defined in this test.

[MaskRay]

Address comments.

llvm/test/ThinLTO/X86/visibility-elf.ll

36 ↗

(On Diff #310705)

Thanks for the suggestions!

llvm/test/ThinLTO/X86/visibility-macho.ll

36 ↗

(On Diff #310705)

My bad. protected is ELF specific and does not make sense on Mach-O. I'll delete protected_*.
Ideally the backend should error on protected.

[tejohnson]

lgtm thanks!

llvm/test/ThinLTO/X86/visibility.ll

+; RUN: split-file %s %t
+; RUN: opt -module-summary %t/a.ll -o %ta.bc
+; RUN: opt -module-summary %t/b.ll -o %tb.bc
+
+; RUN: llvm-lto2 run -save-temps -o %t1.bc %ta.bc %tb.bc \
+; RUN:   -r=%ta.bc,var1,l -r=%ta.bc,var2,l \
+; RUN:   -r=%ta.bc,hidden_def_weak_def,l -r=%ta.bc,protected_def_weak_def,l -r=%ta.bc,not_imported,l \
+; RUN:   -r=%ta.bc,hidden_def_ref,l -r=%ta.bc,hidden_def_weak_ref,l \
+; RUN:   -r=%ta.bc,ext, -r=%ta.bc,main,plx \
+; RUN:   -r=%tb.bc,var1,plx -r=%tb.bc,var2,plx \
+; RUN:   -r=%tb.bc,hidden_def_weak_def,pl -r=%tb.bc,protected_def_weak_def,pl -r=%tb.bc,not_imported,pl \
+; RUN:   -r=%tb.bc,hidden_def_ref,pl -r=%tb.bc,hidden_def_weak_ref,pl
+; RUN: llvm-dis < %t1.bc.1.3.import.bc | FileCheck %s
+
+;--- a.ll
+target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-f80:128-n8:16:32:64-S128"
+target triple = "x86_64-grtev4-linux-gnu"
+
+; CHECK:      @var2 = external global i32, align 4
+; CHECK-NEXT: @var1 = available_externally hidden global i32 1, align 4
+
+@var1 = extern_weak global i32
+@var2 = weak global i32 1, align 4
+
+declare void @ext(void ()*)
+
+; CHECK: declare i32 @hidden_def_weak_def()
+; CHECK: declare void @protected_def_weak_def()
+; CHECK: declare extern_weak void @not_imported()
+; CHECK: define available_externally hidden void @hidden_def_ref() !thinlto_src_module !0
+; CHECK: define available_externally hidden void @hidden_def_weak_ref() !thinlto_src_module !0
+
+define weak i32 @hidden_def_weak_def() {
+entry:
+  %0 = load i32, i32* @var1
+  ret i32 %0
+}
+
+define weak void @protected_def_weak_def() {
+entry:
+  ret void
+}
+
+;; Currently the visibility is not propagated for an unimported function.
+declare extern_weak void @not_imported()
+
+declare void @hidden_def_ref()
+
+declare extern_weak void @hidden_def_weak_ref()
+
+define i32 @main() {
+entry:
+  call void @ext(void ()* bitcast (i32 ()* @hidden_def_weak_def to void ()*))
+  call void @ext(void ()* @protected_def_weak_def)
+  call void @ext(void ()* @hidden_def_ref)
+  call void @ext(void ()* @hidden_def_weak_ref)
+  call void @ext(void ()* @not_imported)
+
+  ;; Calls ensure the functions are imported.
+  call i32 @hidden_def_weak_def()
+  call void @protected_def_weak_def()
+  call void @hidden_def_ref()
+  call void @hidden_def_weak_ref()
+  ret i32 0
+}
+
+;--- b.ll
+target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-f80:128-n8:16:32:64-S128"
+target triple = "x86_64-grtev4-linux-gnu"
+
+@var1 = hidden global i32 1, align 4
+@var2 = hidden global i32 1, align 4
+
+define hidden i32 @hidden_def_weak_def() {
+entry:
+  %0 = load i32, i32* @var1
+  ret i32 %0
+}
+
+define protected void @protected_def_weak_def() {
+entry:
+  ret void
+}
+
+define hidden void @hidden_def_ref() {
+entry:
+  ret void
+}
+
+define hidden void @hidden_def_weak_ref() {
+entry:
+  ret void
+}
+
+define hidden void @not_imported() {
+entry:
+  ret void
+}