gn build: add Lanai target

[dlj]

Summary

gn build: add Lanai target

[thakis]

lgtm with the usual two comments (1. https://reviews.llvm.org/D61859 treatment for MCTargetDesc; 2. Consider omitting unused llvm_build_Lanai variable)

Thanks!

[dlj]

In D61818#1500147, @thakis wrote:

lgtm with the usual two comments (1. https://reviews.llvm.org/D61859 treatment for MCTargetDesc;

Done. FTR:

llvm/lib/Target/Lanai/LanaiInstrInfo.h:#include "LanaiGenInstrInfo.inc"
llvm/lib/Target/Lanai/LanaiRegisterInfo.h:#include "LanaiGenRegisterInfo.inc"
llvm/lib/Target/Lanai/LanaiSubtarget.h:#include "LanaiGenSubtargetInfo.inc"
llvm/lib/Target/Lanai/MCTargetDesc/LanaiMCTargetDesc.h:#include "LanaiGenRegisterInfo.inc"
llvm/lib/Target/Lanai/MCTargetDesc/LanaiMCTargetDesc.h:#include "LanaiGenInstrInfo.inc"
llvm/lib/Target/Lanai/MCTargetDesc/LanaiMCTargetDesc.h:#include "LanaiGenSubtargetInfo.inc"

This matches the behavior for most other Target libraries in D61859.

2. Consider omitting unused llvm_build_Lanai variable)

Done.

[dlj]

https://reviews.llvm.org/rG500a6db47951521cbe4b3d23976aa4b790085019

llvm/utils/gn/secondary/llvm/lib/Target/Lanai/AsmParser/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("LanaiGenAsmMatcher") {
+  visibility = [ ":AsmParser" ]
+  args = [ "-gen-asm-matcher" ]
+  td_file = "../Lanai.td"
+}
+
+static_library("AsmParser") {
+  output_name = "LLVMLanaiAsmParser"
+  deps = [
+    ":LanaiGenAsmMatcher",
+    "//llvm/lib/MC",
+    "//llvm/lib/MC/MCParser",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/Lanai/MCTargetDesc",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "LanaiAsmParser.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/Lanai/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("LanaiGenCallingConv") {
+  visibility = [ ":LLVMLanaiCodeGen" ]
+  args = [ "-gen-callingconv" ]
+  td_file = "Lanai.td"
+}
+
+tablegen("LanaiGenDAGISel") {
+  visibility = [ ":LLVMLanaiCodeGen" ]
+  args = [ "-gen-dag-isel" ]
+  td_file = "Lanai.td"
+}
+
+static_library("LLVMLanaiCodeGen") {
+  deps = [
+    ":LanaiGenCallingConv",
+    ":LanaiGenDAGISel",
+    "MCTargetDesc",
+    "TargetInfo",
+    "//llvm/include/llvm/Config:llvm-config",
+    "//llvm/lib/Analysis",
+    "//llvm/lib/CodeGen",
+    "//llvm/lib/CodeGen/AsmPrinter",
+    "//llvm/lib/CodeGen/SelectionDAG",
+    "//llvm/lib/IR",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target",
+  ]
+  include_dirs = [ "." ]
+  sources = [
+    "LanaiAsmPrinter.cpp",
+    "LanaiDelaySlotFiller.cpp",
+    "LanaiFrameLowering.cpp",
+    "LanaiInstrInfo.cpp",
+    "LanaiISelDAGToDAG.cpp",
+    "LanaiISelLowering.cpp",
+    "LanaiMachineFunctionInfo.cpp",
+    "LanaiMCInstLower.cpp",
+    "LanaiMemAluCombiner.cpp",
+    "LanaiRegisterInfo.cpp",
+    "LanaiSelectionDAGInfo.cpp",
+    "LanaiSubtarget.cpp",
+    "LanaiTargetMachine.cpp",
+    "LanaiTargetObjectFile.cpp",
+  ]
+}
+
+# This is a bit different from most build files: Due to this group
+# having the directory's name, "//llvm/lib/Target/Lanai" will refer to this
+# target, which pulls in the code in this directory *and all subdirectories*.
+# For most other directories, "//llvm/lib/Foo" only pulls in the code directly
+# in "llvm/lib/Foo". The forwarding targets in //llvm/lib/Target expect this
+# different behavior.
+group("Lanai") {
+  deps = [
+    ":LLVMLanaiCodeGen",
+    "AsmParser",
+    "Disassembler",
+    "MCTargetDesc",
+    "TargetInfo",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/Lanai/Disassembler/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("LanaiGenDisassemblerTables") {
+  visibility = [ ":Disassembler" ]
+  args = [ "-gen-disassembler" ]
+  td_file = "../Lanai.td"
+}
+
+static_library("Disassembler") {
+  output_name = "LLVMLanaiDisassembler"
+  deps = [
+    ":LanaiGenDisassemblerTables",
+    "//llvm/lib/MC/MCDisassembler",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/Lanai/MCTargetDesc",
+    "//llvm/lib/Target/Lanai/TargetInfo",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "LanaiDisassembler.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/Lanai/MCTargetDesc/BUILD.gn

+import("//llvm/utils/TableGen/tablegen.gni")
+
+tablegen("LanaiGenAsmWriter") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-asm-writer" ]
+  td_file = "../Lanai.td"
+}
+
+tablegen("LanaiGenInstrInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-instr-info" ]
+  td_file = "../Lanai.td"
+}
+
+tablegen("LanaiGenMCCodeEmitter") {
+  visibility = [ ":MCTargetDesc" ]
+  args = [ "-gen-emitter" ]
+  td_file = "../Lanai.td"
+}
+
+tablegen("LanaiGenRegisterInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-register-info" ]
+  td_file = "../Lanai.td"
+}
+
+tablegen("LanaiGenSubtargetInfo") {
+  visibility = [ ":tablegen" ]
+  args = [ "-gen-subtarget" ]
+  td_file = "../Lanai.td"
+}
+
+# This should contain tablegen targets generating .inc files included
+# by other targets. .inc files only used by .cpp files in this directory
+# should be in deps on the static_library instead.
+group("tablegen") {
+  visibility = [
+    ":MCTargetDesc",
+    "../TargetInfo",
+  ]
+  public_deps = [
+    ":LanaiGenInstrInfo",
+    ":LanaiGenRegisterInfo",
+    ":LanaiGenSubtargetInfo",
+  ]
+}
+
+static_library("MCTargetDesc") {
+  output_name = "LLVMLanaiDesc"
+  public_deps = [
+    ":tablegen",
+  ]
+  deps = [
+    ":LanaiGenAsmWriter",
+    ":LanaiGenMCCodeEmitter",
+    "//llvm/lib/MC",
+    "//llvm/lib/Support",
+    "//llvm/lib/Target/Lanai/TargetInfo",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "LanaiAsmBackend.cpp",
+    "LanaiELFObjectWriter.cpp",
+    "LanaiInstPrinter.cpp",
+    "LanaiMCAsmInfo.cpp",
+    "LanaiMCCodeEmitter.cpp",
+    "LanaiMCExpr.cpp",
+    "LanaiMCTargetDesc.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/Lanai/TargetInfo/BUILD.gn

+static_library("TargetInfo") {
+  output_name = "LLVMLanaiInfo"
+  deps = [
+    "//llvm/lib/IR",
+    "//llvm/lib/Support",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "LanaiTargetInfo.cpp",
+  ]
+}

llvm/utils/gn/secondary/llvm/lib/Target/targets.gni

if (host_cpu == "arm64") {
     assert(false, "add your host_cpu above")
   }
 } else if (llvm_targets_to_build == "all") {
   # FIXME: Port the remaining targets.
   llvm_targets_to_build = [
     "AArch64",
     "ARM",
     "BPF",
+    "Lanai",
     "PowerPC",
     "WebAssembly",
     "X86",
   ]
 }
 
 # Validate that llvm_targets_to_build is set to a list of valid targets,
 # and remember which targets are built.