[gn build] Add fuzzers in llvm/tools that are needed for check-llvm

[thakis]

Summary

Also add a fuzzer() template for defining fuzzers that's similar to add_llvm_fuzzer in the CMake build, and a build file for dependency llvm/lib/FuzzMutate.

[phosek]

llvm/utils/gn/build/fuzzer.gni

29 ↗

(On Diff #179812)

I checked the LLVM add_llvm_fuzzer function and DUMMY_MAIN is just an optional argument which is only included in LLVM_OPTIONAL_SOURCES for IDE but otherwise ignored if llvm_use_sanitize_coverage or llvm_use_sanitize_coverage is set. Shouldn't this behave the same?

[thakis]

llvm/utils/gn/build/fuzzer.gni

29 ↗

(On Diff #179812)

This template also only uses dummy_main if llvm_lib_fuzzing_engine and llvm_use_sanitize_coverage both aren't set (see the two not_neededs) -- it tries to do the same. Maybe I got it wrong?

[phosek]

LGTM

llvm/utils/gn/build/fuzzer.gni

29 ↗

(On Diff #179812)

If I'm reading add_llvm_fuzzer, it's not going to give you an error if you don't pass DUMMY_MAIN while this template will. I think it's fine since you don't want the behavior of this target differ based on whether llvm_use_sanitize_coverage or llvm_use_sanitize_coverage is set or not, but I want to point out the difference. In this case it'd be probably better to change CMake to make those arguments required as well.

Can you please also provide an error message for this assertion and the one below?

[thakis]

llvm/utils/gn/build/fuzzer.gni

29 ↗

(On Diff #179812)

Ah, I see what you mean. I agree it'd be good to always require it on the cmake side too :-)

Landing with error messages added for the asserts.

llvm/trunk/utils/gn/build/fuzzer.gni

+# This file introduces a templates for defining fuzzers.
+#
+# All parameters valid for executable() targets are valid (cflags, defines,
+# deps, include_dirs, sources, ...). In addition to that:
+#
+#   dummy_main (required)
+#       Path to a cpp file containing main(), used when neither
+#       llvm_use_sanitize_coverage nor llvm_use_sanitize_coverage are set.
+#
+# Example of usage:
+#
+#   fuzzer("llvm-opt-fuzzer") {
+#     deps = [ ... ]
+#     dummy_main = "DummyOptFuzzer.cpp"
+#     sources = [ "llvm-opt-fuzzer.cpp" ]
+#   }
+
+declare_args() {
+  # Set to the path of a static library containing a fuzzing engine, e.g.
+  # oss-fuzz's $LIB_FUZZING_ENGINE.
+  llvm_lib_fuzzing_engine = ""
+
+  # If true, pass -fsanitize=fuzzer to the compiler for fuzzer() targets.
+  # Likely only makes sense to set if you know that the host compiler is clang.
+  llvm_use_sanitize_coverage = false
+}
+
+template("fuzzer") {
+  assert(defined(invoker.dummy_main), "must set 'dummy_main' in $target_name")
+  assert(defined(invoker.sources), "must set 'sources' for $target_name")
+  executable(target_name) {
+    forward_variables_from(invoker, "*", [ "dummy_main" ])
+    if (llvm_lib_fuzzing_engine != "") {
+      if (!defined(libs)) {
+        libs = []
+      }
+      libs += [ llvm_lib_fuzzing_engine ]
+      not_needed(invoker, [ "dummy_main" ])
+    } else if (llvm_use_sanitize_coverage) {
+      if (!defined(cflags)) {
+        cflags = []
+      }
+      cflags += [ "-fsanitize=fuzzer" ]
+      not_needed(invoker, [ "dummy_main" ])
+    } else {
+      sources += [ invoker.dummy_main ]
+    }
+  }
+}

llvm/trunk/utils/gn/secondary/BUILD.gn

deps = [
     "//llvm/tools/llvm-cvtres",
     "//llvm/tools/llvm-cxxdump",
     "//llvm/tools/llvm-cxxfilt",
     "//llvm/tools/llvm-cxxmap",
     "//llvm/tools/llvm-diff",
     "//llvm/tools/llvm-dwp",
     "//llvm/tools/llvm-exegesis",
     "//llvm/tools/llvm-extract",
+    "//llvm/tools/llvm-isel-fuzzer",
     "//llvm/tools/llvm-link",
     "//llvm/tools/llvm-mca",
     "//llvm/tools/llvm-mt",
+    "//llvm/tools/llvm-opt-fuzzer",
     "//llvm/tools/llvm-opt-report",
     "//llvm/tools/llvm-rc",
     "//llvm/tools/llvm-rtdyld",
     "//llvm/tools/llvm-size",
     "//llvm/tools/llvm-split",
     "//llvm/tools/llvm-strings",
     "//llvm/tools/llvm-undname",
     "//llvm/tools/llvm-xray",

llvm/trunk/utils/gn/secondary/llvm/include/llvm/Config/BUILD.gn

if (llvm_enable_threads) {
     args += [ "LLVM_ENABLE_THREADS=" ]
   }
 }
 
 ##############################################################################
 # .def files used by llvm/lib/Target
 
 template("write_target_def_file") {
-  assert(defined(invoker.key), "callers must set key")
-  assert(defined(invoker.value), "callers must set value")
+  assert(defined(invoker.key), "must set 'key' in $target_name")
+  assert(defined(invoker.value), "must set 'value' in $target_name")
 
   action(target_name) {
     visibility = [ ":write_target_def_files" ]
     script = "//llvm/utils/gn/build/write_cmake_config.py"
 
     sources = [
       "$target_name.in",
     ]

llvm/trunk/utils/gn/secondary/llvm/lib/FuzzMutate/BUILD.gn

+static_library("FuzzMutate") {
+  output_name = "LLVMFuzzMutate"
+  deps = [
+    "//llvm/lib/Analysis",
+    "//llvm/lib/Bitcode/Reader",
+    "//llvm/lib/Bitcode/Writer",
+    "//llvm/lib/IR",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Transforms/Scalar",
+  ]
+  sources = [
+    "FuzzerCLI.cpp",
+    "IRMutator.cpp",
+    "OpDescriptor.cpp",
+    "Operations.cpp",
+    "RandomIRBuilder.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/tools/llvm-isel-fuzzer/BUILD.gn

+import("//llvm/utils/gn/build/fuzzer.gni")
+
+fuzzer("llvm-isel-fuzzer") {
+  deps = [
+    "//llvm/lib/Analysis",
+    "//llvm/lib/Bitcode/Reader",
+    "//llvm/lib/Bitcode/Writer",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/CodeGen/AsmPrinter",
+    "//llvm/lib/CodeGen/SelectionDAG",
+    "//llvm/lib/FuzzMutate",
+    "//llvm/lib/IR",
+    "//llvm/lib/IRReader",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Target:TargetsToBuild",
+    "//llvm/lib/Transforms/Scalar",
+  ]
+  dummy_main = "DummyISelFuzzer.cpp"
+  sources = [
+    "llvm-isel-fuzzer.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/tools/llvm-opt-fuzzer/BUILD.gn

+import("//llvm/utils/gn/build/fuzzer.gni")
+
+fuzzer("llvm-opt-fuzzer") {
+  deps = [
+    "//llvm/lib/Analysis",
+    "//llvm/lib/Bitcode/Reader",
+    "//llvm/lib/Bitcode/Writer",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/FuzzMutate",
+    "//llvm/lib/IR",
+    "//llvm/lib/IRReader",
+    "//llvm/lib/MC",
+    "//llvm/lib/Passes",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Target:TargetsToBuild",
+    "//llvm/lib/Transforms/AggressiveInstCombine",
+    "//llvm/lib/Transforms/Coroutines",
+    "//llvm/lib/Transforms/IPO",
+    "//llvm/lib/Transforms/InstCombine",
+    "//llvm/lib/Transforms/Instrumentation",
+    "//llvm/lib/Transforms/ObjCARC",
+    "//llvm/lib/Transforms/Scalar",
+    "//llvm/lib/Transforms/Utils",
+    "//llvm/lib/Transforms/Vectorize",
+  ]
+  dummy_main = "DummyOptFuzzer.cpp"
+  sources = [
+    "llvm-opt-fuzzer.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/utils/TableGen/tablegen.gni

 #
 #   tablegen("attributes_compat_func_gen") {
 #     visibility = [ ":IR" ]
 #     args = [ "-gen-attrs" ]
 #     td_file = "AttributesCompatFunc.td"
 #   }
 
 template("tablegen") {
-  assert(defined(invoker.args), "args must be defined for $target_name")
+  assert(defined(invoker.args), "must set 'args' in $target_name")
 
   config_name = "${target_name}_config"
   config(config_name) {
     visibility = [ ":$target_name" ]
     include_dirs = [ target_gen_dir ]
   }
 
   action(target_name) {