[DAGCombiner] Do not generate ISD::ADDE node if adde is not legal for the target when combine ISD::TRUNC node

[• wuzish]

Summary

Do not combine (trunc adde(X, Y, Carry)) into (adde trunc(X), trunc(Y), Carry),
if adde is not legal for the target. Even it's at type-legalize phase.
Because adde is special and will not be legalized at operation-legalize phase later.

This fixes: PR40922
https://bugs.llvm.org/show_bug.cgi?id=40922

[efriedma]

ADDC etc. are deprecated in favor of ADDCARRY. Nothing should generate ADDC etc. unless they're marked "Legal" for the type in question... and they should be Expand by default.

Could you look into where the node in question is getting generated?

[• wuzish]

In D60854#1471842, @efriedma wrote:

ADDC etc. are deprecated in favor of ADDCARRY. Nothing should generate ADDC etc. unless they're marked "Legal" for the type in question... and they should be Expand by default.

Could you look into where the node in question is getting generated?

Yes, they are marked "Legal" in Power target.

t43: i32,glue = addc t42, Constant:i32<6>

      t13: ch = CopyToReg t0, Register:i32 %0, t11
    t27: ch = TokenFactor t13, t11:1
          t44: i32,glue = adde Constant:i32<0>, Constant:i32<0>, t43:1
        t46: i32 = and t44, Constant:i32<1>
      t50: i1 = setcc t46, Constant:i32<0>, seteq:ch
        t45: i32 = and t43, Constant:i32<-17>
      t47: i1 = setcc t45, t42, setuge:ch
    t51: i1 = select t50, t47, Constant:i1<-1>
  t34: ch = brcond t27, t51, BasicBlock:ch<if.end 0x1001ba242e8>
t31: ch = br t34, BasicBlock:ch<if.then 0x1001ba24220>

-->

t43: i32,glue = addc t42, Constant:i32<6>
      t13: ch = CopyToReg t0, Register:i32 %0, t11
    t27: ch = TokenFactor t13, t11:1
      t58: i1,glue = adde Constant:i1<0>, Constant:i1<0>, t43:1
        t45: i32 = and t43, Constant:i32<-17>
      t47: i1 = setcc t45, t42, setuge:ch
    t53: i1 = or t58, t47
  t34: ch = brcond t27, t53, BasicBlock:ch<if.end 0x1001ba242e8>
t31: ch = br t34, BasicBlock:ch<if.then 0x1001ba24220>

It was created with sequences of combining.

Combining: t51: i1 = select t50, t47, Constant:i1<-1>
Creating new node: t52: i1 = xor t50, Constant:i1<-1>
Creating new node: t53: i1 = or t52, t47
... into: t53: i1 = or t52, t47

Combining: t53: i1 = or t52, t47

Combining: t52: i1 = xor t50, Constant:i1<-1>
Creating new node: t55: i1 = setcc t46, Constant:i32<0>, setne:ch
... into: t55: i1 = setcc t46, Constant:i32<0>, setne:ch

Combining: t53: i1 = or t55, t47

Combining: t55: i1 = setcc t46, Constant:i32<0>, setne:ch
Creating new node: t56: i1 = truncate t46
... into: t56: i1 = truncate t46

Combining: t53: i1 = or t56, t47

Replacing.2 t46: i32 = and t44, Constant:i32<1>

With: t44: i32,glue = adde Constant:i32<0>, Constant:i32<0>, t43:1

Combining: t53: i1 = or t56, t47

Combining: t56: i1 = truncate t44
Creating constant: t57: i1 = Constant<0>
Creating new node: t58: i1,glue = adde Constant:i1<0>, Constant:i1<0>, t43:1
... into: t58: i1,glue = adde Constant:i1<0>, Constant:i1<0>, t43:1

[efriedma]

Oh, I see, we start with an i32 ADDE, then https://github.com/llvm/llvm-project/blob/e7fe6dd5edb828e702d02c7cdc6565ace4c84f5b/llvm/lib/CodeGen/SelectionDAG/DAGCombiner.cpp#L10232 narrows the operation. We probably shouldn't perform that transform if it would produce an illegal ADDE.

[• wuzish]

In D60854#1472624, @efriedma wrote:

Oh, I see, we start with an i32 ADDE, then https://github.com/llvm/llvm-project/blob/e7fe6dd5edb828e702d02c7cdc6565ace4c84f5b/llvm/lib/CodeGen/SelectionDAG/DAGCombiner.cpp#L10232 narrows the operation. We probably shouldn't perform that transform if it would produce an illegal ADDE.

if ((N0.getOpcode() == ISD::ADDE || N0.getOpcode() == ISD::ADDCARRY) &&

N0.hasOneUse() && !N0.getNode()->hasAnyUseOfValue(1) &&
(!LegalOperations || TLI.isOperationLegal(N0.getOpcode(), VT))) {

I think there are 2 conditions to combine as above code does. One is before operation legalization phase (!LegalOperations) and the other one is after.
In former condition, such transformation is acceptable even operation ADDE is illegal and it only cares about type legality because illegal operation will be legalized later in DAG legalization phase (as I want to promote it).
So the second condition does consider the legality of ADDE because it's after DAG operation legalization.

[efriedma]

In former condition, such transformation is acceptable even operation ADDE is illegal and it only cares about type legality because illegal operation will be legalized later in DAG legalization phase

Generally, yes, before operation legalization we can create illegal operations.

ADDE is sort of an exception, though; we don't have operation legalization support for it, and we don't want to add it. So the condition for the DAGCombine should be fixed.

[• wuzish]

In D60854#1472817, @efriedma wrote:

In former condition, such transformation is acceptable even operation ADDE is illegal and it only cares about type legality because illegal operation will be legalized later in DAG legalization phase

Generally, yes, before operation legalization we can create illegal operations.

ADDE is sort of an exception, though; we don't have operation legalization support for it, and we don't want to add it. So the condition for the DAGCombine should be fixed.

Yes, I found there is a TODO to support operation legalization as you said for ADDE. https://github.com/llvm/llvm-project/blob/e7fe6dd5edb828e702d02c7cdc6565ace4c84f5b/llvm/lib/CodeGen/SelectionDAG/LegalizeIntegerTypes.cpp#L2049.

So the principle is that the DAG nodes converted from LLVM IR basically all have related common type and operation legalization (in base class), but the nodes only generated during combining and legalizing phases don't have fully support for common type and operation legalization. Instead, we just don't generate such nodes if targets do not support. Right?

Well, so the easiest way to fix this bug is to remove !LegalOperations before ||.

[efriedma]

so the easiest way to fix this bug is to remove !LegalOperations before ||

Essentially, yes, except we don't want to change the way we handle ADDCARRY.

[• wuzish]

If adde is not legal in target, do not combine to generate adde

[efriedma]

llvm/lib/CodeGen/SelectionDAG/DAGCombiner.cpp

10225–10227

Like I said before, we don't want to change the behavior of ADDCARRY. So should be something more like ((!LegalOperations && N0.getOpcode() == ISD::ADDCARRY) || TLI.isOperationLegal(N0.getOpcode(), VT))

[• wuzish]

llvm/lib/CodeGen/SelectionDAG/DAGCombiner.cpp

10225–10227

OK, I see.

[efriedma]

LGTM

[efriedma]

llvm/test/CodeGen/PowerPC/pr40922.ll

2

Err, sorry, I didn't read the test carefully enough.

Please use FileCheck to add some CHECK lines; even though the original issue was just a crash, adding a few lines to check for the expected addc or whatever might catch other issues in the future.

[• wuzish]

complete testcase

[• wuzish]

@eli.friedman Could you please have a look again? :) Thanks a lot.

[efriedma]

LGTM

[• wuzish]

update diff since it's out-of-date.

[• wuzish]

https://reviews.llvm.org/rL359532
https://reviews.llvm.org/rG49d60fdc2e8e

llvm/lib/CodeGen/SelectionDAG/DAGCombiner.cpp

if (!VT.isVector() &&
       SimplifyDemandedBits(SDValue(N, 0)))
     return SDValue(N, 0);
 
   // (trunc adde(X, Y, Carry)) -> (adde trunc(X), trunc(Y), Carry)
   // (trunc addcarry(X, Y, Carry)) -> (addcarry trunc(X), trunc(Y), Carry)
   // When the adde's carry is not used.
   if ((N0.getOpcode() == ISD::ADDE || N0.getOpcode() == ISD::ADDCARRY) &&
       N0.hasOneUse() && !N0.getNode()->hasAnyUseOfValue(1) &&
-      (!LegalOperations || TLI.isOperationLegal(N0.getOpcode(), VT))) {
+      // We only do for addcarry before legalize operation
+      ((!LegalOperations && N0.getOpcode() == ISD::ADDCARRY) ||
+       TLI.isOperationLegal(N0.getOpcode(), VT))) {
     SDLoc SL(N);
     auto X = DAG.getNode(ISD::TRUNCATE, SL, VT, N0.getOperand(0));
     auto Y = DAG.getNode(ISD::TRUNCATE, SL, VT, N0.getOperand(1));
     auto VTs = DAG.getVTList(VT, N0->getValueType(1));
     return DAG.getNode(N0.getOpcode(), SL, VTs, X, Y, N0.getOperand(2));
   }
 
   // fold (truncate (extract_subvector(ext x))) ->

llvm/test/CodeGen/PowerPC/pr39815.ll

entry:
   %conv2 = and i8 %2, 5
   store i8 %conv2, i8* @a, align 1
   ret void
 
 ; CHECK-LABEL: @testADDEPromoteResult
 ; CHECK:      # %bb.0:
 ; CHECK-DAG:   addis [[REG1:[0-9]+]], [[REG2:[0-9]+]], [[VAR1:[a-z0-9A-Z_.]+]]@toc@ha
 ; CHECK-DAG:   ld [[REG3:[0-9]+]], [[VAR1]]@toc@l([[REG1]])
-; CHECK-DAG:   lbz [[REG4:[0-9]+]], 0([[REG3]])
+; CHECK-DAG:   lwz [[REG4:[0-9]+]], 0([[REG3]])
 ; CHECK-DAG:   addic [[REG5:[0-9]+]], [[REG3]], -1
-; CHECK-DAG:   extsb [[REG6:[0-9]+]], [[REG4]]
-; CHECK-DAG:   addze [[REG7:[0-9]+]], [[REG6]]
+; CHECK-DAG:   addze [[REG7:[0-9]+]], [[REG4]]
 ; CHECK-DAG:   addis [[REG8:[0-9]+]], [[REG2]], [[VAR2:[a-z0-9A-Z_.]+]]@toc@ha
 ; CHECK-DAG:   andi. [[REG9:[0-9]+]], [[REG7]], 5
 ; CHECK-DAG:   stb [[REG9]], [[VAR2]]@toc@l([[REG8]])
 ; CHECK:       blr
 }

llvm/test/CodeGen/PowerPC/pr40922.ll

+; RUN: llc -verify-machineinstrs -mtriple=powerpc-unknown-linux-gnu < %s | FileCheck %s
+
+; Test case adapted from PR40922.
+
+@a.b = internal global i32 0, align 4
+
+define i32 @a() {
+entry:
+  %call = tail call i32 bitcast (i32 (...)* @d to i32 ()*)()
+  %0 = load i32, i32* @a.b, align 4
+  %conv = zext i32 %0 to i64
+  %add = add nuw nsw i64 %conv, 6
+  %and = and i64 %add, 8589934575
+  %cmp = icmp ult i64 %and, %conv
+  br i1 %cmp, label %if.then, label %if.end
+
+if.then:                                          ; preds = %entry
+  %call3 = tail call i32 bitcast (i32 (...)* @e to i32 ()*)()
+  br label %if.end
+
+if.end:                                           ; preds = %if.then, %entry
+  store i32 %call, i32* @a.b, align 4
+  ret i32 undef
+}
+
+; CHECK-LABEL: @a
+; CHECK: li 5, 0
+; CHECK: mr 30, 3
+; CHECK: addic 6, 4, 6
+; CHECK: addze 5, 5
+; CHECK: rlwinm 6, 6, 0, 28, 26
+; CHECK: andi. 5, 5, 1
+
+declare i32 @d(...)
+
+declare i32 @e(...)