Add semantics unit test for SYNC IMAGES statement

[rouson]

Summary

Test a range of acceptable forms of SYNC IMAGES statements,
including combinations with and without the stat-variable
and errmsg-variable present. Also test that several invalid
forms of SYNC IMAGES call generate the correct error messages.

[ktras]

The variables superfluous_stat, superfluous_errmsg, co_indexed_integer, and co_indexed_character have not been declared and so you are testing different errors than I believe you intended to, but otherwise it looks good!

[rouson]

Added variable declarations and expanded the variety of standard-conforming calls.

[ktras]

LGTM. The only note is that this test, like the sync all test in differential D114181, should pass if you take away the XFAIL directive, but doesn't because flang doesn't currently enforce the following constraints stated in the standard: C1171 - that no specifier shall appear more than once in a given sync-stat-list, and C1172 - that a stat-variable or errmsg-variable in a sync-stat shall not be a coindexed object, C1173 - that an image-set that is an int-expr shall be scalar or of rank one, and C1174 that the value of image-set shall not depend on the value of stat-variable or errmsg-variable. It seems appropriate to open up an issue on the github repository pointing this out after this commit is pushed, and referencing this test in the issue.

[ktras]

See above comment.

flang/test/Semantics/synchronization02.f90

+! RUN: %python %S/test_errors.py %s %flang_fc1
+! XFAIL: *
+! Check for semantic errors in sync images statements
+
+program test_sync_images
+  implicit none
+
+  integer, parameter :: invalid_rank(*,*) = reshape([1], [1,1])
+  integer sync_status, non_scalar(2), superfluous_stat, coindexed_integer[*], me
+  character(len=128) error_message, superfluous_errmsg, coindexed_character[*]
+  logical invalid_type
+  
+  !___ standard-conforming statement ___
+
+  sync images(*, stat=sync_status, errmsg=error_message)
+  sync images(*, stat=sync_status                      )
+  sync images(*,                   errmsg=error_message)
+  sync images(*                                        )
+
+  sync images(me,   stat=sync_status, errmsg=error_message)
+  sync images(me+1, stat=sync_status, errmsg=error_message)
+  sync images(1,    stat=sync_status, errmsg=error_message)
+  sync images(1,    stat=sync_status                      )
+  sync images(1,                      errmsg=error_message)
+  sync images(1                                           )
+
+  sync images([1],  stat=sync_status, errmsg=error_message)
+  sync images([1],  stat=sync_status                      )
+  sync images([1],                    errmsg=error_message)
+  sync images([1]                                         )
+
+  !___ non-standard-conforming statement ___
+
+  !______ invalid image sets ______
+
+  ! Image set shall not depend on the value of stat-variable
+  !ERROR: TBD
+  sync images(sync_status, stat=sync_status)
+
+  ! Image set shall not depend on the value of errmsg-variable
+  !ERROR: TBD
+  sync images(len(error_message), errmsg=error_message)
+
+  ! Image set shall be a scalar or rank-1 array
+  !ERROR: TBD
+  sync images(invalid_rank)
+ 
+  !______ invalid sync-stat-lists: invalid stat= ____________
+
+  ! Invalid sync-stat-list keyword
+  !ERROR: expected ')'
+  sync images(1, status=sync_status)
+
+  !ERROR: TBD
+  sync images([1], stat=invalid_type)
+
+  ! Stat-variable must an integer scalar
+  !ERROR: TBD
+  sync images(*, stat=non_scalar)
+ 
+  ! Invalid sync-stat-list: missing stat-variable
+  !ERROR: expected ')'
+  sync images(1, stat)
+
+  ! Invalid sync-stat-list: missing 'stat='
+  !ERROR: expected ')'
+  sync images([1], sync_status)
+
+  !______ invalid sync-stat-lists: invalid errmsg= ____________
+
+  ! Invalid errmsg-variable keyword
+  !ERROR: expected ')'
+  sync images(*, errormsg=error_message)
+
+  !ERROR: TBD
+  sync images(1, errmsg=invalid_type)
+
+  ! Invalid sync-stat-list: missing 'errmsg='
+  !ERROR: expected ')'
+  sync images([1], error_message)
+
+  ! Invalid sync-stat-list: missing errmsg-variable
+  !ERROR: expected ')'
+  sync images(*, errmsg)
+
+  !______ invalid sync-stat-lists: redundant sync-stat-list ____________
+
+  ! No specifier shall appear more than once in a given sync-stat-list
+  !ERROR: to be determined
+  sync images(1, stat=sync_status, stat=superfluous_stat)
+
+  ! No specifier shall appear more than once in a given sync-stat-list
+  !ERROR: to be determined
+  sync images([1], errmsg=error_message, errmsg=superfluous_errmsg)
+ 
+  !______ invalid sync-stat-lists: coindexed stat-variable ____________
+
+  ! Check constraint C1173 from the Fortran 2018 standard
+  !ERROR: to be determined
+  sync images(*, stat=coindexed_integer[1])
+ 
+  ! Check constraint C1173 from the Fortran 2018 standard
+  !ERROR: to be determined
+  sync images(1, errmsg=coindexed_character[1])
+
+end program test_sync_images