[FPEnv][InstSimplify] Fold fsub X, +0 ==> X

[kpn]

Summary

Currently the fsub optimizations in InstSimplify don't know how to fold X - +0.0 to X when using the constrained intrinsics. This adds the support.

This review is split out from D107285.

[sepavloff]

llvm/lib/Analysis/InstructionSimplify.cpp

5139

What if X==+0 and rounding is downward? In this case fsub X, +0 should produce -0.0 (https://en.wikipedia.org/wiki/Signed_zero#Arithmetic).

[nlopes]

FWIW, I added support for constrained fadd/fsub/fmul/fdiv to Alive2 yesterday.

[sepavloff]

In D118928#3300459, @nlopes wrote:

FWIW, I added support for constrained fadd/fsub/fmul/fdiv to Alive2 yesterday.

Sounds great!

I tried to play with this case, but got failure: https://alive2.llvm.org/ce/z/BV68q5 .

[nlopes]

In D118928#3301366, @sepavloff wrote:

In D118928#3300459, @nlopes wrote:

FWIW, I added support for constrained fadd/fsub/fmul/fdiv to Alive2 yesterday.

Sounds great!

I tried to play with this case, but got failure: https://alive2.llvm.org/ce/z/BV68q5 .

let's ping @regehr to see if he has time to update the online version.

[kpn]

Update for review comments: don't fold away a case that can and should result in -0.0. Add tests for this very case.

[sepavloff]

LGTM.

llvm/lib/Analysis/InstructionSimplify.cpp

SimplifyFSubInst(Value *Op0, Value *Op1, FastMathFlags FMF,
                  RoundingMode Rounding = RoundingMode::NearestTiesToEven) {
   if (isDefaultFPEnvironment(ExBehavior, Rounding))
     if (Constant *C = foldOrCommuteConstant(Instruction::FSub, Op0, Op1, Q))
       return C;
 
   if (Constant *C = simplifyFPOp({Op0, Op1}, FMF, Q, ExBehavior, Rounding))
     return C;
 
-  if (!isDefaultFPEnvironment(ExBehavior, Rounding))
-    return nullptr;
-
   // fsub X, +0 ==> X
+  if (canIgnoreSNaN(ExBehavior, FMF) &&
+      (!canRoundingModeBe(Rounding, RoundingMode::TowardNegative) ||
+       FMF.noSignedZeros()))
     if (match(Op1, m_PosZeroFP()))
       return Op0;
 
+  if (!isDefaultFPEnvironment(ExBehavior, Rounding))
+    return nullptr;
+
   // fsub X, -0 ==> X, when we know X is not -0
   if (match(Op1, m_NegZeroFP()) &&
       (FMF.noSignedZeros() || CannotBeNegativeZero(Op0, Q.TLI)))
     return Op0;
 
   // fsub -0.0, (fsub -0.0, X) ==> X
   // fsub -0.0, (fneg X) ==> X
   Value *X;

llvm/test/Transforms/InstSimplify/strictfp-fsub.ll

 ; CHECK-LABEL: @fsub_x_p0_ebmaytrap(
 ; CHECK-NEXT:    [[RET:%.*]] = call float @llvm.experimental.constrained.fsub.f32(float [[A:%.*]], float 0.000000e+00, metadata !"round.tonearest", metadata !"fpexcept.maytrap") #[[ATTR0:[0-9]+]]
 ; CHECK-NEXT:    ret float [[RET]]
 ;
   %ret = call float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.tonearest", metadata !"fpexcept.maytrap") #0
   ret float %ret
 }
 
-; TODO: This will fold if we allow non-default floating point environments.
 define float @fsub_nnan_x_p0_ebmaytrap(float %a) #0 {
 ; CHECK-LABEL: @fsub_nnan_x_p0_ebmaytrap(
-; CHECK-NEXT:    [[RET:%.*]] = call nnan float @llvm.experimental.constrained.fsub.f32(float [[A:%.*]], float 0.000000e+00, metadata !"round.tonearest", metadata !"fpexcept.maytrap") #[[ATTR0]]
-; CHECK-NEXT:    ret float [[RET]]
+; CHECK-NEXT:    ret float [[A:%.*]]
 ;
   %ret = call nnan float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.tonearest", metadata !"fpexcept.maytrap") #0
   ret float %ret
 }
 
 ; Missing nnan: must not fire.
 define float @fsub_x_p0_ebstrict(float %a) #0 {
 ; CHECK-LABEL: @fsub_x_p0_ebstrict(
 ; CHECK-NEXT:    [[RET:%.*]] = call float @llvm.experimental.constrained.fsub.f32(float [[A:%.*]], float 0.000000e+00, metadata !"round.tonearest", metadata !"fpexcept.strict") #[[ATTR0]]
 ; CHECK-NEXT:    ret float [[RET]]
 ;
   %ret = call float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.tonearest", metadata !"fpexcept.strict") #0
   ret float %ret
 }
 
-; TODO: This will fold if we allow non-default floating point environments.
 ; TODO: The instruction is expected to remain, but the result isn't used.
 define float @fsub_nnan_x_p0_ebstrict(float %a) #0 {
 ; CHECK-LABEL: @fsub_nnan_x_p0_ebstrict(
 ; CHECK-NEXT:    [[RET:%.*]] = call nnan float @llvm.experimental.constrained.fsub.f32(float [[A:%.*]], float 0.000000e+00, metadata !"round.tonearest", metadata !"fpexcept.strict") #[[ATTR0]]
-; CHECK-NEXT:    ret float [[RET]]
+; CHECK-NEXT:    ret float [[A]]
 ;
   %ret = call nnan float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.tonearest", metadata !"fpexcept.strict") #0
   ret float %ret
 }
 
 ; Test with a fast math flag set but that flag is not "nnan".
 define float @fsub_ninf_x_p0_ebstrict(float %a) #0 {
 ; CHECK-LABEL: @fsub_ninf_x_p0_ebstrict(
 ; CHECK-NEXT:    [[RET:%.*]] = call ninf float @llvm.experimental.constrained.fsub.f32(float [[A:%.*]], float 0.000000e+00, metadata !"round.tonearest", metadata !"fpexcept.strict") #[[ATTR0]]
 ; CHECK-NEXT:    ret float [[RET]]
 ;
   %ret = call ninf float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.tonearest", metadata !"fpexcept.strict") #0
   ret float %ret
 }
 
+; Round to -inf and if x is zero then the result is -0.0: must not fire
+define float @fsub_x_p0_neginf(float %a) #0 {
+; CHECK-LABEL: @fsub_x_p0_neginf(
+; CHECK-NEXT:    [[RET:%.*]] = call float @llvm.experimental.constrained.fsub.f32(float [[A:%.*]], float 0.000000e+00, metadata !"round.downward", metadata !"fpexcept.ignore") #[[ATTR0]]
+; CHECK-NEXT:    ret float [[RET]]
+;
+  %ret = call float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.downward", metadata !"fpexcept.ignore") #0
+  ret float %ret
+}
+
+; Dynamic rounding means the rounding mode might be to -inf:
+; Round to -inf and if x is zero then the result is -0.0: must not fire
+define float @fsub_x_p0_dynamic(float %a) #0 {
+; CHECK-LABEL: @fsub_x_p0_dynamic(
+; CHECK-NEXT:    [[RET:%.*]] = call float @llvm.experimental.constrained.fsub.f32(float [[A:%.*]], float 0.000000e+00, metadata !"round.dynamic", metadata !"fpexcept.ignore") #[[ATTR0]]
+; CHECK-NEXT:    ret float [[RET]]
+;
+  %ret = call float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.dynamic", metadata !"fpexcept.ignore") #0
+  ret float %ret
+}
+
+; With nsz we don't have to worry about -0.0 so the transform is valid.
+define float @fsub_nsz_x_p0_neginf(float %a) #0 {
+; CHECK-LABEL: @fsub_nsz_x_p0_neginf(
+; CHECK-NEXT:    ret float [[A:%.*]]
+;
+  %ret = call nsz float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.downward", metadata !"fpexcept.ignore") #0
+  ret float %ret
+}
+
+; With nsz we don't have to worry about -0.0 so the transform is valid.
+define float @fsub_nsz_x_p0_dynamic(float %a) #0 {
+; CHECK-LABEL: @fsub_nsz_x_p0_dynamic(
+; CHECK-NEXT:    ret float [[A:%.*]]
+;
+  %ret = call nsz float @llvm.experimental.constrained.fsub.f32(float %a, float 0.0, metadata !"round.dynamic", metadata !"fpexcept.ignore") #0
+  ret float %ret
+}
+
 ;
 ; fsub X, -0 ==> X, when we know X is not -0
 ; (fast math flag: nsz)
 ;
 
 define float @fold_fsub_nsz_x_n0_defaultenv(float %a) #0 {
 ; CHECK-LABEL: @fold_fsub_nsz_x_n0_defaultenv(
 ; CHECK-NEXT:    ret float [[A:%.*]]