[vim] Add initial syntax definition for .mir files

[porglezomp]

Summary

This initial definition handles the yaml container and the embedding of
the inner IRs. As a stopgap, this reuses the LLVM IR syntax highlighting
for the MIR function bodies--even though it's not technically correct,
it produces decent highlighting for a first pass.

[porglezomp]

A question for reviewers who might be able to explain:

llvm/utils/vim/syntax/machine-ir.vim

11

I actually don't need this unlet I don't think…

llvm/utils/vim/syntax/mir.vim

10

I don't understand why we bail out if a current_syntax is defined—I just copied this from the llvm.vim file. It seems to cause trouble with embedding syntax inside other syntax, but I assume it does something else useful to make up for that?

[dblaikie]

Can't say I know much about these things - but honestly, if it works enough/helps you, it doesn't seem like it'd do any harm to the project, so I'm good with it.

Out of curiosity, why is there both an mir.vim and a machine-ir.vim?

[porglezomp]

The MIR syntax is based on extending the yaml syntax and then embedding the machine-ir syntax inside it, I've defined it as two separate files so it's easier to separate "highlighting the instructions" from "embedding it inside yaml".

[dblaikie]

In D95552#2567160, @porglezomp wrote:

The MIR syntax is based on extending the yaml syntax and then embedding the machine-ir syntax inside it, I've defined it as two separate files so it's easier to separate "highlighting the instructions" from "embedding it inside yaml".

ah, fair enough - thanks for explaining!

Can you commit these yourself (do you have commit access) or would you like me to do it for you?

[porglezomp]

I can commit them.

llvm/utils/vim/ftdetect/mir.vim

+au BufRead,BufNewFile *.mir set filetype=mir

llvm/utils/vim/ftplugin/mir.vim

+" Vim filetype plugin file
+" Language: LLVM Machine IR
+" Maintainer: The LLVM team, http://llvm.org/
+
+if exists("b:did_ftplugin")
+  finish
+endif
+let b:did_ftplugin = 1
+
+setlocal softtabstop=2 shiftwidth=2
+setlocal expandtab
+setlocal comments+=:;
+

llvm/utils/vim/syntax/machine-ir.vim

+" Vim syntax file
+" Language:   mir
+" Maintainer: The LLVM team, http://llvm.org/
+" Version:      $Revision$
+
+" FIXME: MIR doesn't actually match LLVM IR. Reimplement this.
+" See the MIR LangRef: https://llvm.org/docs/MIRLangRef.html
+unlet b:current_syntax  " Unlet so that the LLVM syntax will load
+runtime! syntax/llvm.vim
+unlet b:current_syntax
+let b:current_syntax = "mir"

llvm/utils/vim/syntax/mir.vim

+" Vim syntax file
+" Language:   mir
+" Maintainer: The LLVM team, http://llvm.org/
+" Version:      $Revision$
+
+if version < 600
+  syntax clear
+elseif exists("b:current_syntax")
+  finish
+endif
+
+syn case match
+
+" MIR is embedded in a yaml container, so we load all of the yaml syntax.
+runtime! syntax/yaml.vim
+unlet b:current_syntax
+
+" The first document of a file is allowed to contain an LLVM IR module inside
+" a top-level yaml block string.
+syntax include @LLVM syntax/llvm.vim
+" FIXME: This should only be allowed for the first document of the file
+syntax region llvm start=/\(^---\s*|\)\@<=/ end=/\(^\.\.\.\)\@=/ contains=@LLVM
+
+" The `body:` field of a document contains the MIR dump of the function
+syntax include @MIR syntax/machine-ir.vim
+syntax region mir start=/\(^body:\s*|\)\@<=/ end=/\(^[^[:space:]]\)\@=/ contains=@MIR
+
+" Syntax-highlight lit test commands and bug numbers.
+syn match  mirSpecialComment /#\s*PR\d*\s*$/
+syn match  mirSpecialComment /#\s*REQUIRES:.*$/
+syn match  mirSpecialComment /#\s*RUN:.*$/
+syn match  mirSpecialComment /#\s*ALLOW_RETRIES:.*$/
+syn match  mirSpecialComment /#\s*CHECK:.*$/
+syn match  mirSpecialComment "\v#\s*CHECK-(NEXT|NOT|DAG|SAME|LABEL):.*$"
+syn match  mirSpecialComment /#\s*XFAIL:.*$/
+
+if version >= 508 || !exists("did_c_syn_inits")
+  if version < 508
+    let did_c_syn_inits = 1
+    command -nargs=+ HiLink hi link <args>
+  else
+    command -nargs=+ HiLink hi def link <args>
+  endif
+
+  HiLink mirSpecialComment SpecialComment
+endif
+
+let b:current_syntax = "mir"