[Bazel] Use dynamic workspace root determination

[aaronmondal]

Summary

The clang:ast and clang:builtin_headers_gen targets currently use hardcoded external/llvm-project
paths to access generated headers.

With bzlmod this path becomes dependent on the module name, module version and module extension,
so we need a more dynamic approach.

Does not affect the WORKSPACE build.

[aaronmondal]

Continuation of https://reviews.llvm.org/D136496

[GMNGeoffrey]

utils/bazel/llvm-project-overlay/clang/BUILD.bazel

731

Oh this is way better. These have always felt like a hack relying on a Bazel implementation detail.

[GMNGeoffrey]

It seems like you're synced to a bad commit that's broken for other reasons. Could you rebase and try the pre-merge checks again?

[aaronmondal]

In D137007#3906800, @GMNGeoffrey wrote:

It seems like you're synced to a bad commit that's broken for other reasons. Could you rebase and try the pre-merge checks again?

Re-ran builds. Seems to work now 😊

[aaronmondal]

Rebase. Let's rerun tests once more to make sure this is fine.

[aaronmondal]

Hahaha reminder to self: I need to of course change the last line in the commit message to "Does not affect the WORKSPACE build" 😂😂

[GMNGeoffrey]

Much nicer, thank you. I thought I'd stamped out all the places where this was hardcoded

[MaskRay]

utils/bazel/llvm-project-overlay/clang/BUILD.bazel

1545

c5f6a287499a816cba5585708999e2c8b134290f fixed an issue due to antique bash on macOS here :)

utils/bazel/llvm-project-overlay/clang/BUILD.bazel

 # This file is licensed under the Apache License v2.0 with LLVM Exceptions.
 # See https://llvm.org/LICENSE.txt for license information.
 # SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
 
 load("@bazel_skylib//rules:expand_template.bzl", "expand_template")
+load("//:workspace_root.bzl", "workspace_root")
 load("//llvm:tblgen.bzl", "gentbl")
 load("//llvm:binary_alias.bzl", "binary_alias")
 load("//llvm:cc_plugin_library.bzl", "cc_plugin_library")
 load(
     "//:vars.bzl",
     "LLVM_VERSION",
     "LLVM_VERSION_MAJOR",
     "LLVM_VERSION_MINOR",
gentbl(
     tblgen = ":clang-tblgen",
     td_file = "include/clang/Basic/TypeNodes.td",
     td_srcs = [
         "include/clang/Basic/ASTNode.td",
         "include/clang/Basic/TypeNodes.td",
     ],
 )
 
+workspace_root(name = "workspace_root")
+
 cc_library(
     name = "ast",
     srcs = glob([
         "lib/AST/*.cpp",
         "lib/AST/*.h",
         "lib/AST/Interp/*.cpp",
         "lib/AST/Interp/*.h",
     ]) + [
         "lib/AST/AttrDocTable.inc",
         "lib/AST/Interp/Opcodes.inc",
     ],
     hdrs = glob([
         "include/clang/AST/*.h",
     ]),
     copts = [
         # FIXME: This is necessary to allow "file relative" include paths from
         # non-generated `srcs` to find generated `srcs` above. Bazel should
         # either make this work automatically by creating a unified tree of
         # `srcs` or at least provide a `local_includes` that has the path
         # translation logic of `includes` but is only used locally (similar to
         # `local_defines` vs. `defines`). Until one of those lands, this is the
         # least bad approach. Using `includes` is *specifically* problematic for
         # this library because it contains files that collide easily with system
         # headers such as `CXXABI.h`.
-        "-I$(GENDIR)/external/llvm-project/clang/lib/AST",
-        "-I$(GENDIR)/external/llvm-project/clang/lib/AST/Interp",
+        "-I$(GENDIR)/$(WORKSPACE_ROOT)/clang/lib/AST",
+        "-I$(GENDIR)/$(WORKSPACE_ROOT)/clang/lib/AST/Interp",
     ],
     textual_hdrs = [
         "include/clang/AST/AttrImpl.inc",
         "include/clang/AST/AttrNodeTraverse.inc",
         "include/clang/AST/Attrs.inc",
         "include/clang/AST/AttrTextNodeDump.inc",
         "include/clang/AST/AttrVisitor.inc",
         "include/clang/AST/CommentCommandInfo.inc",
         "include/clang/AST/CommentCommandList.inc",
         "include/clang/AST/CommentHTMLNamedCharacterReferences.inc",
         "include/clang/AST/CommentHTMLTags.inc",
         "include/clang/AST/CommentHTMLTagsProperties.inc",
         "include/clang/AST/CommentNodes.inc",
         "include/clang/AST/DeclNodes.inc",
         "include/clang/AST/StmtDataCollectors.inc",
         "include/clang/AST/StmtNodes.inc",
     ] + glob([
         "include/clang/AST/*.def",
     ]),
+    toolchains = [
+        ":workspace_root",
+    ],
     deps = [
         ":ast_attr_gen",
         ":ast_comment_command_info_gen",
         ":ast_comment_html_named_character_references_gen",
         ":ast_comment_html_tags_gen",
         ":ast_comment_html_tags_properties_gen",
         ":ast_comment_nodes_gen",
         ":ast_decl_nodes_gen",

 ]
 
 genrule(
     name = "builtin_headers_gen",
     srcs = builtin_headers,
     outs = [hdr.replace("lib/Headers/", "staging/include/") for hdr in builtin_headers],
     cmd = """
        for src in $(SRCS); do
-         relsrc=$${src/*external\\/llvm-project\\/clang\\/lib\\/Headers\\/}
+         relsrc=$${src/*"$(WORKSPACE_ROOT)"\\/clang\\/lib\\/Headers}
          target=$(@D)/staging/include/$$relsrc
          mkdir -p $$(dirname $$target)
          cp $$src $$target
        done""",
     output_to_bindir = 1,
+    toolchains = [
+        ":workspace_root",
+    ],
 )
 
 cc_library(
     name = "frontend",
     srcs = glob([
         "lib/Frontend/*.cpp",
         "lib/Frontend/*.h",
     ]),

utils/bazel/llvm-project-overlay/workspace_root.bzl

+def _workspace_root_impl(ctx):
+    """Dynamically determine the workspace root from the current context.
+
+    The path is made available as a `WORKSPACE_ROOT` environmment variable and
+    may for instance be consumed in the `toolchains` attributes for `cc_library`
+    and `genrule` targets.
+    """
+    return [
+        platform_common.TemplateVariableInfo({
+            "WORKSPACE_ROOT": ctx.label.workspace_root,
+        }),
+    ]
+
+workspace_root = rule(
+    implementation = _workspace_root_impl,
+    attrs = {},
+)