gn build: Move target flags from toolchain to a .gni file.

[pcc]

Summary

While here, add a use_lld flag and default it to true when using
clang on non-mac.

[thakis]

I think it might make sense to pretty soon add build/{android,...}/BUILD.gn that defines a build/{android,...}_compiler config that's added to the config list soon, instead of expanding this duplicate way to define compiler flags.

[pcc]

In D56710#1357780, @thakis wrote:

I think it might make sense to pretty soon add build/{android,...}/BUILD.gn that defines a build/{android,...}_compiler config that's added to the config list soon, instead of expanding this duplicate way to define compiler flags.

Unfortunately it does seem like necessary duplication (per D56713).

llvm/trunk/utils/gn/build/BUILD.gn

 import("//llvm/utils/gn/build/buildflags.gni")
 import("//llvm/utils/gn/build/mac_sdk.gni")
 import("//llvm/utils/gn/build/toolchain/compiler.gni")
+import("//llvm/utils/gn/build/toolchain/target_flags.gni")
 
 config("compiler_defaults") {
   defines = []
 
   if (!llvm_enable_assertions) {
     defines += [ "NDEBUG" ]
   }
 
-  cflags = []
+  cflags = target_flags + target_cflags
+  ldflags = target_flags + target_ldflags
 
   if (host_os == "mac" && clang_base_path != "") {
     cflags += [
       "-isysroot",
       mac_sdk_path,
     ]
   }
 
if (is_clang) {
       cflags += [ "-Wdelete-non-virtual-dtor" ]
     }
     if (is_clang && use_goma) {
       # goma converts all paths to lowercase on the server, breaking this
       # warning.
       cflags += [ "-Wno-nonportable-include-path" ]
     }
   }
+
+  if (use_lld) {
+    ldflags += [ "-fuse-ld=lld" ]
+  }
 }
 
 config("no_rtti") {
   if (current_os == "win") {
     cflags_cc = [ "/GR-" ]
   } else {
     cflags_cc = [ "-fno-rtti" ]
   }

llvm/trunk/utils/gn/build/toolchain/BUILD.gn

 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 declare_args() {
   # If is_goma is true, the location of the goma client install.
   if (host_os == "win") {
     goma_dir = "c:\src\goma\goma-win64"
   } else {
     goma_dir = getenv("HOME") + "/goma"
   }
 }
 
 template("unix_toolchain") {
   toolchain(target_name) {
     forward_variables_from(invoker, "*")
-    if (!defined(target_cflags)) {
-      target_cflags = ""
-    }
-    if (!defined(target_ldflags)) {
-      target_ldflags = ""
-    }
 
     tool("cc") {
       depfile = "{{output}}.d"
-      command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} $target_cflags"
+      command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}}"
       depsformat = "gcc"
       description = "CC {{output}}"
       outputs = [
         "{{source_out_dir}}/{{target_output_name}}.{{source_name_part}}.o",
       ]
     }
 
     tool("cxx") {
       depfile = "{{output}}.d"
-      command = "$cxx -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} $target_cflags"
+      command = "$cxx -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}}"
       depsformat = "gcc"
       description = "CXX {{output}}"
       outputs = [
         "{{source_out_dir}}/{{target_output_name}}.{{source_name_part}}.o",
       ]
     }
 
     tool("asm") {
       depfile = "{{output}}.d"
-      command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{asmflags}} $target_cflags"
+      command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{asmflags}}"
       depsformat = "gcc"
       description = "ASM {{output}}"
       outputs = [
         "{{source_out_dir}}/{{target_output_name}}.{{source_name_part}}.o",
       ]
     }
 
     tool("alink") {
tool("alink") {
       ]
       output_prefix = "lib"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("solink") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       if (current_os == "mac") {
-        command = "$ld -shared {{ldflags}} -o $outfile {{libs}} {{inputs}} $target_ldflags"
+        command = "$ld -shared {{ldflags}} -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".dylib"
       } else {
-        command = "$ld -shared {{ldflags}} -Wl,-z,defs -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{libs}} {{inputs}} $target_ldflags"
+        command = "$ld -shared {{ldflags}} -Wl,-z,defs -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".so"
       }
       description = "SOLINK $outfile"
       outputs = [
         outfile,
       ]
       lib_switch = "-l"
       output_prefix = "lib"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("solink_module") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       if (current_os == "mac") {
-        command = "$ld -shared {{ldflags}} -Wl,-flat_namespace -Wl,-undefined,suppress -o $outfile {{libs}} {{inputs}} $target_ldflags"
+        command = "$ld -shared {{ldflags}} -Wl,-flat_namespace -Wl,-undefined,suppress -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".dylib"
       } else {
-        command = "$ld -shared {{ldflags}} -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{libs}} {{inputs}} $target_ldflags"
+        command = "$ld -shared {{ldflags}} -Wl,-soname,{{target_output_name}}{{output_extension}} -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".so"
       }
       description = "SOLINK $outfile"
       outputs = [
         outfile,
       ]
       lib_switch = "-l"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("link") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
       if (current_os == "mac") {
-        command =
-            "$ld {{ldflags}} -o $outfile {{libs}} {{inputs}} $target_ldflags"
+        command = "$ld {{ldflags}} -o $outfile {{libs}} {{inputs}}"
       } else {
-        command = "$ld {{ldflags}} -o $outfile {{libs}} -Wl,--start-group {{inputs}} -Wl,--end-group $target_ldflags"
+        command = "$ld {{ldflags}} -o $outfile {{libs}} -Wl,--start-group {{inputs}} -Wl,--end-group"
       }
       description = "LINK $outfile"
       outputs = [
         outfile,
       ]
       lib_switch = "-l"
 
       # Setting this allows targets to override the default executable output by
deps = [
       "//:clang($host_toolchain)",
       "//:lld($host_toolchain)",
       "//:llvm-ar($host_toolchain)",
     ]
 
     toolchain_args = {
       current_os = "android"
       current_cpu = "arm64"
+      use_lld = true
     }
-
-    libcxx_path = "$android_ndk_path/sources/cxx-stl/llvm-libc++"
-    platform_lib_path =
-        "$android_ndk_path/platforms/android-21/arch-arm64/usr/lib"
-    libgcc_path = "$android_ndk_path/toolchains/aarch64-linux-android-4.9/prebuilt/linux-x86_64/lib/gcc/aarch64-linux-android/4.9.x"
-
-    target_flags =
-        "--target=aarch64-linux-android21 --sysroot=$android_ndk_path/sysroot"
-    target_cflags = "$target_flags -isystem $libcxx_path/include"
-    target_ldflags = "$target_flags -fuse-ld=lld -B$platform_lib_path -L$platform_lib_path -L$libgcc_path"
-    target_ldflags +=
-        " -nostdlib++ -L$libcxx_path/libs/arm64-v8a -l:libc++.a.21"
   }
 }
 
 toolchain("win") {
   cl = "cl"
   link = "link"
 
   if (clang_base_path != "") {

llvm/trunk/utils/gn/build/toolchain/compiler.gni

declare_args() {
   # Android will be enabled.
   android_ndk_path = ""
 }
 
 declare_args() {
   # Set if the host compiler is clang.  On by default on Mac or if
   # clang_base_path is set.
   is_clang = host_os == "mac" || clang_base_path != ""
+
+  # Set this to true to link with LLD instead of the default linker.
+  use_lld = clang_base_path != "" && host_os != "mac"
 }

llvm/trunk/utils/gn/build/toolchain/target_flags.gni

+import("//llvm/triples.gni")
+import("//llvm/utils/gn/build/toolchain/compiler.gni")
+
+target_flags = []
+target_cflags = []
+target_ldflags = []
+
+if (current_os == "android") {
+  assert(current_cpu == "arm64", "current_cpu not supported")
+
+  libcxx_path = "$android_ndk_path/sources/cxx-stl/llvm-libc++"
+  platform_lib_path =
+      "$android_ndk_path/platforms/android-21/arch-arm64/usr/lib"
+  libgcc_path = "$android_ndk_path/toolchains/aarch64-linux-android-4.9/prebuilt/linux-x86_64/lib/gcc/aarch64-linux-android/4.9.x"
+
+  target_flags += [
+    "--target=$llvm_current_triple",
+    "--sysroot=$android_ndk_path/sysroot",
+  ]
+  target_cflags += [
+    "-isystem",
+    "$libcxx_path/include",
+  ]
+  target_ldflags += [
+    "-B$platform_lib_path",
+    "-L$platform_lib_path",
+    "-L$libgcc_path",
+  ]
+  target_ldflags += [
+    "-nostdlib++",
+    "-L$libcxx_path/libs/arm64-v8a",
+    "-l:libc++.a.21",
+  ]
+}