[X86] Add RMPQUERY to SNP instructions

[GGanesh]

Summary

Add RMPQUERY to the list of SNP instructions.
Tech Documentation: https://www.amd.com/system/files/TechDocs/24594.pdf

[RKSimon]

Is it worth adding a SNP feature predicate to X86.td? Are they ever going to be exposed as intrinsics or just asm?

[GGanesh]

In D141458#4043650, @RKSimon wrote:

Is it worth adding a SNP feature predicate to X86.td? Are they ever going to be exposed as intrinsics or just asm?

SNP is there from znver3. We earlier planned to add some intrinsics. Then decided that these instructions will be system instructions so will be just asm. May be if we decide to add those intrinsics in future, we will have the predicate then. At present, I will not be adding the intrinsics. For znver3, we initially had the predicate as placeholder and then removed it as the intrinsics weren't there.

[craig.topper]

llvm/lib/Target/X86/X86InstrSNP.td

43

Defs doesn't reflect this additional sentence from the spec

Upon completion, a return code is stored in EAX. rFLAGS bits OF, ZF, AF, PF and SF are set based on
return code.

[RKSimon]

llvm/lib/Target/X86/X86InstrSNP.td

43

All the SNP instructions seem to be missing this in fact - and many update RAX/EAX with a return code as well.

[GGanesh]

Updated the SNP instructions for the review comments!

[RKSimon]

llvm/lib/Target/X86/X86InstrSNP.td

38

Looking at the description in APM3 - it uses RDX as well (for permissions)

Modifies RMP permissions for a guest page. The guest virtual address is specified in the RAX register.
The page size is specified in RCX[0]. The target VMPL and its permissions are specified in the RDX
register as follows:

43

Uses RCX as well?

Reads an RMP permission mask for a guest page. The guest virtual address is specified in the RAX
register. The target VMPL is specified in RDX[7:0]. RMP permissions for the specified VMPL are
returned in RDX[63:8] and the RCX register as shown below

[GGanesh]

Modified RMPADJUST instruction definition.

RMPQUERY doesn't use RCX as source. It is used only while returning the permissions.

[RKSimon]

LGTM - cheers

llvm/lib/Target/X86/X86InstrSNP.td

 //
 //===----------------------------------------------------------------------===//
 
 //===----------------------------------------------------------------------===//
 // SNP instructions
 
 let SchedRW = [WriteSystem] in {
 // F3 0F 01 FF
-let Uses = [RAX] in
+let Uses = [RAX], Defs = [EAX, EFLAGS] in
 def PSMASH: I<0x01, MRM_FF, (outs), (ins), "psmash", []>, XS,
             Requires<[In64BitMode]>;
 
 // F2 0F 01 FF
-let Uses = [RAX] in
+let Uses = [RAX, RCX, RDX], Defs = [EAX, EFLAGS] in
 def PVALIDATE64: I<0x01, MRM_FF, (outs), (ins), "pvalidate",[]>,
                  XD, Requires<[In64BitMode]>;
 
-let Uses = [EAX] in
+let Uses = [EAX, ECX, EDX], Defs = [EAX, EFLAGS] in
 def PVALIDATE32: I<0x01, MRM_FF, (outs), (ins), "pvalidate",[]>,
                  XD, Requires<[Not64BitMode]>;
 
 // F2 0F 01 FE
-let Uses = [RAX] in
+let Uses = [RAX, RCX], Defs = [EAX, EFLAGS] in
 def RMPUPDATE: I<0x01, MRM_FE, (outs), (ins), "rmpupdate", []>, XD,
                Requires<[In64BitMode]>;
 
 // F3 0F 01 FE
-let Uses = [RAX] in
+let Uses = [RAX, RCX, RDX], Defs = [EAX, EFLAGS] in
 def RMPADJUST: I<0x01, MRM_FE, (outs), (ins), "rmpadjust", []>, XS,
                Requires<[In64BitMode]>;
+
+// F3 0F 01 FD
+let Uses = [RAX, RDX], Defs = [RAX, RCX, RDX, EFLAGS] in
+def RMPQUERY: I<0x01, MRM_FD, (outs), (ins), "rmpquery", []>, XS,
+               Requires<[In64BitMode]>;
 } // SchedRW
 
 def : InstAlias<"psmash\t{%rax|rax}", (PSMASH)>, Requires<[In64BitMode]>;
-def : InstAlias<"pvalidate\t{%rax|rax}", (PVALIDATE64)>, Requires<[In64BitMode]>;
-def : InstAlias<"pvalidate\t{%eax|eax}", (PVALIDATE32)>, Requires<[Not64BitMode]>;
-def : InstAlias<"rmpupdate\t{%rax|rax}", (RMPUPDATE)>, Requires<[In64BitMode]>;
-def : InstAlias<"rmpadjust\t{%rax|rax}", (RMPADJUST)>, Requires<[In64BitMode]>;
+def : InstAlias<"pvalidate\t{%rax, %rcx, %rdx|rdx, rcx, rax|}", (PVALIDATE64)>, Requires<[In64BitMode]>;
+def : InstAlias<"pvalidate\t{%eax, %ecx, %edx|edx, ecx, eax|}", (PVALIDATE32)>, Requires<[Not64BitMode]>;
+def : InstAlias<"rmpupdate\t{%rax, %rcx|rcx, rax|}", (RMPUPDATE)>, Requires<[In64BitMode]>;
+def : InstAlias<"rmpadjust\t{%rax, %rcx, %rdx|rdx, rcx, rax|}", (RMPADJUST)>, Requires<[In64BitMode]>;
+def : InstAlias<"rmpquery\t{%rax, %rdx|rdx, rax|}", (RMPQUERY)>, Requires<[In64BitMode]>;

llvm/test/MC/Disassembler/X86/x86-64.txt

 0xf2 0x0f 0x01 0xff
 
 # CHECK: rmpupdate
 0xf2 0x0f 0x01 0xfe
 
 # CHECK: rmpadjust
 0xf3 0x0f 0x01 0xfe
 
+# CHECK: rmpquery
+0xf3 0x0f 0x01 0xfd
+
 # CHECK: testui
 0xf3,0x0f,0x01,0xed
 
 # CHECK: senduipi %rax
 0xf3,0x0f,0xc7,0xf0
 
 # CHECK: senduipi %rdx
 0xf3,0x0f,0xc7,0xf2

llvm/test/MC/X86/SNP-32.s

 // RUN: llvm-mc -triple i386-unknown-unknown --show-encoding %s | FileCheck %s
 
 // CHECK: pvalidate
 // CHECK: encoding: [0xf2,0x0f,0x01,0xff]
 pvalidate
 
 // CHECK: pvalidate
 // CHECK: encoding: [0xf2,0x0f,0x01,0xff]
-pvalidate %eax
+pvalidate  %eax, %ecx, %edx

llvm/test/MC/X86/SNP-64.s

 // RUN: llvm-mc -triple x86_64-unknown-unknown --show-encoding %s | FileCheck %s
 
 // CHECK: rmpupdate
 // CHECK: encoding: [0xf2,0x0f,0x01,0xfe]
-rmpupdate
+rmpupdate %rax, %rcx
 
 // CHECK: psmash
 // CHECK: encoding: [0xf3,0x0f,0x01,0xff]
-psmash
+psmash %rax
 
 // CHECK: pvalidate
 // CHECK: encoding: [0xf2,0x0f,0x01,0xff]
-pvalidate
+pvalidate %rax, %rcx, %rdx
 
 // CHECK: rmpadjust
 // CHECK: encoding: [0xf3,0x0f,0x01,0xfe]
-rmpadjust
+rmpadjust %rax, %rcx, %rdx 
+
+// CHECK: rmpquery
+// CHECK: encoding: [0xf3,0x0f,0x01,0xfd]
+rmpquery %rax, %rdx
 
 // CHECK: rmpupdate
 // CHECK: encoding: [0xf2,0x0f,0x01,0xfe]
-rmpupdate %rax
+rmpupdate
 
 // CHECK: psmash
 // CHECK: encoding: [0xf3,0x0f,0x01,0xff]
-psmash %rax
+psmash
 
 // CHECK: pvalidate
 // CHECK: encoding: [0xf2,0x0f,0x01,0xff]
-pvalidate %rax
+pvalidate
 
 // CHECK: rmpadjust
 // CHECK: encoding: [0xf3,0x0f,0x01,0xfe]
-rmpadjust %rax
+rmpadjust
+
+// CHECK: rmpquery
+// CHECK: encoding: [0xf3,0x0f,0x01,0xfd]
+rmpquery