[InstCombine] fold fake floating point vector extract to shift+trunc.

[jacquesguan]

Summary

This patch supports the FP part of D111082.

[RKSimon]

Testing more float types might be a good idea (bfloat / float / double / x86_fp80 / f128 / ppc_f128), even of they're negative tests - not sure how much the isDesirableIntType check is going to interfere?

[jacquesguan]

add more FP type test.

[spatel]

Is there a motivating codegen example for this transform? Or some other IR transform that will fire as a result of this transform?

In the case with a shift, we have an extra IR instruction, so this would be a rare fold that increases instruction count. Maybe that's justifiable just because we want to keep the symmetry with the other patterns, but it would be better to show some kind of win from this patch.

llvm/test/Transforms/InstCombine/extractelement.ll

642

This comment doesn't look accurate. The data layout for both RUN lines says i64 is legal, so that's why we allow converting i64 in the test above. And there's no exception for a 1-element vector. We probably should have a test like this to confirm:

define double @bitcast_fp64vec_index0(i64 %x) {
  %v = bitcast i64 %x to <1 x double>
  %r = extractelement <1 x double> %v, i8 0
  ret double %r
}

Also make sure there's no infinite loop potential with that kind of pattern...I just noticed an odd behavior for it in D125951.

Please pre-commit the baseline tests, so it's easier to see what is or is not changing. Add a RUN with a legal i128 to confirm this is behaving as expected?

[jacquesguan]

add precommit test.

[jacquesguan]

In D125750#3525445, @spatel wrote:

Is there a motivating codegen example for this transform? Or some other IR transform that will fire as a result of this transform?

In the case with a shift, we have an extra IR instruction, so this would be a rare fold that increases instruction count. Maybe that's justifiable just because we want to keep the symmetry with the other patterns, but it would be better to show some kind of win from this patch.

Mostly, it would be much cheaper if we use scalar shift + cast rather than bitcast + vector extractelemt, even the former might cause one more instruction in LLVMIR. For example in RISCV, the former one woule be lower to 3 scalar instructions, but the latter one would firstly move from GPR to vector register and then use 2 vector instruction to extract the element, it is truely much more expensive, even without counting the vector configuration instruction that should be insert for using vector instructions.

llvm/test/Transforms/InstCombine/extractelement.ll

642

Done.

[spatel]

In D125750#3533124, @jacquesguan wrote:

In D125750#3525445, @spatel wrote:

Is there a motivating codegen example for this transform? Or some other IR transform that will fire as a result of this transform?

In the case with a shift, we have an extra IR instruction, so this would be a rare fold that increases instruction count. Maybe that's justifiable just because we want to keep the symmetry with the other patterns, but it would be better to show some kind of win from this patch.

Mostly, it would be much cheaper if we use scalar shift + cast rather than bitcast + vector extractelemt, even the former might cause one more instruction in LLVMIR. For example in RISCV, the former one woule be lower to 3 scalar instructions, but the latter one would firstly move from GPR to vector register and then use 2 vector instruction to extract the element, it is truely much more expensive, even without counting the vector configuration instruction that should be insert for using vector instructions.

Yes, I understand the codegen motivation. I should have been more explicit though - that's generally not enough to justify an IR canonicalization if the backend could just as easily do this transform.

We really want to show that the change in IR leads to an improvement in analysis and/or results in even more optimization. Double-check, but we could probably add a test like this:
https://alive2.llvm.org/ce/z/77k-Zg

[jacquesguan]

Address comment.

[jacquesguan]

In D125750#3534196, @spatel wrote:

In D125750#3533124, @jacquesguan wrote:

In D125750#3525445, @spatel wrote:

Is there a motivating codegen example for this transform? Or some other IR transform that will fire as a result of this transform?

In the case with a shift, we have an extra IR instruction, so this would be a rare fold that increases instruction count. Maybe that's justifiable just because we want to keep the symmetry with the other patterns, but it would be better to show some kind of win from this patch.

Mostly, it would be much cheaper if we use scalar shift + cast rather than bitcast + vector extractelemt, even the former might cause one more instruction in LLVMIR. For example in RISCV, the former one woule be lower to 3 scalar instructions, but the latter one would firstly move from GPR to vector register and then use 2 vector instruction to extract the element, it is truely much more expensive, even without counting the vector configuration instruction that should be insert for using vector instructions.

Yes, I understand the codegen motivation. I should have been more explicit though - that's generally not enough to justify an IR canonicalization if the backend could just as easily do this transform.

We really want to show that the change in IR leads to an improvement in analysis and/or results in even more optimization. Double-check, but we could probably add a test like this:
https://alive2.llvm.org/ce/z/77k-Zg

Thanks, I added this test at the last.

[spatel]

llvm/test/Transforms/InstCombine/extractelement.ll

862

We were missing a transform that would reduce this, so I added it here:
482777123427

Please rebase/update to generate new output.

[jacquesguan]

Address comment.

llvm/test/Transforms/InstCombine/extractelement.ll

862

Done, thanks.

[spatel]

LGTM

llvm/lib/Transforms/InstCombine/InstCombineVectorOps.cpp

Instruction *InstCombinerImpl::foldBitcastExtElt(ExtractElementInst &Ext) {
 
   ElementCount NumElts =
       cast<VectorType>(Ext.getVectorOperandType())->getElementCount();
   Type *DestTy = Ext.getType();
   bool IsBigEndian = DL.isBigEndian();
 
   // If we are casting an integer to vector and extracting a portion, that is
   // a shift-right and truncate.
-  // TODO: Allow FP dest type by casting the trunc to FP?
-  if (X->getType()->isIntegerTy() && DestTy->isIntegerTy() &&
+  if (X->getType()->isIntegerTy() &&
       isDesirableIntType(X->getType()->getPrimitiveSizeInBits())) {
     assert(isa<FixedVectorType>(Ext.getVectorOperand()->getType()) &&
            "Expected fixed vector type for bitcast from scalar integer");
 
     // Big endian requires adjusting the extract index since MSB is at index 0.
     // LittleEndian: extelt (bitcast i32 X to v4i8), 0 -> trunc i32 X to i8
     // BigEndian: extelt (bitcast i32 X to v4i8), 0 -> trunc i32 (X >> 24) to i8
     if (IsBigEndian)
       ExtIndexC = NumElts.getKnownMinValue() - 1 - ExtIndexC;
     unsigned ShiftAmountC = ExtIndexC * DestTy->getPrimitiveSizeInBits();
     if (!ShiftAmountC || Ext.getVectorOperand()->hasOneUse()) {
       Value *Lshr = Builder.CreateLShr(X, ShiftAmountC, "extelt.offset");
+      if (DestTy->isFloatingPointTy()) {
+        Type *DstIntTy = IntegerType::getIntNTy(
+            Lshr->getContext(), DestTy->getPrimitiveSizeInBits());
+        Value *Trunc = Builder.CreateTrunc(Lshr, DstIntTy);
+        return new BitCastInst(Trunc, DestTy);
+      }
       return new TruncInst(Lshr, DestTy);
     }
   }
 
   if (!X->getType()->isVectorTy())
     return nullptr;
 
   // If this extractelement is using a bitcast from a vector of the same number

llvm/test/Transforms/InstCombine/extractelement.ll

 ; ANY-NEXT:    ret i8 [[R]]
 ;
   %v = bitcast float %x to <4 x i8>
   %r = extractelement <4 x i8> %v, i8 0
   ret i8 %r
 }
 
 define half @bitcast_fp16vec_index0(i32 %x) {
-; ANY-LABEL: @bitcast_fp16vec_index0(
-; ANY-NEXT:    [[V:%.*]] = bitcast i32 [[X:%.*]] to <2 x half>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x half> [[V]], i64 0
-; ANY-NEXT:    ret half [[R]]
+; LE64-LABEL: @bitcast_fp16vec_index0(
+; LE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; LE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; LE64-NEXT:    ret half [[R]]
+;
+; BE64-LABEL: @bitcast_fp16vec_index0(
+; BE64-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; BE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; BE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; BE64-NEXT:    ret half [[R]]
+;
+; LE128-LABEL: @bitcast_fp16vec_index0(
+; LE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; LE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; LE128-NEXT:    ret half [[R]]
+;
+; BE128-LABEL: @bitcast_fp16vec_index0(
+; BE128-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; BE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; BE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; BE128-NEXT:    ret half [[R]]
 ;
   %v = bitcast i32 %x to <2 x half>
   %r = extractelement <2 x half> %v, i8 0
   ret half %r
 }
 
 define half @bitcast_fp16vec_index1(i32 %x) {
-; ANY-LABEL: @bitcast_fp16vec_index1(
-; ANY-NEXT:    [[V:%.*]] = bitcast i32 [[X:%.*]] to <2 x half>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x half> [[V]], i64 1
-; ANY-NEXT:    ret half [[R]]
+; LE64-LABEL: @bitcast_fp16vec_index1(
+; LE64-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; LE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; LE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; LE64-NEXT:    ret half [[R]]
+;
+; BE64-LABEL: @bitcast_fp16vec_index1(
+; BE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; BE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; BE64-NEXT:    ret half [[R]]
+;
+; LE128-LABEL: @bitcast_fp16vec_index1(
+; LE128-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; LE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; LE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; LE128-NEXT:    ret half [[R]]
+;
+; BE128-LABEL: @bitcast_fp16vec_index1(
+; BE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; BE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to half
+; BE128-NEXT:    ret half [[R]]
 ;
   %v = bitcast i32 %x to <2 x half>
   %r = extractelement <2 x half> %v, i8 1
   ret half %r
 }
 
 define bfloat @bitcast_bfp16vec_index0(i32 %x) {
-; ANY-LABEL: @bitcast_bfp16vec_index0(
-; ANY-NEXT:    [[V:%.*]] = bitcast i32 [[X:%.*]] to <2 x bfloat>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x bfloat> [[V]], i64 0
-; ANY-NEXT:    ret bfloat [[R]]
+; LE64-LABEL: @bitcast_bfp16vec_index0(
+; LE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; LE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; LE64-NEXT:    ret bfloat [[R]]
+;
+; BE64-LABEL: @bitcast_bfp16vec_index0(
+; BE64-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; BE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; BE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; BE64-NEXT:    ret bfloat [[R]]
+;
+; LE128-LABEL: @bitcast_bfp16vec_index0(
+; LE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; LE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; LE128-NEXT:    ret bfloat [[R]]
+;
+; BE128-LABEL: @bitcast_bfp16vec_index0(
+; BE128-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; BE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; BE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; BE128-NEXT:    ret bfloat [[R]]
 ;
   %v = bitcast i32 %x to <2 x bfloat>
   %r = extractelement <2 x bfloat> %v, i8 0
   ret bfloat %r
 }
 
 define bfloat @bitcast_bfp16vec_index1(i32 %x) {
-; ANY-LABEL: @bitcast_bfp16vec_index1(
-; ANY-NEXT:    [[V:%.*]] = bitcast i32 [[X:%.*]] to <2 x bfloat>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x bfloat> [[V]], i64 1
-; ANY-NEXT:    ret bfloat [[R]]
+; LE64-LABEL: @bitcast_bfp16vec_index1(
+; LE64-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; LE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; LE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; LE64-NEXT:    ret bfloat [[R]]
+;
+; BE64-LABEL: @bitcast_bfp16vec_index1(
+; BE64-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; BE64-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; BE64-NEXT:    ret bfloat [[R]]
+;
+; LE128-LABEL: @bitcast_bfp16vec_index1(
+; LE128-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i32 [[X:%.*]], 16
+; LE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[EXTELT_OFFSET]] to i16
+; LE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; LE128-NEXT:    ret bfloat [[R]]
+;
+; BE128-LABEL: @bitcast_bfp16vec_index1(
+; BE128-NEXT:    [[TMP1:%.*]] = trunc i32 [[X:%.*]] to i16
+; BE128-NEXT:    [[R:%.*]] = bitcast i16 [[TMP1]] to bfloat
+; BE128-NEXT:    ret bfloat [[R]]
 ;
   %v = bitcast i32 %x to <2 x bfloat>
   %r = extractelement <2 x bfloat> %v, i8 1
   ret bfloat %r
 }
 
 define float @bitcast_fp32vec_index0(i64 %x) {
-; ANY-LABEL: @bitcast_fp32vec_index0(
-; ANY-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <2 x float>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x float> [[V]], i64 0
-; ANY-NEXT:    ret float [[R]]
+; LE64-LABEL: @bitcast_fp32vec_index0(
+; LE64-NEXT:    [[TMP1:%.*]] = trunc i64 [[X:%.*]] to i32
+; LE64-NEXT:    [[R:%.*]] = bitcast i32 [[TMP1]] to float
+; LE64-NEXT:    ret float [[R]]
+;
+; BE64-LABEL: @bitcast_fp32vec_index0(
+; BE64-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i64 [[X:%.*]], 32
+; BE64-NEXT:    [[TMP1:%.*]] = trunc i64 [[EXTELT_OFFSET]] to i32
+; BE64-NEXT:    [[R:%.*]] = bitcast i32 [[TMP1]] to float
+; BE64-NEXT:    ret float [[R]]
+;
+; ANY128-LABEL: @bitcast_fp32vec_index0(
+; ANY128-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <2 x float>
+; ANY128-NEXT:    [[R:%.*]] = extractelement <2 x float> [[V]], i64 0
+; ANY128-NEXT:    ret float [[R]]
 ;
   %v = bitcast i64 %x to <2 x float>
   %r = extractelement <2 x float> %v, i8 0
   ret float %r
 }
 
 define float @bitcast_fp32vec_index1(i64 %x) {
-; ANY-LABEL: @bitcast_fp32vec_index1(
-; ANY-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <2 x float>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x float> [[V]], i64 1
-; ANY-NEXT:    ret float [[R]]
+; LE64-LABEL: @bitcast_fp32vec_index1(
+; LE64-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i64 [[X:%.*]], 32
+; LE64-NEXT:    [[TMP1:%.*]] = trunc i64 [[EXTELT_OFFSET]] to i32
+; LE64-NEXT:    [[R:%.*]] = bitcast i32 [[TMP1]] to float
+; LE64-NEXT:    ret float [[R]]
+;
+; BE64-LABEL: @bitcast_fp32vec_index1(
+; BE64-NEXT:    [[TMP1:%.*]] = trunc i64 [[X:%.*]] to i32
+; BE64-NEXT:    [[R:%.*]] = bitcast i32 [[TMP1]] to float
+; BE64-NEXT:    ret float [[R]]
+;
+; ANY128-LABEL: @bitcast_fp32vec_index1(
+; ANY128-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <2 x float>
+; ANY128-NEXT:    [[R:%.*]] = extractelement <2 x float> [[V]], i64 1
+; ANY128-NEXT:    ret float [[R]]
 ;
   %v = bitcast i64 %x to <2 x float>
   %r = extractelement <2 x float> %v, i8 1
   ret float %r
 }
 
 define double @bitcast_fp64vec64_index0(i64 %x) {
-; ANY-LABEL: @bitcast_fp64vec64_index0(
-; ANY-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <1 x double>
-; ANY-NEXT:    [[R:%.*]] = extractelement <1 x double> [[V]], i64 0
-; ANY-NEXT:    ret double [[R]]
+; ANY64-LABEL: @bitcast_fp64vec64_index0(
+; ANY64-NEXT:    [[R:%.*]] = bitcast i64 [[X:%.*]] to double
+; ANY64-NEXT:    ret double [[R]]
+;
+; ANY128-LABEL: @bitcast_fp64vec64_index0(
+; ANY128-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <1 x double>
+; ANY128-NEXT:    [[R:%.*]] = extractelement <1 x double> [[V]], i64 0
+; ANY128-NEXT:    ret double [[R]]
 ;
   %v = bitcast i64 %x to <1 x double>
   %r = extractelement <1 x double> %v, i8 0
   ret double %r
 }
 
 define double @bitcast_fp64vec_index0(i128 %x) {
-; ANY-LABEL: @bitcast_fp64vec_index0(
-; ANY-NEXT:    [[V:%.*]] = bitcast i128 [[X:%.*]] to <2 x double>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x double> [[V]], i64 0
-; ANY-NEXT:    ret double [[R]]
+; ANY64-LABEL: @bitcast_fp64vec_index0(
+; ANY64-NEXT:    [[V:%.*]] = bitcast i128 [[X:%.*]] to <2 x double>
+; ANY64-NEXT:    [[R:%.*]] = extractelement <2 x double> [[V]], i64 0
+; ANY64-NEXT:    ret double [[R]]
+;
+; LE128-LABEL: @bitcast_fp64vec_index0(
+; LE128-NEXT:    [[TMP1:%.*]] = trunc i128 [[X:%.*]] to i64
+; LE128-NEXT:    [[R:%.*]] = bitcast i64 [[TMP1]] to double
+; LE128-NEXT:    ret double [[R]]
+;
+; BE128-LABEL: @bitcast_fp64vec_index0(
+; BE128-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i128 [[X:%.*]], 64
+; BE128-NEXT:    [[TMP1:%.*]] = trunc i128 [[EXTELT_OFFSET]] to i64
+; BE128-NEXT:    [[R:%.*]] = bitcast i64 [[TMP1]] to double
+; BE128-NEXT:    ret double [[R]]
 ;
   %v = bitcast i128 %x to <2 x double>
   %r = extractelement <2 x double> %v, i8 0
   ret double %r
 }
 
 define double @bitcast_fp64vec_index1(i128 %x) {
-; ANY-LABEL: @bitcast_fp64vec_index1(
-; ANY-NEXT:    [[V:%.*]] = bitcast i128 [[X:%.*]] to <2 x double>
-; ANY-NEXT:    [[R:%.*]] = extractelement <2 x double> [[V]], i64 1
-; ANY-NEXT:    ret double [[R]]
+; ANY64-LABEL: @bitcast_fp64vec_index1(
+; ANY64-NEXT:    [[V:%.*]] = bitcast i128 [[X:%.*]] to <2 x double>
+; ANY64-NEXT:    [[R:%.*]] = extractelement <2 x double> [[V]], i64 1
+; ANY64-NEXT:    ret double [[R]]
+;
+; LE128-LABEL: @bitcast_fp64vec_index1(
+; LE128-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i128 [[X:%.*]], 64
+; LE128-NEXT:    [[TMP1:%.*]] = trunc i128 [[EXTELT_OFFSET]] to i64
+; LE128-NEXT:    [[R:%.*]] = bitcast i64 [[TMP1]] to double
+; LE128-NEXT:    ret double [[R]]
+;
+; BE128-LABEL: @bitcast_fp64vec_index1(
+; BE128-NEXT:    [[TMP1:%.*]] = trunc i128 [[X:%.*]] to i64
+; BE128-NEXT:    [[R:%.*]] = bitcast i64 [[TMP1]] to double
+; BE128-NEXT:    ret double [[R]]
 ;
   %v = bitcast i128 %x to <2 x double>
   %r = extractelement <2 x double> %v, i8 1
   ret double %r
 }
 
 ; negative test - input integer should be legal
 

 ; ANY128-NEXT:    ret i8 [[R]]
 ;
   %v = bitcast i64 %x to <8 x i8>
   call void @use(<8 x i8> %v)
   %r = extractelement <8 x i8> %v, i64 0
   ret i8 %r
 }
 
 define i1 @bit_extract_cmp(i64 %x) {
-; ANY-LABEL: @bit_extract_cmp(
-; ANY-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <2 x float>
-; ANY-NEXT:    [[E:%.*]] = extractelement <2 x float> [[V]], i64 1
-; ANY-NEXT:    [[R:%.*]] = fcmp oeq float [[E]], 0.000000e+00
-; ANY-NEXT:    ret i1 [[R]]
+; LE64-LABEL: @bit_extract_cmp(
+; LE64-NEXT:    [[EXTELT_OFFSET:%.*]] = lshr i64 [[X:%.*]], 32
+; LE64-NEXT:    [[TMP1:%.*]] = trunc i64 [[EXTELT_OFFSET]] to i32
+; LE64-NEXT:    [[E:%.*]] = bitcast i32 [[TMP1]] to float
+; LE64-NEXT:    [[R:%.*]] = fcmp oeq float [[E]], 0.000000e+00
+; LE64-NEXT:    ret i1 [[R]]
+;
+; BE64-LABEL: @bit_extract_cmp(
+; BE64-NEXT:    [[TMP1:%.*]] = trunc i64 [[X:%.*]] to i32
+; BE64-NEXT:    [[E:%.*]] = bitcast i32 [[TMP1]] to float
+; BE64-NEXT:    [[R:%.*]] = fcmp oeq float [[E]], 0.000000e+00
+; BE64-NEXT:    ret i1 [[R]]
+;
+; ANY128-LABEL: @bit_extract_cmp(
+; ANY128-NEXT:    [[V:%.*]] = bitcast i64 [[X:%.*]] to <2 x float>
+; ANY128-NEXT:    [[E:%.*]] = extractelement <2 x float> [[V]], i64 1
+; ANY128-NEXT:    [[R:%.*]] = fcmp oeq float [[E]], 0.000000e+00
+; ANY128-NEXT:    ret i1 [[R]]
 ;
   %v = bitcast i64 %x to <2 x float>
   %e = extractelement <2 x float> %v, i8 1
   %r = fcmp oeq float %e, 0.0
   ret i1 %r
 }