[bazel] Restore libpfm as a conditional dependency for exegesis.

[rupprecht]

Summary

We used to have pfm built into exegesis, although since it's an external dependency we marked it as a manual target. Because of this we didn't have buildbot coverage and so we removed it in D134510 after we had a few breakages that weren't caught. This adds it back, but with three possible states similar to the story with mpfr, i.e. it can either be disabled, built from external sources (git/make), or use whatever -lpfm is installed on the system.

This change is modeled after D119547. Like that patch, the default is off (matching the status quo), but unlike that patch we don't enable it for CI because IIRC we don't have the package installed there, and building from source might be expensive. We could enable it later either after installing it on buildbot machines or by measuring build cost and deeming it OK.

[aeubanks]

libpfm4-dev was installed on the postsubmit bot but not the presubmit bot, I've installed it on the presubmit bot

you should be able to make the same change as D119547 to utils/bazel/.bazelrc

[courbet]

I'm not qualified to review this, but thanks for making it work !

[gchatelet]

LGTM. Thx @aeubanks for installing libpfm on the CI bots.

I just have a question about disabling Exegesis in case libpfm is disabled (see below)
FTR D119547 uses external as the default policy which builds from source.

@rupprecht this patch will require a bit of integration downstream.

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

2770

AFAIU it doesn't make sense to build Exegesis without libpfm so I would do something similar to
https://github.com/llvm/llvm-project/blob/ee82b864f2086f944f046bd00b03f30697403f8a/utils/bazel/llvm-project-overlay/libc/utils/MPFRWrapper/BUILD.bazel#L13-L16

This makes sure that the target is skipped when using wildcards (which is the case on CI).

[gchatelet]

utils/bazel/third_party_build/pfm.BUILD

15

Remove if not needed

[GMNGeoffrey]

utils/bazel/WORKSPACE

16–17

This formatting looks wrong to me. These are kwargs

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

2728

Do we want all transitive dependencies to have that defined? It might be better to have the selects in more places and add it in local_defines (note not copts)

2770

I think it's fine to have it without? That's what we had before this patch

[gchatelet]

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

2770

No strong opinion here, I'm fine with the status quo.

[rupprecht]

• Use system pfm for CI
• Undo bad buildifier change
• Remove leftover configure_options from a previous attempt
• Make "external" the default.

[rupprecht]

In D138470#3943208, @gchatelet wrote:

FTR D119547 uses external as the default policy which builds from source.

Made it the default for this too, then.

utils/bazel/WORKSPACE

16–17

Weird, buildifier did this.

Since starlark is sort-of-but-not-really-python this might actually be the expected format. I'll just undo it for now though.

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

2728

I personally think it makes sense to have this apply transitively. This is basically a shim config target that either says "I have pfm" or "I am missing pfm", so advertising that pervasively is an intended goal. If this causes a build target downstream to behave differently, it's because it has a "#ifdef HAVE_LIBPFM" somewhere, and it should be depending on this anyway.

I think the warning that this applies transitively and recommending that one use local defines is in case you build one target with "-UNDEBUG" and then accidentally make all your dependencies run slower because debug mode is enabled everywhere. That's good general advice but not what's happening here.

If we don't do it this way, then we have to:

1. Set copts on "Exegesis"
2. Set copts and linkopts on "llvm-exegesis"
3. Set copts and linkopts on "llvm_exegesis_tests"

Not a whole lot to do if we go down that road, but I think this is simpler.

2770

I'm leaning toward leaving it like this too just because that's what we currently have.

[chapuni]

I am using LLVM Bazel repository without LLVM's WORKSPACE.

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

2764

I think the naming of @pfm//:pfm_external would be different from other external libraries like @llvm_foobar//:foobar

[rupprecht]

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

2764

I don't have a strong preference for this name, I just lifted the naming scheme from D119547, e.g. which uses "@mpfr//:mpfr_external" and others for different ways to depend on mpfr. I'm not well versed in the style guide/naming scheme for these kinds of files so I just went with consistency with something else.

For the repo name, I think "@llvm_pfm" would be fine. Is the idea that we name it "@llvm_pfm" and not "@pfm" to clarify that the configuration for setting up pfm is local to the llvm-project repository, i.e. we're not pulling a bzl configuration from pfm's repo?

For the target name, I personally don't think just ":pfm" would be ideal, because it isn't as explicit about which pfm is being used. But if we wanted to use a different name instead of "external", that's totally fine with me.

utils/bazel/.bazelrc

 build:ci --copt=-O1
 
 # Use clang.
 build:ci --config=generic_clang
 
 # Speedup bazel using a ramdisk.
 build:ci --sandbox_base=/dev/shm
 
-# Use system's mpfr instead of building it from source.
+# Use system's mpfr and pfm instead of building it from source.
 # This is non hermetic but helps with compile time.
 build:ci --@llvm-project//libc:mpfr=system
+build:ci --@llvm-project//llvm:pfm=system
 
 # Don't build/test targets tagged with "nobuildkite".
 build:ci --build_tag_filters=-nobuildkite
 build:ci --test_tag_filters=-nobuildkite
 
 # Show as many errors as possible.
 build:ci --keep_going
 
 # Show test errors.
 build:ci --test_output=errors
 
 ###############################################################################
 
 # The user.bazelrc file is not checked in but available for local mods.
 # Always keep this at the end of the file so that user flags override.
 try-import %workspace%/user.bazelrc

utils/bazel/WORKSPACE

 # This file is licensed under the Apache License v2.0 with LLVM Exceptions.
 # See https://llvm.org/LICENSE.txt for license information.
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
 load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
 load("@bazel_tools//tools/build_defs/repo:utils.bzl", "maybe")
-load("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository")
+load("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository", "new_git_repository")
 
 SKYLIB_VERSION = "1.3.0"
 
 http_archive(
     name = "bazel_skylib",
     sha256 = "74d544d96f4a5bb630d465ca8bbcfe231e3594e5aae57e1edbf17a6eb3ca2506",
     urls = [
         "https://mirror.bazel.build/github.com/bazelbuild/bazel-skylib/releases/download/{version}/bazel-skylib-{version}.tar.gz".format(version=SKYLIB_VERSION),
         "https://github.com/bazelbuild/bazel-skylib/releases/download/{version}/bazel-skylib-{version}.tar.gz".format(version=SKYLIB_VERSION),
     ],
 )
 
 new_local_repository(
     name = "llvm-raw",
-    path = "../../",
     build_file_content = "# empty",
+    path = "../../",
 )
 
 load("@llvm-raw//utils/bazel:configure.bzl", "llvm_configure")
 
 llvm_configure(name = "llvm-project")
 
 load("@llvm-raw//utils/bazel:terminfo.bzl", "llvm_terminfo_from_env")
 

 # The availability of `mpfr` is controlled by a flag and can be either `disable`, `system` or `external`.
 # Continuous integration uses `system` to speed up the build process (see .bazelrc).
 # Otherwise by default it is set to `external`: `mpfr` and `gmp` are built from source by using `rules_foreign_cc`.
 # Note: that building from source requires `m4` to be installed on the host machine.
 # This is a known issue: https://github.com/bazelbuild/rules_foreign_cc/issues/755.
 
 git_repository(
     name = "rules_foreign_cc",
+    remote = "https://github.com/bazelbuild/rules_foreign_cc.git",
     tag = "0.9.0",
-    remote = "https://github.com/bazelbuild/rules_foreign_cc.git"
 )
 
 load("@rules_foreign_cc//foreign_cc:repositories.bzl", "rules_foreign_cc_dependencies")
+
 rules_foreign_cc_dependencies()
 
 maybe(
     http_archive,
     name = "gmp",
     build_file = "@llvm-raw//utils/bazel/third_party_build:gmp.BUILD",
     sha256 = "fd4829912cddd12f84181c3451cc752be224643e87fac497b69edddadc49b4f2",
     strip_prefix = "gmp-6.2.1",
     urls = [
         "https://gmplib.org/download/gmp/gmp-6.2.1.tar.xz",
         "https://ftp.gnu.org/gnu/gmp/gmp-6.2.1.tar.xz",
     ],
 )
 
 # https://www.mpfr.org/mpfr-current/
 maybe(
     http_archive,
     name = "mpfr",
     build_file = "@llvm-raw//utils/bazel/third_party_build:mpfr.BUILD",
     sha256 = "9cbed5d0af0d9ed5e9f8dd013e17838eb15e1db9a6ae0d371d55d35f93a782a7",
     strip_prefix = "mpfr-4.1.1",
     urls = ["https://www.mpfr.org/mpfr-current/mpfr-4.1.1.tar.gz"],
 )
 
+maybe(
+    new_git_repository,
+    name = "pfm",
+    build_file = "@llvm-raw//utils/bazel/third_party_build:pfm.BUILD",
+    remote = "https://git.code.sf.net/p/perfmon2/libpfm4",
+    tag = "v4.12.1",
+)

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

 # This file is licensed under the Apache License v2.0 with LLVM Exceptions.
 # See https://llvm.org/LICENSE.txt for license information.
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
+load("@bazel_skylib//rules:common_settings.bzl", "string_flag")
 load("@bazel_skylib//rules:expand_template.bzl", "expand_template")
 load(":tblgen.bzl", "gentbl")
 load(":config.bzl", "llvm_config_defines")
 load(":targets.bzl", "llvm_targets")
 load(":enum_targets_gen.bzl", "enum_targets_gen")
 load(":binary_alias.bzl", "binary_alias")
 
 package(default_visibility = ["//visibility:public"])
cc_library(
     hdrs = glob(["include/llvm/XRay/*.h"]),
     copts = llvm_copts,
     deps = [
         ":Object",
         ":Support",
     ],
 )
 
+# A flag to pick which `pfm` to use for Exegesis.
+# Usage: `--@llvm-project//llvm:pfm=<disable|external|system>`.
+# Flag documentation: https://bazel.build/extending/config
+string_flag(
+    name = "pfm",
+    build_setting_default = "external",
+    values = [
+        "disable",  # Don't include pfm at all
+        "external",  # Build pfm from source
+        "system",  # Use system pfm (non hermetic)
+    ],
+)
+
+config_setting(
+    name = "pfm_disable",
+    flag_values = {":pfm": "disable"},
+)
+
+config_setting(
+    name = "pfm_external",
+    flag_values = {":pfm": "external"},
+)
+
+config_setting(
+    name = "pfm_system",
+    flag_values = {":pfm": "system"},
+)
+
+cc_library(
+    name = "maybe_pfm",
+    # We want dependencies of this library to have -DHAVE_LIBPFM conditionally
+    # defined, so we set `defines` instead of `copts`.
+    defines = select({
+        ":pfm_external": ["HAVE_LIBPFM=1"],
+        ":pfm_system": ["HAVE_LIBPFM=1"],
+        "//conditions:default": [],
+    }),
+    deps = select({
+        ":pfm_external": ["@pfm//:pfm_external"],
+        ":pfm_system": ["@pfm//:pfm_system"],
+        "//conditions:default": [],
+    }),
+)
+
 cc_library(
     name = "Exegesis",
     srcs = glob([
         "tools/llvm-exegesis/lib/*.cpp",
         # We have to include these headers here as well as in the `hdrs` below
         # to allow the `.cpp` files to use file-relative-inclusion to find
         # them, even though consumers of this library use inclusion relative to
         # `tools/llvm-exegesis/lib` with the `strip_includes_prefix` of this
         # library. This mixture appears to be incompatible with header modules.
deps = [
         ":MCA",
         ":MCDisassembler",
         ":MCJIT",
         ":Object",
         ":ObjectYAML",
         ":Support",
         ":Target",
         ":config",
+        ":maybe_pfm",
     ],
 )
 
 ################################################################################
 # LLVM toolchain and development binaries
 
 gentbl(
     name = "DsymutilTableGen",

utils/bazel/third_party_build/pfm.BUILD

+# This file is licensed under the Apache License v2.0 with LLVM Exceptions.
+# See https://llvm.org/LICENSE.txt for license information.
+# SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+
+load("@rules_foreign_cc//foreign_cc:defs.bzl", "make_variant")
+
+filegroup(
+    name = "sources",
+    srcs = glob(["**"]),
+)
+
+make_variant(
+    name = "pfm",
+    copts = ["-w"],
+    lib_name = "libpfm",
+    lib_source = ":sources",
+    toolchain = "@rules_foreign_cc//toolchains:preinstalled_autoconf_toolchain",
+    visibility = ["//visibility:public"],
+)
+
+alias(
+    name = "pfm_external",
+    actual = "@pfm//:pfm_",
+    visibility = ["//visibility:public"],
+)
+
+cc_library(
+    name = "pfm_system",
+    linkopts = ["-lpfm"],
+    visibility = ["//visibility:public"],
+)