[libc++] Correctly handle Objective-C++ ARC qualifiers in std::is_pointer

[ldionne]

Summary

Otherwise, std::is_pointer<id strong> works, but std::is_pointer<id weak>
(and others) don't work as expected.

rdar://problem/49126333

[mclow.lists]

Do we have to worry about other pointer types than id?

[ldionne]

In D60087#1450344, @mclow.lists wrote:

Do we have to worry about other pointer types than id?

Yes, we do. Is it OK to include <Foundation/Foundation.h> in the libc++ test suite? I haven't seen it done before.

[ldionne]

Add test for pointers to Objective-C classes.

[ahatanak]

LGTM

libcxx/test/libcxx/type_traits/is_pointer_objc.arc.pass.mm

27

I think you can just declare Foo with __attribute__((objc_root_class)) or just @class Foo. You don't need Foundation.h.

[ahatanak]

libcxx/test/libcxx/type_traits/is_pointer_objc.arc.pass.mm

22

Also, can you add a test case that tests the combination of const or volatile and __weak?

std::is_pointer<__weak const id>

[ldionne]

Add tests for variations of cv-qualifiers, and remove Foundation.h

[ldionne]

Add tests for cv-qualifiers of id

[ldionne]

This was reverted in r357569 because it broke the Chromium build.

[ldionne]

Updated patch with fix for void pointers.

libcxx/include/type_traits

 _LIBCPP_INLINE_VAR _LIBCPP_CONSTEXPR bool is_array_v
     = is_array<_Tp>::value;
 #endif
 
 // is_pointer
 
 template <class _Tp> struct __libcpp_is_pointer       : public false_type {};
 template <class _Tp> struct __libcpp_is_pointer<_Tp*> : public true_type {};
+#if defined(_LIBCPP_HAS_OBJC_ARC)
+template <class _Tp> struct __libcpp_is_pointer<_Tp* __weak> : public true_type {};
+template <class _Tp> struct __libcpp_is_pointer<_Tp* __autoreleasing> : public true_type {};
+template <class _Tp> struct __libcpp_is_pointer<_Tp* __unsafe_unretained> : public true_type {};
+#endif
 
 template <class _Tp> struct _LIBCPP_TEMPLATE_VIS is_pointer
     : public __libcpp_is_pointer<typename remove_cv<_Tp>::type> {};
 
 #if _LIBCPP_STD_VER > 14 && !defined(_LIBCPP_HAS_NO_VARIABLE_TEMPLATES)
 template <class _Tp>
 _LIBCPP_INLINE_VAR _LIBCPP_CONSTEXPR bool is_pointer_v
     = is_pointer<_Tp>::value;

libcxx/test/libcxx/type_traits/is_pointer_objc.arc.pass.mm

+//===----------------------------------------------------------------------===//
+//
+// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
+// See https://llvm.org/LICENSE.txt for license information.
+// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
+//
+//===----------------------------------------------------------------------===//
+//
+// UNSUPPORTED: c++98, c++03
+
+// <type_traits>
+
+// std::is_pointer
+
+// Test that we correctly handle Objective-C++ ARC qualifiers on pointers.
+
+#include <type_traits>
+
+
+template <typename T>
+void test() {
+    static_assert(std::is_pointer<T __weak>::value, "");
+    static_assert(std::is_pointer<T __strong>::value, "");
+    static_assert(std::is_pointer<T __autoreleasing>::value, "");
+    static_assert(std::is_pointer<T __unsafe_unretained>::value, "");
+
+    static_assert(std::is_pointer<T __weak const>::value, "");
+    static_assert(std::is_pointer<T __strong const>::value, "");
+    static_assert(std::is_pointer<T __autoreleasing const>::value, "");
+    static_assert(std::is_pointer<T __unsafe_unretained const>::value, "");
+
+    static_assert(std::is_pointer<T __weak volatile>::value, "");
+    static_assert(std::is_pointer<T __strong volatile>::value, "");
+    static_assert(std::is_pointer<T __autoreleasing volatile>::value, "");
+    static_assert(std::is_pointer<T __unsafe_unretained volatile>::value, "");
+
+    static_assert(std::is_pointer<T __weak const volatile>::value, "");
+    static_assert(std::is_pointer<T __strong const volatile>::value, "");
+    static_assert(std::is_pointer<T __autoreleasing const volatile>::value, "");
+    static_assert(std::is_pointer<T __unsafe_unretained const volatile>::value, "");
+}
+
+@class Foo;
+
+int main(int, char**) {
+    test<id>();
+    test<id const>();
+    test<id volatile>();
+    test<id const volatile>();
+    test<Foo*>();
+    test<Foo const*>();
+    test<Foo volatile*>();
+    test<Foo const volatile*>();
+
+    return 0;
+}