[gn build] Fix Android compiler-rt targets

[aeubanks]

Summary

If a sysroot was specified, it would take precedence over the Android
NDK sysroot since it would appear after in the command line.

Also only build runtimes for enabled target arches. Many places have
copied this around so create and use supported_android_toolchains.

[aeubanks]

or maybe the general sysroot flag can be part of the default llvm_code config instead? all the compiler-rt targets opt out of that config

[pcc]

llvm/utils/gn/build/BUILD.gn

272–273

Maybe this should be

} else if (current_os != "ios" && current_os != "mac" && current_os != "android") {

instead? (Random thought: maybe we should change how sysroot works to better support cross compilation -- maybe a different variable for each target OS? -- but not as part of this change, I imagine.)

[pcc]

I don't think we can use llvm_code for this because we do cross-compile other parts of LLVM for Android (llvm-symbolizer, lldb-server).

[aeubanks]

use pcc's suggestion

[pcc]

llvm/utils/gn/secondary/compiler-rt/BUILD.gn

13–14

I think this will need to be refactored a bit because the list of supported Android toolchains has been copied into a few places (grep for stage2_android_aarch64). Maybe create a supported_android_toolchains variable and use it in those places?

[aeubanks]

create supported_android_toolchains

[aeubanks]

fix hwasan (only AArch64 is supported)

[pcc]

LGTM

llvm/utils/gn/build/BUILD.gn

if (is_clang) {
     if (use_relative_paths_in_debug_info) {
       cflags += [ "-fdebug-compilation-dir=." ]
     }
   }
   if (sysroot != "") {
     if (current_os == "win") {
       assert(is_clang, "sysroot only works with clang-cl as host compiler")
       cflags += [ "/winsysroot" + rebase_path(sysroot, root_build_dir) ]
-    } else if (current_os != "ios" && current_os != "mac") {
+    } else if (current_os != "ios" && current_os != "mac" &&
+               current_os != "android") {
       cflags += [ "--sysroot=" + rebase_path(sysroot, root_build_dir) ]
     }
   }
   if ((current_os == "ios" || current_os == "mac") &&
       (clang_base_path != "" || sysroot != "")) {
     if (current_os == "ios" && current_cpu == "arm64") {
       sdk_path = ios_sdk_path
     } else if (current_os == "ios" && current_cpu == "x64") {

llvm/utils/gn/secondary/compiler-rt/BUILD.gn

 import("//llvm/lib/Target/targets.gni")
 import("//llvm/utils/gn/build/mac_sdk.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 # In the GN build, compiler-rt is always built by just-built clang and lld.
 # FIXME: For macOS and iOS builds, depend on lib in all needed target arch
 # toolchains and then lipo them together for the final output.
 if (current_os == "win") {
   supported_toolchains = [ "//llvm/utils/gn/build/toolchain:stage2_win" ]
   supported_toolchains += [ "//llvm/utils/gn/build/toolchain:stage2_win_x86" ]
 } else {
   supported_toolchains = [ "//llvm/utils/gn/build/toolchain:stage2_unix" ]
 }
-if (android_ndk_path != "") {
-  supported_toolchains += [
-    "//llvm/utils/gn/build/toolchain:stage2_android_aarch64",
-    "//llvm/utils/gn/build/toolchain:stage2_android_arm",
-  ]
-}
+supported_toolchains += supported_android_toolchains
 group("compiler-rt") {
   deps = [ "//compiler-rt/include($host_toolchain)" ]
   foreach(toolchain, supported_toolchains) {
     deps += [ "//compiler-rt/lib($toolchain)" ]
   }
 
   # FIXME: Do this only if a gn arg compiler_rt_enable_ios is set?
   # That would match the cmake build.

llvm/utils/gn/secondary/compiler-rt/lib/scudo/BUILD.gn

+import("//llvm/lib/Target/targets.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 supported_toolchains = []
 if (target_os == "linux" || target_os == "fuchsia") {
   supported_toolchains += [ "//llvm/utils/gn/build/toolchain:stage2_unix" ]
 }
-if (android_ndk_path != "") {
-  supported_toolchains += [
-    "//llvm/utils/gn/build/toolchain:stage2_android_aarch64",
-    "//llvm/utils/gn/build/toolchain:stage2_android_arm",
-  ]
-}
+supported_toolchains += supported_android_toolchains
 
 group("scudo") {
   deps = []
   foreach(toolchain, supported_toolchains) {
     deps += [
       "standalone/benchmarks:ScudoBenchmarks($toolchain)",
       "standalone/tests:ScudoCUnitTest($toolchain)",
       "standalone/tests:ScudoCxxUnitTest($toolchain)",

llvm/utils/gn/secondary/compiler-rt/test/hwasan/BUILD.gn

 import("//compiler-rt/target.gni")
 import("//compiler-rt/test/test.gni")
+import("//llvm/lib/Target/targets.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 import("//llvm/utils/gn/build/write_cmake_config.gni")
 import("//llvm/version.gni")
 
 write_cmake_config("lit_site_cfg") {
   input = "lit.site.cfg.py.in"
   output = "$target_gen_dir/lit.site.cfg.py"
 
group("hwasan_toolchain") {
     }
   }
 }
 
 supported_toolchains = []
 if (host_os == "linux" && host_cpu == "x64") {
   supported_toolchains += [ "//llvm/utils/gn/build/toolchain:stage2_unix" ]
 }
-if (android_ndk_path != "") {
+if (llvm_build_AArch64 && android_ndk_path != "") {
   supported_toolchains +=
       [ "//llvm/utils/gn/build/toolchain:stage2_android_aarch64" ]
 }
 
 group("hwasan") {
   deps = []
   foreach(toolchain, supported_toolchains) {
     deps += [ ":hwasan_toolchain($toolchain)" ]

llvm/utils/gn/secondary/libunwind/BUILD.gn

+import("//llvm/lib/Target/targets.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
-supported_toolchains = [ "//llvm/utils/gn/build/toolchain:stage2_unix" ]
-if (android_ndk_path != "") {
-  supported_toolchains += [
-    "//llvm/utils/gn/build/toolchain:stage2_android_aarch64",
-    "//llvm/utils/gn/build/toolchain:stage2_android_arm",
-  ]
-}
+supported_toolchains = [ "//llvm/utils/gn/build/toolchain:stage2_unix" ] +
+                       supported_android_toolchains
 
 group("libunwind") {
   deps = []
   foreach(toolchain, supported_toolchains) {
     deps += [ "//libunwind/src($toolchain)" ]
   }
 }

llvm/utils/gn/secondary/lldb/tools/driver/BUILD.gn

+import("//llvm/lib/Target/targets.gni")
 import("//llvm/utils/TableGen/tablegen.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 import("//llvm/utils/gn/build/write_cmake_config.gni")
 import("//llvm/version.gni")
 
 tablegen("Options") {
   visibility = [ ":lldb" ]
   args = [ "-gen-opt-parser-defs" ]
 }
 
 if (current_os == "mac") {
   write_cmake_config("write_info_plist") {
     input = "lldb-Info.plist.in"
     output = "$target_gen_dir/lldb-Info.plist"
     values = [ "LLDB_VERSION=$llvm_version" ]
   }
 }
 
-supported_toolchains = []
-if (android_ndk_path != "") {
-  supported_toolchains += [
-    "//llvm/utils/gn/build/toolchain:stage2_android_aarch64",
-    "//llvm/utils/gn/build/toolchain:stage2_android_arm",
-  ]
-}
+supported_toolchains = supported_android_toolchains
 
 executable("lldb") {
   configs += [ "//llvm/utils/gn/build:lldb_code" ]
   deps = [
     ":Options",
     "//lldb/include/lldb/Host:Config",
     "//lldb/source/API:liblldb",
     "//llvm/lib/Option",

llvm/utils/gn/secondary/llvm/lib/Target/targets.gni

+import("//llvm/utils/gn/build/toolchain/compiler.gni")
+
 declare_args() {
   # The target archs LLVM should support. Defaults to the host arch.
   # Set to a list, e.g. `llvm_targets_to_build = [ "X86", "ARM" ]`,
   # or to the string "all" to get all known targets.
   llvm_targets_to_build = "host"
 }
 
 # FIXME: Port the remaining targets.
if (host_cpu == "arm64") {
   native_target = "ARM"
 } else if (host_cpu == "ppc" || host_cpu == "ppc64") {
   native_target = "PowerPC"
 } else if (host_cpu == "x86" || host_cpu == "x64") {
   native_target = "X86"
 } else {
   assert(false, "Unsuppored host_cpu '$host_cpu'.")
 }
+
+supported_android_toolchains = []
+
+if (android_ndk_path != "") {
+  if (llvm_build_AArch64) {
+    supported_android_toolchains +=
+        [ "//llvm/utils/gn/build/toolchain:stage2_android_aarch64" ]
+  }
+  if (llvm_build_ARM) {
+    supported_android_toolchains +=
+        [ "//llvm/utils/gn/build/toolchain:stage2_android_arm" ]
+  }
+}