[MLIR][Math] Enable constant folding of ops

[wsmoses]

Summary

Enable constant folding of ops within the math dialect, and introduce constant folders for ceil and log2

mlir/include/mlir/Dialect/Math/IR/MathBase.td

 include "mlir/IR/OpBase.td"
 def Math_Dialect : Dialect {
   let name = "math";
   let cppNamespace = "::mlir::math";
   let description = [{
     The math dialect is intended to hold mathematical operations on integer and
     floating type beyond simple arithmetics.
   }];
+  let hasConstantMaterializer = 1;
   let emitAccessorPrefix = kEmitAccessorPrefix_Prefixed;
 }
 #endif // MATH_BASE

mlir/include/mlir/Dialect/Math/IR/MathOps.td

let description = [{
 
     // SIMD vector element-wise ceiling value.
     %f = math.ceil %g : vector<4xf32>
 
     // Tensor element-wise ceiling value.
     %x = math.ceil %y : tensor<4x?xf8>
     ```
   }];
+  let hasFolder = 1;
 }
 
 //===----------------------------------------------------------------------===//
 // CopySignOp
 //===----------------------------------------------------------------------===//
 
 def Math_CopySignOp : Math_FloatBinaryOp<"copysign"> {
   let summary = "A copysign operation";
let description = [{
     returns one result of the same type.
 
     Example:
 
     ```mlir
     %y = math.log2 %x : f64
     ```
   }];
+  let hasFolder = 1;
 }
 
 //===----------------------------------------------------------------------===//
 // PowFOp
 //===----------------------------------------------------------------------===//
 
 def Math_PowFOp : Math_FloatBinaryOp<"powf"> {
   let summary = "floating point raised to the power of operation";

mlir/lib/Dialect/Math/IR/MathOps.cpp

 //===- MathOps.cpp - MLIR operations for math implementation --------------===//
 //
 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
 // See https://llvm.org/LICENSE.txt for license information.
 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 //
 //===----------------------------------------------------------------------===//
 
+#include "mlir/Dialect/Arithmetic/IR/Arithmetic.h"
 #include "mlir/Dialect/Math/IR/Math.h"
+#include "mlir/IR/Builders.h"
 
 using namespace mlir;
 using namespace mlir::math;
 
 //===----------------------------------------------------------------------===//
 // TableGen'd op method definitions
 //===----------------------------------------------------------------------===//
 
 #define GET_OP_CLASSES
 #include "mlir/Dialect/Math/IR/MathOps.cpp.inc"
+
+//===----------------------------------------------------------------------===//
+// CeilOp folder
+//===----------------------------------------------------------------------===//
+
+OpFoldResult math::CeilOp::fold(ArrayRef<Attribute> operands) {
+  auto constOperand = operands.front();
+  if (!constOperand)
+    return {};
+
+  auto attr = constOperand.dyn_cast<FloatAttr>();
+  if (!attr)
+    return {};
+
+  APFloat sourceVal = attr.getValue();
+  sourceVal.roundToIntegral(llvm::RoundingMode::TowardPositive);
+
+  return FloatAttr::get(getType(), sourceVal);
+}
+
+//===----------------------------------------------------------------------===//
+// Log2Op folder
+//===----------------------------------------------------------------------===//
+
+OpFoldResult math::Log2Op::fold(ArrayRef<Attribute> operands) {
+  auto constOperand = operands.front();
+  if (!constOperand)
+    return {};
+
+  auto attr = constOperand.dyn_cast<FloatAttr>();
+  if (!attr)
+    return {};
+
+  auto FT = getType().cast<FloatType>();
+
+  APFloat APF = attr.getValue();
+
+  if (APF.isNegative())
+    return {};
+
+  if (FT.getWidth() == 64)
+    return FloatAttr::get(getType(), log2(APF.convertToDouble()));
+
+  if (FT.getWidth() == 32)
+    return FloatAttr::get(getType(), log2f(APF.convertToDouble()));
+
+  return {};
+}
+
+/// Materialize an integer or floating point constant.
+Operation *math::MathDialect::materializeConstant(OpBuilder &builder,
+                                                  Attribute value, Type type,
+                                                  Location loc) {
+  return builder.create<arith::ConstantOp>(loc, value, type);
+}

mlir/test/Dialect/Math/canonicalize.mlir

+// RUN: mlir-opt %s -canonicalize | FileCheck %s 
+
+// CHECK-LABEL: @ceil_fold
+// CHECK: %[[cst:.+]] = arith.constant 1.000000e+00 : f32
+// CHECK: return %[[cst]]
+func @ceil_fold() -> f32 {
+  %c = arith.constant 0.3 : f32
+  %r = math.ceil %c : f32
+  return %r : f32
+}
+
+// CHECK-LABEL: @ceil_fold2
+// CHECK: %[[cst:.+]] = arith.constant 2.000000e+00 : f32
+// CHECK: return %[[cst]]
+func @ceil_fold2() -> f32 {
+  %c = arith.constant 2.0 : f32
+  %r = math.ceil %c : f32
+  return %r : f32
+}
+
+// CHECK-LABEL: @log2_fold
+// CHECK: %[[cst:.+]] = arith.constant 2.000000e+00 : f32
+  // CHECK: return %[[cst]]
+func @log2_fold() -> f32 {
+  %c = arith.constant 4.0 : f32
+  %r = math.log2 %c : f32
+  return %r : f32
+}
+
+// CHECK-LABEL: @log2_fold2
+// CHECK: %[[cst:.+]] = arith.constant 0xFF800000 : f32
+  // CHECK: return %[[cst]]
+func @log2_fold2() -> f32 {
+  %c = arith.constant 0.0 : f32
+  %r = math.log2 %c : f32
+  return %r : f32
+}
+
+// CHECK-LABEL: @log2_nofold2
+// CHECK: %[[cst:.+]] = arith.constant -1.000000e+00 : f32
+// CHECK:  %[[res:.+]] = math.log2 %[[cst]] : f32
+  // CHECK: return %[[res]]
+func @log2_nofold2() -> f32 {
+  %c = arith.constant -1.0 : f32
+  %r = math.log2 %c : f32
+  return %r : f32
+}
+
+// CHECK-LABEL: @log2_fold_64
+// CHECK: %[[cst:.+]] = arith.constant 2.000000e+00 : f64
+  // CHECK: return %[[cst]]
+func @log2_fold_64() -> f64 {
+  %c = arith.constant 4.0 : f64
+  %r = math.log2 %c : f64
+  return %r : f64
+}
+
+// CHECK-LABEL: @log2_fold2_64
+// CHECK: %[[cst:.+]] = arith.constant 0xFFF0000000000000 : f64
+  // CHECK: return %[[cst]]
+func @log2_fold2_64() -> f64 {
+  %c = arith.constant 0.0 : f64
+  %r = math.log2 %c : f64
+  return %r : f64
+}
+
+// CHECK-LABEL: @log2_nofold2_64
+// CHECK: %[[cst:.+]] = arith.constant -1.000000e+00 : f64
+// CHECK:  %[[res:.+]] = math.log2 %[[cst]] : f64
+  // CHECK: return %[[res]]
+func @log2_nofold2_64() -> f64 {
+  %c = arith.constant -1.0 : f64
+  %r = math.log2 %c : f64
+  return %r : f64
+}