Renames google_benchmark BUILD files to BUILD.bazel.

[ldionne]

Just curious -- why is that needed? Is it not possible to make this change upstream? Otherwise, we'll have to do the same thing again when we update Google Benchmark next.

[bgraur]

In D105887#2874000, @ldionne wrote:

Just curious -- why is that needed? Is it not possible to make this change upstream? Otherwise, we'll have to do the same thing again when we update Google Benchmark next.

All bazel build files in LLVM have the ".bazel" suffix. It would be nice to keep this consistent.
I've spoken with the the Google benchmark maintainer to also update that repository -- they're looking into it.

[lebedev.ri]

This review seems to be stuck/dead, consider abandoning if no longer relevant.

[ldionne]

[Github PR transition cleanup]

We should do this by updating GoogleBenchmark to the latest upstream version -- we should not make changes to our downstream copy of it since it means we'll basically fork that third-party library.

Commandeering to close.

libcxx/utils/google-benchmark/bindings/python/BUILD.bazel

 exports_files(glob(["*.BUILD"]))
 exports_files(["build_defs.bzl"])
 

libcxx/utils/google-benchmark/bindings/python/google_benchmark/BUILD.bazel

 load("//bindings/python:build_defs.bzl", "py_extension")
 
 py_library(
     name = "google_benchmark",
     srcs = ["__init__.py"],
     visibility = ["//visibility:public"],
     deps = [
         ":_benchmark",
         # pip; absl:app
     ],
 )
 
 py_extension(
     name = "_benchmark",
     srcs = ["benchmark.cc"],
     copts = [
         "-fexceptions",
         "-fno-strict-aliasing",
     ],
     features = ["-use_header_modules"],
     deps = [
         "//:benchmark",
         "@pybind11",
         "@python_headers",
     ],
 )
 
 py_test(
     name = "example",
     srcs = ["example.py"],
     python_version = "PY3",
     srcs_version = "PY3",
     visibility = ["//visibility:public"],
     deps = [
         ":google_benchmark",
     ],
 )
 

libcxx/utils/google-benchmark/test/BUILD.bazel

 TEST_COPTS = [
     "-pedantic",
     "-pedantic-errors",
     "-std=c++11",
     "-Wall",
     "-Wextra",
     "-Wshadow",
     #    "-Wshorten-64-to-32",
     "-Wfloat-equal",
     "-fstrict-aliasing",
 ]
 
 PER_SRC_COPTS = ({
     "cxx03_test.cc": ["-std=c++03"],
     # Some of the issues with DoNotOptimize only occur when optimization is enabled
     "donotoptimize_test.cc": ["-O3"],
 })
 
 TEST_ARGS = ["--benchmark_min_time=0.01"]
 
 PER_SRC_TEST_ARGS = ({
     "user_counters_tabular_test.cc": ["--benchmark_counters_tabular=true"],
     "repetitions_test.cc": [" --benchmark_repetitions=3"],
 })
 
 load("@rules_cc//cc:defs.bzl", "cc_library", "cc_test")
 
 cc_library(
     name = "output_test_helper",
     testonly = 1,
     srcs = ["output_test_helper.cc"],
     hdrs = ["output_test.h"],
     copts = TEST_COPTS,
     deps = [
         "//:benchmark",
         "//:benchmark_internal_headers",
     ],
 )
 
 [
     cc_test(
         name = test_src[:-len(".cc")],
         size = "small",
         srcs = [test_src],
         args = TEST_ARGS + PER_SRC_TEST_ARGS.get(test_src, []),
         copts = TEST_COPTS + PER_SRC_COPTS.get(test_src, []),
         deps = [
             ":output_test_helper",
             "//:benchmark",
             "//:benchmark_internal_headers",
             "@com_google_googletest//:gtest",
         ] + (
             ["@com_google_googletest//:gtest_main"] if (test_src[-len("gtest.cc"):] == "gtest.cc") else []
         ),
         # FIXME: Add support for assembly tests to bazel.
         # See Issue #556
         # https://github.com/google/benchmark/issues/556
     )
     for test_src in glob(
         ["*test.cc"],
         exclude = [
             "*_assembly_test.cc",
             "link_main_test.cc",
         ],
     )
 ]
 
 cc_test(
     name = "link_main_test",
     size = "small",
     srcs = ["link_main_test.cc"],
     copts = TEST_COPTS,
     deps = ["//:benchmark_main"],
 )