[SimplifyCFG] Update debug location when folding branch to common destination

[davide]

Summary

Fixes https://bugs.llvm.org/show_bug.cgi?id=46008

SimplifyCFG flattens the CFG transforming:

@a = local_unnamed_addr global i16 1, align 2, !dbg !0
@c = local_unnamed_addr global i32 0, align 4, !dbg !9
@b = local_unnamed_addr global i32 0, align 4, !dbg !6

; Function Attrs: nounwind ssp uwtable
define void @d() #0 !dbg !17 {
  ret void, !dbg !20
}

; Function Attrs: nounwind ssp uwtable
define i32 @main() local_unnamed_addr #0 !dbg !21 {
  call void @llvm.dbg.value(metadata i32* @c, metadata !25, metadata !DIExpression()), !dbg !27
  br label %1, !dbg !28

1:                                                ; preds = %7, %0
  %2 = load i16, i16* @a, align 2, !dbg !29, !tbaa !32
  %3 = icmp slt i16 %2, 1, !dbg !36
  br i1 %3, label %4, label %8, !dbg !37

4:                                                ; preds = %1
  %5 = load i32, i32* @c, align 4, !dbg !38, !tbaa !40
  %6 = icmp eq i32 %5, 0, !dbg !42
  br i1 %6, label %7, label %8, !dbg !43

7:                                                ; preds = %4
  store i16 ptrtoint (void ()* @d to i16), i16* @a, align 2, !dbg !44, !tbaa !32
  br label %1, !dbg !45, !llvm.loop !46

8:                                                ; preds = %4, %1
  %9 = load i32, i32* @c, align 4, !dbg !49, !tbaa !40
  store i32 %9, i32* @b, align 4, !dbg !50, !tbaa !40
  ret i32 0, !dbg !51
}

into

; Function Attrs: nounwind ssp uwtable
define i32 @main() local_unnamed_addr #0 !dbg !21 {
  call void @llvm.dbg.value(metadata i32* @c, metadata !25, metadata !DIExpression()), !dbg !27
  br label %1, !dbg !28

1:                                                ; preds = %6, %0
  %2 = load i16, i16* @a, align 2, !dbg !29, !tbaa !32
  %3 = icmp slt i16 %2, 1, !dbg !36
  %4 = load i32, i32* @c, align 4, !dbg !37
  %5 = icmp eq i32 %4, 0, !dbg !39
  %or.cond = and i1 %3, %5, !dbg !40
  br i1 %or.cond, label %6, label %7, !dbg !40

6:                                                ; preds = %1
  store i16 ptrtoint (void ()* @d to i16), i16* @a, align 2, !dbg !41, !tbaa !32
  br label %1, !dbg !42, !llvm.loop !43

7:                                                ; preds = %1
  %8 = load i32, i32* @c, align 4, !dbg !46, !tbaa !47
  store i32 %8, i32* @b, align 4, !dbg !49, !tbaa !47
  ret i32 0, !dbg !50
}

When the instructions get folded, a dead block gets folded and the debug information is still retained. This manifests as jumpy stepping in lldb, see the bugzilla PR for an end-to-end C testcase

[davide]

Correct diff.

[vsk]

Thanks, lgtm!

llvm/lib/Transforms/Utils/SimplifyCFG.cpp

2642 ↗

(On Diff #271527)

Ah - In the single predecessor case, we erase instructions from the successor and replace their uses with an equivalent instruction in the predecessor. So I think this is fine, no change needed here.

2761 ↗

(On Diff #271527)

Ditto, it seems fine to keep the location of the condition on the 'not' instruction.

[davide]

commit 8cdd2a158c9cc94ad265fe4f0d45edd3bf916b6f (HEAD -> master, origin/master, origin/HEAD)
Author: Davide Italiano <[e-mail]>
Date: Thu Jun 18 12:33:02 2020 -0700

[SimplifyCFG] Update debug location when folding branch to common destination

Sometimes a dead block gets folded and the debug information is still
retained. This manifests as jumpy stepping in lldb, see the bugzilla PR
for an end-to-end C testcase.

Fixes https://bugs.llvm.org/show_bug.cgi?id=46008

Differential Revision:  https://reviews.llvm.org/D82062

llvm/lib/CodeGen/CodeGenPrepare.cpp

class TruncBuilder : public TypePromotionAction {
     Value *Val;
 
   public:
     /// Build a truncate instruction of \p Opnd producing a \p Ty
     /// result.
     /// trunc Opnd to Ty.
     TruncBuilder(Instruction *Opnd, Type *Ty) : TypePromotionAction(Opnd) {
       IRBuilder<> Builder(Opnd);
+      Builder.SetCurrentDebugLocation(DebugLoc());
       Val = Builder.CreateTrunc(Opnd, Ty, "promoted");
       LLVM_DEBUG(dbgs() << "Do: TruncBuilder: " << *Val << "\n");
     }
 
     /// Get the built value.
     Value *getBuiltValue() { return Val; }
 
     /// Remove the built instruction.

llvm/test/Transforms/CodeGenPrepare/X86/promoted-trunc-loc.ll

+; RUN: opt < %s -codegenprepare -S -mtriple=x86_64-unknown-unknown | FileCheck %s
+
+; Make sure the promoted trunc doesn't get a debug location associated.
+; CHECK: %promoted = trunc i32 %or to i16
+
+target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
+target triple = "x86_64-apple-macosx10.13.0"
+
+@b = global i16 0, align 2
+
+declare void @bar(i64)
+
+define i32 @foo(i16 %kkk) !dbg !6 {
+entry:
+  %t4 = load i16, i16* @b, align 2, !dbg !8
+  %conv4 = zext i16 %t4 to i32, !dbg !9
+  %or = or i16 %kkk, %t4, !dbg !10
+  %c = sext i16 %or to i64, !dbg !11
+  call void @bar(i64 %c), !dbg !12
+  %t5 = and i16 %or, 5, !dbg !13
+  %z = zext i16 %t5 to i32, !dbg !14
+  ret i32 %z, !dbg !15
+}
+
+!llvm.dbg.cu = !{!0}
+!llvm.debugify = !{!3, !4}
+!llvm.module.flags = !{!5}
+
+!0 = distinct !DICompileUnit(language: DW_LANG_C, file: !1, producer: "debugify", isOptimized: true, runtimeVersion: 0, emissionKind: FullDebug, enums: !2)
+!1 = !DIFile(filename: "/Users/davide/work/llvm-project/patatino.ll", directory: "/")
+!2 = !{}
+!3 = !{i32 8}
+!4 = !{i32 0}
+!5 = !{i32 2, !"Debug Info Version", i32 3}
+!6 = distinct !DISubprogram(name: "foo", linkageName: "foo", scope: null, file: !1, line: 1, type: !7, scopeLine: 1, spFlags: DISPFlagDefinition | DISPFlagOptimized, unit: !0, retainedNodes: !2)
+!7 = !DISubroutineType(types: !2)
+!8 = !DILocation(line: 1, column: 1, scope: !6)
+!9 = !DILocation(line: 2, column: 1, scope: !6)
+!10 = !DILocation(line: 3, column: 1, scope: !6)
+!11 = !DILocation(line: 4, column: 1, scope: !6)
+!12 = !DILocation(line: 5, column: 1, scope: !6)
+!13 = !DILocation(line: 6, column: 1, scope: !6)
+!14 = !DILocation(line: 7, column: 1, scope: !6)
+!15 = !DILocation(line: 8, column: 1, scope: !6)