gn build: Add BPF target.

[ast]

thanks for doing this work.
any pointers to read about GN?
Also please include code owners as reviewers next time.

[phosek]

LGTM

llvm/utils/gn/secondary/llvm/lib/Target/BPF/MCTargetDesc/BUILD.gn

39

Nit: newline between targets.

[pcc]

@ast See https://github.com/llvm/llvm-project/blob/master/llvm/utils/gn/README.rst

[pcc]

Re-opening since this was reverted in rL352649.

@yonghong-song this wasn't a change to the BPF backend so I'm not entirely clear on why you think this needed to be reviewed by a BPF code owner?

[thakis]

lgtm too.

@ast @yonghong-song This code isn't in lib/Target/BPF and you're not taking on any maintenance of these new files. This is just a clone of the CMake build files; see git log llvm/utils/gn/secondary/llvm/lib/Target for several other files like this.

[yonghong-song]

I read through the link and yes the code looks okay. I think this is a communication issue.
It would be good next time if you have better commit messages which provides enough info. about the change so reviewers can at least
take a look knowing what happens. In the case the reviewer requested a change, it would be good to send out information (as you did)
and wait for acknowledgement before merging.

[ast]

hmm. so you're saying when we add new file to the normal CMakeFiles, we don't need to touch GN ?
So it's going to bit rot immediately?
what's the purpose of this GN work then?

[thakis]

In D57436#1377680, @ast wrote:

hmm. so you're saying when we add new file to the normal CMakeFiles, we don't need to touch GN ?

Yes.

So it's going to bit rot immediately?

No – turns out files aren't changed that frequently, and people who use the GN build usually fix up the build files pretty quickly. (git log --pretty=oneline --grep Merge llvm/utils/gn/)

what's the purpose of this GN work then?

gn runs 1000x faster than cmake, and it allows things like https://reviews.llvm.org/D56713 . It also has the effect of us reading the cmake files very closely and cleaning them up a bit :-)

[ast]

In D57436#1377707, @thakis wrote:

In D57436#1377680, @ast wrote:

hmm. so you're saying when we add new file to the normal CMakeFiles, we don't need to touch GN ?

Yes.

ok. fair enough.

llvm/utils/gn/secondary/llvm/lib/Target/BPF/AsmParser/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("BPFGenAsmMatcher") {
+  visibility = [ ":AsmParser" ]
+  args = [ "-gen-asm-matcher" ]
+  td_file = "../BPF.td"
+}
+
+static_library("AsmParser") {
+  output_name = "LLVMBPFAsmParser"
+  deps = [
+    ":BPFGenAsmMatcher",
+    "//llvm/lib/MC",
+    "//llvm/lib/MC/MCParser",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/BPF/MCTargetDesc",
+    "//llvm/lib/Target/BPF/TargetInfo",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "BPFAsmParser.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/BPF/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("BPFGenCallingConv") {
+  visibility = [ ":LLVMBPFCodeGen" ]
+  args = [ "-gen-callingconv" ]
+  td_file = "BPF.td"
+}
+
+tablegen("BPFGenDAGISel") {
+  visibility = [ ":LLVMBPFCodeGen" ]
+  args = [ "-gen-dag-isel" ]
+  td_file = "BPF.td"
+}
+
+tablegen("BPFGenFastISel") {
+  visibility = [ ":LLVMBPFCodeGen" ]
+  args = [ "-gen-fast-isel" ]
+  td_file = "BPF.td"
+}
+
+tablegen("BPFGenGlobalISel") {
+  visibility = [ ":LLVMBPFCodeGen" ]
+  args = [ "-gen-global-isel" ]
+  td_file = "BPF.td"
+}
+
+tablegen("BPFGenMCPseudoLowering") {
+  visibility = [ ":LLVMBPFCodeGen" ]
+  args = [ "-gen-pseudo-lowering" ]
+  td_file = "BPF.td"
+}
+
+tablegen("BPFGenRegisterBank") {
+  visibility = [ ":LLVMBPFCodeGen" ]
+  args = [ "-gen-register-bank" ]
+  td_file = "BPF.td"
+}
+
+static_library("LLVMBPFCodeGen") {
+  deps = [
+    ":BPFGenCallingConv",
+    ":BPFGenDAGISel",
+    ":BPFGenFastISel",
+    ":BPFGenGlobalISel",
+    ":BPFGenMCPseudoLowering",
+    ":BPFGenRegisterBank",
+    "InstPrinter",
+    "MCTargetDesc",
+    "TargetInfo",
+    "//llvm/include/llvm/Config:llvm-config",
+    "//llvm/lib/Analysis",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/CodeGen/AsmPrinter",
+    "//llvm/lib/CodeGen/GlobalISel",
+    "//llvm/lib/CodeGen/SelectionDAG",
+    "//llvm/lib/IR",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+  ]
+  include_dirs = [ "." ]
+  sources = [
+    "BPFAsmPrinter.cpp",
+    "BPFFrameLowering.cpp",
+    "BPFISelDAGToDAG.cpp",
+    "BPFISelLowering.cpp",
+    "BPFInstrInfo.cpp",
+    "BPFMCInstLower.cpp",
+    "BPFMIChecking.cpp",
+    "BPFMIPeephole.cpp",
+    "BPFRegisterInfo.cpp",
+    "BPFSelectionDAGInfo.cpp",
+    "BPFSubtarget.cpp",
+    "BPFTargetMachine.cpp",
+    "BTFDebug.cpp",
+  ]
+}
+
+# This is a bit different from most build files: Due to this group
+# having the directory's name, "//llvm/lib/Target/BPF" will refer to this
+# target, which pulls in the code in this directory *and all subdirectories*.
+# For most other directories, "//llvm/lib/Foo" only pulls in the code directly
+# in "llvm/lib/Foo". The forwarding targets in //llvm/lib/Target expect this
+# different behavior.
+group("BPF") {
+  deps = [
+    ":LLVMBPFCodeGen",
+    "AsmParser",
+    "Disassembler",
+    "InstPrinter",
+    "MCTargetDesc",
+    "TargetInfo",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/BPF/Disassembler/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("BPFGenDisassemblerTables") {
+  visibility = [ ":Disassembler" ]
+  args = [ "-gen-disassembler" ]
+  td_file = "../BPF.td"
+}
+
+static_library("Disassembler") {
+  output_name = "LLVMBPFDisassembler"
+  deps = [
+    ":BPFGenDisassemblerTables",
+    "//llvm/lib/MC",
+    "//llvm/lib/MC/MCDisassembler",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/BPF/MCTargetDesc",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "BPFDisassembler.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/BPF/InstPrinter/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("BPFGenAsmWriter") {
+  visibility = [ ":InstPrinter" ]
+  args = [ "-gen-asm-writer" ]
+  td_file = "../BPF.td"
+}
+
+static_library("InstPrinter") {
+  output_name = "LLVMBPFAsmPrinter"
+  deps = [
+    ":BPFGenAsmWriter",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+
+    # MCTargetDesc depends on InstPrinter, so we can't depend on the full
+    # MCTargetDesc target here: it would form a cycle.
+    "//llvm/lib/Target/BPF/MCTargetDesc:tablegen",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "BPFInstPrinter.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/BPF/MCTargetDesc/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("BPFGenInstrInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-instr-info" ]
+  td_file = "../BPF.td"
+}
+
+tablegen("BPFGenMCCodeEmitter") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-emitter" ]
+  td_file = "../BPF.td"
+}
+
+tablegen("BPFGenRegisterInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-register-info" ]
+  td_file = "../BPF.td"
+}
+
+tablegen("BPFGenSubtargetInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-subtarget" ]
+  td_file = "../BPF.td"
+}
+
+group("tablegen") {
+  visibility = [
+    ":MCTargetDesc",
+    "../InstPrinter",
+    "../TargetInfo",
+  ]
+  public_deps = [
+    ":BPFGenInstrInfo",
+    ":BPFGenMCCodeEmitter",
+    ":BPFGenRegisterInfo",
+    ":BPFGenSubtargetInfo",
+  ]
+}
+static_library("MCTargetDesc") {
+  output_name = "LLVMBPFDesc"
+  public_deps = [
+    ":tablegen",
+  ]
+  deps = [
+    "//llvm/lib/MC",
+    "//llvm/lib/MC/MCDisassembler",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/BPF/InstPrinter",
+    "//llvm/lib/Target/BPF/TargetInfo",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "BPFAsmBackend.cpp",
+    "BPFELFObjectWriter.cpp",
+    "BPFMCCodeEmitter.cpp",
+    "BPFMCTargetDesc.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/BPF/TargetInfo/BUILD.gn

+static_library("TargetInfo") {
+  output_name = "LLVMBPFInfo"
+  deps = [
+    "//llvm/lib/Support",
+
+    # MCTargetDesc depends on TargetInfo, so we can't depend on the full
+    # MCTargetDesc target here: it would form a cycle.
+    "//llvm/lib/Target/BPF/MCTargetDesc:tablegen",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "BPFTargetInfo.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/targets.gni

if (llvm_targets_to_build == "host") {
   } else {
     assert(false, "add your host_cpu above")
   }
 } else if (llvm_targets_to_build == "all") {
   # FIXME: Port the remaining targets.
   llvm_targets_to_build = [
     "AArch64",
     "ARM",
+    "BPF",
     "PowerPC",
     "WebAssembly",
     "X86",
   ]
 }
 
 # Validate that llvm_targets_to_build is set to a list of valid targets,
 # and remember which targets are built.
 llvm_build_AArch64 = false
 llvm_build_ARM = false
+llvm_build_BPF = false
 llvm_build_PowerPC = false
 llvm_build_WebAssembly = false
 llvm_build_X86 = false
 foreach(target, llvm_targets_to_build) {
   if (target == "AArch64") {
     llvm_build_AArch64 = true
   } else if (target == "ARM") {
     llvm_build_ARM = true
+  } else if (target == "BPF") {
+    llvm_build_BPF = true
   } else if (target == "PowerPC") {
     llvm_build_PowerPC = true
   } else if (target == "WebAssembly") {
     llvm_build_WebAssembly = true
   } else if (target == "X86") {
     llvm_build_X86 = true
   } else {
     # FIXME: Port the remaining targets.