[MLIR] Add test for multiple gpu.all_reduce in the same kernel when lowering to NVVM

[clementval]

Summary

This patch add tests when lowering multiple gpu.all_reduce operations in the same kernel. This was previously failing.

[herhut]

mlir/lib/Conversion/GPUToNVVM/LowerGpuOpsToNVVMOps.cpp

386

It would be better to use SymbolTable::insert for this. See KernelOutlining.cpp for an example.

[clementval]

@herhut Thanks for the pointer to SymbolTable::insert. I have updated the patch accordingly.

[herhut]

csigg@ just landed some code that does in-dialect lowering and should achieve the same that is done here via using function attributions, instead. Can you verify?

[clementval]

In D75930#1917056, @herhut wrote:

csigg@ just landed some code that does in-dialect lowering and should achieve the same that is done here via using function attributions, instead. Can you verify?

The patch from @csigg works fine. I updated the patch with just the tests if it makes sense to add them. Otherwise just discard the patch.

[herhut]

Thanks for the extra tests, more tests are always better. Could you fix the Summary in the commit message and I will land it.

mlir/test/Dialect/GPU/multiple-all-reduce.mlir

22

We should not rely on actual names here, as those might change. Does this test currently pass? In any case, please use @{{.*}} instead.

[clementval]

@herhut I updated the test. It was passing but for sure if the name of the buffer were to change it would fail as you mentioned. By the way I heard from Medhi that if I used arc the attribution would be done correctly for the patch. Will use it for my next patches.

[clementval]

@ftynse Thanks for the review. As I do not have commit right, do you mind pushing this patch? I did not create it with arc so attribution my not be done correctly.

mlir/lib/Conversion/GPUToNVVM/LowerGpuOpsToNVVMOps.cpp

matchAndRewrite(Operation *op, ArrayRef<Value> operands,
     assert(factory && "failed to create accumulator factory");
     Value result = createBlockReduce(loc, operand, factory, rewriter);
 
     rewriter.replaceOp(op, {result});
     return matchSuccess();
   }
 
 private:
+  /// Next ID to assign to a reduction buffer.
+  unsigned nextReduceBufferID = 0;
+
   /// Returns an accumulator factory using either the op attribute or the body
   /// region.
   AccumulatorFactory getFactory(gpu::AllReduceOp allReduce,
                                 Value operand) const {
     if (!allReduce.body().empty()) {
       return getFactory(allReduce.body());
     }
     if (allReduce.op()) {
createIf(
                 /*return_value_and_is_valid=*/UnitAttr());
             value = accumFactory(loc, value, shflValue, rewriter);
           }
           return SmallVector<Value, 1>{value};
         });
     return rewriter.getInsertionBlock()->getArgument(0);
   }
 
+  /// Return next ID to be used to name reduce buffer
+  unsigned getNextReduceBufferName() {
+    return nextReduceBufferID++;
+  }
+
   /// Creates a global array stored in shared memory.
   Value createSharedMemoryArray(Location loc, gpu::GPUModuleOp module,
                                 LLVM::LLVMType elementType, int numElements,
                                 ConversionPatternRewriter &rewriter) const {
     OpBuilder builder(module.body());
 
     auto arrayType = LLVM::LLVMType::getArrayTy(elementType, numElements);
-    StringRef name = "reduce_buffer";
+    unsigned bufferID = 
+        (const_cast<GPUAllReduceOpLowering*>(this))->getNextReduceBufferName();
+    SmallString<16> out;
+    StringRef name = ("reduce_buffer" + Twine(bufferID)).toStringRef(out);
     auto globalOp = builder.create<LLVM::GlobalOp>(
         loc, arrayType.cast<LLVM::LLVMType>(),
         /*isConstant=*/false, LLVM::Linkage::Internal, name,
         /*value=*/Attribute(), gpu::GPUDialect::getWorkgroupAddressSpace());
 
     return rewriter.create<LLVM::AddressOfOp>(loc, globalOp);
   }
 
   /// Returns the index of the thread within the block.

mlir/test/Dialect/GPU/multiple-all-reduce.mlir

+// RUN: mlir-opt --gpu-kernel-outlining --convert-gpu-to-nvvm %s | FileCheck %s
+
+func @main() {
+  %data = alloc() : memref<2x6xf32>
+  %sum = alloc() : memref<2xf32>
+  %mul = alloc() : memref<2xf32>
+  %c1 = constant 1 : index
+
+  // ADD + MUL
+  gpu.launch blocks(%bx, %by, %bz) in (%grid_x = %c1, %grid_y = %c1, %grid_z = %c1)
+             threads(%tx, %ty, %tz) in (%block_x = %c1, %block_y = %c1, %block_z = %c1) {
+    %val = load %data[%bx, %tx] : memref<2x6xf32>
+    %reduced0 = "gpu.all_reduce"(%val) ({}) { op = "add" } : (f32) -> (f32)
+    store %reduced0, %sum[%bx] : memref<2xf32>
+    %reduced1 = "gpu.all_reduce"(%val) ({}) { op = "mul" } : (f32) -> (f32)
+    store %reduced1, %mul[%bx] : memref<2xf32>
+    gpu.terminator
+  }
+
+// CHECK:      gpu.module @main_kernel {
+// CHECK-NEXT:   llvm.mlir.global internal @reduce_buffer1() {addr_space = 3 : i32} : !llvm<"[32 x float]">
+// CHECK-NEXT:   llvm.mlir.global internal @reduce_buffer0() {addr_space = 3 : i32} : !llvm<"[32 x float]">
+
+  return
+}
 No newline at end of file

mlir/test/mlir-cuda-runner/multiple-all-reduce.mlir

+// RUN: mlir-cuda-runner %s --shared-libs=%cuda_wrapper_library_dir/libcuda-runtime-wrappers%shlibext,%linalg_test_lib_dir/libmlir_runner_utils%shlibext --entry-point-result=void | FileCheck %s
+
+func @main() {
+  %data = alloc() : memref<2x6xf32>
+  %sum = alloc() : memref<2xf32>
+  %mul = alloc() : memref<2xf32>
+  %cst0 = constant 0.0 : f32
+  %cst1 = constant 1.0 : f32
+  %cst2 = constant 2.0 : f32
+  %cst4 = constant 4.0 : f32
+  %cst8 = constant 8.0 : f32
+  %cst16 = constant 16.0 : f32
+
+  %cst3 = constant 3.0 : f32
+  %cst6 = constant 6.0 : f32
+  %cst7 = constant 7.0 : f32
+  %cst10 = constant 10.0 : f32
+  %cst11 = constant 11.0 : f32
+
+  %c0 = constant 0 : index
+  %c1 = constant 1 : index
+  %c2 = constant 2 : index
+  %c3 = constant 3 : index
+  %c4 = constant 4 : index
+  %c5 = constant 5 : index
+  %c6 = constant 6 : index
+    
+  store %cst0, %data[%c0, %c0] : memref<2x6xf32>
+  store %cst1, %data[%c0, %c1] : memref<2x6xf32>
+  store %cst2, %data[%c0, %c2] : memref<2x6xf32>
+  store %cst4, %data[%c0, %c3] : memref<2x6xf32>
+  store %cst8, %data[%c0, %c4] : memref<2x6xf32>
+  store %cst16, %data[%c0, %c5] : memref<2x6xf32>
+
+  store %cst2, %data[%c1, %c0] : memref<2x6xf32>
+  store %cst3, %data[%c1, %c1] : memref<2x6xf32>
+  store %cst6, %data[%c1, %c2] : memref<2x6xf32>
+  store %cst7, %data[%c1, %c3] : memref<2x6xf32>
+  store %cst10, %data[%c1, %c4] : memref<2x6xf32>
+  store %cst11, %data[%c1, %c5] : memref<2x6xf32>
+
+  // ADD + MUL
+  gpu.launch blocks(%bx, %by, %bz) in (%grid_x = %c2, %grid_y = %c1, %grid_z = %c1)
+             threads(%tx, %ty, %tz) in (%block_x = %c6, %block_y = %c1, %block_z = %c1) {
+    %val = load %data[%bx, %tx] : memref<2x6xf32>
+    %reduced0 = "gpu.all_reduce"(%val) ({}) { op = "add" } : (f32) -> (f32)
+    store %reduced0, %sum[%bx] : memref<2xf32>
+    %reduced1 = "gpu.all_reduce"(%val) ({}) { op = "mul" } : (f32) -> (f32)
+    store %reduced1, %mul[%bx] : memref<2xf32>
+    gpu.terminator
+  }
+
+  %ptr_sum = memref_cast %sum : memref<2xf32> to memref<*xf32>
+  call @print_memref_f32(%ptr_sum) : (memref<*xf32>) -> ()
+  // CHECK: [31, 39]
+
+  %ptr_mul = memref_cast %mul : memref<2xf32> to memref<*xf32>
+  call @print_memref_f32(%ptr_mul) : (memref<*xf32>) -> ()
+  // CHECK: [0, 27720]
+
+  return
+}
+
+func @print_memref_f32(memref<*xf32>)
 No newline at end of file