gn build: Create a template for unix toolchains.

[thakis]

lgtm!

llvm/utils/gn/build/toolchain/BUILD.gn

37

Please mention the host_os->current_os change in this file in the CL description too.

140

Should we set current_os in the win toolchain too? OK to defer that until we actually need it too, but the failure mode for not having it here and trying to use current_os in a cross build involving a win toolchain is probably a bit confusing unless you know what's needed to fix it.

[pcc]

llvm/utils/gn/build/toolchain/BUILD.gn

140

Makes sense, done.

llvm/utils/gn/build/toolchain/BUILD.gn

 import("//llvm/utils/gn/build/toolchain/compiler.gni")
 
 declare_args() {
   # If is_goma is true, the location of the goma client install.
   if (host_os == "win") {
     goma_dir = "c:\src\goma\goma-win64"
   } else {
     goma_dir = getenv("HOME") + "/goma"
   }
 }
 
-toolchain("unix") {
-  cc = "cc"
-  cxx = "c++"
-
-  if (clang_base_path != "") {
-    cc = "$clang_base_path/bin/clang"
-    cxx = "$clang_base_path/bin/clang++"
-  }
-
-  ld = cxx  # Don't use goma wrapper for linking.
-  if (use_goma) {
-    cc = "$goma_dir/gomacc $cc"
-    cxx = "$goma_dir/gomacc $cxx"
-  }
+template("unix_toolchain") {
+  toolchain(target_name) {
+    forward_variables_from(invoker, "*")
 
     tool("cc") {
       depfile = "{{output}}.d"
       command = "$cc -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}}"
       depsformat = "gcc"
       description = "CC {{output}}"
       outputs = [
         "{{source_out_dir}}/{{target_output_name}}.{{source_name_part}}.o",
       ]
     }
 
     tool("cxx") {
       depfile = "{{output}}.d"
       command = "$cxx -MMD -MF $depfile -o {{output}} -c {{source}} {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}}"
       depsformat = "gcc"
       description = "CXX {{output}}"
       outputs = [
         "{{source_out_dir}}/{{target_output_name}}.{{source_name_part}}.o",
       ]
     }
 
     tool("alink") {
-    if (host_os == "mac") {
+      if (current_os == "mac") {
         command = "libtool -static -no_warning_for_no_symbols {{arflags}} -o {{output}} {{inputs}}"
       } else {
         # Remove the output file first so that ar doesn't try to modify the
         # existing file.
-      command = "rm -f {{output}} && ar rcsDT {{arflags}} {{output}} {{inputs}}"
+        command = "rm -f {{output}} && $ar rcsDT {{arflags}} {{output}} {{inputs}}"
       }
       description = "AR {{output}}"
       outputs = [
         "{{output_dir}}/{{target_output_name}}.a",
       ]
       output_prefix = "lib"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("solink") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
-    if (host_os == "mac") {
+      if (current_os == "mac") {
         command = "$ld -shared {{ldflags}} -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".dylib"
       } else {
         command =
             "$ld -shared {{ldflags}} -Wl,-z,defs -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".so"
       }
       description = "SOLINK $outfile"
       outputs = [
         outfile,
       ]
       lib_switch = "-l"
       output_prefix = "lib"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("solink_module") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
-    if (host_os == "mac") {
+      if (current_os == "mac") {
         command = "$ld -shared {{ldflags}} -Wl,-flat_namespace -Wl,-undefined,suppress -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".dylib"
       } else {
         command = "$ld -shared {{ldflags}} -o $outfile {{libs}} {{inputs}}"
         default_output_extension = ".so"
       }
       description = "SOLINK $outfile"
       outputs = [
         outfile,
       ]
       lib_switch = "-l"
       default_output_dir = "{{root_out_dir}}/lib"
     }
 
     tool("link") {
       outfile = "{{output_dir}}/{{target_output_name}}{{output_extension}}"
-    if (host_os == "mac") {
+      if (current_os == "mac") {
         command = "$ld {{ldflags}} -o $outfile {{libs}} {{inputs}}"
       } else {
         command = "$ld {{ldflags}} -o $outfile {{libs}} -Wl,--start-group {{inputs}} -Wl,--end-group"
       }
       description = "LINK $outfile"
       outputs = [
         outfile,
       ]
       lib_switch = "-l"
 
       # Setting this allows targets to override the default executable output by
       # setting output_dir.
       default_output_dir = "{{root_out_dir}}/bin"
     }
 
     tool("copy") {
       command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
       description = "COPY {{source}} {{output}}"
     }
 
     tool("stamp") {
       command = "touch {{output}}"
       description = "STAMP {{output}}"
     }
   }
+}
+
+unix_toolchain("unix") {
+  cc = "cc"
+  cxx = "c++"
+
+  if (clang_base_path != "") {
+    cc = "$clang_base_path/bin/clang"
+    cxx = "$clang_base_path/bin/clang++"
+  }
+
+  ld = cxx  # Don't use goma wrapper for linking.
+  if (use_goma) {
+    cc = "$goma_dir/gomacc $cc"
+    cxx = "$goma_dir/gomacc $cxx"
+  }
+
+  ar = "ar"
+
+  toolchain_args = {
+    current_os = host_os
+  }
+}
 
 toolchain("win") {
   cl = "cl"
   link = "link"
 
   if (clang_base_path != "") {
     cl = "$clang_base_path/bin/clang-cl"
     link = "$clang_base_path/bin/lld-link"
   }