[mlir][openacc][NFC] Use oilist in assembly format

[clementval]

Summary

Use the oilist syntax in assembly format where appropriate.
This makes the dialect format more flexible as an order
is not imposed for the clauses.

[PeteSteinfeld]

All builds and tests correctly and looks good.

[clementval]

fix ops.mlir tests

flang/test/Lower/OpenACC/acc-init.f90

 ! This test checks lowering of OpenACC init directive.
 
 ! RUN: bbc -fopenacc -emit-fir %s -o - | FileCheck %s
 
 subroutine acc_init
   logical :: ifCondition = .TRUE.
 
   !$acc init
-!CHECK: acc.init{{$}}
+!CHECK: acc.init{{ *}}{{$}}
 
   !$acc init if(.true.)
 !CHECK: [[IF1:%.*]] = arith.constant true
 !CHECK: acc.init if([[IF1]]){{$}}
 
   !$acc init if(ifCondition)
 !CHECK: [[IFCOND:%.*]] = fir.load %{{.*}} : !fir.ref<!fir.logical<4>>
 !CHECK: [[IF2:%.*]] = fir.convert [[IFCOND]] : (!fir.logical<4>) -> i1
 !CHECK: acc.init if([[IF2]]){{$}}
 
   !$acc init device_num(1)
 !CHECK: [[DEVNUM:%.*]] = arith.constant 1 : i32
 !CHECK: acc.init device_num([[DEVNUM]] : i32){{$}}
 
   !$acc init device_num(1) device_type(1, 2)
 !CHECK: [[DEVNUM:%.*]] = arith.constant 1 : i32
 !CHECK: [[DEVTYPE1:%.*]] = arith.constant 1 : i32
 !CHECK: [[DEVTYPE2:%.*]] = arith.constant 2 : i32
 !CHECK: acc.init device_type([[DEVTYPE1]], [[DEVTYPE2]] : i32, i32) device_num([[DEVNUM]] : i32){{$}}
 
-end subroutine acc_init
+end subroutine acc_init
 

flang/test/Lower/OpenACC/acc-shutdown.f90

 ! This test checks lowering of OpenACC shutdown directive.
 
 ! RUN: bbc -fopenacc -emit-fir %s -o - | FileCheck %s
 
 subroutine acc_shutdown
   logical :: ifCondition = .TRUE.
 
   !$acc shutdown
-!CHECK: acc.shutdown{{$}}
+!CHECK: acc.shutdown{{ *}}{{$}}
 
   !$acc shutdown if(.true.)
 !CHECK: [[IF1:%.*]] = arith.constant true
 !CHECK: acc.shutdown if([[IF1]]){{$}}
 
   !$acc shutdown if(ifCondition)
 !CHECK: [[IFCOND:%.*]] = fir.load %{{.*}} : !fir.ref<!fir.logical<4>>
 !CHECK: [[IF2:%.*]] = fir.convert [[IFCOND]] : (!fir.logical<4>) -> i1
 !CHECK: acc.shutdown if([[IF2]]){{$}}
 
   !$acc shutdown device_num(1)
 !CHECK: [[DEVNUM:%.*]] = arith.constant 1 : i32
 !CHECK: acc.shutdown device_num([[DEVNUM]] : i32){{$}}
 
   !$acc shutdown device_num(1) device_type(1, 2)
 !CHECK: [[DEVNUM:%.*]] = arith.constant 1 : i32
 !CHECK: [[DEVTYPE1:%.*]] = arith.constant 1 : i32
 !CHECK: [[DEVTYPE2:%.*]] = arith.constant 2 : i32
 !CHECK: acc.shutdown device_type([[DEVTYPE1]], [[DEVTYPE2]] : i32, i32) device_num([[DEVNUM]] : i32){{$}}
 
-end subroutine acc_shutdown
+end subroutine acc_shutdown
 

flang/test/Lower/OpenACC/acc-wait.f90

 ! This test checks lowering of OpenACC wait directive.
 
 ! RUN: bbc -fopenacc -emit-fir %s -o - | FileCheck %s
 
 subroutine acc_update
   integer :: async = 1
   logical :: ifCondition = .TRUE.
 
   !$acc wait
-!CHECK: acc.wait{{$}}
+!CHECK: acc.wait{{ *}}{{$}}
 
   !$acc wait if(.true.)
 !CHECK: [[IF1:%.*]] = arith.constant true
 !CHECK: acc.wait if([[IF1]]){{$}}
 
   !$acc wait if(ifCondition)
 !CHECK: [[IFCOND:%.*]] = fir.load %{{.*}} : !fir.ref<!fir.logical<4>>
 !CHECK: [[IF2:%.*]] = fir.convert [[IFCOND]] : (!fir.logical<4>) -> i1
 !CHECK: acc.wait if([[IF2]]){{$}}
 
   !$acc wait(1, 2)
 !CHECK: [[WAIT1:%.*]] = arith.constant 1 : i32
 !CHECK: [[WAIT2:%.*]] = arith.constant 2 : i32
-!CHECK: acc.wait([[WAIT1]], [[WAIT2]] : i32, i32){{$}}
+!CHECK: acc.wait([[WAIT1]], [[WAIT2]] : i32, i32){{ *}}{{$}}
 
   !$acc wait(1) async
 !CHECK: [[WAIT3:%.*]] = arith.constant 1 : i32
 !CHECK: acc.wait([[WAIT3]] : i32) attributes {async}
 
   !$acc wait(1) async(async)
 !CHECK: [[WAIT3:%.*]] = arith.constant 1 : i32
 !CHECK: [[ASYNC1:%.*]] = fir.load %{{.*}} : !fir.ref<i32>

mlir/include/mlir/Dialect/OpenACC/OpenACCOps.td

let extraClassDeclaration = [{
     /// The number of data operands.
     unsigned getNumDataOperands();
 
     /// The i-th data operand passed.
     Value getDataOperand(unsigned i);
   }];
 
   let assemblyFormat = [{
-    ( `if` `(` $ifCond^ `)` )?
-    ( `copy` `(` $copyOperands^ `:` type($copyOperands) `)` )?
-    ( `copyin` `(` $copyinOperands^ `:` type($copyinOperands) `)` )?
-    ( `copyin_readonly` `(` $copyinReadonlyOperands^ `:`
-        type($copyinReadonlyOperands) `)` )?
-    ( `copyout` `(` $copyoutOperands^ `:` type($copyoutOperands) `)` )?
-    ( `copyout_zero` `(` $copyoutZeroOperands^ `:`
-        type($copyoutZeroOperands) `)` )?
-    ( `create` `(` $createOperands^ `:` type($createOperands) `)` )?
-    ( `create_zero` `(` $createZeroOperands^ `:`
-        type($createZeroOperands) `)` )?
-    ( `no_create` `(` $noCreateOperands^ `:` type($noCreateOperands) `)` )?
-    ( `present` `(` $presentOperands^ `:` type($presentOperands) `)` )?
-    ( `deviceptr` `(` $deviceptrOperands^ `:` type($deviceptrOperands) `)` )?
-    ( `attach` `(` $attachOperands^ `:` type($attachOperands) `)` )?
+    oilist(
+        `if` `(` $ifCond `)`
+      | `copy` `(` $copyOperands `:` type($copyOperands) `)`
+      | `copyin` `(` $copyinOperands `:` type($copyinOperands) `)`
+      | `copyin_readonly` `(` $copyinReadonlyOperands `:`
+            type($copyinReadonlyOperands) `)`
+      | `copyout` `(` $copyoutOperands `:` type($copyoutOperands) `)`
+      | `copyout_zero` `(` $copyoutZeroOperands `:`
+            type($copyoutZeroOperands) `)`
+      | `create` `(` $createOperands `:` type($createOperands) `)`
+      | `create_zero` `(` $createZeroOperands `:`
+            type($createZeroOperands) `)`
+      | `no_create` `(` $noCreateOperands `:` type($noCreateOperands) `)`
+      | `present` `(` $presentOperands `:` type($presentOperands) `)`
+      | `deviceptr` `(` $deviceptrOperands `:` type($deviceptrOperands) `)`
+      | `attach` `(` $attachOperands `:` type($attachOperands) `)`
+    )
     $region attr-dict-with-keyword
   }];
   let hasVerifier = 1;
 }
 
 def OpenACC_TerminatorOp : OpenACC_Op<"terminator", [Terminator]> {
   let summary = "Generic terminator for OpenACC regions";
 
let extraClassDeclaration = [{
     /// The number of data operands.
     unsigned getNumDataOperands();
 
     /// The i-th data operand passed.
     Value getDataOperand(unsigned i);
   }];
 
   let assemblyFormat = [{
-    ( `if` `(` $ifCond^ `)` )?
-    ( `async` `(` $asyncOperand^ `:` type($asyncOperand) `)` )?
-    ( `wait_devnum` `(` $waitDevnum^ `:` type($waitDevnum) `)` )?
-    ( `wait` `(` $waitOperands^ `:` type($waitOperands) `)` )?
-    ( `copyin` `(` $copyinOperands^ `:` type($copyinOperands) `)` )?
-    ( `create` `(` $createOperands^ `:` type($createOperands) `)` )?
-    ( `create_zero` `(` $createZeroOperands^ `:`
-        type($createZeroOperands) `)` )?
-    ( `attach` `(` $attachOperands^ `:` type($attachOperands) `)` )?
+    oilist(
+        `if` `(` $ifCond `)`
+      | `async` `(` $asyncOperand `:` type($asyncOperand) `)`
+      | `wait_devnum` `(` $waitDevnum `:` type($waitDevnum) `)`
+      | `wait` `(` $waitOperands `:` type($waitOperands) `)`
+      | `copyin` `(` $copyinOperands `:` type($copyinOperands) `)`
+      | `create` `(` $createOperands `:` type($createOperands) `)`
+      | `create_zero` `(` $createZeroOperands `:`
+          type($createZeroOperands) `)`
+      | `attach` `(` $attachOperands `:` type($attachOperands) `)`
+    )
     attr-dict-with-keyword
   }];
 
   let hasCanonicalizer = 1;
   let hasVerifier = 1;
 }
 
 //===----------------------------------------------------------------------===//
let extraClassDeclaration = [{
     /// The number of data operands.
     unsigned getNumDataOperands();
 
     /// The i-th data operand passed.
     Value getDataOperand(unsigned i);
   }];
 
   let assemblyFormat = [{
-    ( `if` `(` $ifCond^ `)` )?
-    ( `async` `(` $asyncOperand^ `:` type($asyncOperand) `)` )?
-    ( `wait_devnum` `(` $waitDevnum^ `:` type($waitDevnum) `)` )?
-    ( `wait` `(` $waitOperands^ `:` type($waitOperands) `)` )?
-    ( `copyout` `(` $copyoutOperands^ `:` type($copyoutOperands) `)` )?
-    ( `delete` `(` $deleteOperands^ `:` type($deleteOperands) `)` )?
-    ( `detach` `(` $detachOperands^ `:` type($detachOperands) `)` )?
+    oilist(
+        `if` `(` $ifCond `)`
+      | `async` `(` $asyncOperand `:` type($asyncOperand) `)`
+      | `wait_devnum` `(` $waitDevnum `:` type($waitDevnum) `)`
+      | `wait` `(` $waitOperands `:` type($waitOperands) `)`
+      | `copyout` `(` $copyoutOperands `:` type($copyoutOperands) `)`
+      | `delete` `(` $deleteOperands `:` type($deleteOperands) `)`
+      | `detach` `(` $detachOperands `:` type($detachOperands) `)`
+    )
     attr-dict-with-keyword
   }];
 
   let hasCanonicalizer = 1;
   let hasVerifier = 1;
 }
 
 //===----------------------------------------------------------------------===//
let description = [{
     ```
   }];
 
   let arguments = (ins Variadic<AnyInteger>:$deviceTypeOperands,
                        Optional<IntOrIndex>:$deviceNumOperand,
                        Optional<I1>:$ifCond);
 
   let assemblyFormat = [{
-    ( `device_type` `(` $deviceTypeOperands^ `:` type($deviceTypeOperands) `)` )?
-    ( `device_num` `(` $deviceNumOperand^ `:` type($deviceNumOperand) `)` )?
-    ( `if` `(` $ifCond^ `)` )? attr-dict-with-keyword
+    oilist(
+        `device_type` `(` $deviceTypeOperands `:` type($deviceTypeOperands) `)`
+      | `device_num` `(` $deviceNumOperand `:` type($deviceNumOperand) `)`
+      | `if` `(` $ifCond `)`
+    ) attr-dict-with-keyword
   }];
   let hasVerifier = 1;
 }
 
 //===----------------------------------------------------------------------===//
 // 2.14.2. Shutdown
 //===----------------------------------------------------------------------===//
 
let description = [{
     ```
   }];
 
   let arguments = (ins Variadic<AnyInteger>:$deviceTypeOperands,
                        Optional<IntOrIndex>:$deviceNumOperand,
                        Optional<I1>:$ifCond);
 
   let assemblyFormat = [{
-    ( `device_type` `(` $deviceTypeOperands^ `:` type($deviceTypeOperands) `)` )?
-    ( `device_num` `(` $deviceNumOperand^ `:` type($deviceNumOperand) `)` )?
-    ( `if` `(` $ifCond^ `)` )? attr-dict-with-keyword
+    oilist(`device_type` `(` $deviceTypeOperands `:` type($deviceTypeOperands) `)`
+    |`device_num` `(` $deviceNumOperand `:` type($deviceNumOperand) `)`
+    |`if` `(` $ifCond `)`
+    ) attr-dict-with-keyword
   }];
   let hasVerifier = 1;
 }
 
 //===----------------------------------------------------------------------===//
 // 2.14.4. Update Directive
 //===----------------------------------------------------------------------===//
 
let extraClassDeclaration = [{
     /// The number of data operands.
     unsigned getNumDataOperands();
 
     /// The i-th data operand passed.
     Value getDataOperand(unsigned i);
   }];
 
   let assemblyFormat = [{
-    ( `if` `(` $ifCond^ `)` )?
-    ( `async` `(` $asyncOperand^ `:` type($asyncOperand) `)` )?
-    ( `wait_devnum` `(` $waitDevnum^ `:` type($waitDevnum) `)` )?
-    ( `device_type` `(` $deviceTypeOperands^ `:`
-        type($deviceTypeOperands) `)` )?
-    ( `wait` `(` $waitOperands^ `:` type($waitOperands) `)` )?
-    ( `host` `(` $hostOperands^ `:` type($hostOperands) `)` )?
-    ( `device` `(` $deviceOperands^ `:` type($deviceOperands) `)` )?
+    oilist(
+        `if` `(` $ifCond `)`
+      | `async` `(` $asyncOperand `:` type($asyncOperand) `)`
+      | `wait_devnum` `(` $waitDevnum `:` type($waitDevnum) `)`
+      | `device_type` `(` $deviceTypeOperands `:`
+          type($deviceTypeOperands) `)`
+      | `wait` `(` $waitOperands `:` type($waitOperands) `)`
+      | `host` `(` $hostOperands `:` type($hostOperands) `)`
+      | `device` `(` $deviceOperands `:` type($deviceOperands) `)`
+    )
     attr-dict-with-keyword
   }];
 
   let hasCanonicalizer = 1;
   let hasVerifier = 1;
 }
 
 //===----------------------------------------------------------------------===//
def OpenACC_WaitOp : OpenACC_Op<"wait", [AttrSizedOperandSegments]> {
   let arguments = (ins Variadic<IntOrIndex>:$waitOperands,
                        Optional<IntOrIndex>:$asyncOperand,
                        Optional<IntOrIndex>:$waitDevnum,
                        UnitAttr:$async,
                        Optional<I1>:$ifCond);
 
   let assemblyFormat = [{
     ( `(` $waitOperands^ `:` type($waitOperands) `)` )?
-    ( `async` `(` $asyncOperand^ `:` type($asyncOperand) `)` )?
-    ( `wait_devnum` `(` $waitDevnum^ `:` type($waitDevnum) `)` )?
-    ( `if` `(` $ifCond^ `)` )? attr-dict-with-keyword
+    oilist(`async` `(` $asyncOperand `:` type($asyncOperand) `)`
+      |`wait_devnum` `(` $waitDevnum `:` type($waitDevnum) `)`
+      |`if` `(` $ifCond `)`
+    ) attr-dict-with-keyword
   }];
   let hasVerifier = 1;
 }
 
 #endif // OPENACC_OPS

mlir/test/Dialect/OpenACC/ops.mlir

 // CHECK-NEXT: } attributes {selfAttr}
 
 // -----
 
 func.func @testdataop(%a: memref<10xf32>, %b: memref<10xf32>, %c: memref<10x10xf32>) -> () {
   %ifCond = arith.constant true
   acc.data if(%ifCond) present(%a : memref<10xf32>) {
   }
+  acc.data present(%a : memref<10xf32>) if(%ifCond) {
+  }
   acc.data present(%a, %b, %c : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
   }
   acc.data copy(%a, %b, %c : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
   }
   acc.data copyin(%a, %b, %c : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
   }
   acc.data copyin_readonly(%a, %b, %c : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
   }
func.func @testdataop(%a: memref<10xf32>, %b: memref<10xf32>, %c: memref<10x10xf32>) -> () {
   } attributes { defaultAttr = #acc<defaultvalue none> }
   return
 }
 
 // CHECK:      func @testdataop([[ARGA:%.*]]: memref<10xf32>, [[ARGB:%.*]]: memref<10xf32>, [[ARGC:%.*]]: memref<10x10xf32>) {
 // CHECK:      [[IFCOND1:%.*]] = arith.constant true
 // CHECK:      acc.data if([[IFCOND1]]) present([[ARGA]] : memref<10xf32>) {
 // CHECK-NEXT: }
+// CHECK:      acc.data if([[IFCOND1]]) present([[ARGA]] : memref<10xf32>) {
+// CHECK-NEXT: }
 // CHECK:      acc.data present([[ARGA]], [[ARGB]], [[ARGC]] : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
 // CHECK-NEXT: }
 // CHECK:      acc.data copy([[ARGA]], [[ARGB]], [[ARGC]] : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
 // CHECK-NEXT: }
 // CHECK:      acc.data copyin([[ARGA]], [[ARGB]], [[ARGC]] : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
 // CHECK-NEXT: }
 // CHECK:      acc.data copyin_readonly([[ARGA]], [[ARGB]], [[ARGC]] : memref<10xf32>, memref<10xf32>, memref<10x10xf32>) {
 // CHECK-NEXT: }

 
 func.func @testupdateop(%a: memref<10xf32>, %b: memref<10xf32>, %c: memref<10x10xf32>) -> () {
   %i64Value = arith.constant 1 : i64
   %i32Value = arith.constant 1 : i32
   %idxValue = arith.constant 1 : index
   %ifCond = arith.constant true
   acc.update async(%i64Value: i64) host(%a: memref<10xf32>)
   acc.update async(%i32Value: i32) host(%a: memref<10xf32>)
+  acc.update async(%i32Value: i32) host(%a: memref<10xf32>)
   acc.update async(%idxValue: index) host(%a: memref<10xf32>)
   acc.update wait_devnum(%i64Value: i64) wait(%i32Value, %idxValue : i32, index) host(%a: memref<10xf32>)
   acc.update if(%ifCond) host(%a: memref<10xf32>)
   acc.update device_type(%i32Value : i32) host(%a: memref<10xf32>)
   acc.update host(%a: memref<10xf32>) device(%b, %c : memref<10xf32>, memref<10x10xf32>)
   acc.update host(%a: memref<10xf32>) device(%b, %c : memref<10xf32>, memref<10x10xf32>) attributes {async}
   acc.update host(%a: memref<10xf32>) device(%b, %c : memref<10xf32>, memref<10x10xf32>) attributes {wait}
   acc.update host(%a: memref<10xf32>) device(%b, %c : memref<10xf32>, memref<10x10xf32>) attributes {ifPresent}
   return
 }
 
 // CHECK: func @testupdateop([[ARGA:%.*]]: memref<10xf32>, [[ARGB:%.*]]: memref<10xf32>, [[ARGC:%.*]]: memref<10x10xf32>) {
 // CHECK:   [[I64VALUE:%.*]] = arith.constant 1 : i64
 // CHECK:   [[I32VALUE:%.*]] = arith.constant 1 : i32
 // CHECK:   [[IDXVALUE:%.*]] = arith.constant 1 : index
 // CHECK:   [[IFCOND:%.*]] = arith.constant true
 // CHECK:   acc.update async([[I64VALUE]] : i64) host([[ARGA]] : memref<10xf32>)
 // CHECK:   acc.update async([[I32VALUE]] : i32) host([[ARGA]] : memref<10xf32>)
+// CHECK:   acc.update async([[I32VALUE]] : i32) host([[ARGA]] : memref<10xf32>)
 // CHECK:   acc.update async([[IDXVALUE]] : index) host([[ARGA]] : memref<10xf32>)
 // CHECK:   acc.update wait_devnum([[I64VALUE]] : i64) wait([[I32VALUE]], [[IDXVALUE]] : i32, index) host([[ARGA]] : memref<10xf32>)
 // CHECK:   acc.update if([[IFCOND]]) host([[ARGA]] : memref<10xf32>)
 // CHECK:   acc.update device_type([[I32VALUE]] : i32) host([[ARGA]] : memref<10xf32>)
 // CHECK:   acc.update host([[ARGA]] : memref<10xf32>) device([[ARGB]], [[ARGC]] : memref<10xf32>, memref<10x10xf32>)
 // CHECK:   acc.update host([[ARGA]] : memref<10xf32>) device([[ARGB]], [[ARGC]] : memref<10xf32>, memref<10x10xf32>) attributes {async}
 // CHECK:   acc.update host([[ARGA]] : memref<10xf32>) device([[ARGB]], [[ARGC]] : memref<10xf32>, memref<10x10xf32>) attributes {wait}
 // CHECK:   acc.update host([[ARGA]] : memref<10xf32>) device([[ARGB]], [[ARGC]] : memref<10xf32>, memref<10x10xf32>) attributes {ifPresent}

 acc.wait(%i32Value, %idxValue : i32, index)
 acc.wait async(%i64Value: i64)
 acc.wait async(%i32Value: i32)
 acc.wait async(%idxValue: index)
 acc.wait(%i32Value: i32) async(%idxValue: index)
 acc.wait(%i64Value: i64) wait_devnum(%i32Value: i32)
 acc.wait attributes {async}
 acc.wait(%i64Value: i64) async(%idxValue: index) wait_devnum(%i32Value: i32)
+acc.wait(%i64Value: i64) wait_devnum(%i32Value: i32) async(%idxValue: index)
 acc.wait if(%ifCond)
 
 // CHECK: [[I64VALUE:%.*]] = arith.constant 1 : i64
 // CHECK: [[I32VALUE:%.*]] = arith.constant 1 : i32
 // CHECK: [[IDXVALUE:%.*]] = arith.constant 1 : index
 // CHECK: [[IFCOND:%.*]] = arith.constant true
 // CHECK: acc.wait
 // CHECK: acc.wait([[I64VALUE]] : i64)
 // CHECK: acc.wait([[I32VALUE]] : i32)
 // CHECK: acc.wait([[IDXVALUE]] : index)
 // CHECK: acc.wait([[I32VALUE]], [[IDXVALUE]] : i32, index)
 // CHECK: acc.wait async([[I64VALUE]] : i64)
 // CHECK: acc.wait async([[I32VALUE]] : i32)
 // CHECK: acc.wait async([[IDXVALUE]] : index)
 // CHECK: acc.wait([[I32VALUE]] : i32) async([[IDXVALUE]] : index)
 // CHECK: acc.wait([[I64VALUE]] : i64) wait_devnum([[I32VALUE]] : i32)
 // CHECK: acc.wait attributes {async}
 // CHECK: acc.wait([[I64VALUE]] : i64) async([[IDXVALUE]] : index) wait_devnum([[I32VALUE]] : i32)
+// CHECK: acc.wait([[I64VALUE]] : i64) async([[IDXVALUE]] : index) wait_devnum([[I32VALUE]] : i32)
 // CHECK: acc.wait if([[IFCOND]])
 
 // -----
 
 %i64Value = arith.constant 1 : i64
 %i32Value = arith.constant 1 : i32
 %i32Value2 = arith.constant 2 : i32
 %idxValue = arith.constant 1 : index
 %ifCond = arith.constant true
 acc.init
 acc.init device_type(%i32Value : i32)
 acc.init device_type(%i32Value, %i32Value2 : i32, i32)
 acc.init device_num(%i64Value : i64)
 acc.init device_num(%i32Value : i32)
 acc.init device_num(%idxValue : index)
 acc.init if(%ifCond)
+acc.init if(%ifCond) device_num(%idxValue : index)
+acc.init device_num(%idxValue : index) if(%ifCond)
 
 // CHECK: [[I64VALUE:%.*]] = arith.constant 1 : i64
 // CHECK: [[I32VALUE:%.*]] = arith.constant 1 : i32
 // CHECK: [[I32VALUE2:%.*]] = arith.constant 2 : i32
 // CHECK: [[IDXVALUE:%.*]] = arith.constant 1 : index
 // CHECK: [[IFCOND:%.*]] = arith.constant true
 // CHECK: acc.init
 // CHECK: acc.init device_type([[I32VALUE]] : i32)
 // CHECK: acc.init device_type([[I32VALUE]], [[I32VALUE2]] : i32, i32)
 // CHECK: acc.init device_num([[I64VALUE]] : i64)
 // CHECK: acc.init device_num([[I32VALUE]] : i32)
 // CHECK: acc.init device_num([[IDXVALUE]] : index)
 // CHECK: acc.init if([[IFCOND]])
+// CHECK: acc.init device_num([[IDXVALUE]] : index) if([[IFCOND]])
+// CHECK: acc.init device_num([[IDXVALUE]] : index) if([[IFCOND]])
 
 // -----
 
 %i64Value = arith.constant 1 : i64
 %i32Value = arith.constant 1 : i32
 %i32Value2 = arith.constant 2 : i32
 %idxValue = arith.constant 1 : index
 %ifCond = arith.constant true
 acc.shutdown
 acc.shutdown device_type(%i32Value : i32)
 acc.shutdown device_type(%i32Value, %i32Value2 : i32, i32)
 acc.shutdown device_num(%i64Value : i64)
 acc.shutdown device_num(%i32Value : i32)
 acc.shutdown device_num(%idxValue : index)
 acc.shutdown if(%ifCond)
+acc.shutdown if(%ifCond) device_num(%idxValue : index)
+acc.shutdown device_num(%idxValue : index) if(%ifCond)
 
 // CHECK: [[I64VALUE:%.*]] = arith.constant 1 : i64
 // CHECK: [[I32VALUE:%.*]] = arith.constant 1 : i32
 // CHECK: [[I32VALUE2:%.*]] = arith.constant 2 : i32
 // CHECK: [[IDXVALUE:%.*]] = arith.constant 1 : index
 // CHECK: [[IFCOND:%.*]] = arith.constant true
 // CHECK: acc.shutdown
 // CHECK: acc.shutdown device_type([[I32VALUE]] : i32)
 // CHECK: acc.shutdown device_type([[I32VALUE]], [[I32VALUE2]] : i32, i32)
 // CHECK: acc.shutdown device_num([[I64VALUE]] : i64)
 // CHECK: acc.shutdown device_num([[I32VALUE]] : i32)
 // CHECK: acc.shutdown device_num([[IDXVALUE]] : index)
 // CHECK: acc.shutdown if([[IFCOND]])
+// CHECK: acc.shutdown device_num([[IDXVALUE]] : index) if([[IFCOND]])
+// CHECK: acc.shutdown device_num([[IDXVALUE]] : index) if([[IFCOND]])
 
 // -----
 
 func.func @testexitdataop(%a: memref<10xf32>, %b: memref<10xf32>, %c: memref<10x10xf32>) -> () {
   %ifCond = arith.constant true
   %i64Value = arith.constant 1 : i64
   %i32Value = arith.constant 1 : i32
   %idxValue = arith.constant 1 : index
 
   acc.exit_data copyout(%a : memref<10xf32>)
   acc.exit_data delete(%a : memref<10xf32>)
   acc.exit_data delete(%a : memref<10xf32>) attributes {async,finalize}
   acc.exit_data detach(%a : memref<10xf32>)
   acc.exit_data copyout(%a : memref<10xf32>) attributes {async}
   acc.exit_data delete(%a : memref<10xf32>) attributes {wait}
   acc.exit_data async(%i64Value : i64) copyout(%a : memref<10xf32>)
+  acc.exit_data copyout(%a : memref<10xf32>) async(%i64Value : i64)
   acc.exit_data if(%ifCond) copyout(%a : memref<10xf32>)
   acc.exit_data wait_devnum(%i64Value: i64) wait(%i32Value, %idxValue : i32, index) copyout(%a : memref<10xf32>)
 
   return
 }
 
 // CHECK: func @testexitdataop([[ARGA:%.*]]: memref<10xf32>, [[ARGB:%.*]]: memref<10xf32>, [[ARGC:%.*]]: memref<10x10xf32>) {
 // CHECK: [[IFCOND1:%.*]] = arith.constant true
 // CHECK: [[I64VALUE:%.*]] = arith.constant 1 : i64
 // CHECK: [[I32VALUE:%.*]] = arith.constant 1 : i32
 // CHECK: [[IDXVALUE:%.*]] = arith.constant 1 : index
 // CHECK: acc.exit_data copyout([[ARGA]] : memref<10xf32>)
 // CHECK: acc.exit_data delete([[ARGA]] : memref<10xf32>)
 // CHECK: acc.exit_data delete([[ARGA]] : memref<10xf32>) attributes {async, finalize}
 // CHECK: acc.exit_data detach([[ARGA]] : memref<10xf32>)
 // CHECK: acc.exit_data copyout([[ARGA]] : memref<10xf32>) attributes {async}
 // CHECK: acc.exit_data delete([[ARGA]] : memref<10xf32>) attributes {wait}
 // CHECK: acc.exit_data async([[I64VALUE]] : i64) copyout([[ARGA]] : memref<10xf32>)
+// CHECK: acc.exit_data async([[I64VALUE]] : i64) copyout([[ARGA]] : memref<10xf32>)
 // CHECK: acc.exit_data if([[IFCOND]]) copyout([[ARGA]] : memref<10xf32>)
 // CHECK: acc.exit_data wait_devnum([[I64VALUE]] : i64) wait([[I32VALUE]], [[IDXVALUE]] : i32, index) copyout([[ARGA]] : memref<10xf32>)
 // -----
 
 
 func.func @testenterdataop(%a: memref<10xf32>, %b: memref<10xf32>, %c: memref<10x10xf32>) -> () {
   %ifCond = arith.constant true
   %i64Value = arith.constant 1 : i64
   %i32Value = arith.constant 1 : i32
   %idxValue = arith.constant 1 : index
 
   acc.enter_data copyin(%a : memref<10xf32>)
   acc.enter_data create(%a : memref<10xf32>) create_zero(%b, %c : memref<10xf32>, memref<10x10xf32>)
   acc.enter_data attach(%a : memref<10xf32>)
   acc.enter_data copyin(%a : memref<10xf32>) attributes {async}
   acc.enter_data create(%a : memref<10xf32>) attributes {wait}
   acc.enter_data async(%i64Value : i64) copyin(%a : memref<10xf32>)
+  acc.enter_data copyin(%a : memref<10xf32>) async(%i64Value : i64)
   acc.enter_data if(%ifCond) copyin(%a : memref<10xf32>)
   acc.enter_data wait_devnum(%i64Value: i64) wait(%i32Value, %idxValue : i32, index) copyin(%a : memref<10xf32>)
 
   return
 }
 
 // CHECK: func @testenterdataop([[ARGA:%.*]]: memref<10xf32>, [[ARGB:%.*]]: memref<10xf32>, [[ARGC:%.*]]: memref<10x10xf32>) {
 // CHECK: [[IFCOND1:%.*]] = arith.constant true
 // CHECK: [[I64VALUE:%.*]] = arith.constant 1 : i64
 // CHECK: [[I32VALUE:%.*]] = arith.constant 1 : i32
 // CHECK: [[IDXVALUE:%.*]] = arith.constant 1 : index
 // CHECK: acc.enter_data copyin([[ARGA]] : memref<10xf32>)
 // CHECK: acc.enter_data create([[ARGA]] : memref<10xf32>) create_zero([[ARGB]], [[ARGC]] : memref<10xf32>, memref<10x10xf32>)
 // CHECK: acc.enter_data attach([[ARGA]] : memref<10xf32>)
 // CHECK: acc.enter_data copyin([[ARGA]] : memref<10xf32>) attributes {async}
 // CHECK: acc.enter_data create([[ARGA]] : memref<10xf32>) attributes {wait}
 // CHECK: acc.enter_data async([[I64VALUE]] : i64) copyin([[ARGA]] : memref<10xf32>)
+// CHECK: acc.enter_data async([[I64VALUE]] : i64) copyin([[ARGA]] : memref<10xf32>)
 // CHECK: acc.enter_data if([[IFCOND]]) copyin([[ARGA]] : memref<10xf32>)
 // CHECK: acc.enter_data wait_devnum([[I64VALUE]] : i64) wait([[I32VALUE]], [[IDXVALUE]] : i32, index) copyin([[ARGA]] : memref<10xf32>)