[gn build] Add some llvm/tools: bugpoint, dsymutil, llvm-opt-report

[thakis]

Summary

Also add build file for dependency llvm/lib/OptRemarks.

Needed for check-llvm.

[phosek]

LGTM

llvm/trunk/utils/gn/secondary/BUILD.gn

 import("//clang/lib/ARCMigrate/enable.gni")
 import("//clang/lib/StaticAnalyzer/Frontend/enable.gni")
 
 group("default") {
   deps = [
     "//clang/test",
     "//lld/test",
+    "//llvm/tools/bugpoint",
+    "//llvm/tools/dsymutil",
     "//llvm/tools/llvm-c-test",
     "//llvm/tools/llvm-cfi-verify",
     "//llvm/tools/llvm-cov",
     "//llvm/tools/llvm-cvtres",
     "//llvm/tools/llvm-cxxdump",
     "//llvm/tools/llvm-cxxfilt",
     "//llvm/tools/llvm-cxxmap",
     "//llvm/tools/llvm-diff",
     "//llvm/tools/llvm-dwp",
     "//llvm/tools/llvm-exegesis",
     "//llvm/tools/llvm-extract",
     "//llvm/tools/llvm-link",
     "//llvm/tools/llvm-mca",
     "//llvm/tools/llvm-mt",
+    "//llvm/tools/llvm-opt-report",
     "//llvm/tools/llvm-rc",
     "//llvm/tools/llvm-rtdyld",
     "//llvm/tools/llvm-size",
     "//llvm/tools/llvm-split",
     "//llvm/tools/llvm-strings",
     "//llvm/tools/llvm-undname",
     "//llvm/tools/llvm-xray",
     "//llvm/tools/sancov",

llvm/trunk/utils/gn/secondary/llvm/lib/OptRemarks/BUILD.gn

+static_library("OptRemarks") {
+  output_name = "LLVMOptRemarks"
+  deps = [
+    "//llvm/lib/Support",
+  ]
+
+  sources = [
+    "OptRemarksParser.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/tools/bugpoint/BUILD.gn

+executable("bugpoint") {
+  deps = [
+    "//llvm/include/llvm/Config:config",
+    "//llvm/include/llvm/Config:llvm-config",
+    "//llvm/lib/Analysis",
+    "//llvm/lib/Bitcode/Writer",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/IR",
+    "//llvm/lib/IRReader",
+    "//llvm/lib/Linker",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Target:TargetsToBuild",
+    "//llvm/lib/Transforms/AggressiveInstCombine",
+    "//llvm/lib/Transforms/IPO",
+    "//llvm/lib/Transforms/Instrumentation",
+    "//llvm/lib/Transforms/ObjCARC",
+    "//llvm/lib/Transforms/Scalar",
+    "//llvm/lib/Transforms/Utils",
+    "//llvm/lib/Transforms/Vectorize",
+  ]
+  sources = [
+    "BugDriver.cpp",
+    "CrashDebugger.cpp",
+    "ExecutionDriver.cpp",
+    "ExtractFunction.cpp",
+    "FindBugs.cpp",
+    "Miscompilation.cpp",
+    "OptimizerDriver.cpp",
+    "ToolRunner.cpp",
+    "bugpoint.cpp",
+  ]
+
+  # Support plugins.
+  # FIXME: Disable dead stripping once other binaries are dead-stripped.
+  if (host_os == "linux") {
+    # Make sure bugpoint plugins can access bugpoint's symbols.
+    # Corresponds to export_executable_symbols() in cmake.
+    ldflags = [ "-rdynamic" ]
+  }
+}

llvm/trunk/utils/gn/secondary/llvm/tools/dsymutil/BUILD.gn

+executable("dsymutil") {
+  deps = [
+    "//llvm/lib/CodeGen/AsmPrinter",
+    "//llvm/lib/DebugInfo/DWARF",
+    "//llvm/lib/MC",
+    "//llvm/lib/Object",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Target:TargetsToBuild",
+  ]
+  sources = [
+    "BinaryHolder.cpp",
+    "CFBundle.cpp",
+    "CompileUnit.cpp",
+    "DebugMap.cpp",
+    "DeclContext.cpp",
+    "DwarfLinker.cpp",
+    "DwarfStreamer.cpp",
+    "MachODebugMapParser.cpp",
+    "MachOUtils.cpp",
+    "NonRelocatableStringpool.cpp",
+    "dsymutil.cpp",
+  ]
+  if (host_os == "mac") {
+    libs = [ "CoreFoundation.framework" ]
+  }
+}

llvm/trunk/utils/gn/secondary/llvm/tools/llvm-opt-report/BUILD.gn

+executable("llvm-opt-report") {
+  deps = [
+    "//llvm/lib/Demangle",
+    "//llvm/lib/IR",
+    "//llvm/lib/Object",
+    "//llvm/lib/OptRemarks",
+    "//llvm/lib/Support",
+  ]
+  sources = [
+    "OptReport.cpp",
+  ]
+}