AMDGPU: Skip GetUnderlyingObject check in pointsToConstantMemory

[arsenm]

Summary

Check the address space first before searching for the object
definition to save compile time. As an added bonus, this will now
treat casts to constant addrspace as constant.

We also seemed to be missing target tests for this, so add a few
missing other cases too.

[rampitec]

I do not think it is right:

int *p;
const int *x = p;

We cannot assume that x points to constant memory, just that we will not modify that memory via that pointer.

[rampitec]

On the second thought, this is not an access qualifier but address space cast, and the only valid situation should be to cast from generic if memory is really constant... So presumably caller may specialize a generic pointer and call a special version of a function taking a pointer to constant. LGTM.

[arsenm]

beda9d04c284ab68073c6b7d5a858ee609b5311c

llvm/lib/Target/AMDGPU/AMDGPUAliasAnalysis.cpp

if (Result == NoAlias)
     return Result;
 
   // Forward the query to the next alias analysis.
   return AAResultBase::alias(LocA, LocB, AAQI);
 }
 
 bool AMDGPUAAResult::pointsToConstantMemory(const MemoryLocation &Loc,
                                             AAQueryInfo &AAQI, bool OrLocal) {
+  unsigned AS = Loc.Ptr->getType()->getPointerAddressSpace();
+  if (AS == AMDGPUAS::CONSTANT_ADDRESS ||
+      AS == AMDGPUAS::CONSTANT_ADDRESS_32BIT)
+    return true;
+
   const Value *Base = GetUnderlyingObject(Loc.Ptr, DL);
-  unsigned AS = Base->getType()->getPointerAddressSpace();
+  AS = Base->getType()->getPointerAddressSpace();
   if (AS == AMDGPUAS::CONSTANT_ADDRESS ||
-      AS == AMDGPUAS::CONSTANT_ADDRESS_32BIT) {
+      AS == AMDGPUAS::CONSTANT_ADDRESS_32BIT)
     return true;
-  }
 
   if (const GlobalVariable *GV = dyn_cast<GlobalVariable>(Base)) {
     if (GV->isConstant())
       return true;
   } else if (const Argument *Arg = dyn_cast<Argument>(Base)) {
     const Function *F = Arg->getParent();
 
     // Only assume constant memory for arguments on kernels.

llvm/test/CodeGen/AMDGPU/aa-points-to-constant-memory.ll

+; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
+; RUN: opt -mtriple=amdgcn-amd-amdhsa -S -amdgpu-aa-wrapper -amdgpu-aa -instcombine -o - %s | FileCheck %s
+;
+; Test AA::pointsToConstantMemory implementation. These should mostly
+; turn out to be stores to constant memory, and will therefore be
+; deleted as UB.
+
+define void @test_constant_addrspace(i8 addrspace(4)* %p) {
+; CHECK-LABEL: @test_constant_addrspace(
+; CHECK-NEXT:    ret void
+;
+  store i8 0, i8 addrspace(4)* %p
+  ret void
+}
+
+define void @test_constant32bit_addrspace(i8 addrspace(6)* %p) {
+; CHECK-LABEL: @test_constant32bit_addrspace(
+; CHECK-NEXT:    ret void
+;
+  store i8 0, i8 addrspace(6)* %p
+  ret void
+}
+
+define void @test_cast_generic_from_constant_addrspace(i8 addrspace(4)* %p) {
+; CHECK-LABEL: @test_cast_generic_from_constant_addrspace(
+; CHECK-NEXT:    ret void
+;
+  %cast = addrspacecast i8 addrspace(4)* %p to i8*
+  store i8 0, i8* %cast
+  ret void
+}
+
+define void @test_cast_generic_from_constant32bit_addrspace(i8 addrspace(6)* %p) {
+; CHECK-LABEL: @test_cast_generic_from_constant32bit_addrspace(
+; CHECK-NEXT:    ret void
+;
+  %cast = addrspacecast i8 addrspace(6)* %p to i8*
+  store i8 0, i8* %cast
+  ret void
+}
+
+define void @test_cast_generic_to_constant_addrspace(i8* %p) {
+; CHECK-LABEL: @test_cast_generic_to_constant_addrspace(
+; CHECK-NEXT:    ret void
+;
+  %cast = addrspacecast i8* %p to i8 addrspace(4)*
+  store i8 0, i8 addrspace(4)* %cast
+  ret void
+}
+
+define void @test_cast_generic_to_constant32bit_addrspace(i8* %p) {
+; CHECK-LABEL: @test_cast_generic_to_constant32bit_addrspace(
+; CHECK-NEXT:    ret void
+;
+  %cast = addrspacecast i8* %p to i8 addrspace(6)*
+  store i8 0, i8 addrspace(6)* %cast
+  ret void
+}
+
+define amdgpu_kernel void @noalias_readnone_global_kernarg(i32 addrspace(1)* noalias readnone %arg) {
+; CHECK-LABEL: @noalias_readnone_global_kernarg(
+; CHECK-NEXT:    ret void
+;
+  store i32 0, i32 addrspace(1)* %arg
+  ret void
+}
+
+define amdgpu_kernel void @noalias_readonly_global_kernarg(i32 addrspace(1)* noalias readonly %arg) {
+; CHECK-LABEL: @noalias_readonly_global_kernarg(
+; CHECK-NEXT:    ret void
+;
+  store i32 0, i32 addrspace(1)* %arg
+  ret void
+}
+
+define amdgpu_kernel void @readnone_global_kernarg(i32 addrspace(1)* readnone %arg) {
+; CHECK-LABEL: @readnone_global_kernarg(
+; CHECK-NEXT:    store i32 0, i32 addrspace(1)* [[ARG:%.*]], align 4
+; CHECK-NEXT:    ret void
+;
+  store i32 0, i32 addrspace(1)* %arg
+  ret void
+}
+
+define amdgpu_kernel void @readonly_global_kernarg(i32 addrspace(1)* readonly %arg) {
+; CHECK-LABEL: @readonly_global_kernarg(
+; CHECK-NEXT:    store i32 0, i32 addrspace(1)* [[ARG:%.*]], align 4
+; CHECK-NEXT:    ret void
+;
+  store i32 0, i32 addrspace(1)* %arg
+  ret void
+}
+
+@global_as_constant = external addrspace(1) constant i32, align 4
+
+define amdgpu_kernel void @constant_gv_global_as() {
+; CHECK-LABEL: @constant_gv_global_as(
+; CHECK-NEXT:    ret void
+;
+  store i32 0, i32 addrspace(1)* @global_as_constant
+  ret void
+}
+
+@global_nonconstant_constant_as = external addrspace(4) global i32, align 4
+
+define amdgpu_kernel void @nonconst_gv_constant_as() {
+; CHECK-LABEL: @nonconst_gv_constant_as(
+; CHECK-NEXT:    ret void
+;
+  store i32 0, i32 addrspace(4)* @global_nonconstant_constant_as
+  ret void
+}