gn build: Add build files for some clang-tools-extra

[thakis]

Summary

Adds clang-change-namespace, clang-move, clang-query,
clang-reorder-fields.

[mbonadei]

llvm/utils/gn/secondary/clang-tools-extra/clang-move/BUILD.gn

12

Do we also need "//clang/lib/Serialization" here (https://github.com/llvm/llvm-project/blob/master/clang-tools-extra/clang-move/CMakeLists.txt#L17)?

[thakis]

comments

[thakis]

Thanks!

llvm/utils/gn/secondary/clang-tools-extra/clang-move/BUILD.gn

12

Good catch, done.

In practice it doesn't matter because the tool/ has the dep, but all targets currently try to match the cmake deps (which has them for component builds I think), so I agree this should be here :)

[mbonadei]

LGTM!

clang-tools-extra/clang-query/tool/CMakeLists.txt

 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/..)
 
-add_clang_executable(clang-query ClangQuery.cpp)
+add_clang_executable(clang-query
+  ClangQuery.cpp
+  )
 target_link_libraries(clang-query
   PRIVATE
   clangAST
   clangASTMatchers
   clangBasic
   clangDynamicASTMatchers
   clangFrontend
   clangQuery
   clangSerialization
   clangTooling
   )
 
 install(TARGETS clang-query RUNTIME DESTINATION bin)

clang-tools-extra/clang-reorder-fields/tool/CMakeLists.txt

-add_clang_tool(clang-reorder-fields ClangReorderFields.cpp)
+add_clang_tool(clang-reorder-fields
+  ClangReorderFields.cpp
+  )
 
 target_link_libraries(clang-reorder-fields
   PRIVATE
   clangBasic
   clangFrontend
   clangReorderFields
   clangRewrite
   clangSerialization
   clangTooling
   clangToolingCore
   )

llvm/utils/gn/secondary/BUILD.gn

 import("//clang/lib/ARCMigrate/enable.gni")
 import("//clang/lib/StaticAnalyzer/Frontend/enable.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 group("default") {
   deps = [
     "//clang-tools-extra/clang-apply-replacements/tool:clang-apply-replacements",
+    "//clang-tools-extra/clang-change-namespace/tool:clang-change-namespace",
     "//clang-tools-extra/clang-doc/tool:clang-doc",
+    "//clang-tools-extra/clang-move/tool:clang-move",
+    "//clang-tools-extra/clang-query/tool:clang-query",
+    "//clang-tools-extra/clang-reorder-fields/tool:clang-reorder-fields",
     "//clang-tools-extra/clang-tidy/tool:clang-tidy",
     "//clang/test",
     "//lld/test",
     "//llvm/test",
   ]
   if (current_os == "linux" || current_os == "android") {
     deps += [ "//compiler-rt/test/hwasan" ]
   }

llvm/utils/gn/secondary/clang-tools-extra/clang-change-namespace/BUILD.gn

+static_library("clang-change-namespace") {
+  output_name = "clangChangeNamespace"
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang/lib/AST",
+    "//clang/lib/ASTMatchers",
+    "//clang/lib/Basic",
+    "//clang/lib/Format",
+    "//clang/lib/Frontend",
+    "//clang/lib/Lex",
+    "//clang/lib/Serialization",
+    "//clang/lib/Tooling",
+    "//clang/lib/Tooling/Core",
+    "//llvm/lib/Support",
+  ]
+  sources = [
+    "ChangeNamespace.cpp",
+  ]
+}

llvm/utils/gn/secondary/clang-tools-extra/clang-change-namespace/tool/BUILD.gn

+executable("clang-change-namespace") {
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang-tools-extra/clang-change-namespace",
+    "//clang/lib/AST",
+    "//clang/lib/ASTMatchers",
+    "//clang/lib/Basic",
+    "//clang/lib/Format",
+    "//clang/lib/Frontend",
+    "//clang/lib/Rewrite",
+    "//clang/lib/Serialization",
+    "//clang/lib/Tooling",
+    "//clang/lib/Tooling/Core",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "ClangChangeNamespace.cpp",
+  ]
+}

llvm/utils/gn/secondary/clang-tools-extra/clang-move/BUILD.gn

+static_library("clang-move") {
+  output_name = "clangMove"
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang/lib/AST",
+    "//clang/lib/ASTMatchers",
+    "//clang/lib/Analysis",
+    "//clang/lib/Basic",
+    "//clang/lib/Format",
+    "//clang/lib/Frontend",
+    "//clang/lib/Lex",
+    "//clang/lib/Serialization",
+    "//clang/lib/Tooling",
+    "//clang/lib/Tooling/Core",
+    "//llvm/lib/Support",
+  ]
+  sources = [
+    "ClangMove.cpp",
+    "HelperDeclRefGraph.cpp",
+  ]
+}

llvm/utils/gn/secondary/clang-tools-extra/clang-move/tool/BUILD.gn

+executable("clang-move") {
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang-tools-extra/clang-move",
+    "//clang/lib/AST",
+    "//clang/lib/ASTMatchers",
+    "//clang/lib/Basic",
+    "//clang/lib/Format",
+    "//clang/lib/Frontend",
+    "//clang/lib/Rewrite",
+    "//clang/lib/Serialization",
+    "//clang/lib/Tooling",
+    "//clang/lib/Tooling/Core",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "ClangMoveMain.cpp",
+  ]
+}

llvm/utils/gn/secondary/clang-tools-extra/clang-query/BUILD.gn

+static_library("clang-query") {
+  output_name = "clangQuery"
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang/lib/AST",
+    "//clang/lib/ASTMatchers",
+    "//clang/lib/ASTMatchers/Dynamic",
+    "//clang/lib/Basic",
+    "//clang/lib/Frontend",
+    "//clang/lib/Serialization",
+    "//llvm/lib/LineEditor",
+    "//llvm/lib/Support",
+  ]
+  sources = [
+    "Query.cpp",
+    "QueryParser.cpp",
+  ]
+}

llvm/utils/gn/secondary/clang-tools-extra/clang-query/tool/BUILD.gn

+executable("clang-query") {
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang-tools-extra/clang-query",
+    "//clang/lib/AST",
+    "//clang/lib/ASTMatchers",
+    "//clang/lib/ASTMatchers/Dynamic",
+    "//clang/lib/Basic",
+    "//clang/lib/Frontend",
+    "//clang/lib/Serialization",
+    "//clang/lib/Tooling",
+  ]
+  include_dirs = [ ".." ]
+  sources = [
+    "ClangQuery.cpp",
+  ]
+}

llvm/utils/gn/secondary/clang-tools-extra/clang-reorder-fields/BUILD.gn

+static_library("clang-reorder-fields") {
+  output_name = "clangReorderFields"
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang/lib/AST",
+    "//clang/lib/ASTMatchers",
+    "//clang/lib/Basic",
+    "//clang/lib/Index",
+    "//clang/lib/Lex",
+    "//clang/lib/Serialization",
+    "//clang/lib/Tooling/Core",
+    "//llvm/lib/Support",
+  ]
+  sources = [
+    "ReorderFieldsAction.cpp",
+  ]
+}

llvm/utils/gn/secondary/clang-tools-extra/clang-reorder-fields/tool/BUILD.gn

+executable("clang-reorder-fields") {
+  configs += [ "//llvm/utils/gn/build:clang_code" ]
+  deps = [
+    "//clang-tools-extra/clang-reorder-fields",
+    "//clang/lib/Basic",
+    "//clang/lib/Frontend",
+    "//clang/lib/Rewrite",
+    "//clang/lib/Serialization",
+    "//clang/lib/Tooling",
+    "//clang/lib/Tooling/Core",
+  ]
+  sources = [
+    "ClangReorderFields.cpp",
+  ]
+}