[InstCombine] Fold phi ( inttoptr/ptrtoint x ) to phi (x)

[Krishnakariya]

Summary

The inttoptr/ptrtoint roundtrip optimization is not always correct.
We are working towards removing this optimization and adding support to specific cases where this optimization works.

In this patch, we focus on phi-node operands with inttoptr casts.
We know that ptrtoint( inttoptr( ptrtoint x) ) is same as ptrtoint (x).
So, we want to remove this roundtrip cast which goes through phi-node.

[aqjune]

llvm/lib/Transforms/InstCombine/InstCombinePHI.cpp

324

Should we exclude cases where input pointers have different types?
After opaque pointers are introduced everything will be fine - it is a safeguard that will work until then.

[aqjune]

llvm/lib/Transforms/InstCombine/InstCombinePHI.cpp

324

For example:

p = phi i64 [ ptrtoint i8* %a, BB1 ], [ ptrtoint float* %b, BB2 ]
i = inttoptr p

[Krishnakariya]

Added a test for different input pointer types (func_pointer_different_types).

[aqjune]

I have a question about addrspacecast: is ptrtoint(inttoptr(ptrtoint pty1 p) to pty2) equivalent to ptrtoint(addrspacecast pty1 p to pty2)?
Does anyone have idea about this?

[lebedev.ri]

In D106289#2916089, @aqjune wrote:

I have a question about addrspacecast: is ptrtoint(inttoptr(ptrtoint pty1 p) to pty2) equivalent to ptrtoint(addrspacecast pty1 p to pty2)?
Does anyone have idea about this?

I'm going to guess no. inttoptr/ptrtoint are essentially no-op bitcasts,
while addrspacecast is implementation-defined and in general case can be assumed to e.g. offset the pointer.

[aqjune]

In D106289#2916096, @lebedev.ri wrote:

In D106289#2916089, @aqjune wrote:

I have a question about addrspacecast: is ptrtoint(inttoptr(ptrtoint pty1 p) to pty2) equivalent to ptrtoint(addrspacecast pty1 p to pty2)?
Does anyone have idea about this?

I'm going to guess no. inttoptr/ptrtoint are essentially no-op bitcasts,
while addrspacecast is implementation-defined and in general case can be assumed to e.g. offset the pointer.

Oh, thanks. @Krishnakariya does this patch deal with the case?

[Krishnakariya]

Yes, it handles this case. I have added a new test for the same.

[aqjune]

LGTM.

[aqjune]

I left a few nitpicks that is probably worth addressed

llvm/lib/Transforms/InstCombine/InstCombinePHI.cpp

306

You can do this folding when PN has multiple uses all of which are ptrtoint as well.

334

Is there a reason why a new phi is created?
Would replacing the corresponding op with the optimized pointer be enough?

[Krishnakariya]

Simplified code.

[aqjune]

llvm/lib/Transforms/InstCombine/InstCombinePHI.cpp

307

Perhaps there was llvm::all_of that can take this loop body as lambda. Let's use it to simplify this further.

1332

I think you'll need to return &PN if it was updated:

if (foldPHIArgIntToPtrToPHI(PN))
  return &PN;

[Krishnakariya]

[Krishnakariya]

llvm/lib/Transforms/InstCombine/InstCombinePHI.cpp

307

Thanks, I have updated the patch.

llvm/lib/Transforms/InstCombine/InstCombineInternal.h

 
 #include "llvm/ADT/Statistic.h"
 #include "llvm/Analysis/InstructionSimplify.h"
 #include "llvm/Analysis/TargetFolder.h"
 #include "llvm/Analysis/ValueTracking.h"
 #include "llvm/IR/IRBuilder.h"
 #include "llvm/IR/InstVisitor.h"
 #include "llvm/IR/PatternMatch.h"
+#include "llvm/IR/Value.h"
 #include "llvm/Support/Debug.h"
 #include "llvm/Support/KnownBits.h"
 #include "llvm/Transforms/InstCombine/InstCombineWorklist.h"
 #include "llvm/Transforms/InstCombine/InstCombiner.h"
 #include "llvm/Transforms/Utils/Local.h"
 #include <cassert>
 
 #define DEBUG_TYPE "instcombine"
public:
   /// its operands.
   Instruction *foldPHIArgOpIntoPHI(PHINode &PN);
   Instruction *foldPHIArgBinOpIntoPHI(PHINode &PN);
   Instruction *foldPHIArgInsertValueInstructionIntoPHI(PHINode &PN);
   Instruction *foldPHIArgExtractValueInstructionIntoPHI(PHINode &PN);
   Instruction *foldPHIArgGEPIntoPHI(PHINode &PN);
   Instruction *foldPHIArgLoadIntoPHI(PHINode &PN);
   Instruction *foldPHIArgZextsIntoPHI(PHINode &PN);
+  Instruction *foldPHIArgIntToPtrToPHI(PHINode &PN);
 
   /// If an integer typed PHI has only one use which is an IntToPtr operation,
   /// replace the PHI with an existing pointer typed PHI if it exists. Otherwise
   /// insert a new pointer typed PHI and replace the original one.
   Instruction *foldIntegerTypedPHI(PHINode &PN);
 
   /// Helper function for FoldPHIArgXIntoPHI() to set debug location for the
   /// folded operation.

llvm/lib/Transforms/InstCombine/InstCombinePHI.cpp

#endif
     NewPtrPHI->addIncoming(CI, IncomingBB);
   }
 
   // The PtrToCast + IntToPtr will be simplified later
   return CastInst::CreateBitOrPointerCast(NewPtrPHI,
                                           IntToPtr->getOperand(0)->getType());
 }
 
+// Remove RoundTrip IntToPtr/PtrToInt Cast on PHI-Operand and
+// fold Phi-operand to bitcast.
+Instruction *InstCombinerImpl::foldPHIArgIntToPtrToPHI(PHINode &PN) {
+  // convert ptr2int ( phi[ int2ptr(ptr2int(x))] ) --> ptr2int ( phi [ x ] )
+  // Make sure all uses of phi are ptr2int.
+  if (!all_of(PN.users(), [](User *U) { return isa<PtrToIntInst>(U); }))
+    return nullptr;
+
+  // Iterating over all operands to check presence of target pointers for
+  // optimization.
+  bool OperandWithRoundTripCast = false;
+  for (unsigned OpNum = 0; OpNum != PN.getNumIncomingValues(); ++OpNum) {
+    if (auto *NewOp =
+            simplifyIntToPtrRoundTripCast(PN.getIncomingValue(OpNum))) {
+      PN.setIncomingValue(OpNum, NewOp);
+      OperandWithRoundTripCast = true;
+    }
+  }
+  if (!OperandWithRoundTripCast)
+    return nullptr;
+  return &PN;
+}
+
 /// If we have something like phi [insertvalue(a,b,0), insertvalue(c,d,0)],
 /// turn this into a phi[a,c] and phi[b,d] and a single insertvalue.
 Instruction *
 InstCombinerImpl::foldPHIArgInsertValueInstructionIntoPHI(PHINode &PN) {
   auto *FirstIVI = cast<InsertValueInst>(PN.getIncomingValue(0));
 
   // Scan to see if all operands are `insertvalue`'s with the same indicies,
   // and all have a single use.
   for (unsigned i = 1; i != PN.getNumIncomingValues(); ++i) {
     auto *I = dyn_cast<InsertValueInst>(PN.getIncomingValue(i));
     if (!I || !I->hasOneUser() || I->getIndices() != FirstIVI->getIndices())
       return nullptr;
   }
 
   // For each operand of an `insertvalue`
   std::array<PHINode *, 2> NewOperands;
   for (int OpIdx : {0, 1}) {
     auto *&NewOperand = NewOperands[OpIdx];

 //
 Instruction *InstCombinerImpl::visitPHINode(PHINode &PN) {
   if (Value *V = SimplifyInstruction(&PN, SQ.getWithInstruction(&PN)))
     return replaceInstUsesWith(PN, V);
 
   if (Instruction *Result = foldPHIArgZextsIntoPHI(PN))
     return Result;
 
+  if (Instruction *Result = foldPHIArgIntToPtrToPHI(PN))
+    return Result;
+
   // If all PHI operands are the same operation, pull them through the PHI,
   // reducing code size.
   if (isa<Instruction>(PN.getIncomingValue(0)) &&
       isa<Instruction>(PN.getIncomingValue(1)) &&
       cast<Instruction>(PN.getIncomingValue(0))->getOpcode() ==
           cast<Instruction>(PN.getIncomingValue(1))->getOpcode() &&
       PN.getIncomingValue(0)->hasOneUser())
     if (Instruction *Result = foldPHIArgOpIntoPHI(PN))

llvm/lib/Transforms/InstCombine/InstructionCombining.cpp

if (IntToPtr && DL.getPointerTypeSizeInBits(IntToPtr->getDestTy()) ==
                       DL.getTypeSizeInBits(IntToPtr->getSrcTy())) {
     auto *PtrToInt = dyn_cast<PtrToIntInst>(IntToPtr->getOperand(0));
     Type *CastTy = IntToPtr->getDestTy();
     if (PtrToInt &&
         CastTy->getPointerAddressSpace() ==
             PtrToInt->getSrcTy()->getPointerAddressSpace() &&
         DL.getPointerTypeSizeInBits(PtrToInt->getSrcTy()) ==
             DL.getTypeSizeInBits(PtrToInt->getDestTy())) {
-      return Builder.CreateBitCast(PtrToInt->getOperand(0), CastTy);
+      return CastInst::CreateBitOrPointerCast(PtrToInt->getOperand(0), CastTy,
+                                              "", PtrToInt);
     }
   }
   return nullptr;
 }
 
 /// This performs a few simplifications for operators that are associative or
 /// commutative:
 ///

llvm/test/Transforms/InstCombine/phi-int2ptr-fold.ll

+; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
+; RUN: opt -instcombine -S -disable-i2p-p2i-opt < %s | FileCheck %s
+
+target datalayout = "e-p:64:64-p1:16:16-p2:32:32:32-p3:64:64:64"
+target triple = "x86_64-unknown-linux-gnu"
+
+; convert ptrtoint [ phi[ inttoptr (ptrtoint (x) ) ] ---> ptrtoint (phi[x])
+
+define i64 @func(i32** %X, i32** %Y, i1 %cond) {
+; CHECK-LABEL: @func(
+; CHECK-NEXT:    br i1 [[COND:%.*]], label [[BB1:%.*]], label [[BB2:%.*]]
+; CHECK:       bb1:
+; CHECK-NEXT:    br label [[EXIT:%.*]]
+; CHECK:       bb2:
+; CHECK-NEXT:    br label [[EXIT]]
+; CHECK:       exit:
+; CHECK-NEXT:    [[PHI_IN_IN:%.*]] = phi i32** [ [[X:%.*]], [[BB1]] ], [ [[Y:%.*]], [[BB2]] ]
+; CHECK-NEXT:    [[PHI_IN:%.*]] = ptrtoint i32** [[PHI_IN_IN]] to i64
+; CHECK-NEXT:    ret i64 [[PHI_IN]]
+;
+  br i1 %cond, label %bb1, label %bb2
+
+bb1:
+  %X.i = ptrtoint i32** %X to i64
+  %X.p = inttoptr i64 %X.i to i32*
+  br label %exit
+
+bb2:
+  %Y.i = ptrtoint i32** %Y to i64
+  %Y.p = inttoptr i64 %Y.i to i32*
+  br label %exit
+
+exit:
+  %phi = phi i32* [%X.p, %bb1], [%Y.p, %bb2]
+  %X.p.i = ptrtoint i32* %phi to i64
+  ret i64 %X.p.i
+}
+
+define i64 @func_single_operand(i32** %X, i32** %Y, i1 %cond) {
+; CHECK-LABEL: @func_single_operand(
+; CHECK-NEXT:    br i1 [[COND:%.*]], label [[BB1:%.*]], label [[EXIT:%.*]]
+; CHECK:       bb1:
+; CHECK-NEXT:    br label [[EXIT]]
+; CHECK:       exit:
+; CHECK-NEXT:    [[PHI_IN:%.*]] = phi i32** [ [[X:%.*]], [[BB1]] ], [ [[Y:%.*]], [[TMP0:%.*]] ]
+; CHECK-NEXT:    [[X_P_I:%.*]] = ptrtoint i32** [[PHI_IN]] to i64
+; CHECK-NEXT:    ret i64 [[X_P_I]]
+;
+  %Y.p = bitcast i32** %Y to i32*
+  br i1 %cond, label %bb1, label %exit
+
+bb1:
+  %X.i = ptrtoint i32** %X to i64
+  %X.p = inttoptr i64 %X.i to i32*
+  br label %exit
+
+exit:
+  %phi = phi i32* [%X.p, %bb1], [%Y.p, %0]
+  %X.p.i = ptrtoint i32* %phi to i64
+  ret i64 %X.p.i
+}
+
+define i64 @func_pointer_different_types(i16** %X, i32** %Y, i1 %cond) {
+; CHECK-LABEL: @func_pointer_different_types(
+; CHECK-NEXT:    [[Y_P:%.*]] = bitcast i32** [[Y:%.*]] to i32*
+; CHECK-NEXT:    br i1 [[COND:%.*]], label [[BB1:%.*]], label [[EXIT:%.*]]
+; CHECK:       bb1:
+; CHECK-NEXT:    [[TMP1:%.*]] = bitcast i16** [[X:%.*]] to i32*
+; CHECK-NEXT:    br label [[EXIT]]
+; CHECK:       exit:
+; CHECK-NEXT:    [[PHI:%.*]] = phi i32* [ [[TMP1]], [[BB1]] ], [ [[Y_P]], [[TMP0:%.*]] ]
+; CHECK-NEXT:    [[X_P_I:%.*]] = ptrtoint i32* [[PHI]] to i64
+; CHECK-NEXT:    ret i64 [[X_P_I]]
+;
+  %Y.p = bitcast i32** %Y to i32*
+  br i1 %cond, label %bb1, label %exit
+
+bb1:
+  %X.i = ptrtoint i16** %X to i64
+  %X.p = inttoptr i64 %X.i to i32*
+  br label %exit
+
+exit:
+  %phi = phi i32* [%X.p, %bb1], [%Y.p, %0]
+  %X.p.i = ptrtoint i32* %phi to i64
+  ret i64 %X.p.i
+}
+
+; Negative test - Wrong Integer type
+
+define i64 @func_integer_type_too_small(i32** %X, i32** %Y, i1 %cond) {
+; CHECK-LABEL: @func_integer_type_too_small(
+; CHECK-NEXT:    [[Y_P:%.*]] = bitcast i32** [[Y:%.*]] to i32*
+; CHECK-NEXT:    br i1 [[COND:%.*]], label [[BB1:%.*]], label [[EXIT:%.*]]
+; CHECK:       bb1:
+; CHECK-NEXT:    [[TMP1:%.*]] = ptrtoint i32** [[X:%.*]] to i64
+; CHECK-NEXT:    [[TMP2:%.*]] = and i64 [[TMP1]], 4294967295
+; CHECK-NEXT:    [[X_P:%.*]] = inttoptr i64 [[TMP2]] to i32*
+; CHECK-NEXT:    br label [[EXIT]]
+; CHECK:       exit:
+; CHECK-NEXT:    [[PHI:%.*]] = phi i32* [ [[X_P]], [[BB1]] ], [ [[Y_P]], [[TMP0:%.*]] ]
+; CHECK-NEXT:    [[X_P_I:%.*]] = ptrtoint i32* [[PHI]] to i64
+; CHECK-NEXT:    ret i64 [[X_P_I]]
+;
+  %Y.p = bitcast i32** %Y to i32*
+  br i1 %cond, label %bb1, label %exit
+
+bb1:
+  %X.i = ptrtoint i32** %X to i32
+  %X.p = inttoptr i32 %X.i to i32*
+  br label %exit
+
+exit:
+  %phi = phi i32* [%X.p, %bb1], [%Y.p, %0]
+  %X.p.i = ptrtoint i32* %phi to i64
+  ret i64 %X.p.i
+}
+
+; Negative test - phi not used in ptrtoint
+
+define i32* @func_phi_not_use_in_ptr2int(i32** %X, i32** %Y, i1 %cond) {
+; CHECK-LABEL: @func_phi_not_use_in_ptr2int(
+; CHECK-NEXT:    [[Y_P:%.*]] = bitcast i32** [[Y:%.*]] to i32*
+; CHECK-NEXT:    br i1 [[COND:%.*]], label [[BB1:%.*]], label [[EXIT:%.*]]
+; CHECK:       bb1:
+; CHECK-NEXT:    [[TMP1:%.*]] = ptrtoint i32** [[X:%.*]] to i64
+; CHECK-NEXT:    [[TMP2:%.*]] = and i64 [[TMP1]], 4294967295
+; CHECK-NEXT:    [[X_P:%.*]] = inttoptr i64 [[TMP2]] to i32*
+; CHECK-NEXT:    br label [[EXIT]]
+; CHECK:       exit:
+; CHECK-NEXT:    [[PHI:%.*]] = phi i32* [ [[X_P]], [[BB1]] ], [ [[Y_P]], [[TMP0:%.*]] ]
+; CHECK-NEXT:    ret i32* [[PHI]]
+;
+  %Y.p = bitcast i32** %Y to i32*
+  br i1 %cond, label %bb1, label %exit
+
+bb1:
+  %X.i = ptrtoint i32** %X to i32
+  %X.p = inttoptr i32 %X.i to i32*
+  br label %exit
+
+exit:
+  %phi = phi i32* [%X.p, %bb1], [%Y.p, %0]
+  ret i32* %phi
+}
+
+; Negative test - Pointers in different address spaces
+
+define i64 @func_ptr_different_addrspace(i16 addrspace(2)* %X, i32** %Y, i1 %cond) {
+; CHECK-LABEL: @func_ptr_different_addrspace(
+; CHECK-NEXT:    [[Y_P:%.*]] = bitcast i32** [[Y:%.*]] to i32*
+; CHECK-NEXT:    br i1 [[COND:%.*]], label [[BB1:%.*]], label [[EXIT:%.*]]
+; CHECK:       bb1:
+; CHECK-NEXT:    [[TMP1:%.*]] = ptrtoint i16 addrspace(2)* [[X:%.*]] to i32
+; CHECK-NEXT:    [[X_I:%.*]] = zext i32 [[TMP1]] to i64
+; CHECK-NEXT:    [[X_P:%.*]] = inttoptr i64 [[X_I]] to i32*
+; CHECK-NEXT:    br label [[EXIT]]
+; CHECK:       exit:
+; CHECK-NEXT:    [[PHI:%.*]] = phi i32* [ [[X_P]], [[BB1]] ], [ [[Y_P]], [[TMP0:%.*]] ]
+; CHECK-NEXT:    [[X_P_I:%.*]] = ptrtoint i32* [[PHI]] to i64
+; CHECK-NEXT:    ret i64 [[X_P_I]]
+;
+  %Y.p = bitcast i32** %Y to i32*
+  br i1 %cond, label %bb1, label %exit
+
+bb1:
+  %X.i = ptrtoint i16 addrspace(2)* %X to i64
+  %X.p = inttoptr i64 %X.i to i32*
+  br label %exit
+
+exit:
+  %phi = phi i32* [%X.p, %bb1], [%Y.p, %0]
+  %X.p.i = ptrtoint i32* %phi to i64
+  ret i64 %X.p.i
+}