[gn build] Add build files for llvm/lib/{LineEditor,Testing/Support,TextAPI}

[thakis]

Summary

Nothing pulls them in yet, but they will be needed for check-llvm.

LineEditor depends on libedit, so create a gn/build/lib for it, following the usual pattern.

[phosek]

LGTM

llvm/trunk/utils/gn/build/libs/edit/BUILD.gn

+import("//llvm/utils/gn/build/libs/edit/enable.gni")
+
+config("edit_config") {
+  visibility = [ ":edit" ]
+  libs = [ "edit" ]
+}
+
+group("edit") {
+  if (llvm_enable_libedit) {
+    public_configs = [ ":edit_config" ]
+  }
+}

llvm/trunk/utils/gn/build/libs/edit/enable.gni

+declare_args() {
+  llvm_enable_libedit = host_os == "mac"
+}

llvm/trunk/utils/gn/secondary/llvm/include/llvm/Config/BUILD.gn

 import("//llvm/lib/Target/targets.gni")
 import("//llvm/triples.gni")
 import("//llvm/utils/gn/build/buildflags.gni")
+import("//llvm/utils/gn/build/libs/edit/enable.gni")
 import("//llvm/utils/gn/build/libs/pthread/enable.gni")
 import("//llvm/utils/gn/build/libs/terminfo/enable.gni")
 import("//llvm/utils/gn/build/libs/xar/enable.gni")
 import("//llvm/utils/gn/build/libs/xml/enable.gni")
 import("//llvm/utils/gn/build/libs/zlib/enable.gni")
 import("//llvm/version.gni")
 
 # Contains actions to create config.h, llvm-config.h, abi-breaking.h,
if (host_os == "linux") {
     ]
   }
 
   if (host_os == "mac") {
     args += [
       "HAVE_CRASHREPORTER_INFO=1",
       "HAVE_DECL_ARC4RANDOM=1",
       "HAVE_DLADDR=1",
-      "HAVE_LIBEDIT=1",
       "HAVE_MALLOC_H=",
       "HAVE_MACH_MACH_H=1",
       "HAVE_MALLOC_MALLOC_H=1",
       "HAVE_MALLOC_ZONE_STATISTICS=1",
       "HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC=1",
     ]
   } else {
     args += [
       "HAVE_CRASHREPORTER_INFO=",
       "HAVE_DECL_ARC4RANDOM=",
       "HAVE_DLADDR=",
-      "HAVE_LIBEDIT=",
       "HAVE_MACH_MACH_H=",
       "HAVE_MALLOC_H=1",
       "HAVE_MALLOC_MALLOC_H=",
       "HAVE_MALLOC_ZONE_STATISTICS=",
       "HAVE_STRUCT_STAT_ST_MTIMESPEC_TV_NSEC=",
     ]
   }
 
action("config") {
   if (host_os == "linux") {
     args += [ "LTDL_SHLIB_EXT=.so" ]
   } else if (host_os == "mac") {
     args += [ "LTDL_SHLIB_EXT=.dylib" ]
   } else if (host_os == "win") {
     args += [ "LTDL_SHLIB_EXT=.dll" ]
   }
 
+  if (llvm_enable_libedit) {
+    args += [ "HAVE_LIBEDIT=1" ]
+  } else {
+    args += [ "HAVE_LIBEDIT=" ]
+  }
+
   if (llvm_enable_libxar) {
     args += [ "HAVE_LIBXAR=1" ]
   } else {
     args += [ "HAVE_LIBXAR=" ]
   }
 
   if (llvm_enable_terminfo) {
     args += [ "HAVE_TERMINFO=1" ]

llvm/trunk/utils/gn/secondary/llvm/lib/LineEditor/BUILD.gn

+static_library("LineEditor") {
+  output_name = "LLVMLineEditor"
+  deps = [
+    "//llvm/include/llvm/Config:config",
+    "//llvm/lib/Support",
+    "//llvm/utils/gn/build/libs/edit",
+  ]
+
+  sources = [
+    "LineEditor.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Testing/Support/BUILD.gn

+static_library("Support") {
+  output_name = "LLVMTestingSupport"
+  deps = [
+    "//llvm/lib/Support",
+    "//llvm/utils/unittest:gtest",
+  ]
+  sources = [
+    "Error.cpp",
+    "SupportHelpers.cpp",
+  ]
+  testonly = true
+}

llvm/trunk/utils/gn/secondary/llvm/lib/TextAPI/BUILD.gn

+static_library("TextAPI") {
+  output_name = "LLVMTextAPI"
+  deps = [
+    "//llvm/lib/BinaryFormat",
+    "//llvm/lib/Support",
+  ]
+  include_dirs = [ "." ]
+  sources = [
+    "ELF/ELFStub.cpp",
+    "ELF/TBEHandler.cpp",
+  ]
+}