[Bazel] Drop deprecated tblgen includes mechanism

[GMNGeoffrey]

Summary

Includes can now be fully managed via td_library and specified locally
to the tablegen files that require them. This has been deprecated for a
while and is not used upstream. I'm not aware of any downstream users
either.

utils/bazel/llvm-project-overlay/mlir/tblgen.bzl

 def _gentbl_rule_impl(ctx):
     td_file = ctx.file.td_file
 
     trans_srcs = _get_transitive_srcs(
         ctx.files.td_srcs + [td_file],
         ctx.attr.deps,
     )
 
-    # Note that we have two types of includes here. The deprecated ones expanded
-    # only by "_prefix_roots" are already relative to the execution root, i.e.
-    # may contain an `external/<workspace_name>` prefix if the current workspace
-    # is not the main workspace (where workspace_name is something configured
-    # per-project and therefore generally not known). Note that dirname also
-    # already includes this prefix. The new style of includes have it prepended
-    # automatically by `_resolve_includes` to avoid BUILD files having to depend
-    # on project specific configurations and Bazel implementation details.
+    # Note that the td_file.dirname is already relative to the execution root,
+    # i.e. may contain an `external/<workspace_name>` prefix if the current
+    # workspace is not the main workspace. Therefore it is not included in the
+    # _resolve_includes call that prepends this prefix.
     trans_includes = _get_transitive_includes(
         _resolve_includes(ctx, ctx.attr.includes + ["/"]) +
-        _prefix_roots(ctx, ctx.attr.td_includes + [td_file.dirname]),
+        _prefix_roots(ctx, [td_file.dirname]),
         ctx.attr.deps,
     )
 
     args = ctx.actions.args()
     args.add_all(ctx.attr.opts)
     args.add(td_file)
     args.add_all(trans_includes, before_each = "-I")
 
attrs = {
                   " invocation. Relative paths are interpreted as relative to" +
                   " the current label's package. Absolute paths are" +
                   " interpreted as relative to the current label's workspace." +
                   " Includes are applied from all roots available in the" +
                   " execution environment (source, genfiles, and bin" +
                   " directories). The execution roots themselves and the " +
                   " directory of td_file are always added.",
         ),
-        "td_includes": attr.string_list(
-            doc = "Include paths to add to the TableGen invocation. Paths are" +
-                  " interpreted as relative to the current label's workspace" +
-                  " root and applied from all roots available in the" +
-                  " execution environment (source, genfiles, and bin" +
-                  " directories). Deprecated. Use `includes` instead.",
-        ),
     },
 )
 
 # TODO(gcmn): Figure out how to reduce duplication with _gentbl_rule_impl
 def _gentbl_test_impl(ctx):
     td_file = ctx.file.td_file
 
-    # Note that we have two types of includes here. The deprecated ones expanded
-    # only by "_prefix_roots" are already relative to the execution root, i.e.
-    # may contain an `external/<workspace_name>` prefix if the current workspace
-    # is not the main workspace (where workspace_name is something configured
-    # per-project and therefore generally not known). Note that dirname also
-    # already includes this prefix. The new style of includes have it prepended
-    # automatically by `_resolve_includes` to avoid BUILD files having to depend
-    # on project specific configurations and Bazel implementation details.
+    # Note that the td_file.dirname is already relative to the execution root,
+    # i.e. may contain an `external/<workspace_name>` prefix if the current
+    # workspace is not the main workspace. Therefore it is not included in the
+    # _resolve_includes call that prepends this prefix.
     trans_includes = _get_transitive_includes(
         _resolve_includes(ctx, ctx.attr.includes + ["/"]) +
-        _prefix_roots(ctx, ctx.attr.td_includes + [td_file.dirname]),
+        _prefix_roots(ctx, [td_file.dirname]),
         ctx.attr.deps,
     )
 
     test_args = [ctx.executable.tblgen.short_path]
     test_args.extend(ctx.attr.opts)
     test_args.append(td_file.path)
     test_args.extend(["-I " + include for include in trans_includes.to_list()])
 
attrs = {
         ),
         "td_srcs": attr.label_list(
             doc = "See gentbl_rule.td_srcs",
             allow_files = True,
         ),
         "deps": attr.label_list(doc = "See gentbl_rule.deps"),
         "opts": attr.string_list(doc = "See gentbl_rule.opts"),
         "includes": attr.string_list(doc = "See gentbl_rule.includes"),
-        "td_includes": attr.string_list(doc = "See gentbl_rule.td_includes"),
     },
 )
 
 def gentbl_filegroup(
         name,
         tblgen,
         td_file,
         tbl_outs,
         td_srcs = [],
-        td_includes = [],
         includes = [],
         deps = [],
         test = False,
         skip_opts = [],
         **kwargs):
     """Create multiple TableGen generated files using the same tool and input.
 
     All generated outputs are bundled in a file group with the given name.
 
     Args:
       name: The name of the generated filegroup rule for use in dependencies.
       tblgen: The binary used to produce the output.
       td_file: The primary table definitions file.
       tbl_outs: A list of tuples ([opts], out), where each 'opts' is a list of
         options passed to tblgen, each option being a string, and 'out' is the
         corresponding output file produced.
       td_srcs: See gentbl_rule.td_srcs
       includes: See gentbl_rule.includes
-      td_includes: See gentbl_rule.td_includes
       deps: See gentbl_rule.deps
       test: Whether to create a shell test that invokes the tool too.
       skip_opts: Files generated using these opts in tbl_outs will be excluded
         from the generated filegroup.
       **kwargs: Extra keyword arguments to pass to all generated rules.
     """
 
-    llvm_project_execroot_path = Label("//mlir:tblgen.bzl").workspace_root
-
-    # TODO(gcmn): Update callers to td_library and explicit includes and drop
-    # this hardcoded include.
-    hardcoded_includes = [
-        paths.join(llvm_project_execroot_path, "mlir/include"),
-    ]
-
     for (opts, out) in tbl_outs:
         first_opt = opts[0] if opts else ""
         rule_suffix = "_{}_{}".format(
             first_opt.replace("-", "_").replace("=", "_"),
             str(hash(" ".join(opts))),
         )
         gentbl_name = "%s_%s_genrule" % (name, rule_suffix)
         gentbl_rule(
             name = gentbl_name,
             td_file = td_file,
             tblgen = tblgen,
             opts = opts,
             td_srcs = td_srcs,
             deps = deps,
             includes = includes,
-            td_includes = td_includes + hardcoded_includes,
             out = out,
             **kwargs
         )
 
         if test:
             # Also run the generator in the target configuration as a test. This
             # means it gets run with asserts and sanitizers and such when they
             # are enabled and is counted in coverage.
             gentbl_test(
                 name = "%s_test" % (gentbl_name,),
                 td_file = td_file,
                 tblgen = tblgen,
                 opts = opts,
                 td_srcs = td_srcs,
                 deps = deps,
                 includes = includes,
-                td_includes = td_includes + hardcoded_includes,
                 # Shell files not executable on Windows.
                 # TODO(gcmn): Support windows.
                 tags = ["no_windows"],
                 **kwargs
             )
 
     included_srcs = [f for (opts, f) in tbl_outs if not any([skip_opt in opts for skip_opt in skip_opts])]
     native.filegroup(
         name = name,
         srcs = included_srcs,
         **kwargs
     )
 
 def gentbl_cc_library(
         name,
         tblgen,
         td_file,
         tbl_outs,
         td_srcs = [],
-        td_includes = [],
         includes = [],
         deps = [],
         strip_include_prefix = None,
         test = False,
         **kwargs):
     """Create multiple TableGen generated files using the same tool and input.
 
     All generated outputs are bundled in a cc_library rule.
 
     Args:
       name: The name of the generated cc_library rule for use in dependencies.
       tblgen: The binary used to produce the output.
       td_file: The primary table definitions file.
       tbl_outs: A list of tuples ([opts], out), where each 'opts' is a list of
         options passed to tblgen, each option being a string, and 'out' is the
         corresponding output file produced.
       td_srcs: See gentbl_rule.td_srcs
       includes: See gentbl_rule.includes
-      td_includes: See gentbl_rule.td_includes
       deps: See gentbl_rule.deps
       strip_include_prefix: attribute to pass through to cc_library.
       test: whether to create a shell test that invokes the tool too.
       **kwargs: Extra keyword arguments to pass to all generated rules.
     """
 
     filegroup_name = name + "_filegroup"
     gentbl_filegroup(
         name = filegroup_name,
         tblgen = tblgen,
         td_file = td_file,
         tbl_outs = tbl_outs,
         td_srcs = td_srcs,
-        td_includes = td_includes,
         includes = includes,
         deps = deps,
         test = test,
         skip_opts = ["-gen-op-doc"],
         **kwargs
     )
     native.cc_library(
         name = name,
         # strip_include_prefix does not apply to textual_hdrs.
         # https://github.com/bazelbuild/bazel/issues/12424
         hdrs = [":" + filegroup_name] if strip_include_prefix else [],
         strip_include_prefix = strip_include_prefix,
         textual_hdrs = [":" + filegroup_name],
         **kwargs
     )