Use type sizes when determining dependence

[jolanta.jensen]

Summary

In the isDependence function the code does not try hard enough
to determine the dependence between types. If the types are
different it simply gives up, whereas in fact what we really
care about are the type sizes. I've changed the code to compare
sizes instead of types.

[fhahn]

The test should be moved to`llvm/test/Analysis/LoopAccessAnalysis/` and please simplify the input IR to only the required loop + memory operations.

llvm/test/Transforms/LoopVectorize/depend_diff_types.ll

11 ↗

(On Diff #368870)

Please try to simplify the input IR and try to motivate/explain the problem only based on the input IR.

[malharJ]

llvm/lib/Analysis/LoopAccessAnalysis.cpp

1570

Should this now be

"LAA: Zero dependence difference but different type sizes" ?

[malharJ]

llvm/test/Transforms/LoopVectorize/depend_diff_types.ll

40 ↗

(On Diff #368870)

Looks like this isn't being used anywhere and can be removed ?

If so, can also remove line 65

%25 = add nsw i32 %.dY0001_321.0, -1

Then also change

%26 = icmp sgt i32 %.dY0001_321.0, 1

to something like

%26 = icmp slt i32 %indvars.iv.next, M

58–63 ↗

(On Diff #368870)

perhaps this can be removed ?

It looks like the IR corresponds to

1) v3[i+31] = (v1[1903+i] * v3[1023+i]);   // ---> all accesses are double*

2) v3[i+1007] =  v1[i+47];   // ---> all accesses are i64*

3) v3[i+16319] = v1[i+79];   // ---> all accesses are i64* (could remove ?)

Perhaps we are only concerned with the lines 1 and 2, as they are of different types ?

[jolanta.jensen]

The test is rewritten. Also updated the comments about type sizes.

[jolanta.jensen]

Hi,

I would be grateful for re-review.

Cheers,
Jolanta

[jolanta.jensen]

llvm/test/Transforms/LoopVectorize/depend_diff_types.ll

11 ↗

(On Diff #368870)

The whole test is rewritten.

58–63 ↗

(On Diff #368870)

The whole test is rewritten.

[sdesmalen]

Hi @jolanta.jensen thanks for this change!

llvm/lib/Analysis/LoopAccessAnalysis.cpp

1526

nit: s/SizesAreSame/HasSameSize/
(this may be personal preference, so feel free to ignore).

1530

Is it worth also having a negative and positive test for this case, one where the sizes are not the same (guaranteed dependence) and one where the sizes are the same (no dependence). I think we at least need a positive test (i.e. proving no dependence when the types are different, but the same size, because I don't think your current tests covers the case of an unknown dependence distance).

1545

same question for this case.

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

44

nit: s/backwards/backward

[jolanta.jensen]

The code and the test have been updated after the review comments.

[jolanta.jensen]

llvm/lib/Analysis/LoopAccessAnalysis.cpp

1530

The test case has been extended to cover the positive case for unknown distance and the same sizes.

1545

The test case has been extended to cover this case.

[jolanta.jensen]

Corrected line 1556 in LoopAccessAnalysis.cpp where we were still comparing types.
Extended the test to cover the change to line 1556.

[sdesmalen]

Thanks for the changes, looks mostly fine to me. I just had a few more nits on the test.

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

3

nit: can you move this after the -passes='...', that way it's easier to see the difference between the two RUN lines.

17

Can you use CHECK-SAFE-NEXT: for all these? That way there are no other dependences that aren't caught by the CHECK lines. (same for the CHECK lines below).

nit: Can you move the CHECK lines just above define void @backdep_type_size_equivalence(..) {?

35

nit: strange indentation.

35

nit: odd indentation

100

nit: strange indentation.

[jolanta.jensen]

Adjusted indentation and changed CHECK to CHECK-NEXT in depend_diff_types.ll

[sdesmalen]

Thanks for addressing all the comments @jolanta.jensen, the patch looks good to me now!

@fhahn are you happy to remove your request for changes?

[fhahn]

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

2

I think there's an effort to remove remove the legacy opt invocations from opt and this already happened for the tests in this directory. Could you remove the line?

3

does the test need require<tbaa>? It looks like there's no !tbaa metadata in the test.

9

All tests here have types where TypeSize == StoreSize == AllocaSize. Could you add a test with a type where TypeSize != StoreSize != AllocaSize, e.g. using something like i19.

26

Why are there no check lines for CHECK-UNSAFE for this function? Same for CHECK-SAFE for the function below/

[jolanta.jensen]

Removed legacy invocation and require<tbaa>.
Removed -store-to-load-forwarding-conflict-detection flag
as it is set by default and simplified check labels.
Added test where TypeSize != StoreSize != AllocaSize.

[jolanta.jensen]

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

3

Removed.

26

Only using CHECK now as the -store-to-load-forwarding-conflict-detection flag is set by default.

[fhahn]

LGTM with additional comments for the tests addressed. Please also add something like [LAA] to the beginning of the title, so it is easier to categorise the change when reading the commit log.

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

93

nit: formatting is off here and for other stores in this test.

135

can you also throw in a read or write to a 32 bit type? Might be good to move those into a separate test.

[sdesmalen]

@fhahn can you help me understand your comment on the test so that I can address it before I land the patch? (@jolanta.jensen is OoO and I was asked to land the patch on her behalf)

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

135

Can you be a bit more specific about what you'd like to see? I can't quickly see what added value a read/write to 32bit type would add here. Or see which part needs moving to a separate test.

[fhahn]

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

135

I was thinking about a test that explicitly checks that the alloc types are compared in the HasSameSize check. Having a test with i19 and double accesses doesn't really ensure this, as DL.getTypeAllocSize(double) != all the different sizes (store, alloc) for i19,( i19 and double will never have the same size, except in very weird data layouts)

In a test that has accesses with i19 and i32, we should get different results for the HasSameSize check, if we use a different size in the compare (e.g. if we compare the type size directly), like below

(btw the use of unnamed IR values makes it a bit harder to play with the test cases)

define void @neg_dist_dep_type_size_equivalence(i64* nocapture %vec, i64 %n) {
entry:
  br label %loop

loop:
  %indvars.iv = phi i64 [ 0, %entry ], [ %indvars.iv.next, %loop ]

  ;; Load from vec[indvars.iv] as double
  %0 = getelementptr i64, i64* %vec, i64 %indvars.iv
  %1 = bitcast i64* %0 to i32*
  %2 = load i32, i32* %1, align 8
  %3 = mul i32 %2, 5

  ;; Different sizes
  %v8 = add nuw nsw i64 %indvars.iv, %n
  %v9 = getelementptr inbounds i64, i64* %vec, i64 %v8
  %v10 = bitcast i64* %v9 to i19*
  %v11 = trunc i32 %3 to i19
  store i19 %v11, i19* %v10, align 8

  ;; Loop condition.
  %indvars.iv.next = add nuw nsw i64 %indvars.iv, 1
  %cond = icmp eq i64 %indvars.iv.next, %n
  br i1 %cond, label %exit, label %loop

exit:
  ret void
}

[sdesmalen]

Added new test-case (i32 vs float, and i32 vs i19) and gave some more meaningful names to the variables in the test.

[sdesmalen]

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

135

Thanks, that makes sense! I've added a new test. Please have a look to see if that's what you were expecting.

[fhahn]

LGTM, thanks!

[fhahn]

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

74

the patch checks the alloc size, which may be different to the store size, would be good to fix before committing

[sdesmalen]

Thanks for the feedback @fhahn!

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

74

Done.

llvm/lib/Analysis/LoopAccessAnalysis.cpp

if (!StrideAPtr || !StrideBPtr || StrideAPtr != StrideBPtr){
     LLVM_DEBUG(dbgs() << "Pointer access with non-constant stride\n");
     return Dependence::Unknown;
   }
 
   Type *ATy = APtr->getType()->getPointerElementType();
   Type *BTy = BPtr->getType()->getPointerElementType();
   auto &DL = InnermostLoop->getHeader()->getModule()->getDataLayout();
   uint64_t TypeByteSize = DL.getTypeAllocSize(ATy);
+  bool HasSameSize = TypeByteSize == DL.getTypeAllocSize(BTy);
   uint64_t Stride = std::abs(StrideAPtr);
   const SCEVConstant *C = dyn_cast<SCEVConstant>(Dist);
   if (!C) {
-    if (!isa<SCEVCouldNotCompute>(Dist) &&
-        TypeByteSize == DL.getTypeAllocSize(BTy) &&
+    if (!isa<SCEVCouldNotCompute>(Dist) && HasSameSize &&
         isSafeDependenceDistance(DL, *(PSE.getSE()),
                                  *(PSE.getBackedgeTakenCount()), *Dist, Stride,
                                  TypeByteSize))
       return Dependence::NoDep;
 
     LLVM_DEBUG(dbgs() << "LAA: Dependence because of non-constant distance\n");
     FoundNonConstantDistanceDependence = true;
     return Dependence::Unknown;
   }
 
   const APInt &Val = C->getAPInt();
   int64_t Distance = Val.getSExtValue();
 
   // Attempt to prove strided accesses independent.
-  if (std::abs(Distance) > 0 && Stride > 1 && ATy == BTy &&
+  if (std::abs(Distance) > 0 && Stride > 1 && HasSameSize &&
       areStridedAccessesIndependent(std::abs(Distance), Stride, TypeByteSize)) {
     LLVM_DEBUG(dbgs() << "LAA: Strided accesses are independent\n");
     return Dependence::NoDep;
   }
 
   // Negative distances are not plausible dependencies.
   if (Val.isNegative()) {
     bool IsTrueDataDependence = (AIsWrite && !BIsWrite);
     if (IsTrueDataDependence && EnableForwardingConflictDetection &&
         (couldPreventStoreLoadForward(Val.abs().getZExtValue(), TypeByteSize) ||
-         ATy != BTy)) {
+         !HasSameSize)) {
       LLVM_DEBUG(dbgs() << "LAA: Forward but may prevent st->ld forwarding\n");
       return Dependence::ForwardButPreventsForwarding;
     }
 
     LLVM_DEBUG(dbgs() << "LAA: Dependence is negative\n");
     return Dependence::Forward;
   }
 
   // Write to the same location with the same size.
-  // Could be improved to assert type sizes are the same (i32 == float, etc).
   if (Val == 0) {
-    if (ATy == BTy)
+    if (HasSameSize)
       return Dependence::Forward;
     LLVM_DEBUG(
-        dbgs() << "LAA: Zero dependence difference but different types\n");
+        dbgs() << "LAA: Zero dependence difference but different type sizes\n");
     return Dependence::Unknown;
   }
 
   assert(Val.isStrictlyPositive() && "Expect a positive value");
 
-  if (ATy != BTy) {
-    LLVM_DEBUG(
-        dbgs()
-        << "LAA: ReadWrite-Write positive dependency with different types\n");
+  if (!HasSameSize) {
+    LLVM_DEBUG(dbgs() << "LAA: ReadWrite-Write positive dependency with "
+                         "different type sizes\n");
     return Dependence::Unknown;
   }
 
   // Bail out early if passed-in parameters make vectorization not feasible.
   unsigned ForcedFactor = (VectorizerParams::VectorizationFactor ?
                            VectorizerParams::VectorizationFactor : 1);
   unsigned ForcedUnroll = (VectorizerParams::VectorizationInterleave ?
                            VectorizerParams::VectorizationInterleave : 1);

llvm/test/Analysis/LoopAccessAnalysis/depend_diff_types.ll

+; RUN: opt -S -tbaa -loop-accesses -analyze -enable-new-pm=0 < %s | FileCheck %s --check-prefix=CHECK-SAFE
+; RUN: opt -S -disable-output -passes='require<scalar-evolution>,require<tbaa>,require<aa>,loop(print-access-info)' < %s 2>&1 | FileCheck %s --check-prefix=CHECK-SAFE
+; RUN: opt -S -disable-output -store-to-load-forwarding-conflict-detection -passes='require<scalar-evolution>,require<tbaa>,require<aa>,loop(print-access-info)' < %s 2>&1 | FileCheck %s --check-prefix=CHECK-UNSAFE
+
+
+; In the function below some of the accesses are done as float types and some
+; are done as i32 types. When doing dependence analysis the type should not
+; matter if it can be determined that they are the same size.
+
+; CHECK-SAFE-LABEL: function 'backdep_type_size_equivalence':
+; CHECK-SAFE:   loop:
+; CHECK-SAFE:     Memory dependences are safe with a maximum dependence distance of 800 bytes
+; CHECK-SAFE:     Dependences:
+; CHECK-SAFE:       Forward:
+; CHECK-SAFE:           %2 = load float, float* %1, align 8 ->
+; CHECK-SAFE:           store i32 %7, i32* %0, align 8
+
+; CHECK-SAFE:       Forward:
+; CHECK-SAFE:           %2 = load float, float* %1, align 8 ->
+; CHECK-SAFE:           store float %3, float* %6, align 8
+
+; CHECK-SAFE:       BackwardVectorizable:
+; CHECK-SAFE:           store float %3, float* %6, align 8 ->
+; CHECK-SAFE:           store i32 %7, i32* %0, align 8
+
+; CHECK-SAFE:    Run-time memory checks:
+; CHECK-SAFE:    Grouped accesses:
+
+%int_pair = type { i32, i32 }
+
+define void @backdep_type_size_equivalence(%int_pair* nocapture %vec, i64 %n) {
+entry:
+  br label %loop
+
+  loop:
+    %indvars.iv = phi i64 [ 0, %entry ], [ %indvars.iv.next, %loop ]
+
+    ;; Load from vec[indvars.iv].x as float
+    %0 = getelementptr inbounds %int_pair, %int_pair* %vec, i64 %indvars.iv, i32 0
+    %1 = bitcast i32* %0 to float*
+    %2 = load float, float* %1, align 8
+    %3 = fmul fast float %2, 5.0
+
+    ;; Store to vec[indvars.iv - 100].x as float
+    %4 = add nsw i64 %indvars.iv, -100
+    %5 = getelementptr inbounds %int_pair, %int_pair* %vec, i64 %4, i32 0
+    %6 = bitcast i32* %5 to float*
+    store float %3, float* %6, align 8
+
+    ;; Store to vec[indvars.iv].x as i32, creating a backward dependency between
+    ;; the two stores with different element types but the same element size.
+    %7 = trunc i64 %indvars.iv to i32
+    store i32 %7, i32* %0, align 8
+
+    ;; Store to vec[indvars.iv].y as i32, strided accesses should be independent
+    ;; between the two stores with different element types but the same element size.
+    %8 = getelementptr inbounds %int_pair, %int_pair* %vec, i64 %indvars.iv, i32 1
+    store i32 %7, i32* %8, align 8
+
+    ;; Store to vec[indvars.iv + n].y as i32, to verify no dependence in the case
+    ;; of unknown dependence distance.
+    %9 = add nuw nsw i64 %indvars.iv, %n
+    %10 = getelementptr inbounds %int_pair, %int_pair* %vec, i64 %9, i32 1
+    store i32 %7, i32* %10, align 8
+
+    ;; Loop condition.
+    %indvars.iv.next = add nuw nsw i64 %indvars.iv, 1
+    %cond = icmp eq i64 %indvars.iv.next, %n
+    br i1 %cond, label %exit, label %loop
+
+  exit:
+    ret void
+}
+
+
+; In the function below some of the accesses are done as double types and some
+; are done as i64 types. When doing dependence analysis the type should not
+; matter if it can be determined that they are the same size.
+
+; CHECK-UNSAFE-LABEL: function 'neg_dist_dep_type_size_equivalence':
+; CHECK-UNSAFE:   loop:
+; CHECK-UNSAFE:     Report: unsafe dependent memory operations in loop.
+; CHECK-UNSAFE:     Dependences:
+
+; CHECK-UNSAFE:       ForwardButPreventsForwarding:
+; CHECK-UNSAFE:           store double %3, double* %6, align 8 ->
+; CHECK-UNSAFE:           %7 = load i64, i64* %0, align 8
+
+; CHECK-UNSAFE:       BackwardVectorizableButPreventsForwarding:
+; CHECK-UNSAFE:           %2 = load double, double* %1, align 8 ->
+; CHECK-UNSAFE:           store double %3, double* %6, align 8
+
+; CHECK-UNSAFE:    Run-time memory checks:
+; CHECK-UNSAFE:    Grouped accesses:
+
+define void @neg_dist_dep_type_size_equivalence(i64* nocapture %vec, i64 %n) {
+entry:
+  br label %loop
+
+  loop:
+    %indvars.iv = phi i64 [ 0, %entry ], [ %indvars.iv.next, %loop ]
+
+    ;; Load from vec[indvars.iv] as double
+    %0 = getelementptr i64, i64* %vec, i64 %indvars.iv
+    %1 = bitcast i64* %0 to double*
+    %2 = load double, double* %1, align 8
+    %3 = fmul fast double %2, 5.0
+
+    ;; Store to vec[indvars.iv + 101] as double
+    %4 = add nsw i64 %indvars.iv, 101
+    %5 = getelementptr i64, i64* %vec, i64 %4
+    %6 = bitcast i64* %5 to double*
+    store double %3, double* %6, align 8
+
+    ;; Read from vec[indvars.iv] as i64 creating
+    ;; a forward but prevents forwarding dependence
+    ;; with different types but same sizes.
+    %7 = load i64, i64* %0, align 8
+
+    ;; Loop condition.
+    %indvars.iv.next = add nuw nsw i64 %indvars.iv, 1
+    %cond = icmp eq i64 %indvars.iv.next, %n
+    br i1 %cond, label %exit, label %loop
+
+  exit:
+    ret void
+}
+