[WebAssembly] Error out for setjmp within catch clause for Wasm SjLj

[aheejin]

Summary

Wasm EH, used with either of Emscripten SjLj or Wasm SjLj, does not
allow setjmp calls to be placed within a catch clause, because we
don't support jumping into a catch block. Emscripten EH does not have
this restriction. But I think this restriction wouldn't prevent most of
use cases. This CL errors out with a clear messsage for this case.

[aheejin]

Remove debug dump line

[dschuff]

Wasm EH, used with either of Emscripten EH or Wasm EH, does not allow
Do you mean "Wasm SjLj?"

[aheejin]

Cosmetic changes in the test

[kripken]

Seems reasonable to me, this restriction doesn't worry me, and great to have a clear error.

[aheejin]

In D118286#3273921, @dschuff wrote:

Wasm EH, used with either of Emscripten EH or Wasm EH, does not allow
Do you mean "Wasm SjLj?"

The main culprit(?) is Wasm EH. This doesn't work for Wasm EH + Emscripten SjLj either. But Wasm EH + Emscripten SjLj, which was never meant to be a final recommended way to use EH + SjLj but was used as an interim step until Wasm SjLj is not done, even has a broader restriction, so using setjmp with try-catch within the same function will fail anyway.

[dschuff]

Mostly I was confused by the fact that it says Wasm EH "used with" either Emscripten EH (which doesn't make sense) or Wasm EH (redundant). But I guess you mean the wasm EH primitive, used to implement C++ EH and setjmp/longjmp?

[dschuff]

The code, test and the behavior LGTM though.

[aheejin]

In D118286#3274131, @dschuff wrote:

Mostly I was confused by the fact that it says Wasm EH "used with" either Emscripten EH (which doesn't make sense) or Wasm EH (redundant). But I guess you mean the wasm EH primitive, used to implement C++ EH and setjmp/longjmp?

Oh sorry, what I meant was "Wasm EH used with either Emscripten SjLj or Wasm SjLj". I fixed the CL description too.

llvm/lib/Target/WebAssembly/WebAssemblyLowerEmscriptenEHSjLj.cpp

bool WebAssemblyLowerEmscriptenEHSjLj::runSjLjOnFunction(Function &F) {
   // Setjmp transformation
   SmallVector<PHINode *, 4> SetjmpRetPHIs;
   Function *SetjmpF = M.getFunction("setjmp");
   for (auto *U : make_early_inc_range(SetjmpF->users())) {
     auto *CB = dyn_cast<CallBase>(U);
     BasicBlock *BB = CB->getParent();
     if (BB->getParent() != &F) // in other function
       continue;
+    if (CB->getOperandBundle(LLVMContext::OB_funclet))
+      report_fatal_error(
+          "setjmp within a catch clause is not supported in Wasm EH");
 
     CallInst *CI = nullptr;
     // setjmp cannot throw. So if it is an invoke, lower it to a call
     if (auto *II = dyn_cast<InvokeInst>(CB))
       CI = llvm::changeToCall(II);
     else
       CI = cast<CallInst>(CB);
 

llvm/test/CodeGen/WebAssembly/wasm-eh-sjlj-setjmp-within-catch.ll

+; RUN: not --crash opt < %s -wasm-lower-em-ehsjlj -wasm-enable-eh -wasm-enable-sjlj -S 2>&1 | FileCheck %s
+
+target datalayout = "e-m:e-p:32:32-i64:64-n32:64-S128"
+target triple = "wasm32-unknown-unknown"
+
+%struct.__jmp_buf_tag = type { [6 x i32], i32, [32 x i32] }
+@_ZTIi = external constant i8*
+
+define void @setjmp_within_catch() personality i8* bitcast (i32 (...)* @__gxx_wasm_personality_v0 to i8*) {
+entry:
+  %buf = alloca [1 x %struct.__jmp_buf_tag], align 16
+  invoke void @foo()
+          to label %try.cont unwind label %catch.dispatch
+
+catch.dispatch:                                   ; preds = %entry
+  %0 = catchswitch within none [label %catch.start] unwind to caller
+
+catch.start:                                      ; preds = %catch.dispatch
+  %1 = catchpad within %0 [i8* bitcast (i8** @_ZTIi to i8*)]
+  %2 = call i8* @llvm.wasm.get.exception(token %1)
+  %3 = call i32 @llvm.wasm.get.ehselector(token %1)
+  %4 = call i32 @llvm.eh.typeid.for(i8* bitcast (i8** @_ZTIi to i8*)) #0
+  %matches = icmp eq i32 %3, %4
+  br i1 %matches, label %catch, label %rethrow
+
+catch:                                            ; preds = %catch.start
+  %5 = call i8* @__cxa_begin_catch(i8* %2) #0 [ "funclet"(token %1) ]
+  %6 = bitcast i8* %5 to i32*
+  %7 = load i32, i32* %6, align 4
+  %arraydecay = getelementptr inbounds [1 x %struct.__jmp_buf_tag], [1 x %struct.__jmp_buf_tag]* %buf, i32 0, i32 0
+; CHECK: LLVM ERROR: setjmp within a catch clause is not supported in Wasm EH
+  %call = invoke i32 @setjmp(%struct.__jmp_buf_tag* noundef %arraydecay) #2 [ "funclet"(token %1) ]
+          to label %invoke.cont1 unwind label %ehcleanup
+
+invoke.cont1:                                     ; preds = %catch
+  call void @__cxa_end_catch() #0 [ "funclet"(token %1) ]
+  catchret from %1 to label %try.cont
+
+rethrow:                                          ; preds = %catch.start
+  call void @llvm.wasm.rethrow() #1 [ "funclet"(token %1) ]
+  unreachable
+
+try.cont:                                         ; preds = %entry, %invoke.cont1
+  ret void
+
+ehcleanup:                                        ; preds = %catch
+  %8 = cleanuppad within %1 []
+  call void @__cxa_end_catch() #0 [ "funclet"(token %8) ]
+  cleanupret from %8 unwind to caller
+}
+
+
+declare void @foo()
+declare i32 @__gxx_wasm_personality_v0(...)
+; Function Attrs: nounwind
+declare i8* @llvm.wasm.get.exception(token) #0
+; Function Attrs: nounwind
+declare i32 @llvm.wasm.get.ehselector(token) #0
+; Function Attrs: nounwind
+declare i32 @llvm.eh.typeid.for(i8*) #0
+; Function Attrs: noreturn
+declare void @llvm.wasm.rethrow() #1
+declare i8* @__cxa_begin_catch(i8*)
+; Function Attrs: returns_twice
+declare i32 @setjmp(%struct.__jmp_buf_tag* noundef) #2
+declare void @__cxa_end_catch()
+
+attributes #0 = { nounwind }
+attributes #1 = { noreturn }
+attributes #2 = { returns_twice }