This is an archive of the discontinued LLVM Phabricator instance.

Differential D56628

gn build: Add build files for compiler-rt/lib/{hwasan,interception,sanitizer_common,ubsan}.
ClosedPublic

Authored by pcc on Jan 11 2019, 5:38 PM.

Details

Reviewers
thakis
phosek
eugenis
Commits
rG4a22fb18c793: gn build: Add build files for compiler-rt/lib/{hwasan,interception…
rL351246: gn build: Add build files for compiler-rt/lib/{hwasan,interception…
Summary

This allows the hwasan runtime to be built for Android aarch64 (but
currently r347650 needs to be reverted because of pr40250).

Depends on D56626

Depends on D56627

Diff Detail

Repository
rL LLVM

Event Timeline

pcc created this revision.Jan 11 2019, 5:38 PM
Herald added subscribers: fedor.sergeev, kristof.beyls, krytarowski and 4 others. · View Herald TranscriptJan 11 2019, 5:38 PM
Harbormaster completed remote builds in B26739: Diff 181406.Jan 11 2019, 5:39 PM
thakis added a comment.Jan 11 2019, 6:40 PM

Nice! There are enough comments below that I won't hit "accept" just yet, but none of the comments are blocking and you can talk me out of all of them if you disagree with the suggestions.

llvm/utils/gn/build/BUILD.gn
138 ↗(On Diff #181406)

"crt" means "c runtime library" in my head. I guess "compiler_rt_code" is too long for you?

llvm/utils/gn/secondary/BUILD.gn
15 ↗(On Diff #181406)

Maybe

android_aarch64_toolchain = "//llvm/utils/gn/build/toolchain:stage2_android_aarch64"
deps += [
  ""//compiler-rt/lib/hwasan:hwasan_shared($android_aarch64_toolchain)"
  ...

?

llvm/utils/gn/secondary/compiler-rt/lib/hwasan/BUILD.gn
4 ↗(On Diff #181406)

assert(current_os == "android") or something like that up here (ldflags etc assume this)

31 ↗(On Diff #181406)

This is the first source_set :-) I went with static_library almost everywhere because

  • llvm-config expects the presence of many of the llvm libs
  • the chromium build used source_sets pervasively at first but that was bad for binary size and link time, so many of that had to be undone

If you think source_set is the thing to do here it's fine to keep this as-is, just wanted to mention it.

53 ↗(On Diff #181406)

In all the other build files, I kept these alphabetical (config, deps, sources) (except that I put public_configs next to configs). I thought I saw a recommended order somewhere once but couldn't find it. If this is the recommended order, can you point me to where the recommendation is? Then I'll change all the other build files. Else, if I'm making up the memory of there being a public recommendation, it's probably good to make the order here consistent with the order in all the existing build files.

79 ↗(On Diff #181406)

I think we currently unconditionally pass T to ar; probably need some mechanism to not do this for static libaries you want to be "really" complete. (cf https://cs.chromium.org/chromium/src/build/config/compiler/BUILD.gn?q=complete_static_lib+file:build/config&sq=package:chromium&g=0&l=1679 too)

phosek added inline comments.Jan 11 2019, 8:28 PM
llvm/utils/gn/secondary/compiler-rt/lib/ubsan/BUILD.gn
1 ↗(On Diff #181406)

How closely do we want to follow CMake target names? For example, in CMake build this target is called RTUbsan (add_compiler_rt_object_libraries also adds .<arch> but that's an implementation detail).

phosek added inline comments.Jan 11 2019, 8:36 PM
llvm/utils/gn/secondary/compiler-rt/lib/hwasan/BUILD.gn
31 ↗(On Diff #181406)

CMake build uses object libraries, which is GN source set equivalent, for various targets in runtimes, typically to share objects between static and shared libraries, and those use cases are exactly what source sets are intended for so this is IMO fine.

pcc updated this revision to Diff 181700.Jan 14 2019, 7:06 PM
pcc marked 7 inline comments as done.
  • Address review comments
llvm/utils/gn/build/BUILD.gn
138 ↗(On Diff #181406)

I have a mild preference for crt_ as I was going to name variables and such crt_foo in upcoming patches, and I wanted the prefix to be short and consistent. But if you think crt_ is too confusing, let me know.

llvm/utils/gn/secondary/BUILD.gn
15 ↗(On Diff #181406)

Sure, that'll do for now, although I intend to replace this whole block with a reference to a test target (without the toolchain stuff since it will be refactored inside the test target) in an upcoming patch.

llvm/utils/gn/secondary/compiler-rt/lib/hwasan/BUILD.gn
53 ↗(On Diff #181406)

I've done this for the library targets (and removed empty lines and moved output_* to the top since that seems to be the style too). I couldn't find a consistent style for action so I left as is.

79 ↗(On Diff #181406)

We'll probably need something like that if/when we start creating installable packages. This will do for now because we can just assume that the object files will be present on disk.

llvm/utils/gn/secondary/compiler-rt/lib/ubsan/BUILD.gn
1 ↗(On Diff #181406)

I don't think it's worth copying the target names here. CMake is subject to other constraints (e.g. the target name has to be unique throughout the build) and the name I've chosen makes it a little clearer that this is a source set and therefore behaves as a source set when linked into other targets.

Harbormaster completed remote builds in B26827: Diff 181700.Jan 14 2019, 7:07 PM
pcc updated this revision to Diff 181701.Jan 14 2019, 7:11 PM
  • Also update the other files
Harbormaster completed remote builds in B26828: Diff 181701.Jan 14 2019, 7:11 PM
thakis accepted this revision.Jan 15 2019, 6:06 AM
This revision is now accepted and ready to land.Jan 15 2019, 6:06 AM
Closed by commit rL351246: gn build: Add build files for compiler-rt/lib/{hwasan,interception… (authored by pcc). · Explain WhyJan 15 2019, 1:12 PM
This revision was automatically updated to reflect the committed changes.
eugenis added a comment.Jan 15 2019, 1:49 PM

cmake build seems to have a lot of flags that are not in gn, ex. -fno-builtin and more in SANITIZER_COMMON_CFLAGS.
It's possible that they don't matter for hwasan, but I thought I'd mention it anyway.

pcc added a comment.Jan 15 2019, 2:04 PM

Yes, those missing flags didn't cause any issues for me with hwasan. I'd expect that as support for more sanitizers is added we'd need to make the flags used look more like the cmake build.

Revision Contents

PathSize
llvm/
trunk/
utils/
gn/
build/
9 lines
secondary/
7 lines
compiler-rt/
lib/
hwasan/
107 lines
interception/
13 lines
sanitizer_common/
70 lines
ubsan/
30 lines

Diff 181864

llvm/trunk/utils/gn/build/BUILD.gn

Show First 20 Lines • Show All 129 Lines • ▼ Show 20 Lines
config("clang_code") { config("clang_code") {
include_dirs = [ include_dirs = [
"//clang/include", "//clang/include",
"$root_gen_dir/clang/include", "$root_gen_dir/clang/include",
] ]
} }
config("crt_code") {
include_dirs = [ "//compiler-rt/lib" ]
cflags = [
"-fPIC",
"-funwind-tables",
"-gline-tables-only",
]
}
config("warn_covered_switch_default") { config("warn_covered_switch_default") {
if (is_clang) { if (is_clang) {
cflags = [ "-Wcovered-switch-default" ] cflags = [ "-Wcovered-switch-default" ]
} }
} }

llvm/trunk/utils/gn/secondary/BUILD.gn

import("//clang/lib/ARCMigrate/enable.gni") import("//clang/lib/ARCMigrate/enable.gni")
import("//clang/lib/StaticAnalyzer/Frontend/enable.gni") import("//clang/lib/StaticAnalyzer/Frontend/enable.gni")
import("//llvm/utils/gn/build/toolchain/compiler.gni") import("//llvm/utils/gn/build/toolchain/compiler.gni")
group("default") { group("default") {
deps = [ deps = [
"//clang/test", "//clang/test",
"//lld/test", "//lld/test",
"//llvm/test", "//llvm/test",
] ]
if (android_ndk_path != "") { if (android_ndk_path != "") {
# FIXME: This should be a dependency of a test target instead of being # FIXME: This should be a dependency of a test target instead of being
# depended on from here. # depended on from here.
deps += [ "//llvm/tools/llvm-symbolizer(//llvm/utils/gn/build/toolchain:stage2_android_aarch64)" ] android_aarch64_toolchain =
"//llvm/utils/gn/build/toolchain:stage2_android_aarch64"
deps += [
"//compiler-rt/lib/hwasan:hwasan_shared($android_aarch64_toolchain)",
"//llvm/tools/llvm-symbolizer($android_aarch64_toolchain)",
]
} }
testonly = true testonly = true
} }
# Symlink handling. # Symlink handling.
# On POSIX, symlinks to the target can be created before the target exist, # On POSIX, symlinks to the target can be created before the target exist,
# and the target can depend on the symlink targets, so that building the # and the target can depend on the symlink targets, so that building the
▲ Show 20 Lines • Show All 85 Lines • Show Last 20 Lines

llvm/trunk/utils/gn/secondary/compiler-rt/lib/hwasan/BUILD.gn

import("//llvm/version.gni")
# FIXME: Make this support more platforms.
assert(current_os == "android")
runtime_output_dir = "$root_build_dir/lib/clang/$llvm_version/lib/linux"
runtime_target = "aarch64-android"
action("version_script") {
script = "//compiler-rt/lib/sanitizer_common/scripts/gen_dynamic_list.py"
sources = [
"hwasan.syms.extra",
]
deps = [
":hwasan",
":hwasan_cxx",
]
outputs = [
"$target_gen_dir/hwasan.vers",
]
args = [
"--version-list",
"--extra",
rebase_path(sources[0], root_build_dir),
rebase_path("$runtime_output_dir/libclang_rt.hwasan-$runtime_target.a",
root_build_dir),
rebase_path("$runtime_output_dir/libclang_rt.hwasan_cxx-$runtime_target.a",
root_build_dir),
"-o",
rebase_path(outputs[0], root_build_dir),
]
}
source_set("sources") {
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
defines = [ "HWASAN_WITH_INTERCEPTORS=1" ]
deps = [
"//compiler-rt/lib/interception:sources",
"//compiler-rt/lib/sanitizer_common:sources",
"//compiler-rt/lib/ubsan:sources",
]
sources = [
"hwasan.cc",
"hwasan_allocator.cc",
"hwasan_dynamic_shadow.cc",
"hwasan_interceptors.cc",
"hwasan_linux.cc",
"hwasan_memintrinsics.cc",
"hwasan_poisoning.cc",
"hwasan_report.cc",
"hwasan_thread.cc",
"hwasan_thread_list.cc",
]
}
source_set("cxx_sources") {
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
deps = [
"//compiler-rt/lib/ubsan:cxx_sources",
]
sources = [
"hwasan_new_delete.cc",
]
}
static_library("hwasan") {
output_dir = runtime_output_dir
output_name = "clang_rt.hwasan-$runtime_target"
complete_static_lib = true
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
deps = [
":sources",
]
}
static_library("hwasan_cxx") {
output_dir = runtime_output_dir
output_name = "clang_rt.hwasan_cxx-$runtime_target"
complete_static_lib = true
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
deps = [
":cxx_sources",
]
}
shared_library("hwasan_shared") {
output_dir = runtime_output_dir
output_name = "clang_rt.hwasan-$runtime_target"
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
deps = [
":cxx_sources",
":sources",
":version_script",
]
inputs = [
"$target_gen_dir/hwasan.vers",
]
ldflags = [
"-Wl,--version-script," + rebase_path(inputs[0], root_build_dir),
"-Wl,-z,global",
]
}

llvm/trunk/utils/gn/secondary/compiler-rt/lib/interception/BUILD.gn

source_set("sources") {
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
deps = [
"//compiler-rt/lib/sanitizer_common:sources",
]
sources = [
"interception_linux.cc",
"interception_mac.cc",
"interception_type_test.cc",
"interception_win.cc",
]
}

llvm/trunk/utils/gn/secondary/compiler-rt/lib/sanitizer_common/BUILD.gn

source_set("sources") {
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
sources = [
"sancov_flags.cc",
"sanitizer_allocator.cc",
"sanitizer_allocator_checks.cc",
"sanitizer_allocator_report.cc",
"sanitizer_common.cc",
"sanitizer_common_libcdep.cc",
"sanitizer_coverage_fuchsia.cc",
"sanitizer_coverage_libcdep_new.cc",
"sanitizer_coverage_win_sections.cc",
"sanitizer_deadlock_detector1.cc",
"sanitizer_deadlock_detector2.cc",
"sanitizer_errno.cc",
"sanitizer_file.cc",
"sanitizer_flag_parser.cc",
"sanitizer_flags.cc",
"sanitizer_fuchsia.cc",
"sanitizer_libc.cc",
"sanitizer_libignore.cc",
"sanitizer_linux.cc",
"sanitizer_linux_libcdep.cc",
"sanitizer_linux_s390.cc",
"sanitizer_mac.cc",
"sanitizer_mac_libcdep.cc",
"sanitizer_netbsd.cc",
"sanitizer_openbsd.cc",
"sanitizer_persistent_allocator.cc",
"sanitizer_platform_limits_freebsd.cc",
"sanitizer_platform_limits_linux.cc",
"sanitizer_platform_limits_netbsd.cc",
"sanitizer_platform_limits_openbsd.cc",
"sanitizer_platform_limits_posix.cc",
"sanitizer_platform_limits_solaris.cc",
"sanitizer_posix.cc",
"sanitizer_posix_libcdep.cc",
"sanitizer_printf.cc",
"sanitizer_procmaps_bsd.cc",
"sanitizer_procmaps_common.cc",
"sanitizer_procmaps_linux.cc",
"sanitizer_procmaps_mac.cc",
"sanitizer_procmaps_solaris.cc",
"sanitizer_rtems.cc",
"sanitizer_solaris.cc",
"sanitizer_stackdepot.cc",
"sanitizer_stacktrace.cc",
"sanitizer_stacktrace_libcdep.cc",
"sanitizer_stacktrace_printer.cc",
"sanitizer_stacktrace_sparc.cc",
"sanitizer_stoptheworld_linux_libcdep.cc",
"sanitizer_stoptheworld_mac.cc",
"sanitizer_suppressions.cc",
"sanitizer_symbolizer.cc",
"sanitizer_symbolizer_libbacktrace.cc",
"sanitizer_symbolizer_libcdep.cc",
"sanitizer_symbolizer_mac.cc",
"sanitizer_symbolizer_markup.cc",
"sanitizer_symbolizer_posix_libcdep.cc",
"sanitizer_symbolizer_report.cc",
"sanitizer_symbolizer_win.cc",
"sanitizer_termination.cc",
"sanitizer_thread_registry.cc",
"sanitizer_tls_get_addr.cc",
"sanitizer_unwind_linux_libcdep.cc",
"sanitizer_unwind_win.cc",
"sanitizer_win.cc",
]
}

llvm/trunk/utils/gn/secondary/compiler-rt/lib/ubsan/BUILD.gn

source_set("sources") {
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
defines = [ "UBSAN_CAN_USE_CXXABI" ]
deps = [
"//compiler-rt/lib/interception:sources",
"//compiler-rt/lib/sanitizer_common:sources",
]
sources = [
"ubsan_diag.cc",
"ubsan_flags.cc",
"ubsan_handlers.cc",
"ubsan_init.cc",
"ubsan_monitor.cc",
"ubsan_value.cc",
]
}
source_set("cxx_sources") {
configs -= [ "//llvm/utils/gn/build:llvm_code" ]
configs -= [ "//llvm/utils/gn/build:no_rtti" ]
configs += [ "//llvm/utils/gn/build:crt_code" ]
defines = [ "UBSAN_CAN_USE_CXXABI" ]
sources = [
"ubsan_handlers_cxx.cc",
"ubsan_type_hash.cc",
"ubsan_type_hash_itanium.cc",
"ubsan_type_hash_win.cc",
]
}