gn build: add Hexagon target

[thakis]

Like with the Lanai target: lgtm with the usual two comments (1. https://reviews.llvm.org/D61859 treatment for MCTargetDesc; 2. Consider omitting unused llvm_build_Hexago variable)

Thanks!

[dlj]

In D61819#1500150, @thakis wrote:

Like with the Lanai target: lgtm with the usual two comments (1. https://reviews.llvm.org/D61859 treatment for MCTargetDesc;

Done, to satisfy:

llvm/lib/Target/Hexagon/HexagonInstrInfo.h:#include "HexagonGenInstrInfo.inc"
llvm/lib/Target/Hexagon/HexagonISelDAGToDAG.h: #include "HexagonGenDAGISel.inc"
llvm/lib/Target/Hexagon/HexagonRegisterInfo.h:#include "HexagonGenRegisterInfo.inc"
llvm/lib/Target/Hexagon/HexagonSubtarget.h:#include "HexagonGenSubtargetInfo.inc"
llvm/lib/Target/Hexagon/MCTargetDesc/HexagonMCTargetDesc.h:#include "HexagonGenRegisterInfo.inc"
llvm/lib/Target/Hexagon/MCTargetDesc/HexagonMCTargetDesc.h:#include "HexagonGenInstrInfo.inc"
llvm/lib/Target/Hexagon/MCTargetDesc/HexagonMCTargetDesc.h:#include "HexagonGenSubtargetInfo.inc"

2. Consider omitting unused llvm_build_Hexago variable)

Done.

llvm/trunk/utils/gn/secondary/llvm/lib/Target/Hexagon/AsmParser/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("HexagonGenAsmMatcher") {
+  visibility = [ ":AsmParser" ]
+  args = [ "-gen-asm-matcher" ]
+  td_file = "../Hexagon.td"
+}
+
+static_library("AsmParser") {
+  output_name = "LLVMHexagonAsmParser"
+  deps = [
+    ":HexagonGenAsmMatcher",
+    "//llvm/lib/MC",
+    "//llvm/lib/MC/MCParser",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/Hexagon/MCTargetDesc",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "HexagonAsmParser.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/Hexagon/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("HexagonGenCallingConv") {
+  visibility = [ ":LLVMHexagonCodeGen" ]
+  args = [ "-gen-callingconv" ]
+  td_file = "Hexagon.td"
+}
+
+tablegen("HexagonGenDAGISel") {
+  visibility = [ ":LLVMHexagonCodeGen" ]
+  args = [ "-gen-dag-isel" ]
+  td_file = "Hexagon.td"
+}
+
+tablegen("HexagonGenDFAPacketizer") {
+  visibility = [ ":LLVMHexagonCodeGen" ]
+  args = [ "-gen-dfa-packetizer" ]
+  td_file = "Hexagon.td"
+}
+
+static_library("LLVMHexagonCodeGen") {
+  deps = [
+    ":HexagonGenCallingConv",
+    ":HexagonGenDAGISel",
+    ":HexagonGenDFAPacketizer",
+    "MCTargetDesc",
+    "TargetInfo",
+    "//llvm/include/llvm/Config:llvm-config",
+    "//llvm/lib/Analysis",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/CodeGen/AsmPrinter",
+    "//llvm/lib/CodeGen/SelectionDAG",
+    "//llvm/lib/IR",
+    "//llvm/lib/MC",
+    "//llvm/lib/Passes",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+    "//llvm/lib/Transforms/Utils",
+  ]
+  include_dirs = [ "." ]
+  sources = [
+    "BitTracker.cpp",
+    "HexagonAsmPrinter.cpp",
+    "HexagonBitSimplify.cpp",
+    "HexagonBitTracker.cpp",
+    "HexagonBlockRanges.cpp",
+    "HexagonBranchRelaxation.cpp",
+    "HexagonCFGOptimizer.cpp",
+    "HexagonCommonGEP.cpp",
+    "HexagonConstExtenders.cpp",
+    "HexagonConstPropagation.cpp",
+    "HexagonCopyToCombine.cpp",
+    "HexagonEarlyIfConv.cpp",
+    "HexagonExpandCondsets.cpp",
+    "HexagonFixupHwLoops.cpp",
+    "HexagonFrameLowering.cpp",
+    "HexagonGenExtract.cpp",
+    "HexagonGenInsert.cpp",
+    "HexagonGenMux.cpp",
+    "HexagonGenPredicate.cpp",
+    "HexagonHardwareLoops.cpp",
+    "HexagonHazardRecognizer.cpp",
+    "HexagonInstrInfo.cpp",
+    "HexagonISelDAGToDAG.cpp",
+    "HexagonISelDAGToDAGHVX.cpp",
+    "HexagonISelLowering.cpp",
+    "HexagonISelLoweringHVX.cpp",
+    "HexagonLoopIdiomRecognition.cpp",
+    "HexagonMachineFunctionInfo.cpp",
+    "HexagonMachineScheduler.cpp",
+    "HexagonMCInstLower.cpp",
+    "HexagonNewValueJump.cpp",
+    "HexagonOptAddrMode.cpp",
+    "HexagonOptimizeSZextends.cpp",
+    "HexagonPeephole.cpp",
+    "HexagonRDFOpt.cpp",
+    "HexagonRegisterInfo.cpp",
+    "HexagonSelectionDAGInfo.cpp",
+    "HexagonSplitConst32AndConst64.cpp",
+    "HexagonSplitDouble.cpp",
+    "HexagonStoreWidening.cpp",
+    "HexagonSubtarget.cpp",
+    "HexagonTargetMachine.cpp",
+    "HexagonTargetObjectFile.cpp",
+    "HexagonTargetTransformInfo.cpp",
+    "HexagonVectorLoopCarriedReuse.cpp",
+    "HexagonVectorPrint.cpp",
+    "HexagonVExtract.cpp",
+    "HexagonVLIWPacketizer.cpp",
+    "RDFCopy.cpp",
+    "RDFDeadCode.cpp",
+    "RDFGraph.cpp",
+    "RDFLiveness.cpp",
+    "RDFRegisters.cpp",
+  ]
+}
+
+# This is a bit different from most build files: Due to this group
+# having the directory's name, "//llvm/lib/Target/Hexagon" will refer to this
+# target, which pulls in the code in this directory *and all subdirectories*.
+# For most other directories, "//llvm/lib/Foo" only pulls in the code directly
+# in "llvm/lib/Foo". The forwarding targets in //llvm/lib/Target expect this
+# different behavior.
+group("Hexagon") {
+  deps = [
+    ":LLVMHexagonCodeGen",
+    "AsmParser",
+    "Disassembler",
+    "MCTargetDesc",
+    "TargetInfo",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/Hexagon/Disassembler/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("HexagonGenDisassemblerTables") {
+  visibility = [ ":Disassembler" ]
+  args = [ "-gen-disassembler" ]
+  td_file = "../Hexagon.td"
+}
+
+static_library("Disassembler") {
+  output_name = "LLVMHexagonDisassembler"
+  deps = [
+    ":HexagonGenDisassemblerTables",
+    "//llvm/lib/MC/MCDisassembler",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/Hexagon/MCTargetDesc",
+    "//llvm/lib/Target/Hexagon/TargetInfo",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "HexagonDisassembler.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/Hexagon/MCTargetDesc/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("HexagonGenAsmWriter") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-asm-writer" ]
+  td_file = "../Hexagon.td"
+}
+
+tablegen("HexagonGenInstrInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-instr-info" ]
+  td_file = "../Hexagon.td"
+}
+
+tablegen("HexagonGenMCCodeEmitter") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-emitter" ]
+  td_file = "../Hexagon.td"
+}
+
+tablegen("HexagonGenRegisterInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-register-info" ]
+  td_file = "../Hexagon.td"
+}
+
+tablegen("HexagonGenSubtargetInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-subtarget" ]
+  td_file = "../Hexagon.td"
+}
+
+group("tablegen") {
+  visibility = [
+    ":MCTargetDesc",
+    "../TargetInfo",
+  ]
+  public_deps = [
+    ":HexagonGenInstrInfo",
+    ":HexagonGenRegisterInfo",
+    ":HexagonGenSubtargetInfo",
+  ]
+}
+
+static_library("MCTargetDesc") {
+  output_name = "LLVMHexagonDesc"
+  public_deps = [
+    ":tablegen",
+  ]
+  deps = [
+    ":HexagonGenAsmWriter",
+    ":HexagonGenMCCodeEmitter",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/Hexagon/TargetInfo",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "HexagonAsmBackend.cpp",
+    "HexagonELFObjectWriter.cpp",
+    "HexagonInstPrinter.cpp",
+    "HexagonMCAsmInfo.cpp",
+    "HexagonMCChecker.cpp",
+    "HexagonMCCodeEmitter.cpp",
+    "HexagonMCCompound.cpp",
+    "HexagonMCDuplexInfo.cpp",
+    "HexagonMCELFStreamer.cpp",
+    "HexagonMCExpr.cpp",
+    "HexagonMCInstrInfo.cpp",
+    "HexagonMCShuffler.cpp",
+    "HexagonMCTargetDesc.cpp",
+    "HexagonShuffler.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/Hexagon/TargetInfo/BUILD.gn

+static_library("TargetInfo") {
+  output_name = "LLVMHexagonInfo"
+  deps = [
+    "//llvm/lib/IR",
+    "//llvm/lib/Support",
+
+    # MCTargetDesc depends on TargetInfo, so we can't depend on the full
+    # MCTargetDesc target here: it would form a cycle.
+    "//llvm/lib/Target/Hexagon/MCTargetDesc:tablegen",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "HexagonTargetInfo.cpp",
+  ]
+}

llvm/trunk/utils/gn/secondary/llvm/lib/Target/targets.gni

if (host_cpu == "arm64") {
     assert(false, "add your host_cpu above")
   }
 } else if (llvm_targets_to_build == "all") {
   # FIXME: Port the remaining targets.
   llvm_targets_to_build = [
     "AArch64",
     "ARM",
     "BPF",
+    "Hexagon",
     "Lanai",
     "PowerPC",
     "Sparc",
     "WebAssembly",
     "X86",
   ]
 }
 
 # Validate that llvm_targets_to_build is set to a list of valid targets,
 # and remember which targets are built.
 llvm_build_AArch64 = false
 llvm_build_ARM = false
 llvm_build_BPF = false
 llvm_build_PowerPC = false
 llvm_build_WebAssembly = false
 llvm_build_X86 = false
 foreach(target, llvm_targets_to_build) {
   if (target == "AArch64") {
     llvm_build_AArch64 = true
   } else if (target == "ARM") {
     llvm_build_ARM = true
   } else if (target == "BPF") {
     llvm_build_BPF = true
+  } else if (target == "Hexagon") {
+    # Nothing to do.
   } else if (target == "Lanai") {
     # Nothing to do.
   } else if (target == "PowerPC") {
     llvm_build_PowerPC = true
   } else if (target == "Sparc") {
     # Nothing to do.
   } else if (target == "WebAssembly") {
     llvm_build_WebAssembly = true