[Bazel] Derive targets from file presence as in CMake build

[GMNGeoffrey]

Summary

This makes the logic used to determine if targets have the given
features the same as is used in CMake. Incidentally, it enables these
features for the targets added in https://reviews.llvm.org/D106921
which were missing because this was previously a hardcoded list.

[GMNGeoffrey]

Switch to an if instead of a double comprehension. Allows use for AsmPrinter too

[chandlerc]

LGTM

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

8

Should we detect the targets themselves the same way?

utils/bazel/llvm-project-overlay/llvm/BUILD.bazel

 # This file is licensed under the Apache License v2.0 with LLVM Exceptions.
 # See https://llvm.org/LICENSE.txt for license information.
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
 load(":template_rule.bzl", "template_rule")
 load(":tblgen.bzl", "gentbl")
 load(":config.bzl", "llvm_config_defines")
 load(":targets.bzl", "llvm_targets")
 load(":enum_targets_gen.bzl", "enum_targets_gen")
 load(":binary_alias.bzl", "binary_alias")
 
 package(
     default_visibility = ["//visibility:public"],
     licenses = ["notice"],
 )
 

 enum_targets_gen(
     name = "targets_def_gen",
     src = "include/llvm/Config/Targets.def.in",
     out = "include/llvm/Config/Targets.def",
     macro_name = "TARGET",
     targets = llvm_targets,
 )
 
+# Enabled targets with ASM printers.
+llvm_target_asm_printers = [
+    t
+    for t in llvm_targets
+    if glob(["lib/Target/{}/*AsmPrinter.cpp".format(t)])
+]
+
 enum_targets_gen(
     name = "asm_printers_def_gen",
     src = "include/llvm/Config/AsmPrinters.def.in",
     out = "include/llvm/Config/AsmPrinters.def",
     macro_name = "ASM_PRINTER",
-    targets = llvm_targets,
+    targets = llvm_target_asm_printers,
 )
 
-# TODO(gcmn): We should derive these lists from the presence of CMakeLists.txt
-# files, as is done in the CMake build.
-# List of targets with ASM parsers, filtered to our list of overall targets.
-llvm_target_asm_parsers = [t for t in [
-    "AArch64",
-    "AMDGPU",
-    "ARM",
-    "BPF",
-    "Hexagon",
-    "Lanai",
-    "PowerPC",
-    "RISCV",
-    "Sparc",
-    "WebAssembly",
-    "X86",
-] if t in llvm_targets]
+# Enabled targets with ASM parsers.
+llvm_target_asm_parsers = [
+    t
+    for t in llvm_targets
+    if glob(["lib/Target/{}/AsmParser/CMakeLists.txt".format(t)])
+]
 
 enum_targets_gen(
     name = "asm_parsers_def_gen",
     src = "include/llvm/Config/AsmParsers.def.in",
     out = "include/llvm/Config/AsmParsers.def",
     macro_name = "ASM_PARSER",
     targets = llvm_target_asm_parsers,
 )
 
-# List of targets with disassemblers, filtered to our list of overall targets.
-llvm_target_disassemblers = [t for t in [
-    "AArch64",
-    "AMDGPU",
-    "ARM",
-    "BPF",
-    "Hexagon",
-    "Lanai",
-    "PowerPC",
-    "RISCV",
-    "Sparc",
-    "WebAssembly",
-    "X86",
-] if t in llvm_targets]
+# Enabled targets with disassemblers.
+llvm_target_disassemblers = [
+    t
+    for t in llvm_targets
+    if glob(["lib/Target/{}/Disassembler/CMakeLists.txt".format(t)])
+]
 
 enum_targets_gen(
     name = "disassemblers_def_gen",
     src = "include/llvm/Config/Disassemblers.def.in",
     out = "include/llvm/Config/Disassemblers.def",
     macro_name = "DISASSEMBLER",
     targets = llvm_target_disassemblers,
 )
 
-# List of targets with mca, filtered to our list of overall targets.
-llvm_target_mcas = [t for t in [
-    "AMDGPU",
-] if t in llvm_targets]
+# Enabled targets with MCA.
+llvm_target_mcas = [
+    t
+    for t in llvm_targets
+    if glob(["lib/Target/{}/MCA/CMakeLists.txt".format(t)])
+]
 
 enum_targets_gen(
     name = "target_mca_def_gen",
     src = "include/llvm/Config/TargetMCAs.def.in",
     out = "include/llvm/Config/TargetMCAs.def",
     macro_name = "TARGETMCA",
     targets = llvm_target_mcas,
 )