[gn build] add llvm_install_cctools_symlinks arg

[thakis]

Summary

It behaves (mostly) like the LLVM_INSTALL_CCTOOLS_SYMLINKS option
in cmake.

The minor difference is that the llvm-objcopy symlinks bitcode_strip
and install_name_tool symlink to llvm-objcopy directly in the GN build,
while it's a bitcode_strip -> llvm-bitcode-strip -> objcopy chain
in the CMake build (and analogous for install_name_tool).

The implementation is very similar to the implementation of the
existing llvm_install_binutils_symlinks arg.

[aeubanks]

llvm/utils/gn/secondary/llvm/tools/cctools_symlinks.gni

3

[thakis]

thanks!

llvm/utils/gn/secondary/BUILD.gn

group("llvm-nm") {
   deps = [ "//llvm/tools/llvm-nm:symlinks" ]
 }
 group("llvm-cxxfilt") {
   deps = [ "//llvm/tools/llvm-cxxfilt:symlinks" ]
 }
 group("llvm-debuginfod-find") {
   deps = [ "//llvm/tools/llvm-debuginfod-find:symlinks" ]
 }
+group("llvm-libtool-darwin") {
+  deps = [ "//llvm/tools/llvm-libtool-darwin:symlinks" ]
+}
+group("llvm-lipo") {
+  deps = [ "//llvm/tools/llvm-lipo:symlinks" ]
+}
 group("llvm-objcopy") {
   deps = [ "//llvm/tools/llvm-objcopy:symlinks" ]
 }
 group("llvm-objdump") {
   deps = [ "//llvm/tools/llvm-objdump:symlinks" ]
 }
 group("llvm-rc") {
   deps = [ "//llvm/tools/llvm-rc:symlinks" ]

llvm/utils/gn/secondary/lld/test/BUILD.gn

deps = [
     "//llvm/tools/dsymutil",
     "//llvm/tools/llc",
     "//llvm/tools/llvm-ar:symlinks",
     "//llvm/tools/llvm-as",
     "//llvm/tools/llvm-bcanalyzer",
     "//llvm/tools/llvm-cvtres",
     "//llvm/tools/llvm-dis",
     "//llvm/tools/llvm-dwarfdump",
-    "//llvm/tools/llvm-lipo",
+    "//llvm/tools/llvm-lipo:symlinks",
     "//llvm/tools/llvm-mc",
     "//llvm/tools/llvm-nm:symlinks",
     "//llvm/tools/llvm-objcopy:symlinks",
     "//llvm/tools/llvm-objdump:symlinks",
     "//llvm/tools/llvm-pdbutil",
     "//llvm/tools/llvm-profdata",
     "//llvm/tools/llvm-readobj:symlinks",
     "//llvm/tools/llvm-symbolizer:symlinks",

llvm/utils/gn/secondary/llvm/test/BUILD.gn

deps = [
     "//llvm/tools/llvm-dwp",
     "//llvm/tools/llvm-exegesis",
     "//llvm/tools/llvm-extract",
     "//llvm/tools/llvm-gsymutil:llvm-gsymutil",
     "//llvm/tools/llvm-ifs",
     "//llvm/tools/llvm-isel-fuzzer",
     "//llvm/tools/llvm-jitlink",
     "//llvm/tools/llvm-jitlink/llvm-jitlink-executor",
-    "//llvm/tools/llvm-libtool-darwin",
+    "//llvm/tools/llvm-libtool-darwin:symlinks",
     "//llvm/tools/llvm-link",
-    "//llvm/tools/llvm-lipo",
+    "//llvm/tools/llvm-lipo:symlinks",
     "//llvm/tools/llvm-lto",
     "//llvm/tools/llvm-lto2",
     "//llvm/tools/llvm-mc",
     "//llvm/tools/llvm-mca",
     "//llvm/tools/llvm-ml",
     "//llvm/tools/llvm-modextract",
     "//llvm/tools/llvm-mt",
     "//llvm/tools/llvm-nm",

llvm/utils/gn/secondary/llvm/tools/cctools_symlinks.gni

+declare_args() {
+  # If set, creates symlinks for cctools like libtool or lipo in the build
+  # directory.
+  llvm_install_cctools_symlinks = false
+}

llvm/utils/gn/secondary/llvm/tools/llvm-libtool-darwin/BUILD.gn

+import("//llvm/tools/cctools_symlinks.gni")
+import("//llvm/utils/gn/build/symlink_or_copy.gni")
+
+if (llvm_install_cctools_symlinks) {
+  symlink_or_copy("libtool") {
+    deps = [ ":llvm-libtool-darwin" ]
+    source = "llvm-libtool-darwin"
+    output = "$root_out_dir/bin/libtool"
+  }
+}
+
+# //:llvm-libtool-darwin depends on this symlink target, see comment in
+# //BUILD.gn.
+group("symlinks") {
+  if (llvm_install_cctools_symlinks) {
+    deps = [ ":libtool" ]
+  }
+}
+
 executable("llvm-libtool-darwin") {
   deps = [
     "//llvm/lib/Object",
     "//llvm/lib/Support",
     "//llvm/lib/Target:TargetsToBuild",
   ]
   sources = [ "llvm-libtool-darwin.cpp" ]
 }

llvm/utils/gn/secondary/llvm/tools/llvm-lipo/BUILD.gn

+import("//llvm/tools/cctools_symlinks.gni")
 import("//llvm/utils/TableGen/tablegen.gni")
+import("//llvm/utils/gn/build/symlink_or_copy.gni")
 
 tablegen("LipoOpts") {
   visibility = [ ":llvm-lipo" ]
   args = [ "-gen-opt-parser-defs" ]
 }
 
+if (llvm_install_cctools_symlinks) {
+  symlink_or_copy("lipo") {
+    deps = [ ":llvm-lipo" ]
+    source = "llvm-lipo"
+    output = "$root_out_dir/bin/lipo"
+  }
+}
+
+# //:llvm-lipo depends on this symlink target, see comment in //BUILD.gn.
+group("symlinks") {
+  if (llvm_install_cctools_symlinks) {
+    deps = [ ":lipo" ]
+  }
+}
+
 executable("llvm-lipo") {
   deps = [
     ":LipoOpts",
     "//llvm/lib/Object",
     "//llvm/lib/Option",
     "//llvm/lib/Support",
     "//llvm/lib/Target:TargetsToBuild",
   ]
   sources = [ "llvm-lipo.cpp" ]
 }

llvm/utils/gn/secondary/llvm/tools/llvm-objcopy/BUILD.gn

 import("//llvm/tools/binutils_symlinks.gni")
+import("//llvm/tools/cctools_symlinks.gni")
 import("//llvm/utils/TableGen/tablegen.gni")
 import("//llvm/utils/gn/build/symlink_or_copy.gni")
 
 tablegen("BitcodeStripOpts") {
   visibility = [ ":llvm-objcopy" ]
   args = [ "-gen-opt-parser-defs" ]
 }
 
symlinks = [
   "llvm-strip",
 ]
 if (llvm_install_binutils_symlinks) {
   symlinks += [
     "objcopy",
     "strip",
   ]
 }
+if (llvm_install_cctools_symlinks) {
+  symlinks += [
+    "bitcode_strip",
+    "install_name_tool",
+  ]
+}
 foreach(target, symlinks) {
   symlink_or_copy(target) {
     deps = [ ":llvm-objcopy" ]
     source = "llvm-objcopy"
     output = "$root_out_dir/bin/$target"
   }
 }