[gn build] Add some llvm/tools: lli, lli-child-target

[thakis]

Summary

Also add build files for dependencies llvm/lib/ExecutionEngine/{Interpreter,Orc}

[phosek]

llvm/utils/gn/secondary/BUILD.gn

11 ↗

(On Diff #179808)

You seem to be overriding the name of the target to match the name of the directory and then setting the output_name explicitly everywhere. Is there a reason why not to use the same approach here as well?

[thakis]

llvm/utils/gn/secondary/BUILD.gn

11 ↗

(On Diff #179808)

I do that for static_libraries but not for executables (other example I can think of: clang/tools/driver:clang). I can change it to use output_name here if you prefer.

[phosek]

LGTM

llvm/trunk/utils/gn/secondary/BUILD.gn

 import("//clang/lib/ARCMigrate/enable.gni")
 import("//clang/lib/StaticAnalyzer/Frontend/enable.gni")
 
 group("default") {
   deps = [
     "//clang/test",
     "//lld/test",
     "//llvm/tools/bugpoint",
     "//llvm/tools/dsymutil",
+    "//llvm/tools/lli",
+    "//llvm/tools/lli/ChildTarget:lli-child-target",
     "//llvm/tools/llvm-c-test",
     "//llvm/tools/llvm-cfi-verify",
     "//llvm/tools/llvm-cov",
     "//llvm/tools/llvm-cvtres",
     "//llvm/tools/llvm-cxxdump",
     "//llvm/tools/llvm-cxxfilt",
     "//llvm/tools/llvm-cxxmap",
     "//llvm/tools/llvm-diff",

llvm/trunk/utils/gn/secondary/llvm/lib/ExecutionEngine/Interpreter/BUILD.gn

+static_library("Interpreter") {
+  output_name = "LLVMInterpreter"
+  deps = [
+    "//llvm/include/llvm/Config:config",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/ExecutionEngine",
+    "//llvm/lib/IR",
+    "//llvm/lib/Support",
+  ]
+  sources = [
+    "Execution.cpp",
+    "ExternalFunctions.cpp",
+    "Interpreter.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/ExecutionEngine/Orc/BUILD.gn

+static_library("Orc") {
+  output_name = "LLVMOrcJIT"
+  deps = [
+    "//llvm/lib/ExecutionEngine",
+    "//llvm/lib/ExecutionEngine/RuntimeDyld",
+    "//llvm/lib/IR",
+    "//llvm/lib/Object",
+    "//llvm/lib/Support",
+    "//llvm/lib/Transforms/Utils",
+  ]
+  sources = [
+    "CompileOnDemandLayer.cpp",
+    "Core.cpp",
+    "ExecutionUtils.cpp",
+    "IRCompileLayer.cpp",
+    "IRTransformLayer.cpp",
+    "IndirectionUtils.cpp",
+    "JITTargetMachineBuilder.cpp",
+    "LLJIT.cpp",
+    "Layer.cpp",
+    "LazyReexports.cpp",
+    "Legacy.cpp",
+    "NullResolver.cpp",
+    "ObjectTransformLayer.cpp",
+    "OrcABISupport.cpp",
+    "OrcCBindings.cpp",
+    "OrcError.cpp",
+    "OrcMCJITReplacement.cpp",
+    "RPCUtils.cpp",
+    "RTDyldObjectLinkingLayer.cpp",
+    "ThreadSafeModule.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/tools/lli/BUILD.gn

+executable("lli") {
+  deps = [
+    "//llvm/include/llvm/Config:llvm-config",
+    "//llvm/lib/AsmParser",
+    "//llvm/lib/Bitcode/Reader",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/CodeGen/SelectionDAG",
+    "//llvm/lib/ExecutionEngine",
+    "//llvm/lib/ExecutionEngine/Interpreter",
+    "//llvm/lib/ExecutionEngine/MCJIT",
+    "//llvm/lib/ExecutionEngine/Orc",
+    "//llvm/lib/ExecutionEngine/RuntimeDyld",
+    "//llvm/lib/IR",
+    "//llvm/lib/IRReader",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Target:NativeTarget",
+    "//llvm/lib/Transforms/Instrumentation",
+    "//llvm/lib/Transforms/Utils",
+  ]
+  sources = [
+    "lli.cpp",
+  ]
+  if (host_os == "linux") {
+    # Corresponds to export_executable_symbols() in cmake.
+    ldflags = [ "-rdynamic" ]
+  }
+}

llvm/trunk/utils/gn/secondary/llvm/tools/lli/ChildTarget/BUILD.gn

+executable("lli-child-target") {
+  deps = [
+    "//llvm/lib/ExecutionEngine/Orc",
+    "//llvm/lib/ExecutionEngine/RuntimeDyld",
+    "//llvm/lib/Support",
+  ]
+  sources = [
+    "ChildTarget.cpp",
+  ]
+}