[gn] Support for per-target runtime directory layout

[phosek]

Summary

This change also introduces the clang_enable_per_target_runtime_dir
to enable the use of per-target runtime directory layout which is the
equivalent of LLVM_ENABLE_PER_TARGET_RUNTIME_DIR CMake option.

[thakis]

llvm/utils/gn/secondary/clang/runtimes.gni

3

Looks like nothing in clang uses this gni file. Will that happen in a future patch? If not, why is this in clang/?

[phosek]

llvm/utils/gn/secondary/clang/runtimes.gni

3

Yes, this will be used by libunwind, libc++abi and libc++. We could move it to LLVM, but I need to use clang_resource_dir which would invert the dependency (I don't think LLVM should depend on anything in Clang).

[thakis]

Ok, lgtm. I think it's fine to land this; if pcc has comments they can be addressed post-commit.

[pcc]

LGTM as well

llvm/utils/gn/secondary/clang/runtimes.gni

6

I would probably either make this comment more descriptive or remove it. As it is, it's just repeating the name of the flag.

llvm/utils/gn/secondary/clang/runtimes.gni

+import("//clang/resource_dir.gni")
+import("//llvm/triples.gni")
+
+declare_args() {
+  # Use target triple as the name of the runtimes directory.
+  clang_enable_per_target_runtime_dir = false
+}
+
+if (clang_enable_per_target_runtime_dir) {
+  runtimes_dir = "$clang_resource_dir/$llvm_target_triple/lib"
+} else {
+  runtimes_dir = "$root_build_dir/lib"
+}

llvm/utils/gn/secondary/compiler-rt/lib/hwasan/BUILD.gn

action("version_script") {
   ]
   outputs = [
     "$target_gen_dir/hwasan.vers",
   ]
   args = [
     "--version-list",
     "--extra",
     rebase_path(sources[0], root_build_dir),
-    rebase_path("$crt_current_out_dir/libclang_rt.hwasan-$crt_current_target.a",
+    rebase_path("$crt_current_out_dir/libclang_rt.hwasan$crt_current_target_suffix.a",
                 root_build_dir),
     rebase_path(
-        "$crt_current_out_dir/libclang_rt.hwasan_cxx-$crt_current_target.a",
+        "$crt_current_out_dir/libclang_rt.hwasan_cxx$crt_current_target_suffix.a",
         root_build_dir),
     "-o",
     rebase_path(outputs[0], root_build_dir),
   ]
 }
 
 source_set("sources") {
   configs -= [ "//llvm/utils/gn/build:llvm_code" ]
source_set("cxx_sources") {
   ]
   sources = [
     "hwasan_new_delete.cpp",
   ]
 }
 
 static_library("hwasan") {
   output_dir = crt_current_out_dir
-  output_name = "clang_rt.hwasan-$crt_current_target"
+  output_name = "clang_rt.hwasan$crt_current_target_suffix"
   complete_static_lib = true
   configs -= [
     "//llvm/utils/gn/build:llvm_code",
     "//llvm/utils/gn/build:thin_archive",
   ]
   configs += [ "//llvm/utils/gn/build:crt_code" ]
   deps = [
     ":sources",
   ]
 }
 
 static_library("hwasan_cxx") {
   output_dir = crt_current_out_dir
-  output_name = "clang_rt.hwasan_cxx-$crt_current_target"
+  output_name = "clang_rt.hwasan_cxx$crt_current_target_suffix"
   complete_static_lib = true
   configs -= [
     "//llvm/utils/gn/build:llvm_code",
     "//llvm/utils/gn/build:thin_archive",
   ]
   configs += [ "//llvm/utils/gn/build:crt_code" ]
   deps = [
     ":cxx_sources",
   ]
 }
 
 shared_library("hwasan_shared") {
   output_dir = crt_current_out_dir
-  output_name = "clang_rt.hwasan-$crt_current_target"
+  output_name = "clang_rt.hwasan$crt_current_target_suffix"
   configs -= [ "//llvm/utils/gn/build:llvm_code" ]
   configs += [ "//llvm/utils/gn/build:crt_code" ]
   deps = [
     ":cxx_sources",
     ":sources",
     ":version_script",
   ]
   inputs = [
     "$target_gen_dir/hwasan.vers",
   ]
   ldflags = [
     "-Wl,--version-script," + rebase_path(inputs[0], root_build_dir),
     "-Wl,-z,global",
   ]
 }

llvm/utils/gn/secondary/compiler-rt/target.gni

 import("//clang/resource_dir.gni")
-
-if (current_os == "linux" || current_os == "android") {
-  crt_current_out_dir = "$clang_resource_dir/lib/linux"
-} else {
-  assert(false, "unimplemented current_os " + current_os)
-}
+import("//clang/runtimes.gni")
 
 if (current_cpu == "x86") {
   crt_current_target_arch = "i386"
 } else if (current_cpu == "x64") {
   crt_current_target_arch = "x86_64"
 } else if (current_cpu == "arm64") {
   crt_current_target_arch = "aarch64"
 } else {
   assert(false, "unimplemented current_cpu " + current_cpu)
 }
 
-crt_current_target = crt_current_target_arch
+if (clang_enable_per_target_runtime_dir) {
+  crt_current_out_dir = runtimes_dir
+
+  crt_current_target_suffix = ""
+} else if (current_os == "linux" || current_os == "android") {
+  crt_current_out_dir = "$clang_resource_dir/lib/linux"
+
+  crt_current_target_suffix = "-$crt_current_target_arch"
   if (current_os == "android") {
-  crt_current_target += "-android"
+    crt_current_target_suffix += "-android"
+  }
+} else {
+  assert(false, "unimplemented current_os " + current_os)
 }

llvm/utils/gn/secondary/compiler-rt/test/hwasan/BUILD.gn

 import("//compiler-rt/target.gni")
 import("//compiler-rt/test/test.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 import("//llvm/utils/gn/build/write_cmake_config.gni")
 import("//llvm/version.gni")
 
 write_cmake_config("lit_site_cfg") {
   input = "lit.site.cfg.in"
   output = "$target_gen_dir/lit.site.cfg"
 
   values = [
     "LIT_SITE_CFG_IN_HEADER=## Autogenerated from $input, do not edit",
 
-    "HWASAN_TEST_CONFIG_SUFFIX=-$crt_current_target",
+    "HWASAN_TEST_CONFIG_SUFFIX=$crt_current_target_suffix",
     "HWASAN_TEST_TARGET_CFLAGS=$target_flags_string",
     "HWASAN_TEST_TARGET_ARCH=$crt_current_target_arch",
 
     "COMPILER_RT_BINARY_DIR=" + rebase_path("$root_gen_dir/compiler-rt"),
     "HWASAN_LIT_SOURCE_DIR=" + rebase_path("."),
   ]
 
   if (current_os == "android") {
     values += [ "HWASAN_ANDROID_FILES_TO_PUSH=[\"" + rebase_path(
-                    "$crt_current_out_dir/libclang_rt.hwasan-$crt_current_target.so") + "\", \"" + rebase_path(
+                    "$crt_current_out_dir/libclang_rt.hwasan$crt_current_target_suffix.so") + "\", \"" + rebase_path(
                     "$root_out_dir/bin/llvm-symbolizer") + "\"]" ]
   } else {
     values += [ "HWASAN_ANDROID_FILES_TO_PUSH=[]" ]
   }
 }
 
 if (current_toolchain != host_toolchain) {
   group("hwasan_toolchain") {