[InstCombine] Fold sub (or A, B) (and A, B) to (xor A, B)

[xbolva00]

Summary

Name: sub or and to xor
%or = or i32 %y, %x
%and = and i32 %x, %y
%sub = sub i32 %or, %and
  =>
%sub = xor i32 %x, %y

Optimization: sub or and to xor
Done: 1
Optimization is correct!

https://rise4fun.com/Alive/eJu

[lebedev.ri]

LG.
There's also sub(and(x, y), or(x, y)) -> neg(xor(x, y))
https://rise4fun.com/Alive/VI6
https://godbolt.org/z/OMu71B

/home/xbolva00/LLVM/llvm/lib/Transforms/InstCombine/InstCombineAddSub.cpp

1724 ↗

(On Diff #218643)

extra unneeded braces

test/Transforms/InstCombine/sub-or-and-xor.ll

69–78

Precommit.

[xbolva00]

Rebased, fixed braces

[xbolva00]

Thanks!

There's also sub(and(x, y), or(x, y)) -> neg(xor(x, y))

Ok, I will prepare a patch soon.

[xbolva00]

And also
sub(xor(x, y), or(x, y)) -> neg(and(x, y))

https://rise4fun.com/Alive/8OI

lib/Transforms/InstCombine/InstCombineAddSub.cpp

if (match(Op0, m_APInt(Op0C))) {
     if (match(Op1, m_c_Add(m_Specific(Op0), m_Value(Y))))
       return BinaryOperator::CreateNeg(Y);
 
     // (X-Y)-X == -Y
     if (match(Op0, m_Sub(m_Specific(Op1), m_Value(Y))))
       return BinaryOperator::CreateNeg(Y);
   }
 
+  // (sub (or A, B) (and A, B)) --> (xor A, B)
+  {
+    Value *A, *B;
+    if (match(Op1, m_And(m_Value(A), m_Value(B))) &&
+        match(Op0, m_c_Or(m_Specific(A), m_Specific(B))))
+      return BinaryOperator::CreateXor(A, B);
+  }
+
   // (sub (or A, B), (xor A, B)) --> (and A, B)
   {
     Value *A, *B;
     if (match(Op1, m_Xor(m_Value(A), m_Value(B))) &&
         match(Op0, m_c_Or(m_Specific(A), m_Specific(B))))
       return BinaryOperator::CreateAnd(A, B);
   }
 

test/Transforms/InstCombine/sub-or-and-xor.ll

 ; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
 ; RUN: opt -instcombine -S < %s | FileCheck %s
 
 declare void @use(i32)
 
 define i32 @sub_to_xor(i32 %x, i32 %y) {
 ; CHECK-LABEL: @sub_to_xor(
-; CHECK-NEXT:    [[OR:%.*]] = or i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT:    [[AND:%.*]] = and i32 [[X]], [[Y]]
-; CHECK-NEXT:    [[SUB:%.*]] = sub i32 [[OR]], [[AND]]
+; CHECK-NEXT:    [[SUB:%.*]] = xor i32 [[X:%.*]], [[Y:%.*]]
 ; CHECK-NEXT:    ret i32 [[SUB]]
 ;
   %or = or i32 %x, %y
   %and = and i32 %x, %y
   %sub = sub i32 %or, %and
   ret i32 %sub
 }
 
 define i32 @sub_to_xor_extra_use_sub(i32 %x, i32 %y) {
 ; CHECK-LABEL: @sub_to_xor_extra_use_sub(
-; CHECK-NEXT:    [[OR:%.*]] = or i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT:    [[AND:%.*]] = and i32 [[X]], [[Y]]
-; CHECK-NEXT:    [[SUB:%.*]] = sub i32 [[OR]], [[AND]]
+; CHECK-NEXT:    [[SUB:%.*]] = xor i32 [[X:%.*]], [[Y:%.*]]
 ; CHECK-NEXT:    call void @use(i32 [[SUB]])
 ; CHECK-NEXT:    ret i32 [[SUB]]
 ;
   %or = or i32 %x, %y
   %and = and i32 %x, %y
   %sub = sub i32 %or, %and
   call void @use(i32 %sub)
   ret i32 %sub
 }
 
 define i32 @sub_to_xor_extra_use_and(i32 %x, i32 %y) {
 ; CHECK-LABEL: @sub_to_xor_extra_use_and(
-; CHECK-NEXT:    [[OR:%.*]] = or i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT:    [[AND:%.*]] = and i32 [[X]], [[Y]]
+; CHECK-NEXT:    [[AND:%.*]] = and i32 [[X:%.*]], [[Y:%.*]]
 ; CHECK-NEXT:    call void @use(i32 [[AND]])
-; CHECK-NEXT:    [[SUB:%.*]] = sub i32 [[OR]], [[AND]]
+; CHECK-NEXT:    [[SUB:%.*]] = xor i32 [[X]], [[Y]]
 ; CHECK-NEXT:    ret i32 [[SUB]]
 ;
   %or = or i32 %x, %y
   %and = and i32 %x, %y
   call void @use(i32 %and)
   %sub = sub i32 %or, %and
   ret i32 %sub
 }
 
 define i32 @sub_to_xor_extra_use_or(i32 %x, i32 %y) {
 ; CHECK-LABEL: @sub_to_xor_extra_use_or(
 ; CHECK-NEXT:    [[OR:%.*]] = or i32 [[X:%.*]], [[Y:%.*]]
 ; CHECK-NEXT:    call void @use(i32 [[OR]])
-; CHECK-NEXT:    [[AND:%.*]] = and i32 [[X]], [[Y]]
-; CHECK-NEXT:    [[SUB:%.*]] = sub i32 [[OR]], [[AND]]
+; CHECK-NEXT:    [[SUB:%.*]] = xor i32 [[X]], [[Y]]
 ; CHECK-NEXT:    ret i32 [[SUB]]
 ;
   %or = or i32 %x, %y
   call void @use(i32 %or)
   %and = and i32 %x, %y
   %sub = sub i32 %or, %and
   ret i32 %sub
 }
 
 define i32 @sub_to_xor_or_commuted(i32 %x, i32 %y) {
 ; CHECK-LABEL: @sub_to_xor_or_commuted(
-; CHECK-NEXT:    [[OR:%.*]] = or i32 [[Y:%.*]], [[X:%.*]]
-; CHECK-NEXT:    [[AND:%.*]] = and i32 [[X]], [[Y]]
-; CHECK-NEXT:    [[SUB:%.*]] = sub i32 [[OR]], [[AND]]
+; CHECK-NEXT:    [[SUB:%.*]] = xor i32 [[X:%.*]], [[Y:%.*]]
 ; CHECK-NEXT:    ret i32 [[SUB]]
 ;
   %or = or i32 %y, %x
   %and = and i32 %x, %y
   %sub = sub i32 %or, %and
   ret i32 %sub
 }
 
 define i32 @sub_to_xor_and_commuted(i32 %x, i32 %y) {
 ; CHECK-LABEL: @sub_to_xor_and_commuted(
-; CHECK-NEXT:    [[OR:%.*]] = or i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT:    [[AND:%.*]] = and i32 [[Y]], [[X]]
-; CHECK-NEXT:    [[SUB:%.*]] = sub i32 [[OR]], [[AND]]
+; CHECK-NEXT:    [[SUB:%.*]] = xor i32 [[Y:%.*]], [[X:%.*]]
 ; CHECK-NEXT:    ret i32 [[SUB]]
 ;
   %or = or i32 %x, %y
   %and = and i32 %y, %x
   %sub = sub i32 %or, %and
   ret i32 %sub
 }
 
 define <2 x i32> @sub_to_xor_vec(<2 x i32> %x, <2 x i32> %y) {
 ; CHECK-LABEL: @sub_to_xor_vec(
-; CHECK-NEXT:    [[OR:%.*]] = or <2 x i32> [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT:    [[AND:%.*]] = and <2 x i32> [[Y]], [[X]]
-; CHECK-NEXT:    [[SUB:%.*]] = sub <2 x i32> [[OR]], [[AND]]
+; CHECK-NEXT:    [[SUB:%.*]] = xor <2 x i32> [[Y:%.*]], [[X:%.*]]
 ; CHECK-NEXT:    ret <2 x i32> [[SUB]]
 ;
   %or = or <2 x i32> %x, %y
   %and = and <2 x i32> %y, %x
   %sub = sub <2 x i32> %or, %and
   ret <2 x i32> %sub
 }