[xray] Preserve x8 in trampoline on AArch64

[ianlevesque]

Summary

Fixes an ABI violation in the trampoline code for AArch64 that causes the indirect result register to get overwritten if the XRay handler function is complex enough to use it.

[dberris]

I'm not well versed in AArch64 assembler here, so I'll defer to @MaskRay who has more knowledge in this area.

[MaskRay]

I am also trying to make myself more familiar with AArch64.... I think this is correct. From Procedure Call Standard for the Arm 64-bit Architecture, Result Return

Otherwise, the caller shall reserve a block of memory of sufficient size and alignment to hold the result. The address of the memory block shall be passed as an additional argument to the function in x8. The callee may modify the result memory block at any point during the execution of the subroutine (there is no requirement for the callee to preserve the value stored in x8).

compiler-rt/lib/xray/xray_trampoline_AArch64.S

__xray_FunctionEntry:
     STP X1, X2, [SP, #-16]!
     STP X3, X4, [SP, #-16]!
     STP X5, X6, [SP, #-16]!
     STP X7, X30, [SP, #-16]!
     STP Q0, Q1, [SP, #-32]!
     STP Q2, Q3, [SP, #-32]!
     STP Q4, Q5, [SP, #-32]!
     STP Q6, Q7, [SP, #-32]!
+    /* X8 is the indirect result register and needs to be preserved for the body
+     of the function to use */
+    STP X8, X0, [SP, #-16]!
+
     /* Load the page address of _ZN6__xray19XRayPatchedFunctionE into X1 */
     ADRP X1, _ZN6__xray19XRayPatchedFunctionE
     /* Load the handler function pointer into X2 */
     LDR X2, [X1, #:lo12:_ZN6__xray19XRayPatchedFunctionE]
     /* Handler address is nullptr if handler is not set */
     CMP X2, #0
     BEQ FunctionEntry_restore
     /* Function ID is already in W0 (the first parameter).
          X1=0 means that we are tracing an entry event */
     MOV X1, #0
     /* Call the handler with 2 parameters in W0 and X1 */
     BLR X2
 FunctionEntry_restore:
     /* Pop the saved registers */
+    LDP X8, X0, [SP], #16
     LDP Q6, Q7, [SP], #32
     LDP Q4, Q5, [SP], #32
     LDP Q2, Q3, [SP], #32
     LDP Q0, Q1, [SP], #32
     LDP X7, X30, [SP], #16
     LDP X5, X6, [SP], #16
     LDP X3, X4, [SP], #16
     LDP X1, X2, [SP], #16
/* Move the return address beyond the end of sled data. The 12 bytes of
          bits of instrumented function ID and 64 bits of the address of
          the current trampoline. */
     ADD X30, X30, #12
     /* Push the registers which may be modified by the handler function */
     STP X1, X2, [SP, #-16]!
     STP X3, X4, [SP, #-16]!
     STP X5, X6, [SP, #-16]!
     STP X7, X30, [SP, #-16]!
-    STR Q0, [SP, #-16]!
+    STP Q0, Q1, [SP, #-32]!
+    STP Q2, Q3, [SP, #-32]!
+    STP Q4, Q5, [SP, #-32]!
+    STP Q6, Q7, [SP, #-32]!
+    /* X8 is the indirect result register and needs to be preserved for the body
+     of the function to use */
+    STP X8, X0, [SP, #-16]!
+
     /* Load the page address of _ZN6__xray19XRayPatchedFunctionE into X1 */
     ADRP X1, _ZN6__xray19XRayPatchedFunctionE
     /* Load the handler function pointer into X2 */
     LDR X2, [X1, #:lo12:_ZN6__xray19XRayPatchedFunctionE]
     /* Handler address is nullptr if handler is not set */
     CMP X2, #0
     BEQ FunctionExit_restore
     /* Function ID is already in W0 (the first parameter).
          X1=1 means that we are tracing an exit event */
     MOV X1, #1
     /* Call the handler with 2 parameters in W0 and X1 */
     BLR X2
 FunctionExit_restore:
-    LDR Q0, [SP], #16
+    LDP X8, X0, [SP], #16
+    LDP Q6, Q7, [SP], #32
+    LDP Q4, Q5, [SP], #32
+    LDP Q2, Q3, [SP], #32
+    LDP Q0, Q1, [SP], #32
     LDP X7, X30, [SP], #16
     LDP X5, X6, [SP], #16
     LDP X3, X4, [SP], #16
     LDP X1, X2, [SP], #16
     RET
 
     /* Word-aligned function entry point */
     .p2align 2