[xray] Avoid text relocations in trampolines for ARM/AArch64

[ianlevesque]

Summary

Switch to pc-relative lookup of the xray handler function to avoid text relocations.

[dberris]

I'll defer to @MaskRay on the ARM bits.

[MaskRay]

Thanks!

compiler-rt/lib/xray/xray_trampoline_AArch64.S

__xray_FunctionEntry:
     STP X1, X2, [SP, #-16]!
     STP X3, X4, [SP, #-16]!
     STP X5, X6, [SP, #-16]!
     STP X7, X30, [SP, #-16]!
     STP Q0, Q1, [SP, #-32]!
     STP Q2, Q3, [SP, #-32]!
     STP Q4, Q5, [SP, #-32]!
     STP Q6, Q7, [SP, #-32]!
-    /* Load the address of _ZN6__xray19XRayPatchedFunctionE into X1 */
-    LDR X1, =_ZN6__xray19XRayPatchedFunctionE
+    /* Load the page address of _ZN6__xray19XRayPatchedFunctionE into X1 */
+    ADRP X1, _ZN6__xray19XRayPatchedFunctionE
     /* Load the handler function pointer into X2 */
-    LDR X2, [X1]
+    LDR X2, [X1, #:lo12:_ZN6__xray19XRayPatchedFunctionE]
     /* Handler address is nullptr if handler is not set */
     CMP X2, #0
     BEQ FunctionEntry_restore
     /* Function ID is already in W0 (the first parameter).
          X1=0 means that we are tracing an entry event */
     MOV X1, #0
     /* Call the handler with 2 parameters in W0 and X1 */
     BLR X2
/* Move the return address beyond the end of sled data. The 12 bytes of
          the current trampoline. */
     ADD X30, X30, #12
     /* Push the registers which may be modified by the handler function */
     STP X1, X2, [SP, #-16]!
     STP X3, X4, [SP, #-16]!
     STP X5, X6, [SP, #-16]!
     STP X7, X30, [SP, #-16]!
     STR Q0, [SP, #-16]!
-    /* Load the address of _ZN6__xray19XRayPatchedFunctionE into X1 */
-    LDR X1, =_ZN6__xray19XRayPatchedFunctionE
+    /* Load the page address of _ZN6__xray19XRayPatchedFunctionE into X1 */
+    ADRP X1, _ZN6__xray19XRayPatchedFunctionE
     /* Load the handler function pointer into X2 */
-    LDR X2, [X1]
+    LDR X2, [X1, #:lo12:_ZN6__xray19XRayPatchedFunctionE]
     /* Handler address is nullptr if handler is not set */
     CMP X2, #0
     BEQ FunctionExit_restore
     /* Function ID is already in W0 (the first parameter).
          X1=1 means that we are tracing an exit event */
     MOV X1, #1
     /* Call the handler with 2 parameters in W0 and X1 */
     BLR X2
__xray_FunctionTailExit:
     STP X3, X4, [SP, #-16]!
     STP X5, X6, [SP, #-16]!
     STP X7, X30, [SP, #-16]!
     /* Push the parameters of the tail called function */
     STP Q0, Q1, [SP, #-32]!
     STP Q2, Q3, [SP, #-32]!
     STP Q4, Q5, [SP, #-32]!
     STP Q6, Q7, [SP, #-32]!
-    /* Load the address of _ZN6__xray19XRayPatchedFunctionE into X1 */
-    LDR X1, =_ZN6__xray19XRayPatchedFunctionE
+    /* Load the page address of _ZN6__xray19XRayPatchedFunctionE into X1 */
+    ADRP X1, _ZN6__xray19XRayPatchedFunctionE
     /* Load the handler function pointer into X2 */
-    LDR X2, [X1]
+    LDR X2, [X1, #:lo12:_ZN6__xray19XRayPatchedFunctionE]
     /* Handler address is nullptr if handler is not set */
     CMP X2, #0
     BEQ FunctionTailExit_restore
     /* Function ID is already in W0 (the first parameter).
          X1=2 means that we are tracing a tail exit event, but before the
          logging part of XRay is ready, we pretend that here a normal function
          exit happens, so we give the handler code 1 */
     MOV X1, #1

compiler-rt/lib/xray/xray_trampoline_arm.S

#include "../builtins/assembly.h"
     @   for passing parameters to C/C++ functions.
     .type __xray_FunctionEntry, %function
     @ In C++ it is void extern "C" __xray_FunctionEntry(uint32_t FuncId) with
     @   FuncId passed in r0 register.
 __xray_FunctionEntry:
     PUSH {r1-r3,lr}
     @ Save floating-point parameters of the instrumented function
     VPUSH {d0-d7}
-    MOVW r1,#:lower16:_ZN6__xray19XRayPatchedFunctionE
-    MOVT r1,#:upper16:_ZN6__xray19XRayPatchedFunctionE
-    LDR r2, [r1]
+    MOVW r1, #:lower16:_ZN6__xray19XRayPatchedFunctionE - (. + 16)
+    MOVT r1, #:upper16:_ZN6__xray19XRayPatchedFunctionE - (. + 12)
+    LDR r2, [pc, r1]
     @ Handler address is nullptr if handler is not set
     CMP r2, #0
     BEQ FunctionEntry_restore
     @ Function ID is already in r0 (the first parameter).
     @ r1=0 means that we are tracing an entry event
     MOV r1, #0
     @ Call the handler with 2 parameters in r0 and r1
     BLX r2
FunctionEntry_restore:
   .type __xray_FunctionExit, %function
   @ In C++ it is extern "C" void __xray_FunctionExit(uint32_t FuncId) with
     @   FuncId passed in r0 register.
 __xray_FunctionExit:
     PUSH {r1-r3,lr}
     @ Save the floating-point return value of the instrumented function
     VPUSH {d0}
     @ Load the handler address
-    MOVW r1,#:lower16:_ZN6__xray19XRayPatchedFunctionE
-    MOVT r1,#:upper16:_ZN6__xray19XRayPatchedFunctionE
-    LDR r2, [r1]
+    MOVW r1, #:lower16:_ZN6__xray19XRayPatchedFunctionE - (. + 16)
+    MOVT r1, #:upper16:_ZN6__xray19XRayPatchedFunctionE - (. + 12)
+    LDR r2, [pc, r1]
     @ Handler address is nullptr if handler is not set
     CMP r2, #0
     BEQ FunctionExit_restore
     @ Function ID is already in r0 (the first parameter).
     @ 1 means that we are tracing an exit event
     MOV r1, #1
     @ Call the handler with 2 parameters in r0 and r1
     BLX r2
FunctionExit_restore:
     @   for passing parameters to C/C++ functions.
     .type __xray_FunctionTailExit, %function
     @ In C++ it is void extern "C" __xray_FunctionTailExit(uint32_t FuncId)
     @   with FuncId passed in r0 register.
 __xray_FunctionTailExit:
     PUSH {r1-r3,lr}
     @ Save floating-point parameters of the instrumented function
     VPUSH {d0-d7}
-    MOVW r1,#:lower16:_ZN6__xray19XRayPatchedFunctionE
-    MOVT r1,#:upper16:_ZN6__xray19XRayPatchedFunctionE
-    LDR r2, [r1]
+    MOVW r1, #:lower16:_ZN6__xray19XRayPatchedFunctionE - (. + 16)
+    MOVT r1, #:upper16:_ZN6__xray19XRayPatchedFunctionE - (. + 12)
+    LDR r2, [pc, r1]
     @ Handler address is nullptr if handler is not set
     CMP r2, #0
     BEQ FunctionTailExit_restore
     @ Function ID is already in r0 (the first parameter).
     @ r1=2 means that we are tracing a tail exit event
     @ But before the logging part of XRay is ready, we pretend that here a
     @   normal function exit happens, so we give the handler code 1
     MOV r1, #1
     @ Call the handler with 2 parameters in r0 and r1
     BLX r2
 FunctionTailExit_restore:
     @ Restore floating-point parameters of the instrumented function
     VPOP {d0-d7}
     POP {r1-r3,pc}
 
 NO_EXEC_STACK_DIRECTIVE